[bpt/emacs.git] / lisp / autoinsert.el

;;; autoinsert.el --- automatic mode-dependent insertion of text into new files

;; Copyright (C) 1985, 86, 87, 94, 95, 98, 2000, 03 Free Software Foundation, Inc.

;; Author: Charlie Martin <crm@cs.duke.edu>
;; Adapted-By: Daniel Pfeiffer <occitan@esperanto.org>
;; Keywords: convenience
;; Maintainer: FSF

;; This file is part of GNU Emacs.

;; GNU Emacs is free software; you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation; either version 2, or (at your option)
;; any later version.

;; GNU Emacs is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License
;; along with GNU Emacs; see the file COPYING.  If not, write to the
;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
;; Boston, MA 02111-1307, USA.

;;; Commentary:

;;  The following defines an association list for text to be
;;  automatically inserted when a new file is created, and a function
;;  which automatically inserts these files; the idea is to insert
;;  default text much as the mode is automatically set using
;;  auto-mode-alist.
;;
;;  To use:
;;     (add-hook 'find-file-hooks 'auto-insert)
;;     setq auto-insert-directory to an appropriate slash-terminated value
;;
;;  You can also customize the variable `auto-insert-mode' to load the
;;  package.  Alternatively, add the following to your .emacs file:
;;  (auto-insert-mode 1)
;;
;;  Author:  Charlie Martin
;;           Department of Computer Science and
;;           National Biomedical Simulation Resource
;;           Box 3709
;;           Duke University Medical Center
;;           Durham, NC 27710
;;	      (crm@cs.duke.edu,mcnc!duke!crm)

;;; Code:

(defgroup auto-insert nil
  "Automatic mode-dependent insertion of text into new files."
  :prefix "auto-insert-"
  :group 'files
  :group 'convenience)


(defcustom auto-insert 'not-modified
  "*Controls automatic insertion into newly found empty files.
Possible values:
	nil	do nothing
	t	insert if possible
	other	insert if possible, but mark as unmodified.
Insertion is possible when something appropriate is found in
`auto-insert-alist'.  When the insertion is marked as unmodified, you can
save it with  \\[write-file] RET.
This variable is used when the function `auto-insert' is called, e.g.
when you do (add-hook 'find-file-hooks 'auto-insert).
With \\[auto-insert], this is always treated as if it were t."
  :type '(choice (const :tag "Insert if possible" t)
                 (const :tag "Do nothing" nil)
                 (other :tag "insert if possible, mark as unmodified."
                        not-modified))
  :group 'auto-insert)

(defcustom auto-insert-query 'function
  "*Non-nil means ask user before auto-inserting.
When this is `function', only ask when called non-interactively."
  :type '(choice (const :tag "Don't ask" nil)
                 (const :tag "Ask if called non-interactively" function)
                 (other :tag "Ask" t))
  :group 'auto-insert)

