[bpt/emacs.git] / lisp / eshell / em-glob.el

;;; em-glob.el --- extended file name globbing

;; Copyright (C) 1999, 2000, 2001, 2002, 2003, 2004,
;;   2005, 2006, 2007, 2008 Free Software Foundation, Inc.

;; Author: John Wiegley <johnw@gnu.org>

;; This file is part of GNU Emacs.

;; GNU Emacs is free software; you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation; either version 3, or (at your option)
;; any later version.

;; GNU Emacs is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License
;; along with GNU Emacs; see the file COPYING.  If not, write to the
;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
;; Boston, MA 02110-1301, USA.

;;; Commentary:

;; The globbing code used by Eshell closely follows the syntax used by
;; zsh.  Basically, here is a summary of examples:
;;
;;   echo a*       ; anything starting with 'a'
;;   echo a#b      ; zero or more 'a's, then 'b'
;;   echo a##b     ; one or more 'a's, then 'b'
;;   echo a?       ; a followed by any character
;;   echo a*~ab    ; 'a', then anything, but not 'ab'
;;   echo c*~*~    ; all files beginning with 'c', except backups (*~)
;;
;; Recursive globbing is also supported:
;;
;;   echo **/*.c   ; all '.c' files at or under current directory
;;   echo ***/*.c  ; same as above, but traverse symbolic links
;;
;; Using argument predication, the recursive globbing syntax is
;; sufficient to replace the use of 'find <expr> | xargs <cmd>' in
;; most cases.  For example, to change the readership of all files
;; belonging to 'johnw' in the '/tmp' directory or lower, use:
;;
;;   chmod go-r /tmp/**/*(u'johnw')
;;
;; The glob above matches all of the files beneath '/tmp' that are
;; owned by the user 'johnw'.  See [Value modifiers and predicates],
;; for more information about argument predication.

;;; Code:

