[bpt/emacs.git] / lisp / electric.el

;;; electric.el --- window maker and Command loop for `electric' modes

;; Copyright (C) 1985-1986, 1995, 2001-2011 Free Software Foundation, Inc.

;; Author: K. Shane Hartman
;; Maintainer: FSF
;; Keywords: extensions

;; This file is part of GNU Emacs.

;; GNU Emacs is free software: you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation, either version 3 of the License, or
;; (at your option) any later version.

;; GNU Emacs is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License
;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.

;;; Commentary:

;; "Electric" has been used in Emacs to refer to different things.
;; Among them:
;;
;; - electric modes and buffers: modes that typically pop-up in a modal kind of
;;   way a transient buffer that automatically disappears as soon as the user
;;   is done with it.
;;
;; - electric keys: self inserting keys which additionally perform some side
;;   operation which happens to be often convenient at that time.  Examples of
;;   such side operations are: reindenting code, inserting a newline,
;;   ... auto-fill-mode and abbrev-mode can be considered as built-in forms of
;;   electric key behavior.

;;; Code:

(eval-when-compile (require 'cl))

;; This loop is the guts for non-standard modes which retain control
;; until some event occurs.  It is a `do-forever', the only way out is
;; to throw.  It assumes that you have set up the keymap, window, and
;; everything else: all it does is read commands and execute them -
;; providing error messages should one occur (if there is no loop
;; function - which see).  The required argument is a tag which should
;; expect a value of nil if the user decides to punt. The second
;; argument is the prompt to be used: if nil, use "->", if 'noprompt,
;; don't use a prompt, if a string, use that string as prompt, and if
;; a function of no variable, it will be evaluated in every iteration
;; of the loop and its return value, which can be nil, 'noprompt or a
;; string, will be used as prompt.  Given third argument non-nil, it
;; INHIBITS quitting unless the user types C-g at toplevel.  This is
;; so user can do things like C-u C-g and not get thrown out.  Fourth
;; argument, if non-nil, should be a function of two arguments which
;; is called after every command is executed.  The fifth argument, if
;; provided, is the state variable for the function.  If the
;; loop-function gets an error, the loop will abort WITHOUT throwing
;; (moral: use unwind-protect around call to this function for any
;; critical stuff).  The second argument for the loop function is the
;; conditions for any error that occurred or nil if none.