(defcustom auto-insert-prompt "Perform %s auto-insertion? "
  "*Prompt to use when querying whether to auto-insert.
If this contains a %s, that will be replaced by the matching rule."
  :type 'string
  :group 'auto-insert)


(defcustom auto-insert-alist
  '((("\\.\\([Hh]\\|hh\\|hpp\\)\\'" . "C / C++ header")
     (upcase (concat (file-name-nondirectory
		      (substring buffer-file-name 0 (match-beginning 0)))
		     "_"
		     (substring buffer-file-name (1+ (match-beginning 0)))))
     "#ifndef " str \n
     "#define " str "\n\n"
     _ "\n\n#endif")

    (("\\.\\([Cc]\\|cc\\|cpp\\)\\'" . "C / C++ program")
     nil
     "#include \""
     (let ((stem (file-name-sans-extension buffer-file-name)))
       (cond ((file-exists-p (concat stem ".h"))
	      (file-name-nondirectory (concat stem ".h")))
	     ((file-exists-p (concat stem ".hh"))
	      (file-name-nondirectory (concat stem ".hh")))))
     & ?\" | -10)

    (("[Mm]akefile\\'" . "Makefile") . "makefile.inc")

    (html-mode . (lambda () (sgml-tag "html")))

    (plain-tex-mode . "tex-insert.tex")
    (bibtex-mode . "tex-insert.tex")
    (latex-mode
     ;; should try to offer completing read for these
     "options, RET: "
     "\\documentclass[" str & ?\] | -1
     ?{ (read-string "class: ") "}\n"
     ("package, %s: "
      "\\usepackage[" (read-string "options, RET: ") & ?\] | -1 ?{ str "}\n")
     _ "\n\\begin{document}\n" _
     "\n\\end{document}")

    (("/bin/.*[^/]\\'" . "Shell-Script mode magic number")
     lambda ()
       (if (eq major-mode default-major-mode)
	 (sh-mode)))

    (ada-mode . ada-header)

    (("\\.[1-9]\\'" . "Man page skeleton")
     "Short description: "
     ".\\\" Copyright (C), " (substring (current-time-string) -4) "  "
     (getenv "ORGANIZATION") | "Free Software Foundation, Inc."
     "
.\\\" You may distribute this file under the terms of the GNU Free
.\\\" Documentation Licence.
.TH " (file-name-sans-extension (file-name-nondirectory (buffer-file-name)))
     " " (file-name-extension (buffer-file-name))
     " " (format-time-string "%Y-%m-%d ")
     "\n.SH NAME\n"
     (file-name-sans-extension (file-name-nondirectory (buffer-file-name)))
     " \\- " str
     "\n.SH SYNOPSIS
.B " (file-name-sans-extension (file-name-nondirectory (buffer-file-name)))
     "\n"
     _
     "
.SH DESCRIPTION
.SH OPTIONS
.SH FILES
.SH \"SEE ALSO\"
.SH BUGS
.SH AUTHOR
" (user-full-name)
     '(if (search-backward "&" (line-beginning-position) t)
	  (replace-match (capitalize (user-login-name)) t t))
     '(end-of-line 1) " <" (progn user-mail-address) ">\n")

    (("\\.el\\'" . "Emacs Lisp header")
     "Short description: "
     ";;; " (file-name-nondirectory (buffer-file-name)) " --- " str "

;; Copyright (C) " (substring (current-time-string) -4) "  "
 (getenv "ORGANIZATION") | "Free Software Foundation, Inc." "

;; Author: " (user-full-name)
'(if (search-backward "&" (line-beginning-position) t)
     (replace-match (capitalize (user-login-name)) t t))
'(end-of-line 1) " <" (progn user-mail-address) ">
;; Keywords: "
 '(require 'finder)
 ;;'(setq v1 (apply 'vector (mapcar 'car finder-known-keywords)))
 '(setq v1 (mapcar (lambda (x) (list (symbol-name (car x))))
		   finder-known-keywords)
	v2 (mapconcat (lambda (x) (format "%10.0s:  %s" (car x) (cdr x)))
	   finder-known-keywords
	   "\n"))
 ((let ((minibuffer-help-form v2))
    (completing-read "Keyword, C-h: " v1 nil t))
    str ", ") & -2 "

;; This file is free software; you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation; either version 2, or (at your option)
;; any later version.

;; This file is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License
;; along with GNU Emacs; see the file COPYING.  If not, write to
;; the Free Software Foundation, Inc., 59 Temple Place - Suite 330,
;; Boston, MA 02111-1307, USA.

;;; Commentary:

;; " _ "

;;; Code:


