| 1 | ;;; saveplace.el --- automatically save place in files. |
| 2 | |
| 3 | ;; Copyright (C) 1993, 1994 Free Software Foundation, Inc. |
| 4 | |
| 5 | ;; Author: Karl Fogel <kfogel@cs.oberlin.edu> |
| 6 | ;; Maintainer: FSF |
| 7 | ;; Created: July, 1993 |
| 8 | ;; Keywords: bookmarks, placeholders |
| 9 | |
| 10 | ;; This file is part of GNU Emacs. |
| 11 | |
| 12 | ;; GNU Emacs is free software; you can redistribute it and/or modify |
| 13 | ;; it under the terms of the GNU General Public License as published by |
| 14 | ;; the Free Software Foundation; either version 2, or (at your option) |
| 15 | ;; any later version. |
| 16 | |
| 17 | ;; GNU Emacs is distributed in the hope that it will be useful, |
| 18 | ;; but WITHOUT ANY WARRANTY; without even the implied warranty of |
| 19 | ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the |
| 20 | ;; GNU General Public License for more details. |
| 21 | |
| 22 | ;; You should have received a copy of the GNU General Public License |
| 23 | ;; along with GNU Emacs; see the file COPYING. If not, write to the |
| 24 | ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330, |
| 25 | ;; Boston, MA 02111-1307, USA. |
| 26 | |
| 27 | ;;; Commentary: |
| 28 | |
| 29 | ;; Automatically save place in files, so that visiting them later |
| 30 | ;; (even during a different Emacs session) automatically moves point |
| 31 | ;; to the saved position, when the file is first found. Uses the |
| 32 | ;; value of buffer-local variable save-place to determine whether to |
| 33 | ;; save position or not. |
| 34 | ;; |
| 35 | ;; Thanks to Stefan Schoef, who sent a patch with the |
| 36 | ;; `save-place-version-control' stuff in it. |
| 37 | |
| 38 | ;;; Code: |
| 39 | |
| 40 | ;; this is what I was using during testing: |
| 41 | ;; (define-key ctl-x-map "p" 'toggle-save-place) |
| 42 | |
| 43 | (defgroup save-place nil |
| 44 | "Automatically save place in files." |
| 45 | :group 'data) |
| 46 | |
| 47 | |
| 48 | (defvar save-place-alist nil |
| 49 | "Alist of saved places to go back to when revisiting files. |
| 50 | Each element looks like (FILENAME . POSITION); |
| 51 | visiting file FILENAME goes automatically to position POSITION |
| 52 | rather than the beginning of the buffer. |
| 53 | This alist is saved between Emacs sessions.") |
| 54 | |
| 55 | (defcustom save-place nil |
| 56 | "*Non-nil means automatically save place in each file. |
| 57 | This means when you visit a file, point goes to the last place |
| 58 | where it was when you previously visited the same file. |
| 59 | This variable is automatically buffer-local. |
| 60 | |
| 61 | If you wish your place in any file to always be automatically saved, |
| 62 | simply put this in your `~/.emacs' file: |
| 63 | |
| 64 | \(setq-default save-place t\)" |
| 65 | :type 'boolean |
| 66 | :group 'save-place) |
| 67 | |
| 68 | (make-variable-buffer-local 'save-place) |
| 69 | |
| 70 | (defcustom save-place-file (convert-standard-filename "~/.emacs-places") |
| 71 | "*Name of the file that records `save-place-alist' value." |
| 72 | :type 'file |
| 73 | :group 'save-place) |
| 74 | |
| 75 | (defcustom save-place-version-control nil |
| 76 | "*Controls whether to make numbered backups of master save-place file. |
| 77 | It can have four values: t, nil, `never', and `nospecial'. The first |
| 78 | three have the same meaning that they do for the variable |
| 79 | `version-control', and the final value `nospecial' means just use the |
| 80 | value of `version-control'." |
| 81 | :type '(radio (const :tag "Unconditionally" t) |
| 82 | (const :tag "For VC Files" nil) |
| 83 | (const never) |
| 84 | (const :tag "Use value of `version-control'" nospecial)) |
| 85 | :group 'save-place) |
| 86 | |
| 87 | (defvar save-place-loaded nil |
| 88 | "Non-nil means that the `save-place-file' has been loaded.") |
| 89 | |
| 90 | (defcustom save-place-limit nil |
| 91 | "Maximum number of entries to retain in the list; nil means no limit." |
| 92 | :type '(choice (integer :tag "Entries" :value 1) |
| 93 | (const :tag "No Limit" nil)) |
| 94 | :group 'save-place) |
| 95 | |
| 96 | (defun toggle-save-place (&optional parg) |
| 97 | "Toggle whether to save your place in this file between sessions. |
| 98 | If this mode is enabled, point is recorded when you kill the buffer |
| 99 | or exit Emacs. Visiting this file again will go to that position, |
| 100 | even in a later Emacs session. |
| 101 | |
| 102 | If called with a prefix arg, the mode is enabled if and only if |
| 103 | the argument is positive. |
| 104 | |
| 105 | To save places automatically in all files, put this in your `.emacs' file: |
| 106 | |
| 107 | \(setq-default save-place t\)" |
| 108 | (interactive "P") |
| 109 | (if (not buffer-file-name) |
| 110 | (message "Buffer `%s' not visiting a file" (buffer-name)) |
| 111 | (if (and save-place (or (not parg) (<= parg 0))) |
| 112 | (progn |
| 113 | (message "No place will be saved in this file") |
| 114 | (setq save-place nil)) |
| 115 | (message "Place will be saved") |
| 116 | (setq save-place t)))) |
| 117 | |
| 118 | (defun save-place-to-alist () |
| 119 | ;; put filename and point in a cons box and then cons that onto the |
| 120 | ;; front of the save-place-alist, if save-place is non-nil. |
| 121 | ;; Otherwise, just delete that file from the alist. |
| 122 | ;; first check to make sure alist has been loaded in from the master |
| 123 | ;; file. If not, do so, then feel free to modify the alist. It |
| 124 | ;; will be saved again when Emacs is killed. |
| 125 | (or save-place-loaded (load-save-place-alist-from-file)) |
| 126 | (if buffer-file-name |
| 127 | (progn |
| 128 | (let ((cell (assoc buffer-file-name save-place-alist)) |
| 129 | (position (if (not (eq major-mode 'hexl-mode)) |
| 130 | (point) |
| 131 | (1+ (hexl-current-address))))) |
| 132 | (if cell |
| 133 | (setq save-place-alist (delq cell save-place-alist))) |
| 134 | (if (and save-place |
| 135 | (not (= position 1))) ;; Optimize out the degenerate case. |
| 136 | (setq save-place-alist |
| 137 | (cons (cons buffer-file-name position) |
| 138 | save-place-alist))))))) |
| 139 | |
| 140 | (defun save-place-alist-to-file () |
| 141 | (let ((file (expand-file-name save-place-file))) |
| 142 | (save-excursion |
| 143 | (message "Saving places to %s..." file) |
| 144 | (set-buffer (get-buffer-create " *Saved Places*")) |
| 145 | (delete-region (point-min) (point-max)) |
| 146 | (if (file-readable-p file) |
| 147 | (insert-file-contents file)) |
| 148 | (delete-region (point-min) (point-max)) |
| 149 | (goto-char (point-min)) |
| 150 | (print save-place-alist (current-buffer)) |
| 151 | (let ((version-control |
| 152 | (cond |
| 153 | ((null save-place-version-control) nil) |
| 154 | ((eq 'never save-place-version-control) 'never) |
| 155 | ((eq 'nospecial save-place-version-control) version-control) |
| 156 | (t |
| 157 | t)))) |
| 158 | (write-file file) |
| 159 | (kill-buffer (current-buffer)) |
| 160 | (message "Saving places to %s...done" file))))) |
| 161 | |
| 162 | (defun load-save-place-alist-from-file () |
| 163 | (if (not save-place-loaded) |
| 164 | (progn |
| 165 | (setq save-place-loaded t) |
| 166 | (let ((file (expand-file-name save-place-file))) |
| 167 | ;; make sure that the alist does not get overwritten, and then |
| 168 | ;; load it if it exists: |
| 169 | (if (file-readable-p file) |
| 170 | (save-excursion |
| 171 | (message "Loading places from %s..." save-place-file) |
| 172 | ;; don't want to use find-file because we have been |
| 173 | ;; adding hooks to it. |
| 174 | (set-buffer (get-buffer-create " *Saved Places*")) |
| 175 | (delete-region (point-min) (point-max)) |
| 176 | (insert-file-contents file) |
| 177 | (goto-char (point-min)) |
| 178 | (setq save-place-alist |
| 179 | (car (read-from-string |
| 180 | (buffer-substring (point-min) (point-max))))) |
| 181 | |
| 182 | ;; If there is a limit, and we're over it, then we'll |
| 183 | ;; have to truncate the end of the list: |
| 184 | (if save-place-limit |
| 185 | (if (<= save-place-limit 0) |
| 186 | ;; Zero gets special cased. I'm not thrilled |
| 187 | ;; with this, but the loop for >= 1 is tight. |
| 188 | (setq save-place-alist nil) |
| 189 | ;; Else the limit is >= 1, so enforce it by |
| 190 | ;; counting and then `setcdr'ing. |
| 191 | (let ((s save-place-alist) |
| 192 | (count 1)) |
| 193 | (while s |
| 194 | (if (>= count save-place-limit) |
| 195 | (setcdr s nil) |
| 196 | (setq count (1+ count))) |
| 197 | (setq s (cdr s)))))) |
| 198 | |
| 199 | (kill-buffer (current-buffer)) |
| 200 | (message "Loading places from %s...done" file))) |
| 201 | nil)))) |
| 202 | |
| 203 | (defun save-places-to-alist () |
| 204 | ;; go through buffer-list, saving places to alist if save-place is |
| 205 | ;; non-nil, deleting them from alist if it is nil. |
| 206 | (let ((buf-list (buffer-list))) |
| 207 | (while buf-list |
| 208 | ;; put this into a save-excursion in case someone is counting on |
| 209 | ;; another function in kill-emacs-hook to act on the last buffer |
| 210 | ;; they were in: |
| 211 | (save-excursion |
| 212 | (set-buffer (car buf-list)) |
| 213 | ;; save-place checks buffer-file-name too, but we can avoid |
| 214 | ;; overhead of function call by checking here too. |
| 215 | (and buffer-file-name (save-place-to-alist)) |
| 216 | (setq buf-list (cdr buf-list)))))) |
| 217 | |
| 218 | (defun save-place-find-file-hook () |
| 219 | (or save-place-loaded (load-save-place-alist-from-file)) |
| 220 | (let ((cell (assoc buffer-file-name save-place-alist))) |
| 221 | (if cell |
| 222 | (progn |
| 223 | (or after-find-file-from-revert-buffer |
| 224 | (goto-char (cdr cell))) |
| 225 | ;; and make sure it will be saved again for later |
| 226 | (setq save-place t))))) |
| 227 | |
| 228 | (defun save-place-kill-emacs-hook () |
| 229 | ;; First update the alist. This loads the old save-place-file if nec. |
| 230 | (save-places-to-alist) |
| 231 | ;; Now save the alist in the file, if we have ever loaded the file |
| 232 | ;; (including just now). |
| 233 | (if save-place-loaded |
| 234 | (save-place-alist-to-file))) |
| 235 | |
| 236 | (add-hook 'find-file-hooks 'save-place-find-file-hook t) |
| 237 | |
| 238 | (add-hook 'kill-emacs-hook 'save-place-kill-emacs-hook) |
| 239 | |
| 240 | (add-hook 'kill-buffer-hook 'save-place-to-alist) |
| 241 | |
| 242 | (provide 'saveplace) ; why not... |
| 243 | |
| 244 | ;;; saveplace.el ends here |
| 245 | |