(defun Electric-command-loop (return-tag
			      &optional prompt inhibit-quitting
					loop-function loop-state)

  (let (cmd
        (err nil)
        (inhibit-quit inhibit-quitting)
        (prompt-string prompt))
    (while t
      (if (functionp prompt)
          (setq prompt-string (funcall prompt)))
      (if (not (stringp prompt-string))
          (setq prompt-string (unless (eq prompt-string 'noprompt) "->")))
      (setq cmd (read-key-sequence prompt-string))
      (setq last-command-event (aref cmd (1- (length cmd)))
	    this-command (key-binding cmd t)
	    cmd this-command)
      ;; This makes universal-argument-other-key work.
      (setq universal-argument-num-events 0)
      (if (or (prog1 quit-flag (setq quit-flag nil))
	      (eq last-input-event ?\C-g))
	  (progn (setq unread-command-events nil
		       prefix-arg nil)
		 ;; If it wasn't cancelling a prefix character, then quit.
		 (if (or (= (length (this-command-keys)) 1)
			 (not inhibit-quit)) ; safety
		     (progn (ding)
			    (message "Quit")
			    (throw return-tag nil))
		   (setq cmd nil))))
      (setq current-prefix-arg prefix-arg)
      (if cmd
	  (condition-case conditions
	      (progn (command-execute cmd)
		     (setq last-command this-command)
		     (if (or (prog1 quit-flag (setq quit-flag nil))
			     (eq last-input-event ?\C-g))
			 (progn (setq unread-command-events nil)
				(if (not inhibit-quit)
				    (progn (ding)
					   (message "Quit")
					   (throw return-tag nil))
				  (ding)))))
	    (buffer-read-only (if loop-function
				  (setq err conditions)
				(ding)
				(message "Buffer is read-only")
				(sit-for 2)))
	    (beginning-of-buffer (if loop-function
				     (setq err conditions)
				   (ding)
				   (message "Beginning of Buffer")
				   (sit-for 2)))
	    (end-of-buffer (if loop-function
			       (setq err conditions)
			     (ding)
			     (message "End of Buffer")
			     (sit-for 2)))
	    (error (if loop-function
		       (setq err conditions)
		     (ding)
		     (message "Error: %s"
			      (if (eq (car conditions) 'error)
				  (car (cdr conditions))
				(prin1-to-string conditions)))
		     (sit-for 2))))
	(ding))
      (if loop-function (funcall loop-function loop-state err))))
  (ding)
  (throw return-tag nil))

;; This function is like pop-to-buffer, sort of.
;; The algorithm is
;; If there is a window displaying buffer
;; 	Select it
;; Else if there is only one window
;; 	Split it, selecting the window on the bottom with height being
;; 	the lesser of max-height (if non-nil) and the number of lines in
;;      the buffer to be displayed subject to window-min-height constraint.
;; Else
;; 	Switch to buffer in the current window.
;;
;; Then if max-height is nil, and not all of the lines in the buffer
;; are displayed, grab the whole frame.
;;
;; Returns selected window on buffer positioned at point-min.

(defun Electric-pop-up-window (buffer &optional max-height)
  (let* ((win (or (get-buffer-window buffer) (selected-window)))
	 (buf (get-buffer buffer))
	 (one-window (one-window-p t))
	 (pop-up-windows t)
	 (pop-up-frames nil))
    (if (not buf)
	(error "Buffer %s does not exist" buffer)
      (cond ((and (eq (window-buffer win) buf))
	     (select-window win))
	    (one-window
	     (pop-to-buffer buffer)
	     (setq win (selected-window)))
	    (t
	     (switch-to-buffer buf)))
      ;; Don't shrink the window, but expand it if necessary.
      (goto-char (point-min))
      (unless (= (point-max) (window-end win t))
	(fit-window-to-buffer win max-height))
      win)))

;;; Electric keys.

(defgroup electricity ()
  "Electric behavior for self inserting keys."
  :group 'editing)

(defun electric--after-char-pos ()
  "Return the position after the char we just inserted.
Returns nil when we can't find this char."
  (let ((pos (point)))
    (when (or (eq (char-before) last-command-event) ;; Sanity check.
              (save-excursion
                (or (progn (skip-chars-backward " \t")
                           (setq pos (point))
                           (eq (char-before) last-command-event))
                    (progn (skip-chars-backward " \n\t")
                           (setq pos (point))
                           (eq (char-before) last-command-event)))))
      pos)))

;; Electric indentation.

;; Autoloading variables is generally undesirable, but major modes
;; should usually set this variable by adding elements to the default
;; value, which only works well if the variable is preloaded.
;;;###autoload
(defvar electric-indent-chars '(?\n)
  "Characters that should cause automatic reindentation.")

(defun electric-indent-post-self-insert-function ()
  ;; FIXME: This reindents the current line, but what we really want instead is
  ;; to reindent the whole affected text.  That's the current line for simple
  ;; cases, but not all cases.  We do take care of the newline case in an
  ;; ad-hoc fashion, but there are still missing cases such as the case of
  ;; electric-pair-mode wrapping a region with a pair of parens.
  ;; There might be a way to get it working by analyzing buffer-undo-list, but
  ;; it looks challenging.
  (let (pos)
    (when (and (memq last-command-event electric-indent-chars)
               ;; Don't reindent while inserting spaces at beginning of line.
               (or (not (memq last-command-event '(?\s ?\t)))
                   (save-excursion (skip-chars-backward " \t") (not (bolp))))
               (setq pos (electric--after-char-pos))
               ;; Not in a string or comment.
               (not (nth 8 (save-excursion (syntax-ppss pos)))))
      ;; For newline, we want to reindent both lines and basically behave like
      ;; reindent-then-newline-and-indent (whose code we hence copied).
      (when (< (1- pos) (line-beginning-position))
        (let ((before (copy-marker (1- pos) t)))
          (save-excursion
            (unless (memq indent-line-function
                          '(indent-relative indent-to-left-margin
                            indent-relative-maybe))
              ;; Don't reindent the previous line if the indentation function
              ;; is not a real one.
              (goto-char before)
              (indent-according-to-mode))
            ;; We are at EOL before the call to indent-according-to-mode, and
            ;; after it we usually are as well, but not always.  We tried to
            ;; address it with `save-excursion' but that uses a normal marker
            ;; whereas we need `move after insertion', so we do the
            ;; save/restore by hand.
            (goto-char before)
            ;; Remove the trailing whitespace after indentation because
            ;; indentation may (re)introduce the whitespace.
            (delete-horizontal-space t))))
      (unless (memq indent-line-function '(indent-to-left-margin))
        (indent-according-to-mode)))))

;;;###autoload
(define-minor-mode electric-indent-mode
  "Automatically reindent lines of code when inserting particular chars.
`electric-indent-chars' specifies the set of chars that should cause reindentation."
  :global t
  :group 'electricity
  (if electric-indent-mode
      (add-hook 'post-self-insert-hook
                #'electric-indent-post-self-insert-function)
    (remove-hook 'post-self-insert-hook
                 #'electric-indent-post-self-insert-function))
  ;; FIXME: electric-indent-mode and electric-layout-mode interact
  ;; in non-trivial ways.  It turns out that electric-indent-mode works
  ;; better if it is run *after* electric-layout-mode's hook.
  (when (memq #'electric-layout-post-self-insert-function
              (memq #'electric-indent-post-self-insert-function
                    (default-value 'post-self-insert-hook)))
    (remove-hook 'post-self-insert-hook
                 #'electric-layout-post-self-insert-function)
    (add-hook 'post-self-insert-hook
              #'electric-layout-post-self-insert-function)))

;; Electric pairing.

(defcustom electric-pair-pairs
  '((?\" . ?\"))
  "Alist of pairs that should be used regardless of major mode."
  :type '(repeat (cons character character)))

(defcustom electric-pair-skip-self t
  "If non-nil, skip char instead of inserting a second closing paren.
When inserting a closing paren character right before the same character,
just skip that character instead, so that hitting ( followed by ) results
in \"()\" rather than \"())\".
This can be convenient for people who find it easier to hit ) than C-f."
  :type 'boolean)

(defun electric-pair-post-self-insert-function ()
  (let* ((syntax (and (eq (char-before) last-command-event) ; Sanity check.
                      (let ((x (assq last-command-event electric-pair-pairs)))
                        (cond
                         (x (if (eq (car x) (cdr x)) ?\" ?\())
                         ((rassq last-command-event electric-pair-pairs) ?\))
                         (t (char-syntax last-command-event))))))
         ;; FIXME: when inserting the closer, we should maybe use
         ;; self-insert-command, although it may prove tricky running
         ;; post-self-insert-hook recursively, and we wouldn't want to trigger
         ;; blink-matching-open.
         (closer (if (eq syntax ?\()
                     (cdr (or (assq last-command-event electric-pair-pairs)
                              (aref (syntax-table) last-command-event)))
                   last-command-event)))
    (cond
     ;; Wrap a pair around the active region.
     ((and (memq syntax '(?\( ?\" ?\$)) (use-region-p))
      (if (> (mark) (point))
          (goto-char (mark))
        ;; We already inserted the open-paren but at the end of the region,
        ;; so we have to remove it and start over.
        (delete-char -1)
        (save-excursion
          (goto-char (mark))
          (insert last-command-event)))
      (insert closer))
     ;; Backslash-escaped: no pairing, no skipping.
     ((save-excursion
        (goto-char (1- (point)))
        (not (zerop (% (skip-syntax-backward "\\") 2))))
      nil)
     ;; Skip self.
     ((and (memq syntax '(?\) ?\" ?\$))
           electric-pair-skip-self
           (eq (char-after) last-command-event))
      ;; This is too late: rather than insert&delete we'd want to only skip (or
      ;; insert in overwrite mode).  The difference is in what goes in the
      ;; undo-log and in the intermediate state which might be visible to other
      ;; post-self-insert-hook.  We'll just have to live with it for now.
      (delete-char 1))
     ;; Insert matching pair.
     ((not (or (not (memq syntax `(?\( ?\" ?\$)))
               overwrite-mode
               ;; I find it more often preferable not to pair when the
               ;; same char is next.
               (eq last-command-event (char-after))
               (eq last-command-event (char-before (1- (point))))
               ;; I also find it often preferable not to pair next to a word.
               (eq (char-syntax (following-char)) ?w)))
      (save-excursion (insert closer))))))

;;;###autoload
(define-minor-mode electric-pair-mode
  "Automatically pair-up parens when inserting an open paren."
  :global t
  :group 'electricity
  (if electric-pair-mode
      (add-hook 'post-self-insert-hook
                #'electric-pair-post-self-insert-function)
    (remove-hook 'post-self-insert-hook
                 #'electric-pair-post-self-insert-function)))

;; Automatically add newlines after/before/around some chars.

(defvar electric-layout-rules '()
  "List of rules saying where to automatically insert newlines.
Each rule has the form (CHAR . WHERE) where CHAR is the char
that was just inserted and WHERE specifies where to insert newlines
and can be: nil, `before', `after', `around', or a function that returns
one of those symbols.")

(defun electric-layout-post-self-insert-function ()
  (let* ((rule (cdr (assq last-command-event electric-layout-rules)))
         pos)
    (when (and rule
               (setq pos (electric--after-char-pos))
               ;; Not in a string or comment.
               (not (nth 8 (save-excursion (syntax-ppss pos)))))
      (let ((end (copy-marker (point) t)))
        (goto-char pos)
        (case (if (functionp rule) (funcall rule) rule)
          ;; FIXME: we used `newline' down here which called
          ;; self-insert-command and ran post-self-insert-hook recursively.
          ;; It happened to make electric-indent-mode work automatically with
          ;; electric-layout-mode (at the cost of re-indenting lines
          ;; multiple times), but I'm not sure it's what we want.
          (before (goto-char (1- pos)) (skip-chars-backward " \t")
                  (unless (bolp) (insert "\n")))
          (after  (insert "\n"))       ; FIXME: check eolp before inserting \n?
          (around (save-excursion
                    (goto-char (1- pos)) (skip-chars-backward " \t")
                    (unless (bolp) (insert "\n")))
                  (insert "\n")))      ; FIXME: check eolp before inserting \n?
        (goto-char end)))))

;;;###autoload
(define-minor-mode electric-layout-mode
  "Automatically insert newlines around some chars."
  :global t
  :group 'electricity
  (if electric-layout-mode
      (add-hook 'post-self-insert-hook
                #'electric-layout-post-self-insert-function)
    (remove-hook 'post-self-insert-hook
                 #'electric-layout-post-self-insert-function)))

(provide 'electric)

;;; electric.el ends here
Commit	Line	Data
55535639	1	;;; electric.el --- window maker and Command loop for `electric' modes
c0274f38	2
73b0cd50	3	;; Copyright (C) 1985-1986, 1995, 2001-2011 Free Software Foundation, Inc.
9750e079	4
e5167999 ER	5	;; Author: K. Shane Hartman
e5167999 ER	6	;; Maintainer: FSF
fd7fa35a	7	;; Keywords: extensions
e5167999	8
0d20f9a0 JB	9	;; This file is part of GNU Emacs.
0d20f9a0 JB	10
eb3fa2cf	11	;; GNU Emacs is free software: you can redistribute it and/or modify
0d20f9a0	12	;; it under the terms of the GNU General Public License as published by
eb3fa2cf GM	13	;; the Free Software Foundation, either version 3 of the License, or
eb3fa2cf GM	14	;; (at your option) any later version.
0d20f9a0 JB	15
	16	;; GNU Emacs is distributed in the hope that it will be useful,
	17	;; but WITHOUT ANY WARRANTY; without even the implied warranty of
	18	;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
	19	;; GNU General Public License for more details.
	20
	21	;; You should have received a copy of the GNU General Public License
eb3fa2cf	22	;; along with GNU Emacs. If not, see <http://www.gnu.org/licenses/>.
0d20f9a0	23
c8472948	24	;;; Commentary:
0d20f9a0	25
3b843809 SM	26	;; "Electric" has been used in Emacs to refer to different things.
	27	;; Among them:
	28	;;
	29	;; - electric modes and buffers: modes that typically pop-up in a modal kind of
	30	;; way a transient buffer that automatically disappears as soon as the user
	31	;; is done with it.
	32	;;
	33	;; - electric keys: self inserting keys which additionally perform some side
	34	;; operation which happens to be often convenient at that time. Examples of
	35	;; such side operations are: reindenting code, inserting a newline,
	36	;; ... auto-fill-mode and abbrev-mode can be considered as built-in forms of
	37	;; electric key behavior.
0d20f9a0	38
c8472948 ER	39	;;; Code:
c8472948 ER	40
3b843809 SM	41	(eval-when-compile (require 'cl))
3b843809 SM	42
0d20f9a0	43	;; This loop is the guts for non-standard modes which retain control
f135afd3 RS	44	;; until some event occurs. It is a `do-forever', the only way out is
f135afd3 RS	45	;; to throw. It assumes that you have set up the keymap, window, and
0d20f9a0 JB	46	;; everything else: all it does is read commands and execute them -
	47	;; providing error messages should one occur (if there is no loop
	48	;; function - which see). The required argument is a tag which should
f135afd3 RS	49	;; expect a value of nil if the user decides to punt. The second
	50	;; argument is the prompt to be used: if nil, use "->", if 'noprompt,
	51	;; don't use a prompt, if a string, use that string as prompt, and if
	52	;; a function of no variable, it will be evaluated in every iteration
	53	;; of the loop and its return value, which can be nil, 'noprompt or a
	54	;; string, will be used as prompt. Given third argument non-nil, it
	55	;; INHIBITS quitting unless the user types C-g at toplevel. This is
	56	;; so user can do things like C-u C-g and not get thrown out. Fourth
	57	;; argument, if non-nil, should be a function of two arguments which
	58	;; is called after every command is executed. The fifth argument, if
	59	;; provided, is the state variable for the function. If the
0d20f9a0 JB	60	;; loop-function gets an error, the loop will abort WITHOUT throwing
	61	;; (moral: use unwind-protect around call to this function for any
	62	;; critical stuff). The second argument for the loop function is the
	63	;; conditions for any error that occurred or nil if none.
	64
	65	(defun Electric-command-loop (return-tag
06b60517	66	&optional prompt inhibit-quitting
0d20f9a0	67	loop-function loop-state)
f135afd3	68
71296446 JB	69	(let (cmd
71296446 JB	70	(err nil)
06b60517	71	(inhibit-quit inhibit-quitting)
f135afd3	72	(prompt-string prompt))
0d20f9a0	73	(while t
ba5bf5f0	74	(if (functionp prompt)
f135afd3 RS	75	(setq prompt-string (funcall prompt)))
f135afd3 RS	76	(if (not (stringp prompt-string))
ba5bf5f0	77	(setq prompt-string (unless (eq prompt-string 'noprompt) "->")))
f135afd3	78	(setq cmd (read-key-sequence prompt-string))
8989a920	79	(setq last-command-event (aref cmd (1- (length cmd)))
f867d8d3	80	this-command (key-binding cmd t)
0d20f9a0	81	cmd this-command)
f867d8d3 RS	82	;; This makes universal-argument-other-key work.
f867d8d3 RS	83	(setq universal-argument-num-events 0)
0d20f9a0	84	(if (or (prog1 quit-flag (setq quit-flag nil))
1e4bd40d	85	(eq last-input-event ?\C-g))
dbc4e1c1	86	(progn (setq unread-command-events nil
0d20f9a0 JB	87	prefix-arg nil)
	88	;; If it wasn't cancelling a prefix character, then quit.
	89	(if (or (= (length (this-command-keys)) 1)
	90	(not inhibit-quit)) ; safety
	91	(progn (ding)
	92	(message "Quit")
	93	(throw return-tag nil))
	94	(setq cmd nil))))
	95	(setq current-prefix-arg prefix-arg)
	96	(if cmd
	97	(condition-case conditions
	98	(progn (command-execute cmd)
17c17ec9	99	(setq last-command this-command)
0d20f9a0	100	(if (or (prog1 quit-flag (setq quit-flag nil))
1e4bd40d	101	(eq last-input-event ?\C-g))
dbc4e1c1	102	(progn (setq unread-command-events nil)
0d20f9a0 JB	103	(if (not inhibit-quit)
	104	(progn (ding)
	105	(message "Quit")
	106	(throw return-tag nil))
	107	(ding)))))
	108	(buffer-read-only (if loop-function
	109	(setq err conditions)
	110	(ding)
	111	(message "Buffer is read-only")
	112	(sit-for 2)))
	113	(beginning-of-buffer (if loop-function
	114	(setq err conditions)
	115	(ding)
	116	(message "Beginning of Buffer")
	117	(sit-for 2)))
	118	(end-of-buffer (if loop-function
	119	(setq err conditions)
	120	(ding)
	121	(message "End of Buffer")
	122	(sit-for 2)))
	123	(error (if loop-function
	124	(setq err conditions)
	125	(ding)
	126	(message "Error: %s"
	127	(if (eq (car conditions) 'error)
	128	(car (cdr conditions))
	129	(prin1-to-string conditions)))
	130	(sit-for 2))))
	131	(ding))
	132	(if loop-function (funcall loop-function loop-state err))))
	133	(ding)
	134	(throw return-tag nil))
	135
71296446	136	;; This function is like pop-to-buffer, sort of.
0d20f9a0 JB	137	;; The algorithm is
	138	;; If there is a window displaying buffer
	139	;; Select it
	140	;; Else if there is only one window
	141	;; Split it, selecting the window on the bottom with height being
	142	;; the lesser of max-height (if non-nil) and the number of lines in
	143	;; the buffer to be displayed subject to window-min-height constraint.
	144	;; Else
	145	;; Switch to buffer in the current window.
	146	;;
	147	;; Then if max-height is nil, and not all of the lines in the buffer
f98955ea	148	;; are displayed, grab the whole frame.
0d20f9a0 JB	149	;;
	150	;; Returns selected window on buffer positioned at point-min.
	151
	152	(defun Electric-pop-up-window (buffer &optional max-height)
	153	(let* ((win (or (get-buffer-window buffer) (selected-window)))
	154	(buf (get-buffer buffer))
	155	(one-window (one-window-p t))
	156	(pop-up-windows t)
c45c149c	157	(pop-up-frames nil))
0d20f9a0 JB	158	(if (not buf)
0d20f9a0 JB	159	(error "Buffer %s does not exist" buffer)
0d20f9a0 JB	160	(cond ((and (eq (window-buffer win) buf))
	161	(select-window win))
	162	(one-window
0d20f9a0	163	(pop-to-buffer buffer)
c45c149c	164	(setq win (selected-window)))
0d20f9a0 JB	165	(t
0d20f9a0 JB	166	(switch-to-buffer buf)))
48238d1d	167	;; Don't shrink the window, but expand it if necessary.
0d20f9a0	168	(goto-char (point-min))
0e87e61e	169	(unless (= (point-max) (window-end win t))
48238d1d	170	(fit-window-to-buffer win max-height))
0d20f9a0	171	win)))
49116ac0	172
3b843809 SM	173	;;; Electric keys.
	174
	175	(defgroup electricity ()
	176	"Electric behavior for self inserting keys."
	177	:group 'editing)
	178
7100ff98 SM	179	(defun electric--after-char-pos ()
	180	"Return the position after the char we just inserted.
	181	Returns nil when we can't find this char."
	182	(let ((pos (point)))
	183	(when (or (eq (char-before) last-command-event) ;; Sanity check.
	184	(save-excursion
	185	(or (progn (skip-chars-backward " \t")
	186	(setq pos (point))
	187	(eq (char-before) last-command-event))
	188	(progn (skip-chars-backward " \n\t")
	189	(setq pos (point))
	190	(eq (char-before) last-command-event)))))
	191	pos)))
	192
3b843809 SM	193	;; Electric indentation.
3b843809 SM	194
2122161f SM	195	;; Autoloading variables is generally undesirable, but major modes
	196	;; should usually set this variable by adding elements to the default
	197	;; value, which only works well if the variable is preloaded.
	198	;;;###autoload
3b843809 SM	199	(defvar electric-indent-chars '(?\n)
	200	"Characters that should cause automatic reindentation.")
	201
	202	(defun electric-indent-post-self-insert-function ()
	203	;; FIXME: This reindents the current line, but what we really want instead is
	204	;; to reindent the whole affected text. That's the current line for simple
	205	;; cases, but not all cases. We do take care of the newline case in an
	206	;; ad-hoc fashion, but there are still missing cases such as the case of
	207	;; electric-pair-mode wrapping a region with a pair of parens.
	208	;; There might be a way to get it working by analyzing buffer-undo-list, but
	209	;; it looks challenging.
7100ff98 SM	210	(let (pos)
	211	(when (and (memq last-command-event electric-indent-chars)
	212	;; Don't reindent while inserting spaces at beginning of line.
	213	(or (not (memq last-command-event '(?\s ?\t)))
	214	(save-excursion (skip-chars-backward " \t") (not (bolp))))
	215	(setq pos (electric--after-char-pos))
	216	;; Not in a string or comment.
	217	(not (nth 8 (save-excursion (syntax-ppss pos)))))
	218	;; For newline, we want to reindent both lines and basically behave like
	219	;; reindent-then-newline-and-indent (whose code we hence copied).
a733fc37	220	(when (< (1- pos) (line-beginning-position))
7100ff98 SM	221	(let ((before (copy-marker (1- pos) t)))
7100ff98 SM	222	(save-excursion
a733fc37	223	(unless (memq indent-line-function
74a10be5 SM	224	'(indent-relative indent-to-left-margin
74a10be5 SM	225	indent-relative-maybe))
a733fc37 SM	226	;; Don't reindent the previous line if the indentation function
	227	;; is not a real one.
	228	(goto-char before)
	229	(indent-according-to-mode))
7100ff98 SM	230	;; We are at EOL before the call to indent-according-to-mode, and
	231	;; after it we usually are as well, but not always. We tried to
	232	;; address it with `save-excursion' but that uses a normal marker
	233	;; whereas we need `move after insertion', so we do the
	234	;; save/restore by hand.
	235	(goto-char before)
	236	;; Remove the trailing whitespace after indentation because
	237	;; indentation may (re)introduce the whitespace.
	238	(delete-horizontal-space t))))
74a10be5 SM	239	(unless (memq indent-line-function '(indent-to-left-margin))
74a10be5 SM	240	(indent-according-to-mode)))))
3b843809 SM	241
	242	;;;###autoload
	243	(define-minor-mode electric-indent-mode
	244	"Automatically reindent lines of code when inserting particular chars.
	245	`electric-indent-chars' specifies the set of chars that should cause reindentation."
	246	:global t
	247	:group 'electricity
	248	(if electric-indent-mode
	249	(add-hook 'post-self-insert-hook
	250	#'electric-indent-post-self-insert-function)
	251	(remove-hook 'post-self-insert-hook
7100ff98 SM	252	#'electric-indent-post-self-insert-function))
	253	;; FIXME: electric-indent-mode and electric-layout-mode interact
	254	;; in non-trivial ways. It turns out that electric-indent-mode works
	255	;; better if it is run after electric-layout-mode's hook.
	256	(when (memq #'electric-layout-post-self-insert-function
	257	(memq #'electric-indent-post-self-insert-function
	258	(default-value 'post-self-insert-hook)))
	259	(remove-hook 'post-self-insert-hook
	260	#'electric-layout-post-self-insert-function)
	261	(add-hook 'post-self-insert-hook
	262	#'electric-layout-post-self-insert-function)))
3b843809 SM	263
	264	;; Electric pairing.
	265
c51bb5d2 SM	266	(defcustom electric-pair-pairs
	267	'((?\" . ?\"))
	268	"Alist of pairs that should be used regardless of major mode."
	269	:type '(repeat (cons character character)))
	270
3b843809 SM	271	(defcustom electric-pair-skip-self t
	272	"If non-nil, skip char instead of inserting a second closing paren.
	273	When inserting a closing paren character right before the same character,
	274	just skip that character instead, so that hitting ( followed by ) results
	275	in \"()\" rather than \"())\".
	276	This can be convenient for people who find it easier to hit ) than C-f."
	277	:type 'boolean)
	278
	279	(defun electric-pair-post-self-insert-function ()
	280	(let* ((syntax (and (eq (char-before) last-command-event) ; Sanity check.
c51bb5d2 SM	281	(let ((x (assq last-command-event electric-pair-pairs)))
	282	(cond
	283	(x (if (eq (car x) (cdr x)) ?\" ?\())
	284	((rassq last-command-event electric-pair-pairs) ?\))
	285	(t (char-syntax last-command-event))))))
3b843809 SM	286	;; FIXME: when inserting the closer, we should maybe use
	287	;; self-insert-command, although it may prove tricky running
	288	;; post-self-insert-hook recursively, and we wouldn't want to trigger
	289	;; blink-matching-open.
	290	(closer (if (eq syntax ?\()
c51bb5d2 SM	291	(cdr (or (assq last-command-event electric-pair-pairs)
c51bb5d2 SM	292	(aref (syntax-table) last-command-event)))
3b843809 SM	293	last-command-event)))
	294	(cond
	295	;; Wrap a pair around the active region.
	296	((and (memq syntax '(?\( ?\" ?\$)) (use-region-p))
	297	(if (> (mark) (point))
	298	(goto-char (mark))
	299	;; We already inserted the open-paren but at the end of the region,
	300	;; so we have to remove it and start over.
	301	(delete-char -1)
	302	(save-excursion
	303	(goto-char (mark))
	304	(insert last-command-event)))
	305	(insert closer))
	306	;; Backslash-escaped: no pairing, no skipping.
	307	((save-excursion
	308	(goto-char (1- (point)))
	309	(not (zerop (% (skip-syntax-backward "\\") 2))))
	310	nil)
	311	;; Skip self.
	312	((and (memq syntax '(?\) ?\" ?\$))
	313	electric-pair-skip-self
	314	(eq (char-after) last-command-event))
	315	;; This is too late: rather than insert&delete we'd want to only skip (or
	316	;; insert in overwrite mode). The difference is in what goes in the
	317	;; undo-log and in the intermediate state which might be visible to other
	318	;; post-self-insert-hook. We'll just have to live with it for now.
	319	(delete-char 1))
	320	;; Insert matching pair.
	321	((not (or (not (memq syntax `(?\( ?\" ?\$)))
	322	overwrite-mode
	323	;; I find it more often preferable not to pair when the
	324	;; same char is next.
	325	(eq last-command-event (char-after))
	326	(eq last-command-event (char-before (1- (point))))
	327	;; I also find it often preferable not to pair next to a word.
	328	(eq (char-syntax (following-char)) ?w)))
	329	(save-excursion (insert closer))))))
	330
	331	;;;###autoload
	332	(define-minor-mode electric-pair-mode
	333	"Automatically pair-up parens when inserting an open paren."
	334	:global t
	335	:group 'electricity
	336	(if electric-pair-mode
	337	(add-hook 'post-self-insert-hook
	338	#'electric-pair-post-self-insert-function)
	339	(remove-hook 'post-self-insert-hook
	340	#'electric-pair-post-self-insert-function)))
7100ff98 SM	341
	342	;; Automatically add newlines after/before/around some chars.
	343
	344	(defvar electric-layout-rules '()
	345	"List of rules saying where to automatically insert newlines.
	346	Each rule has the form (CHAR . WHERE) where CHAR is the char
	347	that was just inserted and WHERE specifies where to insert newlines
	348	and can be: nil, `before', `after', `around', or a function that returns
	349	one of those symbols.")
	350
	351	(defun electric-layout-post-self-insert-function ()
	352	(let* ((rule (cdr (assq last-command-event electric-layout-rules)))
	353	pos)
	354	(when (and rule
	355	(setq pos (electric--after-char-pos))
	356	;; Not in a string or comment.
	357	(not (nth 8 (save-excursion (syntax-ppss pos)))))
	358	(let ((end (copy-marker (point) t)))
	359	(goto-char pos)
	360	(case (if (functionp rule) (funcall rule) rule)
	361	;; FIXME: we used `newline' down here which called
	362	;; self-insert-command and ran post-self-insert-hook recursively.
	363	;; It happened to make electric-indent-mode work automatically with
	364	;; electric-layout-mode (at the cost of re-indenting lines
	365	;; multiple times), but I'm not sure it's what we want.
c51bb5d2 SM	366	(before (goto-char (1- pos)) (skip-chars-backward " \t")
	367	(unless (bolp) (insert "\n")))
	368	(after (insert "\n")) ; FIXME: check eolp before inserting \n?
	369	(around (save-excursion
	370	(goto-char (1- pos)) (skip-chars-backward " \t")
	371	(unless (bolp) (insert "\n")))
	372	(insert "\n"))) ; FIXME: check eolp before inserting \n?
7100ff98 SM	373	(goto-char end)))))
	374
	375	;;;###autoload
	376	(define-minor-mode electric-layout-mode
	377	"Automatically insert newlines around some chars."
	378	:global t
	379	:group 'electricity
	380	(if electric-layout-mode
	381	(add-hook 'post-self-insert-hook
	382	#'electric-layout-post-self-insert-function)
	383	(remove-hook 'post-self-insert-hook
	384	#'electric-layout-post-self-insert-function)))
	385
c0274f38 ER	386	(provide 'electric)
c0274f38 ER	387
c8472948	388	;;; electric.el ends here