\(provide '"
       (file-name-sans-extension (file-name-nondirectory (buffer-file-name)))
       ")
;;; " (file-name-nondirectory (buffer-file-name)) " ends here\n"))
  "A list specifying text to insert by default into a new file.
Elements look like (CONDITION . ACTION) or ((CONDITION . DESCRIPTION) . ACTION).
CONDITION maybe a regexp that must match the new file's name, or it may be
a symbol that must match the major mode for this element to apply.
Only the first matching element is effective.
Optional DESCRIPTION is a string for filling `auto-insert-prompt'.
ACTION may be a skeleton to insert (see `skeleton-insert'), an absolute
file-name or one relative to `auto-insert-directory' or a function to call.
ACTION may also be a vector containing several successive single actions as
described above, e.g. [\"header.insert\" date-and-author-update]."
  :type 'sexp
  :group 'auto-insert)


;; Establish a default value for auto-insert-directory
(defcustom auto-insert-directory "~/insert/"
  "*Directory from which auto-inserted files are taken.
The value must be an absolute directory name;
thus, on a GNU or Unix system, it must end in a slash."
  :type 'directory
  :group 'auto-insert)


;;;###autoload
(defun auto-insert ()
  "Insert default contents into new files if variable `auto-insert' is non-nil.
Matches the visited file name against the elements of `auto-insert-alist'."
  (interactive)
  (and (not buffer-read-only)
       (or (eq this-command 'auto-insert)
	   (and auto-insert
		(bobp) (eobp)))
       (let ((alist auto-insert-alist)
	     case-fold-search cond desc action)
	 (goto-char 1)
	 ;; find first matching alist entry
	 (while alist
	   (if (atom (setq cond (car (car alist))))
	       (setq desc cond)
	     (setq desc (cdr cond)
		   cond (car cond)))
	   (if (if (symbolp cond)
		   (eq cond major-mode)
		 (and buffer-file-name
		      (string-match cond buffer-file-name)))
	       (setq action (cdr (car alist))
		     alist nil)
	     (setq alist (cdr alist))))

	 ;; Now, if we found something, do it
	 (and action
	      (if (stringp action)
		  (file-readable-p (concat auto-insert-directory action))
		t)
	      (if auto-insert-query
		  (or (if (eq auto-insert-query 'function)
			  (eq this-command 'auto-insert))
		      (y-or-n-p (format auto-insert-prompt desc)))
		t)
	      (mapcar
	       (lambda (action)
		 (if (stringp action)
		     (if (file-readable-p
			  (setq action (concat auto-insert-directory action)))
			 (insert-file-contents action))
		   (save-window-excursion
		     ;; make buffer visible before skeleton or function
		     ;; which might ask the user for something
		     (switch-to-buffer (current-buffer))
		     (if (and (consp action)
			      (not (eq (car action) 'lambda)))
			 (skeleton-insert action)
		       (funcall action)))))
	       (if (vectorp action)
		   action
		 (vector action))))
	 (and (buffer-modified-p)
	      (not (eq this-command 'auto-insert))
	      (set-buffer-modified-p (eq auto-insert t)))))
  ;; Return nil so that it could be used in
  ;; `find-file-not-found-hooks', though that's probably inadvisable.
  nil)


;;;###autoload
(defun define-auto-insert (condition action &optional after)
  "Associate CONDITION with (additional) ACTION in `auto-insert-alist'.
Optional AFTER means to insert action after all existing actions for CONDITION,
or if CONDITION had no actions, after all other CONDITIONs."
  (let ((elt (assoc condition auto-insert-alist)))
    (if elt
	(setcdr elt
		(if (vectorp (cdr elt))
		    (vconcat (if after (cdr elt))
			     (if (vectorp action) action (vector action))
			     (if after () (cdr elt)))
		  (if after
		      (vector (cdr elt) action)
		    (vector action (cdr elt)))))
      (if after
	  (nconc auto-insert-alist (list (cons condition action)))
	(setq auto-insert-alist (cons (cons condition action)
				      auto-insert-alist))))))

;;;###autoload
(define-minor-mode auto-insert-mode
  "Toggle Auto-insert mode.
With prefix ARG, turn Auto-insert mode on if and only if ARG is positive.
Returns the new status of Auto-insert mode (non-nil means on).

When Auto-insert mode is enabled, when new files are created you can
insert a template for the file depending on the mode of the buffer."
  :global t :group 'auto-insert
  (if auto-insert-mode
      (add-hook 'find-file-hooks 'auto-insert)
    (remove-hook 'find-file-hooks 'auto-insert)))

