Commit | Line | Data |
---|---|---|
19f79085 | 1 | ;;; fast-lock.el --- Automagic text properties caching for fast Font Lock mode. |
6492fcd1 | 2 | |
b578f267 | 3 | ;; Copyright (C) 1994, 1995, 1996 Free Software Foundation, Inc. |
6492fcd1 | 4 | |
19f79085 | 5 | ;; Author: Simon Marshall <simon@gnu.ai.mit.edu> |
6492fcd1 | 6 | ;; Keywords: faces files |
9ebfa5ef | 7 | ;; Version: 3.08 |
6492fcd1 | 8 | |
b578f267 | 9 | ;; This file is part of GNU Emacs. |
6492fcd1 RS |
10 | |
11 | ;; GNU Emacs is free software; you can redistribute it and/or modify | |
12 | ;; it under the terms of the GNU General Public License as published by | |
13 | ;; the Free Software Foundation; either version 2, or (at your option) | |
14 | ;; any later version. | |
15 | ||
16 | ;; GNU Emacs is distributed in the hope that it will be useful, | |
17 | ;; but WITHOUT ANY WARRANTY; without even the implied warranty of | |
18 | ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the | |
19 | ;; GNU General Public License for more details. | |
20 | ||
21 | ;; You should have received a copy of the GNU General Public License | |
b578f267 EN |
22 | ;; along with GNU Emacs; see the file COPYING. If not, write to the |
23 | ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330, | |
24 | ;; Boston, MA 02111-1307, USA. | |
6492fcd1 RS |
25 | |
26 | ;;; Commentary: | |
27 | ||
28 | ;; Purpose: | |
29 | ;; | |
30 | ;; To make visiting a file in `font-lock-mode' faster by restoring its face | |
19f79085 | 31 | ;; text properties from automatically saved associated Font Lock cache files. |
6492fcd1 | 32 | ;; |
19f79085 | 33 | ;; See caveats and feedback below. |
6492fcd1 RS |
34 | ;; See also the lazy-lock package. (But don't use the two at the same time!) |
35 | ||
6492fcd1 RS |
36 | ;; Installation: |
37 | ;; | |
19f79085 | 38 | ;; Put in your ~/.emacs: |
6492fcd1 RS |
39 | ;; |
40 | ;; (add-hook 'font-lock-mode-hook 'turn-on-fast-lock) | |
41 | ;; | |
42 | ;; Start up a new Emacs and use font-lock as usual (except that you can use the | |
43 | ;; so-called "gaudier" fontification regexps on big files without frustration). | |
44 | ;; | |
45 | ;; When you visit a file (which has `font-lock-mode' enabled) that has a | |
19f79085 SM |
46 | ;; corresponding Font Lock cache file associated with it, the Font Lock cache |
47 | ;; will be loaded from that file instead of being generated by Font Lock code. | |
48 | ||
49 | ;; Caveats: | |
6492fcd1 | 50 | ;; |
19f79085 SM |
51 | ;; A cache will be saved when visiting a compressed file using crypt++, but not |
52 | ;; be read. This is a "feature"/"consequence"/"bug" of crypt++. | |
6492fcd1 | 53 | ;; |
19f79085 SM |
54 | ;; Version control packages are likely to stamp all over file modification |
55 | ;; times. Therefore the act of checking out may invalidate a cache. | |
6492fcd1 RS |
56 | |
57 | ;; Feedback: | |
58 | ;; | |
19f79085 SM |
59 | ;; Feedback is welcome. |
60 | ;; To submit a bug report (or make comments) please use the mechanism provided: | |
61 | ;; | |
62 | ;; M-x fast-lock-submit-bug-report RET | |
6492fcd1 | 63 | \f |
ebdee0a0 SM |
64 | ;; History: |
65 | ;; | |
66 | ;; 0.02--1.00: | |
67 | ;; - Changed name from turbo-prop to fast-lock. Automagic for font-lock only. | |
68 | ;; - Made `fast-lock-mode' a minor mode, like G. Dinesh Dutt's fss-mode. | |
69 | ;; 1.00--1.01: | |
70 | ;; - Turn on `fast-lock-mode' only if `buffer-file-name' or `interactive-p'. | |
71 | ;; - Made `fast-lock-file-name' use `buffer-name' if `buffer-file-name' is nil. | |
72 | ;; - Moved save-all conditions to `fast-lock-save-cache'. | |
73 | ;; - Added `fast-lock-save-text-properties' to `kill-buffer-hook'. | |
74 | ;; 1.01--2.00: complete rewrite---not worth the space to document. | |
75 | ;; - Changed structure of text properties cache and threw out file mod checks. | |
76 | ;; 2.00--2.01: | |
77 | ;; - Made `condition-case' forms understand `quit'. | |
78 | ;; - Made `fast-lock' require `font-lock'. | |
79 | ;; - Made `fast-lock-cache-name' chase links (from Ben Liblit). | |
80 | ;; 2.01--3.00: | |
81 | ;; - Changed structure of cache to include `font-lock-keywords' (from rms). | |
82 | ;; - Changed `fast-lock-cache-mechanisms' to `fast-lock-cache-directories'. | |
83 | ;; - Removed `fast-lock-read-others'. | |
84 | ;; - Made `fast-lock-read-cache' ignore cache owner. | |
85 | ;; - Made `fast-lock-save-cache-external' create cache directory. | |
86 | ;; - Made `fast-lock-save-cache-external' save `font-lock-keywords'. | |
87 | ;; - Made `fast-lock-cache-data' check `font-lock-keywords'. | |
88 | ;; 3.00--3.01: incorporated port of 2.00 to Lucid, made by Barry Warsaw. | |
89 | ;; - Package now provides itself. | |
90 | ;; - Lucid: Use `font-lock-any-extents-p' for `font-lock-any-properties-p'. | |
91 | ;; - Lucid: Use `list-faces' for `face-list'. | |
92 | ;; - Lucid: Added `set-text-properties'. | |
93 | ;; - Lucid: Made `turn-on-fast-lock' pass 1 not t to `fast-lock-mode'. | |
94 | ;; - Removed test for `fast-lock-mode' from `fast-lock-read-cache'. | |
95 | ;; - Lucid: Added Lucid-specific `fast-lock-get-face-properties'. | |
96 | ;; 3.01--3.02: now works with Lucid Emacs, thanks to Barry Warsaw. | |
97 | ;; - Made `fast-lock-cache-name' map ":" to ";" for OS/2 (from Serganova Vera). | |
98 | ;; - Made `fast-lock-cache-name' use abbreviated file name (from Barry Warsaw). | |
99 | ;; - Lucid: Separated handlers for `error' and `quit' for `condition-case'. | |
100 | ;; 3.02--3.03: | |
101 | ;; - Changed `fast-lock-save-cache-external' to `fast-lock-save-cache-data'. | |
102 | ;; - Lucid: Added Lucid-specific `fast-lock-set-face-properties'. | |
103 | ;; 3.03--3.04: | |
104 | ;; - Corrected `subrp' test of Lucid code. | |
105 | ;; - Replaced `font-lock-any-properties-p' with `text-property-not-all'. | |
106 | ;; - Lucid: Made `fast-lock-set-face-properties' put `text-prop' on extents. | |
107 | ;; - Made `fast-lock-cache-directories' a regexp alist (from Colin Rafferty). | |
108 | ;; - Made `fast-lock-cache-directory' to return a usable cache file directory. | |
109 | ;; 3.04--3.05: | |
110 | ;; - Lucid: Fix for XEmacs 19.11 `text-property-not-all'. | |
111 | ;; - Replaced `subrp' test of Lucid code with `emacs-version' `string-match'. | |
112 | ;; - Made `byte-compile-warnings' omit `unresolved' on compilation. | |
113 | ;; - Made `fast-lock-save-cache-data' use a buffer (from Rick Sladkey). | |
114 | ;; - Reverted to old `fast-lock-get-face-properties' (from Rick Sladkey). | |
115 | ;; 3.05--3.06: incorporated hack of 3.03, made by Jonathan Stigelman (Stig). | |
116 | ;; - Reverted to 3.04 version of `fast-lock-get-face-properties'. | |
117 | ;; - XEmacs: Removed `list-faces' `defalias'. | |
118 | ;; - Made `fast-lock-mode' and `turn-on-fast-lock' succeed `autoload' cookies. | |
119 | ;; - Added `lazy-lock-submit-bug-report'. | |
120 | ;; - Renamed `fast-lock-save-size' to `fast-lock-minimum-size'. | |
121 | ;; - Made `fast-lock-save-cache' output a message if no save ever attempted. | |
122 | ;; - Made `fast-lock-save-cache-data' output a message if save attempted. | |
123 | ;; - Made `fast-lock-cache-data' output a message if load attempted. | |
124 | ;; - Made `fast-lock-save-cache-data' do `condition-case' not `unwind-protect'. | |
125 | ;; - Made `fast-lock-save-cache' and `fast-lock-read-cache' return nothing. | |
126 | ;; - Made `fast-lock-save-cache' check `buffer-modified-p' (Stig). | |
127 | ;; - Added `fast-lock-save-events'. | |
128 | ;; - Added `fast-lock-after-save-hook' to `after-save-hook' (Stig). | |
129 | ;; - Added `fast-lock-kill-buffer-hook' to `kill-buffer-hook'. | |
130 | ;; - Changed `fast-lock-save-caches' to `fast-lock-kill-emacs-hook'. | |
131 | ;; - Added `fast-lock-kill-emacs-hook' to `kill-emacs-hook'. | |
132 | ;; - Made `fast-lock-save-cache' check `verify-visited-file-modtime' (Stig). | |
133 | ;; - Made `visited-file-modtime' be the basis of the timestamp (Stig). | |
134 | ;; - Made `fast-lock-save-cache-1' and `fast-lock-cache-data' use/reformat it. | |
135 | ;; - Added `fast-lock-cache-filename' to keep track of the cache file name. | |
136 | ;; - Added `fast-lock-after-fontify-buffer'. | |
137 | ;; - Added `fast-lock-save-faces' list of faces to save (idea from Stig/Tibor). | |
138 | ;; - Made `fast-lock-get-face-properties' functions use it. | |
139 | ;; - XEmacs: Made `fast-lock-set-face-properties' do extents the Font Lock way. | |
140 | ;; - XEmacs: Removed fix for `text-property-not-all' (19.11 support dropped). | |
141 | ;; - Made `fast-lock-mode' ensure `font-lock-mode' is on. | |
142 | ;; - Made `fast-lock-save-cache' do `cdr-safe' not `cdr' (from Dave Foster). | |
143 | ;; - Made `fast-lock-save-cache' do `set-buffer' first (from Dave Foster). | |
144 | ;; - Made `fast-lock-save-cache' loop until saved or quit (from Georg Nikodym). | |
145 | ;; - Made `fast-lock-cache-data' check `buffer-modified-p'. | |
146 | ;; - Made `fast-lock-cache-data' do `font-lock-compile-keywords' if necessary. | |
147 | ;; - XEmacs: Made `font-lock-compile-keywords' `defalias'. | |
148 | ;; 3.06--3.07: | |
149 | ;; - XEmacs: Add `fast-lock-after-fontify-buffer' to the Font Lock hook. | |
150 | ;; - Made `fast-lock-cache-name' explain the use of `directory-abbrev-alist'. | |
151 | ;; - Made `fast-lock-mode' use `buffer-file-truename' not `buffer-file-name'. | |
9ebfa5ef SM |
152 | ;; 3.07--3.08: |
153 | ;; - Made `fast-lock-read-cache' set `fast-lock-cache-filename'. | |
ebdee0a0 | 154 | \f |
6492fcd1 RS |
155 | (require 'font-lock) |
156 | ||
157 | (eval-when-compile | |
158 | ;; Shut Emacs' byte-compiler up (cf. stop me getting mail from users). | |
159 | (setq byte-compile-warnings '(free-vars callargs redefine))) | |
160 | ||
19f79085 SM |
161 | (defun fast-lock-submit-bug-report () |
162 | "Submit via mail a bug report on fast-lock.el." | |
163 | (interactive) | |
164 | (let ((reporter-prompt-for-summary-p t)) | |
9ebfa5ef | 165 | (reporter-submit-bug-report "simon@gnu.ai.mit.edu" "fast-lock 3.08" |
19f79085 SM |
166 | '(fast-lock-cache-directories fast-lock-minimum-size |
167 | fast-lock-save-others fast-lock-save-events fast-lock-save-faces) | |
168 | nil nil | |
169 | (concat "Hi Si., | |
170 | ||
171 | I want to report a bug. I've read the `Bugs' section of `Info' on Emacs, so I | |
172 | know how to make a clear and unambiguous report. To reproduce the bug: | |
173 | ||
174 | Start a fresh Emacs via `" invocation-name " -no-init-file -no-site-file'. | |
175 | In the `*scratch*' buffer, evaluate:")))) | |
176 | ||
177 | ;;;###autoload | |
178 | (defvar fast-lock-mode nil) ; for modeline | |
179 | (defvar fast-lock-cache-timestamp nil) ; for saving/reading | |
180 | (defvar fast-lock-cache-filename nil) ; for deleting | |
181 | \f | |
182 | ;; User Variables: | |
6492fcd1 RS |
183 | |
184 | (defvar fast-lock-cache-directories '("." "~/.emacs-flc") | |
19f79085 SM |
185 | ; - `internal', keep each file's Font Lock cache file in the same file. |
186 | ; - `external', keep each file's Font Lock cache file in the same directory. | |
187 | "Directories in which Font Lock cache files are saved and read. | |
6492fcd1 RS |
188 | Each item should be either DIR or a cons pair of the form (REGEXP . DIR) where |
189 | DIR is a directory name (relative or absolute) and REGEXP is a regexp. | |
190 | ||
19f79085 | 191 | An attempt will be made to save or read Font Lock cache files using these items |
6492fcd1 RS |
192 | until one succeeds (i.e., until a readable or writable one is found). If an |
193 | item contains REGEXP, DIR is used only if the buffer file name matches REGEXP. | |
194 | For example: | |
195 | ||
ebdee0a0 SM |
196 | (let ((home (expand-file-name (abbreviate-file-name (file-truename \"~/\"))))) |
197 | (list (cons (concat \"^\" (regexp-quote home)) \".\") \"~/.emacs-flc\")) | |
198 | => | |
199 | ((\"^/your/true/home/directory/\" . \".\") \"~/.emacs-flc\") | |
6492fcd1 RS |
200 | |
201 | would cause a file's current directory to be used if the file is under your | |
19f79085 | 202 | home directory hierarchy, or otherwise the absolute directory `~/.emacs-flc'.") |
6492fcd1 | 203 | |
19f79085 SM |
204 | (defvar fast-lock-minimum-size (* 25 1024) |
205 | "If non-nil, the minimum size for buffers. | |
206 | Only buffers more than this can have associated Font Lock cache files saved. | |
207 | If nil, means size is irrelevant.") | |
6492fcd1 | 208 | |
19f79085 SM |
209 | (defvar fast-lock-save-events '(kill-buffer kill-emacs) |
210 | "A list of events under which caches will be saved. | |
211 | Valid events are `save-buffer', `kill-buffer' and `kill-emacs'. | |
212 | If concurrent editing sessions use the same associated cache file for a file's | |
213 | buffer, then you should add `save-buffer' to this list.") | |
6492fcd1 | 214 | |
19f79085 SM |
215 | (defvar fast-lock-save-others t |
216 | "If non-nil, save Font Lock cache files irrespective of file owner. | |
217 | If nil, means only buffer files known to be owned by you can have associated | |
218 | Font Lock cache files saved. Ownership may be unknown for networked files.") | |
219 | ||
220 | (defvar fast-lock-save-faces | |
221 | ;; Since XEmacs uses extents for everything, we have to pick the right ones. | |
ebdee0a0 | 222 | ;; In XEmacs 19.13 we can't identify which text properties are Font Lock's. |
19f79085 SM |
223 | (if (save-match-data (string-match "XEmacs" (emacs-version))) |
224 | '(font-lock-string-face font-lock-doc-string-face font-lock-type-face | |
225 | font-lock-function-name-face font-lock-comment-face | |
ebdee0a0 SM |
226 | font-lock-keyword-face font-lock-preprocessor-face) |
227 | ;; For Emacs 19.30 I don't think this is generally necessary. | |
228 | nil) | |
19f79085 SM |
229 | "A list of faces that will be saved in a Font Lock cache file. |
230 | If nil, means information for all faces will be saved.") | |
6492fcd1 | 231 | \f |
19f79085 | 232 | ;; User Functions: |
6492fcd1 | 233 | |
19f79085 | 234 | ;;;###autoload |
6492fcd1 RS |
235 | (defun fast-lock-mode (&optional arg) |
236 | "Toggle Fast Lock mode. | |
237 | With arg, turn Fast Lock mode on if and only if arg is positive and the buffer | |
19f79085 SM |
238 | is associated with a file. Enable it automatically in your `~/.emacs' by: |
239 | ||
240 | (add-hook 'font-lock-mode-hook 'turn-on-fast-lock) | |
6492fcd1 RS |
241 | |
242 | If Fast Lock mode is enabled, and the current buffer does not contain any text | |
19f79085 SM |
243 | properties, any associated Font Lock cache is used if its timestamp matches the |
244 | buffer's file, and its `font-lock-keywords' match those that you are using. | |
245 | ||
246 | Font Lock caches may be saved: | |
247 | - When you save the file's buffer. | |
248 | - When you kill an unmodified file's buffer. | |
249 | - When you exit Emacs, for all unmodified or saved buffers. | |
250 | Depending on the value of `fast-lock-save-events'. | |
251 | See also the commands `fast-lock-read-cache' and `fast-lock-save-cache'. | |
6492fcd1 | 252 | |
19f79085 | 253 | Use \\[font-lock-fontify-buffer] to fontify the buffer if the cache is bad. |
6492fcd1 | 254 | |
19f79085 | 255 | Various methods of control are provided for the Font Lock cache. In general, |
6492fcd1 | 256 | see variable `fast-lock-cache-directories' and function `fast-lock-cache-name'. |
19f79085 SM |
257 | For saving, see variables `fast-lock-minimum-size', `fast-lock-save-events', |
258 | `fast-lock-save-others' and `fast-lock-save-faces'. | |
259 | ||
260 | Use \\[fast-lock-submit-bug-report] to send bug reports or feedback." | |
6492fcd1 | 261 | (interactive "P") |
9ebfa5ef SM |
262 | ;; Only turn on if we are visiting a file. We could use `buffer-file-name', |
263 | ;; but many packages temporarily wrap that to nil when doing their own thing. | |
6492fcd1 | 264 | (set (make-local-variable 'fast-lock-mode) |
ebdee0a0 | 265 | (and buffer-file-truename |
6492fcd1 | 266 | (if arg (> (prefix-numeric-value arg) 0) (not fast-lock-mode)))) |
19f79085 SM |
267 | (if (and fast-lock-mode (not font-lock-mode)) |
268 | ;; Turned on `fast-lock-mode' rather than using `font-lock-mode-hook'. | |
269 | (progn | |
270 | (add-hook 'font-lock-mode-hook 'turn-on-fast-lock) | |
ebdee0a0 | 271 | (font-lock-mode t)) |
19f79085 SM |
272 | ;; Let's get down to business. |
273 | (set (make-local-variable 'fast-lock-cache-timestamp) nil) | |
274 | (set (make-local-variable 'fast-lock-cache-filename) nil) | |
275 | (if (and fast-lock-mode (not font-lock-fontified)) | |
276 | (fast-lock-read-cache)))) | |
6492fcd1 RS |
277 | |
278 | (defun fast-lock-read-cache () | |
19f79085 | 279 | "Read the Font Lock cache for the current buffer. |
6492fcd1 | 280 | |
19f79085 | 281 | The following criteria must be met for a Font Lock cache file to be read: |
6492fcd1 | 282 | - Fast Lock mode must be turned on in the buffer. |
19f79085 | 283 | - The buffer must not be modified. |
6492fcd1 RS |
284 | - The buffer's `font-lock-keywords' must match the cache's. |
285 | - The buffer file's timestamp must match the cache's. | |
286 | - Criteria imposed by `fast-lock-cache-directories'. | |
287 | ||
19f79085 | 288 | See `fast-lock-mode'." |
6492fcd1 | 289 | (interactive) |
19f79085 SM |
290 | (let ((directories fast-lock-cache-directories) |
291 | (modified (buffer-modified-p)) (inhibit-read-only t) | |
6492fcd1 RS |
292 | (fontified font-lock-fontified)) |
293 | (set (make-local-variable 'font-lock-fontified) nil) | |
294 | ;; Keep trying directories until fontification is turned off. | |
295 | (while (and directories (not font-lock-fontified)) | |
9ebfa5ef SM |
296 | (let ((directory (fast-lock-cache-directory (car directories) nil))) |
297 | (if (not directory) | |
298 | nil | |
299 | (setq fast-lock-cache-filename (fast-lock-cache-name directory)) | |
300 | (condition-case nil | |
301 | (if (file-readable-p fast-lock-cache-filename) | |
302 | (load fast-lock-cache-filename t t t)) | |
303 | (error nil) (quit nil))) | |
19f79085 | 304 | (setq directories (cdr directories)))) |
9ebfa5ef SM |
305 | ;; Unset `fast-lock-cache-filename', and restore `font-lock-fontified', if |
306 | ;; we don't use a cache. (Note that `fast-lock-cache-data' sets the value | |
307 | ;; of `fast-lock-cache-timestamp'.) | |
6492fcd1 | 308 | (set-buffer-modified-p modified) |
9ebfa5ef SM |
309 | (if (not font-lock-fontified) |
310 | (setq fast-lock-cache-filename nil font-lock-fontified fontified)))) | |
6492fcd1 RS |
311 | |
312 | (defun fast-lock-save-cache (&optional buffer) | |
19f79085 | 313 | "Save the Font Lock cache of BUFFER or the current buffer. |
6492fcd1 | 314 | |
19f79085 | 315 | The following criteria must be met for a Font Lock cache file to be saved: |
6492fcd1 | 316 | - Fast Lock mode must be turned on in the buffer. |
19f79085 SM |
317 | - The event must be one of `fast-lock-save-events'. |
318 | - The buffer must be at least `fast-lock-minimum-size' bytes long. | |
6492fcd1 RS |
319 | - The buffer file must be owned by you, or `fast-lock-save-others' must be t. |
320 | - The buffer must contain at least one `face' text property. | |
19f79085 SM |
321 | - The buffer must not be modified. |
322 | - The buffer file's timestamp must be the same as the file's on disk. | |
323 | - The on disk file's timestamp must be different than the buffer's cache. | |
6492fcd1 RS |
324 | - Criteria imposed by `fast-lock-cache-directories'. |
325 | ||
19f79085 | 326 | See `fast-lock-mode'." |
6492fcd1 | 327 | (interactive) |
19f79085 SM |
328 | (save-excursion |
329 | (and buffer (set-buffer buffer)) | |
330 | (let ((file-timestamp (visited-file-modtime)) (saved nil)) | |
6492fcd1 | 331 | (if (and fast-lock-mode |
19f79085 SM |
332 | ;; |
333 | ;; "Only save if the buffer matches the file, the file has | |
334 | ;; changed, and it was changed by the current emacs session." | |
335 | ;; | |
336 | ;; Only save if the buffer is not modified, | |
337 | ;; (i.e., so we don't save for something not on disk) | |
338 | (not (buffer-modified-p)) | |
339 | ;; and the file's timestamp is the same as the buffer's, | |
340 | ;; (i.e., someone else hasn't written the file in the meantime) | |
341 | (verify-visited-file-modtime (current-buffer)) | |
342 | ;; and the file's timestamp is different from the cache's. | |
343 | ;; (i.e., a save has occurred since the cache was read) | |
344 | (not (equal fast-lock-cache-timestamp file-timestamp)) | |
345 | ;; | |
346 | ;; Only save if user's restrictions are satisfied. | |
347 | (or (not fast-lock-minimum-size) | |
348 | (<= fast-lock-minimum-size (buffer-size))) | |
349 | (or fast-lock-save-others | |
350 | (eq (user-uid) (nth 2 (file-attributes buffer-file-name)))) | |
351 | ;; | |
352 | ;; Only save if there are `face' properties to save. | |
6492fcd1 | 353 | (text-property-not-all (point-min) (point-max) 'face nil)) |
19f79085 SM |
354 | ;; Try each directory until we manage to save or the user quits. |
355 | (let ((directories fast-lock-cache-directories)) | |
356 | (while (and directories (memq saved '(nil error))) | |
357 | (let* ((dir (fast-lock-cache-directory (car directories) t)) | |
358 | (file (and dir (fast-lock-cache-name dir)))) | |
359 | (if (and file (file-writable-p file)) | |
360 | (setq saved (fast-lock-save-cache-1 file file-timestamp))) | |
361 | (setq directories (cdr directories))))))))) | |
362 | ||
363 | ;;;###autoload | |
6492fcd1 RS |
364 | (defun turn-on-fast-lock () |
365 | "Unconditionally turn on Fast Lock mode." | |
ebdee0a0 | 366 | (fast-lock-mode t)) |
19f79085 SM |
367 | \f |
368 | ;;; API Functions: | |
369 | ||
370 | (defun fast-lock-after-fontify-buffer () | |
371 | ;; Delete the Font Lock cache file used to restore fontification, if any. | |
372 | (if fast-lock-cache-filename | |
373 | (if (file-writable-p fast-lock-cache-filename) | |
374 | (delete-file fast-lock-cache-filename) | |
375 | (message "File %s font lock cache cannot be deleted" (buffer-name)))) | |
376 | ;; Flag so that a cache will be saved later even if the file is never saved. | |
377 | (setq fast-lock-cache-timestamp nil)) | |
378 | \f | |
379 | ;; Miscellaneous Functions: | |
380 | ||
381 | (defun fast-lock-after-save-hook () | |
382 | ;; Do `fast-lock-save-cache' if `save-buffer' is on `fast-lock-save-events'. | |
383 | (if (memq 'save-buffer fast-lock-save-events) | |
384 | (fast-lock-save-cache))) | |
385 | ||
386 | (defun fast-lock-kill-buffer-hook () | |
387 | ;; Do `fast-lock-save-cache' if `kill-buffer' is on `fast-lock-save-events'. | |
388 | (if (memq 'kill-buffer fast-lock-save-events) | |
389 | (fast-lock-save-cache))) | |
6492fcd1 | 390 | |
19f79085 SM |
391 | (defun fast-lock-kill-emacs-hook () |
392 | ;; Do `fast-lock-save-cache's if `kill-emacs' is on `fast-lock-save-events'. | |
393 | (if (memq 'kill-emacs fast-lock-save-events) | |
394 | (mapcar 'fast-lock-save-cache (buffer-list)))) | |
6492fcd1 RS |
395 | |
396 | (defun fast-lock-cache-directory (directory create) | |
397 | "Return usable directory based on DIRECTORY. | |
398 | Returns nil if the directory does not exist, or, if CREATE non-nil, cannot be | |
399 | created. DIRECTORY may be a string or a cons pair of the form (REGEXP . DIR). | |
400 | See `fast-lock-cache-directories'." | |
19f79085 SM |
401 | (let ((dir |
402 | (cond ((not buffer-file-name) | |
403 | ;; Should never be nil, but `crypt++' screws it up. | |
404 | nil) | |
405 | ((stringp directory) | |
406 | ;; Just a directory. | |
407 | directory) | |
408 | (t | |
409 | ;; A directory iff the file name matches the regexp. | |
410 | (let ((bufile (expand-file-name buffer-file-truename)) | |
411 | (case-fold-search nil)) | |
412 | (if (save-match-data (string-match (car directory) bufile)) | |
413 | (cdr directory))))))) | |
6492fcd1 RS |
414 | (cond ((not dir) |
415 | nil) | |
19f79085 SM |
416 | ((file-accessible-directory-p dir) |
417 | dir) | |
418 | (create | |
419 | (condition-case nil | |
420 | (progn (make-directory dir t) dir) | |
421 | (error nil)))))) | |
6492fcd1 | 422 | |
ebdee0a0 SM |
423 | ;; If you are wondering why we only hash if the directory is not ".", rather |
424 | ;; than if `file-name-absolute-p', it is because if we just appended ".flc" for | |
425 | ;; relative cache directories (that are not ".") then it is possible that more | |
426 | ;; than one file would have the same cache name in that directory, if the luser | |
427 | ;; made a link from one relative cache directory to another. (Phew!) | |
6492fcd1 RS |
428 | (defun fast-lock-cache-name (directory) |
429 | "Return full cache path name using caching DIRECTORY. | |
430 | If DIRECTORY is `.', the path is the buffer file name appended with `.flc'. | |
431 | Otherwise, the path name is constructed from DIRECTORY and the buffer's true | |
432 | abbreviated file name, with all `/' characters in the name replaced with `#' | |
433 | characters, and appended with `.flc'. | |
434 | ||
ebdee0a0 SM |
435 | If the same file has different cache path names when edited on different |
436 | machines, e.g., on one machine the cache file name has the prefix `#home', | |
437 | perhaps due to automount, try putting in your `~/.emacs' something like: | |
438 | ||
439 | (setq directory-abbrev-alist (cons '(\"^/home/\" . \"/\") directory-abbrev-alist)) | |
440 | ||
441 | Emacs automagically removes the common `/tmp_mnt' automount prefix by default. | |
442 | ||
443 | See `fast-lock-cache-directory'." | |
6492fcd1 RS |
444 | (if (string-equal directory ".") |
445 | (concat buffer-file-name ".flc") | |
19f79085 | 446 | (let* ((bufile (expand-file-name buffer-file-truename)) |
6492fcd1 RS |
447 | (chars-alist |
448 | (if (eq system-type 'emx) | |
449 | '((?/ . (?#)) (?# . (?# ?#)) (?: . (?\;)) (?\; . (?\; ?\;))) | |
450 | '((?/ . (?#)) (?# . (?# ?#))))) | |
451 | (mapchars | |
452 | (function (lambda (c) (or (cdr (assq c chars-alist)) (list c)))))) | |
453 | (concat | |
454 | (file-name-as-directory (expand-file-name directory)) | |
455 | (mapconcat 'char-to-string (apply 'append (mapcar mapchars bufile)) "") | |
456 | ".flc")))) | |
457 | \f | |
19f79085 SM |
458 | ;; Font Lock Cache Processing Functions: |
459 | ||
460 | (defun fast-lock-save-cache-1 (file timestamp) | |
461 | ;; Save the FILE with the TIMESTAMP as: | |
462 | ;; (fast-lock-cache-data Version=2 TIMESTAMP font-lock-keywords PROPERTIES). | |
463 | ;; Returns non-nil if a save was attempted to a writable cache file. | |
464 | (let ((tpbuf (generate-new-buffer " *fast-lock*")) | |
465 | (buname (buffer-name)) (saved t)) | |
466 | (message "Saving %s font lock cache..." buname) | |
467 | (condition-case nil | |
468 | (save-excursion | |
469 | (print (list 'fast-lock-cache-data 2 | |
470 | (list 'quote timestamp) | |
471 | (list 'quote font-lock-keywords) | |
472 | (list 'quote (fast-lock-get-face-properties))) | |
473 | tpbuf) | |
474 | (set-buffer tpbuf) | |
475 | (write-region (point-min) (point-max) file nil 'quietly) | |
476 | (setq fast-lock-cache-timestamp timestamp | |
477 | fast-lock-cache-filename file)) | |
478 | (error (setq saved 'error)) (quit (setq saved 'quit))) | |
479 | (kill-buffer tpbuf) | |
480 | (message "Saving %s font lock cache... %s." buname | |
481 | (cond ((eq saved 'error) "failed") | |
482 | ((eq saved 'quit) "aborted") | |
483 | (t "done"))) | |
484 | ;; We return non-nil regardless of whether a failure occurred. | |
485 | saved)) | |
6492fcd1 RS |
486 | |
487 | (defun fast-lock-cache-data (version timestamp keywords properties | |
488 | &rest ignored) | |
19f79085 SM |
489 | ;; Change from (HIGH LOW) for back compatibility. Remove for version 3! |
490 | (if (consp (cdr-safe timestamp)) (setcdr timestamp (nth 1 timestamp))) | |
491 | ;; Compile KEYWORDS and `font-lock-keywords' in case one is and one isn't. | |
492 | (let ((current font-lock-keywords)) | |
493 | (setq keywords (font-lock-compile-keywords keywords) | |
494 | font-lock-keywords (font-lock-compile-keywords current))) | |
495 | ;; Use the Font Lock cache PROPERTIES if we're using cache VERSION format 2, | |
6492fcd1 RS |
496 | ;; the current buffer's file timestamp matches the TIMESTAMP, and the current |
497 | ;; buffer's font-lock-keywords are the same as KEYWORDS. | |
19f79085 SM |
498 | (let ((buf-timestamp (visited-file-modtime)) |
499 | (buname (buffer-name)) (loaded t)) | |
6492fcd1 | 500 | (if (or (/= version 2) |
19f79085 | 501 | (buffer-modified-p) |
6492fcd1 RS |
502 | (not (equal timestamp buf-timestamp)) |
503 | (not (equal keywords font-lock-keywords))) | |
504 | (setq loaded nil) | |
505 | (message "Loading %s font lock cache..." buname) | |
506 | (condition-case nil | |
507 | (fast-lock-set-face-properties properties) | |
19f79085 SM |
508 | (error (setq loaded 'error)) (quit (setq loaded 'quit))) |
509 | (message "Loading %s font lock cache... %s." buname | |
510 | (cond ((eq loaded 'error) "failed") | |
511 | ((eq loaded 'quit) "aborted") | |
512 | (t "done")))) | |
19f79085 | 513 | (setq font-lock-fontified (eq loaded t) |
9ebfa5ef | 514 | fast-lock-cache-timestamp (and (eq loaded t) timestamp)))) |
19f79085 SM |
515 | \f |
516 | ;; Text Properties Processing Functions: | |
517 | ||
518 | ;; This is faster, but fails if adjacent characters have different `face' text | |
519 | ;; properties. Maybe that's why I dropped it in the first place? | |
520 | ;(defun fast-lock-get-face-properties () | |
521 | ; "Return a list of all `face' text properties in the current buffer. | |
522 | ;Each element of the list is of the form (VALUE START1 END1 START2 END2 ...) | |
523 | ;where VALUE is a `face' property value and STARTx and ENDx are positions." | |
524 | ; (save-restriction | |
525 | ; (widen) | |
526 | ; (let ((start (text-property-not-all (point-min) (point-max) 'face nil)) | |
527 | ; (limit (point-max)) end properties value cell) | |
528 | ; (while start | |
529 | ; (setq end (next-single-property-change start 'face nil limit) | |
530 | ; value (get-text-property start 'face)) | |
531 | ; ;; Make, or add to existing, list of regions with same `face'. | |
532 | ; (if (setq cell (assq value properties)) | |
533 | ; (setcdr cell (cons start (cons end (cdr cell)))) | |
534 | ; (setq properties (cons (list value start end) properties))) | |
535 | ; (setq start (next-single-property-change end 'face))) | |
536 | ; properties))) | |
537 | ||
538 | (defun fast-lock-get-face-properties () | |
539 | "Return a list of all `face' text properties in the current buffer. | |
6492fcd1 | 540 | Each element of the list is of the form (VALUE START1 END1 START2 END2 ...) |
19f79085 SM |
541 | where VALUE is a `face' property value and STARTx and ENDx are positions. |
542 | Only those `face' VALUEs in `fast-lock-save-faces' are returned." | |
543 | (save-restriction | |
544 | (widen) | |
545 | (let ((faces (or fast-lock-save-faces (face-list))) (limit (point-max)) | |
546 | properties regions face start end) | |
547 | (while faces | |
548 | (setq face (car faces) faces (cdr faces) regions () end (point-min)) | |
549 | ;; Make a list of start/end regions with `face' property face. | |
550 | (while (setq start (text-property-any end limit 'face face)) | |
551 | (setq end (or (text-property-not-all start limit 'face face) limit) | |
552 | regions (cons start (cons end regions)))) | |
553 | ;; Add `face' face's regions, if any, to properties. | |
554 | (if regions (setq properties (cons (cons face regions) properties)))) | |
555 | properties))) | |
556 | ||
557 | (defun fast-lock-set-face-properties (properties) | |
558 | "Set all `face' text properties to PROPERTIES in the current buffer. | |
559 | Any existing `face' text properties are removed first. Leaves buffer modified. | |
6492fcd1 | 560 | See `fast-lock-get-face-properties' for the format of PROPERTIES." |
19f79085 SM |
561 | (save-restriction |
562 | (widen) | |
563 | (font-lock-unfontify-region (point-min) (point-max)) | |
564 | (while properties | |
565 | (let ((plist (list 'face (car (car properties)))) | |
566 | (regions (cdr (car properties)))) | |
567 | ;; Set the `face' property for each start/end region. | |
568 | (while regions | |
569 | (set-text-properties (nth 0 regions) (nth 1 regions) plist) | |
570 | (setq regions (nthcdr 2 regions))) | |
571 | (setq properties (cdr properties)))))) | |
6492fcd1 | 572 | \f |
19f79085 | 573 | ;; Functions for XEmacs: |
6492fcd1 | 574 | |
19f79085 SM |
575 | (if (save-match-data (string-match "XEmacs" (emacs-version))) |
576 | ;; It would be better to use XEmacs 19.12's `map-extents' over extents with | |
577 | ;; `font-lock' property, but `face' properties are on different extents. | |
578 | (defun fast-lock-get-face-properties () | |
579 | "Return a list of all `face' text properties in the current buffer. | |
6492fcd1 | 580 | Each element of the list is of the form (VALUE START1 END1 START2 END2 ...) |
19f79085 SM |
581 | where VALUE is a `face' property value and STARTx and ENDx are positions. |
582 | Only those `face' VALUEs in `fast-lock-save-faces' are returned." | |
583 | (save-restriction | |
584 | (widen) | |
585 | (let ((properties ()) cell) | |
586 | (map-extents | |
587 | (function | |
588 | (lambda (extent ignore) | |
589 | (let ((value (extent-face extent))) | |
590 | ;; We're only interested if it's one of `fast-lock-save-faces'. | |
591 | (if (and value (or (null fast-lock-save-faces) | |
592 | (memq value fast-lock-save-faces))) | |
593 | (let ((start (extent-start-position extent)) | |
594 | (end (extent-end-position extent))) | |
595 | ;; Make or add to existing list of regions with the same | |
596 | ;; `face' property value. | |
597 | (if (setq cell (assq value properties)) | |
598 | (setcdr cell (cons start (cons end (cdr cell)))) | |
599 | (setq properties (cons (list value start end) | |
600 | properties))))) | |
6492fcd1 RS |
601 | ;; Return nil to keep `map-extents' going. |
602 | nil)))) | |
19f79085 | 603 | properties)))) |
6492fcd1 | 604 | |
19f79085 SM |
605 | (if (save-match-data (string-match "XEmacs" (emacs-version))) |
606 | ;; Make extents just like XEmacs's font-lock.el does. | |
607 | (defun fast-lock-set-face-properties (properties) | |
608 | "Set all `face' text properties to PROPERTIES in the current buffer. | |
609 | Any existing `face' text properties are removed first. | |
6492fcd1 | 610 | See `fast-lock-get-face-properties' for the format of PROPERTIES." |
19f79085 SM |
611 | (save-restriction |
612 | (widen) | |
613 | (font-lock-unfontify-region (point-min) (point-max)) | |
614 | (while properties | |
615 | (let ((face (car (car properties))) | |
616 | (regions (cdr (car properties)))) | |
617 | ;; Set the `face' property, etc., for each start/end region. | |
618 | (while regions | |
619 | (font-lock-set-face (nth 0 regions) (nth 1 regions) face) | |
620 | (setq regions (nthcdr 2 regions))) | |
621 | (setq properties (cdr properties))))))) | |
622 | ||
ebdee0a0 SM |
623 | (if (save-match-data (string-match "XEmacs" (emacs-version))) |
624 | ;; XEmacs 19.12 font-lock.el's `font-lock-fontify-buffer' runs a hook. | |
625 | (add-hook 'font-lock-after-fontify-buffer-hook | |
626 | 'fast-lock-after-fontify-buffer)) | |
627 | ||
19f79085 SM |
628 | (or (fboundp 'font-lock-compile-keywords) |
629 | (defalias 'font-lock-compile-keywords 'identity)) | |
6492fcd1 RS |
630 | \f |
631 | ;; Install ourselves: | |
632 | ||
19f79085 | 633 | ;; We don't install ourselves on `font-lock-mode-hook' as packages with similar |
ebdee0a0 SM |
634 | ;; functionality exist, and fast-lock.el should be dumpable without forcing |
635 | ;; people to use caches or making it difficult for people to use alternatives. | |
19f79085 SM |
636 | (add-hook 'after-save-hook 'fast-lock-after-save-hook) |
637 | (add-hook 'kill-buffer-hook 'fast-lock-kill-buffer-hook) | |
638 | (add-hook 'kill-emacs-hook 'fast-lock-kill-emacs-hook) | |
639 | ||
640 | ;; Maybe save on the modeline? | |
641 | ;;(setcdr (assq 'font-lock-mode minor-mode-alist) '(" Fast")) | |
642 | ||
6492fcd1 RS |
643 | (or (assq 'fast-lock-mode minor-mode-alist) |
644 | (setq minor-mode-alist (cons '(fast-lock-mode " Fast") minor-mode-alist))) | |
645 | ||
6492fcd1 RS |
646 | ;; Provide ourselves: |
647 | ||
648 | (provide 'fast-lock) | |
649 | ||
650 | ;;; fast-lock.el ends here |