(eval-when-compile (require 'eshell))
(require 'esh-util)

(defgroup eshell-glob nil
  "This module provides extended globbing syntax, similar what is used
by zsh for filename generation."
  :tag "Extended filename globbing"
  :group 'eshell-module)

;;; User Variables:

(defcustom eshell-glob-load-hook '(eshell-glob-initialize)
  "*A list of functions to run when `eshell-glob' is loaded."
  :type 'hook
  :group 'eshell-glob)

(defcustom eshell-glob-include-dot-files nil
  "*If non-nil, glob patterns will match files beginning with a dot."
  :type 'boolean
  :group 'eshell-glob)

(defcustom eshell-glob-include-dot-dot t
  "*If non-nil, glob patterns that match dots will match . and .."
  :type 'boolean
  :group 'eshell-glob)

(defcustom eshell-glob-case-insensitive (eshell-under-windows-p)
  "*If non-nil, glob pattern matching will ignore case."
  :type 'boolean
  :group 'eshell-glob)

(defcustom eshell-glob-show-progress nil
  "*If non-nil, display progress messages during a recursive glob.
This option slows down recursive glob processing by quite a bit."
  :type 'boolean
  :group 'eshell-glob)

(defcustom eshell-error-if-no-glob nil
  "*If non-nil, it is an error for a glob pattern not to match.
 This mimcs the behavior of zsh if non-nil, but bash if nil."
  :type 'boolean
  :group 'eshell-glob)

(defcustom eshell-glob-chars-list '(?\] ?\[ ?* ?? ?~ ?\( ?\) ?| ?# ?^)
  "*List of additional characters used in extended globbing."
  :type '(repeat character)
  :group 'eshell-glob)

(defcustom eshell-glob-translate-alist
  '((?\] . "]")
    (?\[ . "[")
    (?^  . "^")
    (??  . ".")
    (?*  . ".*")
    (?~  . "~")
    (?\( . "\\(")
    (?\) . "\\)")
    (?\| . "\\|")
    (?#  . (lambda (str pos)
	     (if (and (< (1+ pos) (length str))
		      (memq (aref str (1+ pos)) '(?* ?# ?+ ??)))
		 (cons (if (eq (aref str (1+ pos)) ??)
			   "?"
			 (if (eq (aref str (1+ pos)) ?*)
			     "*" "+")) (+ pos 2))
	       (cons "*" (1+ pos))))))
  "*An alist for translation of extended globbing characters."
  :type '(repeat (cons character (choice regexp function)))
  :group 'eshell-glob)

;;; Functions:

(defun eshell-glob-initialize ()
  "Initialize the extended globbing code."
  ;; it's important that `eshell-glob-chars-list' come first
  (when (boundp 'eshell-special-chars-outside-quoting)
    (set (make-local-variable 'eshell-special-chars-outside-quoting)
	 (append eshell-glob-chars-list eshell-special-chars-outside-quoting)))
  (add-hook 'eshell-parse-argument-hook 'eshell-parse-glob-chars t t)
  (add-hook 'eshell-pre-rewrite-command-hook
	    'eshell-no-command-globbing nil t))

(defun eshell-no-command-globbing (terms)
  "Don't glob the command argument.  Reflect this by modifying TERMS."
  (ignore
   (when (and (listp (car terms))
	      (eq (caar terms) 'eshell-extended-glob))
     (setcar terms (cadr (car terms))))))

(defun eshell-add-glob-modifier ()
  "Add `eshell-extended-glob' to the argument modifier list."
  (when (memq 'expand-file-name eshell-current-modifiers)
    (setq eshell-current-modifiers
	  (delq 'expand-file-name eshell-current-modifiers))
    ;; if this is a glob pattern than needs to be expanded, then it
    ;; will need to expand each member of the resulting glob list
    (add-to-list 'eshell-current-modifiers
		 '(lambda (list)
		    (if (listp list)
			(mapcar 'expand-file-name list)
		      (expand-file-name list)))))
  (add-to-list 'eshell-current-modifiers 'eshell-extended-glob))

(defun eshell-parse-glob-chars ()
  "Parse a globbing delimiter.
The character is not advanced for ordinary globbing characters, so
that other function may have a chance to override the globbing
interpretation."
  (when (memq (char-after) eshell-glob-chars-list)
    (if (not (memq (char-after) '(?\( ?\[)))
	(ignore (eshell-add-glob-modifier))
      (let ((here (point)))
	(forward-char)
	(let* ((delim (char-before))
	       (end (eshell-find-delimiter
		     delim (if (eq delim ?\[) ?\] ?\)))))
	  (if (not end)
	      (throw 'eshell-incomplete delim)
	    (if (and (eshell-using-module 'eshell-pred)
		     (eshell-arg-delimiter (1+ end)))
		(ignore (goto-char here))
	      (eshell-add-glob-modifier)
	      (prog1
		  (buffer-substring-no-properties (1- (point)) (1+ end))
		(goto-char (1+ end))))))))))

(defvar eshell-glob-chars-regexp nil)

(defun eshell-glob-regexp (pattern)
  "Convert glob-pattern PATTERN to a regular expression.
The basic syntax is:

  glob  regexp   meaning
  ----  ------   -------
  ?      .       matches any single character
  *      .*      matches any group of characters (or none)
  #      *       matches zero or more occurrences of preceding
  ##     +       matches one or more occurrences of preceding
  (x)    \(x\)   makes 'x' a regular expression group
  |      \|      boolean OR within an expression group
  [a-b]  [a-b]   matches a character or range
  [^a]   [^a]    excludes a character or range

If any characters in PATTERN have the text property `eshell-escaped'
set to true, then these characters will match themselves in the
resulting regular expression."
  (let ((matched-in-pattern 0)          ; How much of PATTERN handled
	regexp)
    (while (string-match
	    (or eshell-glob-chars-regexp
		(set (make-local-variable 'eshell-glob-chars-regexp)
		     (format "[%s]+" (apply 'string eshell-glob-chars-list))))
	    pattern matched-in-pattern)
      (let* ((op-begin (match-beginning 0))
	     (op-char (aref pattern op-begin)))
	(setq regexp
	      (concat regexp
		      (regexp-quote
		       (substring pattern matched-in-pattern op-begin))))
	(if (get-text-property op-begin 'escaped pattern)
	    (setq regexp (concat regexp
				 (regexp-quote (char-to-string op-char)))
		  matched-in-pattern (1+ op-begin))
	  (let ((xlat (assq op-char eshell-glob-translate-alist)))
	    (if (not xlat)
		(error "Unrecognized globbing character '%c'" op-char)
	      (if (stringp (cdr xlat))
		  (setq regexp (concat regexp (cdr xlat))
			matched-in-pattern (1+ op-begin))
		(let ((result (funcall (cdr xlat) pattern op-begin)))
		  (setq regexp (concat regexp (car result))
			matched-in-pattern (cdr result)))))))))
    (concat "\\`"
	    regexp
	    (regexp-quote (substring pattern matched-in-pattern))
	    "\\'")))

(defun eshell-extended-glob (glob)
  "Return a list of files generated from GLOB, perhaps looking for DIRS-ONLY.
This function almost fully supports zsh style filename generation
syntax.  Things that are not supported are:

   ^foo        for matching everything but foo
   (foo~bar)   tilde within a parenthesis group
   foo<1-10>   numeric ranges
   foo~x(a|b)  (a|b) will be interpreted as a predicate/modifier list

Mainly they are not supported because file matching is done with Emacs
regular expressions, and these cannot support the above constructs.

If this routine fails, it returns nil.  Otherwise, it returns a list
the form:

   (INCLUDE-REGEXP EXCLUDE-REGEXP (PRED-FUNC-LIST) (MOD-FUNC-LIST))"
  (let ((paths (eshell-split-path glob))
	matches message-shown ange-cache)
    (unwind-protect
	(if (and (cdr paths)
		 (file-name-absolute-p (car paths)))
	    (eshell-glob-entries (file-name-as-directory (car paths))
				 (cdr paths))
	  (eshell-glob-entries (file-name-as-directory ".") paths))
      (if message-shown
	  (message nil)))
    (or (and matches (sort matches #'string<))
	(if eshell-error-if-no-glob
	    (error "No matches found: %s" glob)
	  glob))))

(eval-when-compile
  (defvar matches)
  (defvar message-shown))

;; FIXME does this really need to abuse matches, message-shown?
(defun eshell-glob-entries (path globs &optional recurse-p)
  "Glob the entries in PATHS, possibly recursing if RECURSE-P is non-nil."
  (let* ((entries (ignore-errors
		    (file-name-all-completions "" path)))
	 (case-fold-search eshell-glob-case-insensitive)
	 (glob (car globs))
	 (len (length glob))
	 dirs rdirs
	 incl excl
	 name isdir pathname)
    (while (cond
	    ((and (= len 3) (equal glob "**/"))
	     (setq recurse-p 2
		   globs (cdr globs)
		   glob (car globs)
		   len (length glob)))
	    ((and (= len 4) (equal glob "***/"))
	     (setq recurse-p 3
		   globs (cdr globs)
		   glob (car globs)
		   len (length glob)))))
    (if (and recurse-p (not glob))
	(error "'**' cannot end a globbing pattern"))
    (let ((index 1))
      (setq incl glob)
      (while (and (eq incl glob)
		  (setq index (string-match "~" glob index)))
	(if (or (get-text-property index 'escaped glob)
		(or (= (1+ index) len)))
	    (setq index (1+ index))
	  (setq incl (substring glob 0 index)
		excl (substring glob (1+ index))))))
    ;; can't use `directory-file-name' because it strips away text
    ;; properties in the string
    (let ((len (1- (length incl))))
      (if (eq (aref incl len) ?/)
	  (setq incl (substring incl 0 len)))
      (when excl
	(setq len (1- (length excl)))
	(if (eq (aref excl len) ?/)
	    (setq excl (substring excl 0 len)))))
    (setq incl (eshell-glob-regexp incl)
	  excl (and excl (eshell-glob-regexp excl)))
    (if (or eshell-glob-include-dot-files
	    (eq (aref glob 0) ?.))
	(unless (or eshell-glob-include-dot-dot
		    (cdr globs))
	  (setq excl (if excl
			 (concat "\\(\\`\\.\\.?\\'\\|" excl "\\)")
		       "\\`\\.\\.?\\'")))
      (setq excl (if excl
		     (concat "\\(\\`\\.\\|" excl "\\)")
		   "\\`\\.")))
    (when (and recurse-p eshell-glob-show-progress)
      (message "Building file list...%d so far: %s"
	       (length matches) path)
      (setq message-shown t))
    (if (equal path "./") (setq path ""))
    (while entries
      (setq name (car entries)
	    len (length name)
	    isdir (eq (aref name (1- len)) ?/))
      (if (let ((fname (directory-file-name name)))
	    (and (not (and excl (string-match excl fname)))
		 (string-match incl fname)))
	  (if (cdr globs)
	      (if isdir
		  (setq dirs (cons (concat path name) dirs)))
	    (setq matches (cons (concat path name) matches))))
      (if (and recurse-p isdir
	       (or (> len 3)
		   (not (or (and (= len 2) (equal name "./"))
			    (and (= len 3) (equal name "../")))))
	       (setq pathname (concat path name))
	       (not (and (= recurse-p 2)
			 (file-symlink-p
			  (directory-file-name pathname)))))
	  (setq rdirs (cons pathname rdirs)))
      (setq entries (cdr entries)))
    (setq dirs (nreverse dirs)
	  rdirs (nreverse rdirs))
    (while dirs
      (eshell-glob-entries (car dirs) (cdr globs))
      (setq dirs (cdr dirs)))
    (while rdirs
      (eshell-glob-entries (car rdirs) globs recurse-p)
      (setq rdirs (cdr rdirs)))))

(provide 'em-glob)

;; arch-tag: d0548f54-fb7c-4978-a88e-f7c26f7f68ca
;;; em-glob.el ends here
Commit	Line	Data
60370d40	1	;;; em-glob.el --- extended file name globbing
affbf647	2
f2e3589a	3	;; Copyright (C) 1999, 2000, 2001, 2002, 2003, 2004,
8b72699e	4	;; 2005, 2006, 2007, 2008 Free Software Foundation, Inc.
affbf647	5
7de5b421 GM	6	;; Author: John Wiegley <johnw@gnu.org>
7de5b421 GM	7
affbf647 GM	8	;; This file is part of GNU Emacs.
	9
	10	;; GNU Emacs is free software; you can redistribute it and/or modify
	11	;; it under the terms of the GNU General Public License as published by
e0085d62	12	;; the Free Software Foundation; either version 3, or (at your option)
affbf647 GM	13	;; any later version.
	14
	15	;; GNU Emacs is distributed in the hope that it will be useful,
	16	;; but WITHOUT ANY WARRANTY; without even the implied warranty of
	17	;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
	18	;; GNU General Public License for more details.
	19
	20	;; You should have received a copy of the GNU General Public License
	21	;; along with GNU Emacs; see the file COPYING. If not, write to the
3a35cf56 LK	22	;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
3a35cf56 LK	23	;; Boston, MA 02110-1301, USA.
affbf647	24
affbf647 GM	25	;;; Commentary:
	26
	27	;; The globbing code used by Eshell closely follows the syntax used by
	28	;; zsh. Basically, here is a summary of examples:
	29	;;
	30	;; echo a* ; anything starting with 'a'
	31	;; echo a#b ; zero or more 'a's, then 'b'
	32	;; echo a##b ; one or more 'a's, then 'b'
	33	;; echo a? ; a followed by any character
	34	;; echo a*~ab ; 'a', then anything, but not 'ab'
	35	;; echo c~~ ; all files beginning with 'c', except backups (*~)
	36	;;
	37	;; Recursive globbing is also supported:
	38	;;
	39	;; echo */.c ; all '.c' files at or under current directory
	40	;; echo **/.c ; same as above, but traverse symbolic links
	41	;;
	42	;; Using argument predication, the recursive globbing syntax is
	43	;; sufficient to replace the use of 'find <expr> \| xargs <cmd>' in
	44	;; most cases. For example, to change the readership of all files
	45	;; belonging to 'johnw' in the '/tmp' directory or lower, use:
	46	;;
	47	;; chmod go-r /tmp/*/(u'johnw')
	48	;;
	49	;; The glob above matches all of the files beneath '/tmp' that are
	50	;; owned by the user 'johnw'. See [Value modifiers and predicates],
	51	;; for more information about argument predication.
	52
dbba8a04 GM	53	;;; Code:
	54
	55	(eval-when-compile (require 'eshell))
	56	(require 'esh-util)
	57
	58	(defgroup eshell-glob nil
	59	"This module provides extended globbing syntax, similar what is used
	60	by zsh for filename generation."
	61	:tag "Extended filename globbing"
	62	:group 'eshell-module)
	63
affbf647 GM	64	;;; User Variables:
	65
	66	(defcustom eshell-glob-load-hook '(eshell-glob-initialize)
	67	"*A list of functions to run when `eshell-glob' is loaded."
	68	:type 'hook
	69	:group 'eshell-glob)
	70
	71	(defcustom eshell-glob-include-dot-files nil
	72	"*If non-nil, glob patterns will match files beginning with a dot."
	73	:type 'boolean
	74	:group 'eshell-glob)
	75
	76	(defcustom eshell-glob-include-dot-dot t
	77	"*If non-nil, glob patterns that match dots will match . and .."
	78	:type 'boolean
	79	:group 'eshell-glob)
	80
70a06174	81	(defcustom eshell-glob-case-insensitive (eshell-under-windows-p)
affbf647 GM	82	"*If non-nil, glob pattern matching will ignore case."
	83	:type 'boolean
	84	:group 'eshell-glob)
	85
dace60cf JW	86	(defcustom eshell-glob-show-progress nil
	87	"*If non-nil, display progress messages during a recursive glob.
	88	This option slows down recursive glob processing by quite a bit."
affbf647 GM	89	:type 'boolean
	90	:group 'eshell-glob)
	91
	92	(defcustom eshell-error-if-no-glob nil
	93	"*If non-nil, it is an error for a glob pattern not to match.
	94	This mimcs the behavior of zsh if non-nil, but bash if nil."
	95	:type 'boolean
	96	:group 'eshell-glob)
	97
f80c9382	98	(defcustom eshell-glob-chars-list '(?\] ?\[ ?* ?? ?~ ?\( ?\) ?\| ?# ?^)
affbf647 GM	99	"*List of additional characters used in extended globbing."
	100	:type '(repeat character)
	101	:group 'eshell-glob)
	102
	103	(defcustom eshell-glob-translate-alist
	104	'((?\] . "]")
	105	(?\[ . "[")
f80c9382	106	(?^ . "^")
affbf647 GM	107	(?? . ".")
	108	(?* . ".*")
	109	(?~ . "~")
	110	(?\( . "\\(")
	111	(?\) . "\\)")
	112	(?\\| . "\\\|")
	113	(?# . (lambda (str pos)
	114	(if (and (< (1+ pos) (length str))
	115	(memq (aref str (1+ pos)) '(?* ?# ?+ ??)))
	116	(cons (if (eq (aref str (1+ pos)) ??)
	117	"?"
	118	(if (eq (aref str (1+ pos)) ?*)
	119	"*" "+")) (+ pos 2))
	120	(cons "*" (1+ pos))))))
	121	"*An alist for translation of extended globbing characters."
	122	:type '(repeat (cons character (choice regexp function)))
	123	:group 'eshell-glob)
	124
affbf647 GM	125	;;; Functions:
	126
	127	(defun eshell-glob-initialize ()
	128	"Initialize the extended globbing code."
	129	;; it's important that `eshell-glob-chars-list' come first
6d736b08 SM	130	(when (boundp 'eshell-special-chars-outside-quoting)
	131	(set (make-local-variable 'eshell-special-chars-outside-quoting)
	132	(append eshell-glob-chars-list eshell-special-chars-outside-quoting)))
affbf647	133	(add-hook 'eshell-parse-argument-hook 'eshell-parse-glob-chars t t)
affbf647 GM	134	(add-hook 'eshell-pre-rewrite-command-hook
	135	'eshell-no-command-globbing nil t))
	136
	137	(defun eshell-no-command-globbing (terms)
	138	"Don't glob the command argument. Reflect this by modifying TERMS."
	139	(ignore
	140	(when (and (listp (car terms))
	141	(eq (caar terms) 'eshell-extended-glob))
	142	(setcar terms (cadr (car terms))))))
	143
	144	(defun eshell-add-glob-modifier ()
	145	"Add `eshell-extended-glob' to the argument modifier list."
	146	(when (memq 'expand-file-name eshell-current-modifiers)
	147	(setq eshell-current-modifiers
	148	(delq 'expand-file-name eshell-current-modifiers))
	149	;; if this is a glob pattern than needs to be expanded, then it
	150	;; will need to expand each member of the resulting glob list
	151	(add-to-list 'eshell-current-modifiers
	152	'(lambda (list)
	153	(if (listp list)
	154	(mapcar 'expand-file-name list)
	155	(expand-file-name list)))))
	156	(add-to-list 'eshell-current-modifiers 'eshell-extended-glob))
	157
	158	(defun eshell-parse-glob-chars ()
	159	"Parse a globbing delimiter.
	160	The character is not advanced for ordinary globbing characters, so
	161	that other function may have a chance to override the globbing
	162	interpretation."
	163	(when (memq (char-after) eshell-glob-chars-list)
	164	(if (not (memq (char-after) '(?\( ?\[)))
	165	(ignore (eshell-add-glob-modifier))
	166	(let ((here (point)))
	167	(forward-char)
	168	(let* ((delim (char-before))
	169	(end (eshell-find-delimiter
	170	delim (if (eq delim ?\[) ?\] ?\)))))
	171	(if (not end)
	172	(throw 'eshell-incomplete delim)
	173	(if (and (eshell-using-module 'eshell-pred)
	174	(eshell-arg-delimiter (1+ end)))
	175	(ignore (goto-char here))
	176	(eshell-add-glob-modifier)
	177	(prog1
	178	(buffer-substring-no-properties (1- (point)) (1+ end))
	179	(goto-char (1+ end))))))))))
	180
4403b1e1 JW	181	(defvar eshell-glob-chars-regexp nil)
4403b1e1 JW	182
affbf647 GM	183	(defun eshell-glob-regexp (pattern)
	184	"Convert glob-pattern PATTERN to a regular expression.
	185	The basic syntax is:
	186
	187	glob regexp meaning
	188	---- ------ -------
	189	? . matches any single character
	190	* .* matches any group of characters (or none)
	191	# * matches zero or more occurrences of preceding
	192	## + matches one or more occurrences of preceding
	193	(x) \(x\) makes 'x' a regular expression group
	194	\| \\| boolean OR within an expression group
	195	[a-b] [a-b] matches a character or range
	196	[^a] [^a] excludes a character or range
	197
	198	If any characters in PATTERN have the text property `eshell-escaped'
	199	set to true, then these characters will match themselves in the
	200	resulting regular expression."
	201	(let ((matched-in-pattern 0) ; How much of PATTERN handled
	202	regexp)
4403b1e1 JW	203	(while (string-match
	204	(or eshell-glob-chars-regexp
	205	(set (make-local-variable 'eshell-glob-chars-regexp)
	206	(format "[%s]+" (apply 'string eshell-glob-chars-list))))
	207	pattern matched-in-pattern)
affbf647 GM	208	(let* ((op-begin (match-beginning 0))
	209	(op-char (aref pattern op-begin)))
	210	(setq regexp
	211	(concat regexp
	212	(regexp-quote
	213	(substring pattern matched-in-pattern op-begin))))
	214	(if (get-text-property op-begin 'escaped pattern)
	215	(setq regexp (concat regexp
	216	(regexp-quote (char-to-string op-char)))
	217	matched-in-pattern (1+ op-begin))
	218	(let ((xlat (assq op-char eshell-glob-translate-alist)))
	219	(if (not xlat)
	220	(error "Unrecognized globbing character '%c'" op-char)
	221	(if (stringp (cdr xlat))
	222	(setq regexp (concat regexp (cdr xlat))
	223	matched-in-pattern (1+ op-begin))
	224	(let ((result (funcall (cdr xlat) pattern op-begin)))
	225	(setq regexp (concat regexp (car result))
	226	matched-in-pattern (cdr result)))))))))
	227	(concat "\\`"
	228	regexp
	229	(regexp-quote (substring pattern matched-in-pattern))
	230	"\\'")))
	231
	232	(defun eshell-extended-glob (glob)
	233	"Return a list of files generated from GLOB, perhaps looking for DIRS-ONLY.
6d736b08 SM	234	This function almost fully supports zsh style filename generation
6d736b08 SM	235	syntax. Things that are not supported are:
affbf647 GM	236
	237	^foo for matching everything but foo
	238	(foo~bar) tilde within a parenthesis group
	239	foo<1-10> numeric ranges
	240	foo~x(a\|b) (a\|b) will be interpreted as a predicate/modifier list
	241
6d736b08 SM	242	Mainly they are not supported because file matching is done with Emacs
6d736b08 SM	243	regular expressions, and these cannot support the above constructs.
affbf647	244
6d736b08 SM	245	If this routine fails, it returns nil. Otherwise, it returns a list
6d736b08 SM	246	the form:
affbf647 GM	247
	248	(INCLUDE-REGEXP EXCLUDE-REGEXP (PRED-FUNC-LIST) (MOD-FUNC-LIST))"
	249	(let ((paths (eshell-split-path glob))
8c6b1d83	250	matches message-shown ange-cache)
affbf647 GM	251	(unwind-protect
	252	(if (and (cdr paths)
	253	(file-name-absolute-p (car paths)))
	254	(eshell-glob-entries (file-name-as-directory (car paths))
	255	(cdr paths))
dbc56a8b	256	(eshell-glob-entries (file-name-as-directory ".") paths))
affbf647 GM	257	(if message-shown
affbf647 GM	258	(message nil)))
53afc686	259	(or (and matches (sort matches #'string<))
affbf647 GM	260	(if eshell-error-if-no-glob
	261	(error "No matches found: %s" glob)
	262	glob))))
	263
	264	(eval-when-compile
	265	(defvar matches)
	266	(defvar message-shown))
	267
f117c226	268	;; FIXME does this really need to abuse matches, message-shown?
affbf647 GM	269	(defun eshell-glob-entries (path globs &optional recurse-p)
	270	"Glob the entries in PATHS, possibly recursing if RECURSE-P is non-nil."
	271	(let* ((entries (ignore-errors
	272	(file-name-all-completions "" path)))
	273	(case-fold-search eshell-glob-case-insensitive)
	274	(glob (car globs))
	275	(len (length glob))
	276	dirs rdirs
	277	incl excl
	278	name isdir pathname)
	279	(while (cond
	280	((and (= len 3) (equal glob "**/"))
	281	(setq recurse-p 2
	282	globs (cdr globs)
	283	glob (car globs)
	284	len (length glob)))
	285	((and (= len 4) (equal glob "***/"))
	286	(setq recurse-p 3
	287	globs (cdr globs)
	288	glob (car globs)
	289	len (length glob)))))
	290	(if (and recurse-p (not glob))
	291	(error "'**' cannot end a globbing pattern"))
	292	(let ((index 1))
	293	(setq incl glob)
	294	(while (and (eq incl glob)
	295	(setq index (string-match "~" glob index)))
	296	(if (or (get-text-property index 'escaped glob)
	297	(or (= (1+ index) len)))
	298	(setq index (1+ index))
	299	(setq incl (substring glob 0 index)
	300	excl (substring glob (1+ index))))))
	301	;; can't use `directory-file-name' because it strips away text
	302	;; properties in the string
	303	(let ((len (1- (length incl))))
6b0e3e4d	304	(if (eq (aref incl len) ?/)
affbf647 GM	305	(setq incl (substring incl 0 len)))
	306	(when excl
	307	(setq len (1- (length excl)))
6b0e3e4d	308	(if (eq (aref excl len) ?/)
affbf647 GM	309	(setq excl (substring excl 0 len)))))
	310	(setq incl (eshell-glob-regexp incl)
	311	excl (and excl (eshell-glob-regexp excl)))
	312	(if (or eshell-glob-include-dot-files
	313	(eq (aref glob 0) ?.))
	314	(unless (or eshell-glob-include-dot-dot
	315	(cdr globs))
	316	(setq excl (if excl
	317	(concat "\\(\\`\\.\\.?\\'\\\|" excl "\\)")
	318	"\\`\\.\\.?\\'")))
	319	(setq excl (if excl
	320	(concat "\\(\\`\\.\\\|" excl "\\)")
	321	"\\`\\.")))
	322	(when (and recurse-p eshell-glob-show-progress)
	323	(message "Building file list...%d so far: %s"
	324	(length matches) path)
	325	(setq message-shown t))
	326	(if (equal path "./") (setq path ""))
	327	(while entries
	328	(setq name (car entries)
	329	len (length name)
6b0e3e4d	330	isdir (eq (aref name (1- len)) ?/))
affbf647 GM	331	(if (let ((fname (directory-file-name name)))
	332	(and (not (and excl (string-match excl fname)))
	333	(string-match incl fname)))
	334	(if (cdr globs)
	335	(if isdir
	336	(setq dirs (cons (concat path name) dirs)))
	337	(setq matches (cons (concat path name) matches))))
	338	(if (and recurse-p isdir
	339	(or (> len 3)
	340	(not (or (and (= len 2) (equal name "./"))
	341	(and (= len 3) (equal name "../")))))
	342	(setq pathname (concat path name))
	343	(not (and (= recurse-p 2)
	344	(file-symlink-p
	345	(directory-file-name pathname)))))
	346	(setq rdirs (cons pathname rdirs)))
	347	(setq entries (cdr entries)))
	348	(setq dirs (nreverse dirs)
	349	rdirs (nreverse rdirs))
	350	(while dirs
	351	(eshell-glob-entries (car dirs) (cdr globs))
	352	(setq dirs (cdr dirs)))
	353	(while rdirs
	354	(eshell-glob-entries (car rdirs) globs recurse-p)
	355	(setq rdirs (cdr rdirs)))))
	356
dbba8a04 GM	357	(provide 'em-glob)
dbba8a04 GM	358
cbee283d	359	;; arch-tag: d0548f54-fb7c-4978-a88e-f7c26f7f68ca
affbf647	360	;;; em-glob.el ends here