(provide 'autoinsert)

;;; arch-tag: 5b6630ac-c735-43cf-b097-b78c622af909
;;; autoinsert.el ends here
Commit	Line	Data
c0274f38	1	;;; autoinsert.el --- automatic mode-dependent insertion of text into new files
b578f267	2
bf9f5c17	3	;; Copyright (C) 1985, 86, 87, 94, 95, 98, 2000, 03 Free Software Foundation, Inc.
9750e079	4
e5167999	5	;; Author: Charlie Martin <crm@cs.duke.edu>
3e910376	6	;; Adapted-By: Daniel Pfeiffer <occitan@esperanto.org>
f5f727f8	7	;; Keywords: convenience
4228277d	8	;; Maintainer: FSF
b1d6ae0b JB	9
	10	;; This file is part of GNU Emacs.
	11
	12	;; GNU Emacs is free software; you can redistribute it and/or modify
	13	;; it under the terms of the GNU General Public License as published by
e5167999	14	;; the Free Software Foundation; either version 2, or (at your option)
b1d6ae0b JB	15	;; any later version.
	16
	17	;; GNU Emacs is distributed in the hope that it will be useful,
	18	;; but WITHOUT ANY WARRANTY; without even the implied warranty of
	19	;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
	20	;; GNU General Public License for more details.
	21
	22	;; You should have received a copy of the GNU General Public License
b578f267 EN	23	;; along with GNU Emacs; see the file COPYING. If not, write to the
	24	;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
	25	;; Boston, MA 02111-1307, USA.
b1d6ae0b	26
e5167999	27	;;; Commentary:
b1d6ae0b	28
c11af8a5 KH	29	;; The following defines an association list for text to be
	30	;; automatically inserted when a new file is created, and a function
	31	;; which automatically inserts these files; the idea is to insert
	32	;; default text much as the mode is automatically set using
	33	;; auto-mode-alist.
	34	;;
12394086	35	;; To use:
c11af8a5 KH	36	;; (add-hook 'find-file-hooks 'auto-insert)
	37	;; setq auto-insert-directory to an appropriate slash-terminated value
	38	;;
6c5b39e4 SE	39	;; You can also customize the variable `auto-insert-mode' to load the
	40	;; package. Alternatively, add the following to your .emacs file:
	41	;; (auto-insert-mode 1)
	42	;;
c11af8a5 KH	43	;; Author: Charlie Martin
	44	;; Department of Computer Science and
	45	;; National Biomedical Simulation Resource
	46	;; Box 3709
	47	;; Duke University Medical Center
	48	;; Durham, NC 27710
12394086	49	;; (crm@cs.duke.edu,mcnc!duke!crm)
b1d6ae0b	50
e5167999 ER	51	;;; Code:
e5167999 ER	52
6c5b39e4 SE	53	(defgroup auto-insert nil
	54	"Automatic mode-dependent insertion of text into new files."
	55	:prefix "auto-insert-"
f5f727f8 DN	56	:group 'files
f5f727f8 DN	57	:group 'convenience)
6c5b39e4 SE	58
6c5b39e4 SE	59
6c5b39e4	60	(defcustom auto-insert 'not-modified
12394086 DL	61	"*Controls automatic insertion into newly found empty files.
12394086 DL	62	Possible values:
c11af8a5 KH	63	nil do nothing
	64	t insert if possible
	65	other insert if possible, but mark as unmodified.
	66	Insertion is possible when something appropriate is found in
	67	`auto-insert-alist'. When the insertion is marked as unmodified, you can
	68	save it with \\[write-file] RET.
a461758e	69	This variable is used when the function `auto-insert' is called, e.g.
c11af8a5	70	when you do (add-hook 'find-file-hooks 'auto-insert).
12394086	71	With \\[auto-insert], this is always treated as if it were t."
4605a50d DL	72	:type '(choice (const :tag "Insert if possible" t)
4605a50d DL	73	(const :tag "Do nothing" nil)
12394086	74	(other :tag "insert if possible, mark as unmodified."
4605a50d	75	not-modified))
6c5b39e4	76	:group 'auto-insert)
c11af8a5	77
6c5b39e4	78	(defcustom auto-insert-query 'function
12394086	79	"*Non-nil means ask user before auto-inserting.
6c5b39e4	80	When this is `function', only ask when called non-interactively."
5c213454 AS	81	:type '(choice (const :tag "Don't ask" nil)
	82	(const :tag "Ask if called non-interactively" function)
	83	(other :tag "Ask" t))
6c5b39e4	84	:group 'auto-insert)
c11af8a5	85
6c5b39e4	86	(defcustom auto-insert-prompt "Perform %s auto-insertion? "
c11af8a5	87	"*Prompt to use when querying whether to auto-insert.
6c5b39e4 SE	88	If this contains a %s, that will be replaced by the matching rule."
	89	:type 'string
	90	:group 'auto-insert)
c11af8a5 KH	91
c11af8a5 KH	92
6c5b39e4	93	(defcustom auto-insert-alist
c11af8a5 KH	94	'((("\\.\\([Hh]\\\|hh\\\|hpp\\)\\'" . "C / C++ header")
	95	(upcase (concat (file-name-nondirectory
	96	(substring buffer-file-name 0 (match-beginning 0)))
	97	"_"
	98	(substring buffer-file-name (1+ (match-beginning 0)))))
	99	"#ifndef " str \n
	100	"#define " str "\n\n"
	101	_ "\n\n#endif")
	102
	103	(("\\.\\([Cc]\\\|cc\\\|cpp\\)\\'" . "C / C++ program")
	104	nil
	105	"#include \""
f6ec1532 RS	106	(let ((stem (file-name-sans-extension buffer-file-name)))
	107	(cond ((file-exists-p (concat stem ".h"))
	108	(file-name-nondirectory (concat stem ".h")))
	109	((file-exists-p (concat stem ".hh"))
	110	(file-name-nondirectory (concat stem ".hh")))))
	111	& ?\" \| -10)
	112
	113	(("[Mm]akefile\\'" . "Makefile") . "makefile.inc")
c11af8a5	114
d60ae75c	115	(html-mode . (lambda () (sgml-tag "html")))
71296446	116
c11af8a5 KH	117	(plain-tex-mode . "tex-insert.tex")
	118	(bibtex-mode . "tex-insert.tex")
	119	(latex-mode
	120	;; should try to offer completing read for these
	121	"options, RET: "
47e58cf5	122	"\\documentclass[" str & ?\] \| -1
c11af8a5 KH	123	?{ (read-string "class: ") "}\n"
	124	("package, %s: "
	125	"\\usepackage[" (read-string "options, RET: ") & ?\] \| -1 ?{ str "}\n")
	126	_ "\n\\begin{document}\n" _
	127	"\n\\end{document}")
	128
	129	(("/bin/.*[^/]\\'" . "Shell-Script mode magic number")
	130	lambda ()
	131	(if (eq major-mode default-major-mode)
	132	(sh-mode)))
71296446	133
c11af8a5 KH	134	(ada-mode . ada-header)
c11af8a5 KH	135
bf9f5c17 DL	136	(("\\.[1-9]\\'" . "Man page skeleton")
	137	"Short description: "
	138	".\\\" Copyright (C), " (substring (current-time-string) -4) " "
	139	(getenv "ORGANIZATION") \| "Free Software Foundation, Inc."
	140	"
	141	.\\\" You may distribute this file under the terms of the GNU Free
	142	.\\\" Documentation Licence.
	143	.TH " (file-name-sans-extension (file-name-nondirectory (buffer-file-name)))
	144	" " (file-name-extension (buffer-file-name))
	145	" " (format-time-string "%Y-%m-%d ")
	146	"\n.SH NAME\n"
	147	(file-name-sans-extension (file-name-nondirectory (buffer-file-name)))
	148	" \\- " str
	149	"\n.SH SYNOPSIS
	150	.B " (file-name-sans-extension (file-name-nondirectory (buffer-file-name)))
	151	"\n"
	152	_
	153	"
	154	.SH DESCRIPTION
	155	.SH OPTIONS
	156	.SH FILES
	157	.SH \"SEE ALSO\"
	158	.SH BUGS
	159	.SH AUTHOR
	160	" (user-full-name)
	161	'(if (search-backward "&" (line-beginning-position) t)
	162	(replace-match (capitalize (user-login-name)) t t))
	163	'(end-of-line 1) " <" (progn user-mail-address) ">\n")
	164
c11af8a5 KH	165	(("\\.el\\'" . "Emacs Lisp header")
	166	"Short description: "
	167	";;; " (file-name-nondirectory (buffer-file-name)) " --- " str "
	168
2103c9fb	169	;; Copyright (C) " (substring (current-time-string) -4) " "
c11af8a5 KH	170	(getenv "ORGANIZATION") \| "Free Software Foundation, Inc." "
	171
	172	;; Author: " (user-full-name)
a461758e	173	'(if (search-backward "&" (line-beginning-position) t)
c11af8a5	174	(replace-match (capitalize (user-login-name)) t t))
c5f7d536	175	'(end-of-line 1) " <" (progn user-mail-address) ">
c11af8a5 KH	176	;; Keywords: "
	177	'(require 'finder)
	178	;;'(setq v1 (apply 'vector (mapcar 'car finder-known-keywords)))
	179	'(setq v1 (mapcar (lambda (x) (list (symbol-name (car x))))
	180	finder-known-keywords)
	181	v2 (mapconcat (lambda (x) (format "%10.0s: %s" (car x) (cdr x)))
	182	finder-known-keywords
	183	"\n"))
	184	((let ((minibuffer-help-form v2))
	185	(completing-read "Keyword, C-h: " v1 nil t))
	186	str ", ") & -2 "
	187
c5178e8e	188	;; This file is free software; you can redistribute it and/or modify
c11af8a5 KH	189	;; it under the terms of the GNU General Public License as published by
	190	;; the Free Software Foundation; either version 2, or (at your option)
	191	;; any later version.
	192
c5178e8e	193	;; This file is distributed in the hope that it will be useful,
c11af8a5 KH	194	;; but WITHOUT ANY WARRANTY; without even the implied warranty of
	195	;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
	196	;; GNU General Public License for more details.
	197
	198	;; You should have received a copy of the GNU General Public License
	199	;; along with GNU Emacs; see the file COPYING. If not, write to
01bb7524 EN	200	;; the Free Software Foundation, Inc., 59 Temple Place - Suite 330,
01bb7524 EN	201	;; Boston, MA 02111-1307, USA.
c11af8a5 KH	202
	203	;;; Commentary:
	204
	205	;; " _ "
	206
	207	;;; Code:
	208
	209
	210
3c98b2e9 SM	211	\(provide '"
	212	(file-name-sans-extension (file-name-nondirectory (buffer-file-name)))
	213	")
2103c9fb	214	;;; " (file-name-nondirectory (buffer-file-name)) " ends here\n"))
b1d6ae0b	215	"A list specifying text to insert by default into a new file.
c11af8a5 KH	216	Elements look like (CONDITION . ACTION) or ((CONDITION . DESCRIPTION) . ACTION).
	217	CONDITION maybe a regexp that must match the new file's name, or it may be
	218	a symbol that must match the major mode for this element to apply.
	219	Only the first matching element is effective.
	220	Optional DESCRIPTION is a string for filling `auto-insert-prompt'.
	221	ACTION may be a skeleton to insert (see `skeleton-insert'), an absolute
	222	file-name or one relative to `auto-insert-directory' or a function to call.
	223	ACTION may also be a vector containing several successive single actions as
6c5b39e4 SE	224	described above, e.g. [\"header.insert\" date-and-author-update]."
	225	:type 'sexp
	226	:group 'auto-insert)
b1d6ae0b	227
c11af8a5 KH	228
c11af8a5 KH	229	;; Establish a default value for auto-insert-directory
6c5b39e4	230	(defcustom auto-insert-directory "~/insert/"
66e0fd2b	231	"*Directory from which auto-inserted files are taken.
87810ca9 RS	232	The value must be an absolute directory name;
87810ca9 RS	233	thus, on a GNU or Unix system, it must end in a slash."
6c5b39e4 SE	234	:type 'directory
6c5b39e4 SE	235	:group 'auto-insert)
b1d6ae0b	236
c11af8a5 KH	237
	238	;;;###autoload
	239	(defun auto-insert ()
a461758e	240	"Insert default contents into new files if variable `auto-insert' is non-nil.
b1d6ae0b	241	Matches the visited file name against the elements of `auto-insert-alist'."
c11af8a5 KH	242	(interactive)
	243	(and (not buffer-read-only)
	244	(or (eq this-command 'auto-insert)
	245	(and auto-insert
	246	(bobp) (eobp)))
	247	(let ((alist auto-insert-alist)
	248	case-fold-search cond desc action)
	249	(goto-char 1)
	250	;; find first matching alist entry
	251	(while alist
	252	(if (atom (setq cond (car (car alist))))
	253	(setq desc cond)
	254	(setq desc (cdr cond)
	255	cond (car cond)))
	256	(if (if (symbolp cond)
	257	(eq cond major-mode)
a461758e DL	258	(and buffer-file-name
a461758e DL	259	(string-match cond buffer-file-name)))
c11af8a5 KH	260	(setq action (cdr (car alist))
	261	alist nil)
	262	(setq alist (cdr alist))))
	263
	264	;; Now, if we found something, do it
	265	(and action
	266	(if (stringp action)
	267	(file-readable-p (concat auto-insert-directory action))
	268	t)
	269	(if auto-insert-query
	270	(or (if (eq auto-insert-query 'function)
	271	(eq this-command 'auto-insert))
	272	(y-or-n-p (format auto-insert-prompt desc)))
	273	t)
	274	(mapcar
	275	(lambda (action)
	276	(if (stringp action)
	277	(if (file-readable-p
	278	(setq action (concat auto-insert-directory action)))
	279	(insert-file-contents action))
	280	(save-window-excursion
	281	;; make buffer visible before skeleton or function
	282	;; which might ask the user for something
	283	(switch-to-buffer (current-buffer))
	284	(if (and (consp action)
	285	(not (eq (car action) 'lambda)))
	286	(skeleton-insert action)
	287	(funcall action)))))
	288	(if (vectorp action)
	289	action
	290	(vector action))))
	291	(and (buffer-modified-p)
	292	(not (eq this-command 'auto-insert))
12394086 DL	293	(set-buffer-modified-p (eq auto-insert t)))))
	294	;; Return nil so that it could be used in
	295	;; `find-file-not-found-hooks', though that's probably inadvisable.
	296	nil)
c11af8a5 KH	297
	298
	299	;;;###autoload
4605a50d	300	(defun define-auto-insert (condition action &optional after)
c11af8a5 KH	301	"Associate CONDITION with (additional) ACTION in `auto-insert-alist'.
	302	Optional AFTER means to insert action after all existing actions for CONDITION,
	303	or if CONDITION had no actions, after all other CONDITIONs."
4605a50d	304	(let ((elt (assoc condition auto-insert-alist)))
c11af8a5 KH	305	(if elt
	306	(setcdr elt
	307	(if (vectorp (cdr elt))
	308	(vconcat (if after (cdr elt))
	309	(if (vectorp action) action (vector action))
	310	(if after () (cdr elt)))
	311	(if after
	312	(vector (cdr elt) action)
	313	(vector action (cdr elt)))))
	314	(if after
4605a50d DL	315	(nconc auto-insert-alist (list (cons condition action)))
4605a50d DL	316	(setq auto-insert-alist (cons (cons condition action)
c11af8a5	317	auto-insert-alist))))))
c0274f38	318
6c5b39e4	319	;;;###autoload
bff6da3d	320	(define-minor-mode auto-insert-mode
12394086 DL	321	"Toggle Auto-insert mode.
	322	With prefix ARG, turn Auto-insert mode on if and only if ARG is positive.
	323	Returns the new status of Auto-insert mode (non-nil means on).
6c5b39e4	324
12394086	325	When Auto-insert mode is enabled, when new files are created you can
6c5b39e4	326	insert a template for the file depending on the mode of the buffer."
44e70da2	327	:global t :group 'auto-insert
bff6da3d SM	328	(if auto-insert-mode
	329	(add-hook 'find-file-hooks 'auto-insert)
	330	(remove-hook 'find-file-hooks 'auto-insert)))
6c5b39e4	331
896546cd RS	332	(provide 'autoinsert)
896546cd RS	333
ab5796a9	334	;;; arch-tag: 5b6630ac-c735-43cf-b097-b78c622af909
c0274f38	335	;;; autoinsert.el ends here