[bpt/emacs.git] / lisp / textmodes / paragraphs.el

;;; paragraphs.el --- paragraph and sentence parsing.

;; Copyright (C) 1985, 86, 87, 1991 Free Software Foundation, Inc.

;; Maintainer: FSF
;; Keywords: wp

;; This file is part of GNU Emacs.

;; GNU Emacs is free software; you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation; either version 2, or (at your option)
;; any later version.

;; GNU Emacs is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License
;; along with GNU Emacs; see the file COPYING.  If not, write to
;; the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.

;;; Code:

(defconst paragraph-start "^[ \t\n\f]" "\
*Regexp for beginning of a line that starts OR separates paragraphs.")

(defconst paragraph-separate "^[ \t\f]*$" "\
*Regexp for beginning of a line that separates paragraphs.
If you change this, you may have to change paragraph-start also.")

(defconst sentence-end (purecopy "[.?!][]\"')}]*\\($\\| $\\|\t\\|  \\)[ \t\n]*") "\
*Regexp describing the end of a sentence.
All paragraph boundaries also end sentences, regardless.")

(defconst page-delimiter "^\014" "\
*Regexp describing line-beginnings that separate pages.")

(defvar paragraph-ignore-fill-prefix nil "\
Non-nil means the paragraph commands are not affected by `fill-prefix'.
This is desirable in modes where blank lines are the paragraph delimiters.")


(defun forward-paragraph (&optional arg)
  "Move forward to end of paragraph.
With arg N, do it N times; negative arg -N means move forward N paragraphs.

A line which `paragraph-start' matches either separates paragraphs
\(if `paragraph-separate' matches it also) or is the first line of a paragraph.
A paragraph end is the beginning of a line which is not part of the paragraph
to which the end of the previous line belongs, or the end of the buffer."
  (interactive "p")
  (or arg (setq arg 1))
  (let* ((fill-prefix-regexp
	  (and fill-prefix (not (equal fill-prefix ""))
	       (not paragraph-ignore-fill-prefix)
	       (regexp-quote fill-prefix)))
	 (paragraph-separate
	  (if fill-prefix-regexp
	      (concat paragraph-separate "\\|^"
		      fill-prefix-regexp "[ \t]*$")
	    paragraph-separate)))
    (while (< arg 0)
      (if (and (not (looking-at paragraph-separate))
	       (re-search-backward "^\n" (max (1- (point)) (point-min)) t))
	  nil
	(forward-char -1) (beginning-of-line)
	(while (and (not (bobp)) (looking-at paragraph-separate))
	  (forward-line -1))
	(end-of-line)
	;; Search back for line that starts or separates paragraphs.
	(if (if fill-prefix-regexp
		;; There is a fill prefix; it overrides paragraph-start.
		(progn
		 (while (progn (beginning-of-line)
			       (and (not (bobp))
				    (not (looking-at paragraph-separate))
				    (looking-at fill-prefix-regexp)))
		   (forward-line -1))
		 (not (bobp)))
	      (re-search-backward paragraph-start nil t))
	    ;; Found one.
	    (progn
	      (while (and (not (eobp)) (looking-at paragraph-separate))
		(forward-line 1))
	      (if (eq (char-after (- (point) 2)) ?\n)
		  (forward-line -1)))
	  ;; No starter or separator line => use buffer beg.
	  (goto-char (point-min))))
      (setq arg (1+ arg)))
    (while (> arg 0)
      (beginning-of-line)
      (while (prog1 (and (not (eobp))
			 (looking-at paragraph-separate))
		    (forward-line 1)))
      (if fill-prefix-regexp
	  ;; There is a fill prefix; it overrides paragraph-start.
	  (while (and (not (eobp))
		      (not (looking-at paragraph-separate))
		      (looking-at fill-prefix-regexp))
	    (forward-line 1))
	(if (re-search-forward paragraph-start nil t)
	    (goto-char (match-beginning 0))
	  (goto-char (point-max))))
      (setq arg (1- arg)))))

(defun backward-paragraph (&optional arg)
  "Move backward to start of paragraph.
With arg N, do it N times; negative arg -N means move forward N paragraphs.

A paragraph start is the beginning of a line which is a
`first-line-of-paragraph' or which is ordinary text and follows a
paragraph-separating line; except: if the first real line of a
paragraph is preceded by a blank line, the paragraph starts at that
blank line.

See `forward-paragraph' for more information."
  (interactive "p")
  (or arg (setq arg 1))
  (forward-paragraph (- arg)))

(defun mark-paragraph ()
  "Put point at beginning of this paragraph, mark at end.
The paragraph marked is the one that contains point or follows point."
  (interactive)
  (forward-paragraph 1)
  (push-mark nil t)
  (backward-paragraph 1))

(defun kill-paragraph (arg)
  "Kill forward to end of paragraph.
With arg N, kill forward to Nth end of paragraph;
negative arg -N means kill backward to Nth start of paragraph."
  (interactive "p")
  (kill-region (point) (save-excursion (forward-paragraph arg) (point))))

(defun backward-kill-paragraph (arg)
  "Kill back to start of paragraph.
With arg N, kill back to Nth start of paragraph;
negative arg -N means kill forward to Nth end of paragraph."
  (interactive "p")
  (kill-region (point) (save-excursion (backward-paragraph arg) (point))))

(defun transpose-paragraphs (arg)
  "Interchange this (or next) paragraph with previous one."
  (interactive "*p")
  (transpose-subr 'forward-paragraph arg))

(defun start-of-paragraph-text ()
  (let ((opoint (point)) npoint)
    (forward-paragraph -1)
    (setq npoint (point))
    (skip-chars-forward " \t\n")
    ;; If the range of blank lines found spans the original start point,
    ;; try again from the beginning of it.
    ;; Must be careful to avoid infinite loop
    ;; when following a single return at start of buffer.
    (if (and (>= (point) opoint) (< npoint opoint))
	(progn
	  (goto-char npoint)
	  (if (> npoint (point-min))
	      (start-of-paragraph-text))))))

(defun end-of-paragraph-text ()
  (let ((opoint (point)))
    (forward-paragraph 1)
    (if (eq (preceding-char) ?\n) (forward-char -1))
    (if (<= (point) opoint)
	(progn
	  (forward-char 1)
	  (if (< (point) (point-max))
	      (end-of-paragraph-text))))))

(defun forward-sentence (&optional arg)
  "Move forward to next`sentence-end'.  With argument, repeat.
With negative argument, move backward repeatedly to `sentence-beginning'.

The variable `sentence-end' is a regular expression that matches ends of
sentences.  Also, every paragraph boundary terminates sentences as well."
  (interactive "p")
  (or arg (setq arg 1))
  (while (< arg 0)
    (let ((par-beg (save-excursion (start-of-paragraph-text) (point))))
      (if (re-search-backward (concat sentence-end "[^ \t\n]") par-beg t)
	  (goto-char (1- (match-end 0)))
	(goto-char par-beg)))
    (setq arg (1+ arg)))
  (while (> arg 0)
    (let ((par-end (save-excursion (end-of-paragraph-text) (point))))
      (if (re-search-forward sentence-end par-end t)
	  (skip-chars-backward " \t\n")
	(goto-char par-end)))
    (setq arg (1- arg))))

(defun backward-sentence (&optional arg)
  "Move backward to start of sentence.  With arg, do it arg times.
See `forward-sentence' for more information."
  (interactive "p")
  (or arg (setq arg 1))
  (forward-sentence (- arg)))

(defun kill-sentence (&optional arg)
  "Kill from point to end of sentence.
With arg, repeat; negative arg -N means kill back to Nth start of sentence."
  (interactive "*p")
  (kill-region (point) (save-excursion (forward-sentence arg) (point))))

(defun backward-kill-sentence (&optional arg)
  "Kill back from point to start of sentence.
With arg, repeat, or kill forward to Nth end of sentence if negative arg -N."
  (interactive "*p")
  (kill-region (point) (save-excursion (backward-sentence arg) (point))))

(defun mark-end-of-sentence (arg)
  "Put mark at end of sentence.  Arg works as in `forward-sentence'."
  (interactive "p")
  (push-mark
    (save-excursion
      (forward-sentence arg)
      (point))))

(defun transpose-sentences (arg)
  "Interchange this (next) and previous sentence."
  (interactive "*p")
  (transpose-subr 'forward-sentence arg))

;;; paragraphs.el ends here
Commit	Line	Data
6594deb0 ER	1	;;; paragraphs.el --- paragraph and sentence parsing.
6594deb0 ER	2
9750e079 ER	3	;; Copyright (C) 1985, 86, 87, 1991 Free Software Foundation, Inc.
9750e079 ER	4
4821e2af	5	;; Maintainer: FSF
d7b4d18f	6	;; Keywords: wp
4821e2af	7
a2535589 JA	8	;; This file is part of GNU Emacs.
	9
	10	;; GNU Emacs is free software; you can redistribute it and/or modify
	11	;; it under the terms of the GNU General Public License as published by
29add8b9	12	;; the Free Software Foundation; either version 2, or (at your option)
a2535589 JA	13	;; any later version.
	14
	15	;; GNU Emacs is distributed in the hope that it will be useful,
	16	;; but WITHOUT ANY WARRANTY; without even the implied warranty of
	17	;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
	18	;; GNU General Public License for more details.
	19
	20	;; You should have received a copy of the GNU General Public License
	21	;; along with GNU Emacs; see the file COPYING. If not, write to
	22	;; the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.
	23
4821e2af	24	;;; Code:
a2535589	25
6503cec3 JB	26	(defconst paragraph-start "^[ \t\n\f]" "\
	27	*Regexp for beginning of a line that starts OR separates paragraphs.")
	28
6503cec3 JB	29	(defconst paragraph-separate "^[ \t\f]*$" "\
	30	*Regexp for beginning of a line that separates paragraphs.
	31	If you change this, you may have to change paragraph-start also.")
	32
6503cec3 JB	33	(defconst sentence-end (purecopy "[.?!][]\"')}]\\($\\\| $\\\|\t\\\| \\)[ \t\n]") "\
	34	*Regexp describing the end of a sentence.
	35	All paragraph boundaries also end sentences, regardless.")
	36
6503cec3 JB	37	(defconst page-delimiter "^\014" "\
	38	*Regexp describing line-beginnings that separate pages.")
	39
6503cec3 JB	40	(defvar paragraph-ignore-fill-prefix nil "\
	41	Non-nil means the paragraph commands are not affected by `fill-prefix'.
	42	This is desirable in modes where blank lines are the paragraph delimiters.")
77176e73	43
a2535589 JA	44
	45	(defun forward-paragraph (&optional arg)
	46	"Move forward to end of paragraph.
	47	With arg N, do it N times; negative arg -N means move forward N paragraphs.
	48
	49	A line which `paragraph-start' matches either separates paragraphs
	50	\(if `paragraph-separate' matches it also) or is the first line of a paragraph.
	51	A paragraph end is the beginning of a line which is not part of the paragraph
	52	to which the end of the previous line belongs, or the end of the buffer."
	53	(interactive "p")
	54	(or arg (setq arg 1))
	55	(let* ((fill-prefix-regexp
	56	(and fill-prefix (not (equal fill-prefix ""))
	57	(not paragraph-ignore-fill-prefix)
	58	(regexp-quote fill-prefix)))
	59	(paragraph-separate
	60	(if fill-prefix-regexp
	61	(concat paragraph-separate "\\\|^"
	62	fill-prefix-regexp "[ \t]*$")
	63	paragraph-separate)))
	64	(while (< arg 0)
	65	(if (and (not (looking-at paragraph-separate))
	66	(re-search-backward "^\n" (max (1- (point)) (point-min)) t))
	67	nil
	68	(forward-char -1) (beginning-of-line)
	69	(while (and (not (bobp)) (looking-at paragraph-separate))
	70	(forward-line -1))
	71	(end-of-line)
	72	;; Search back for line that starts or separates paragraphs.
	73	(if (if fill-prefix-regexp
	74	;; There is a fill prefix; it overrides paragraph-start.
	75	(progn
	76	(while (progn (beginning-of-line)
	77	(and (not (bobp))
	78	(not (looking-at paragraph-separate))
	79	(looking-at fill-prefix-regexp)))
	80	(forward-line -1))
	81	(not (bobp)))
	82	(re-search-backward paragraph-start nil t))
	83	;; Found one.
	84	(progn
	85	(while (and (not (eobp)) (looking-at paragraph-separate))
	86	(forward-line 1))
	87	(if (eq (char-after (- (point) 2)) ?\n)
	88	(forward-line -1)))
	89	;; No starter or separator line => use buffer beg.
	90	(goto-char (point-min))))
	91	(setq arg (1+ arg)))
	92	(while (> arg 0)
	93	(beginning-of-line)
	94	(while (prog1 (and (not (eobp))
	95	(looking-at paragraph-separate))
	96	(forward-line 1)))
	97	(if fill-prefix-regexp
	98	;; There is a fill prefix; it overrides paragraph-start.
	99	(while (and (not (eobp))
	100	(not (looking-at paragraph-separate))
	101	(looking-at fill-prefix-regexp))
	102	(forward-line 1))
	103	(if (re-search-forward paragraph-start nil t)
	104	(goto-char (match-beginning 0))
	105	(goto-char (point-max))))
	106	(setq arg (1- arg)))))
	107
108	(defun backward-paragraph (&optional arg)
109	"Move backward to start of paragraph.
110	With arg N, do it N times; negative arg -N means move forward N paragraphs.
111
23b34992 BP	112	A paragraph start is the beginning of a line which is a
	113	`first-line-of-paragraph' or which is ordinary text and follows a
	114	paragraph-separating line; except: if the first real line of a
	115	paragraph is preceded by a blank line, the paragraph starts at that
	116	blank line.
	117
	118	See `forward-paragraph' for more information."
a2535589 JA	119	(interactive "p")
	120	(or arg (setq arg 1))
	121	(forward-paragraph (- arg)))
	122
	123	(defun mark-paragraph ()
	124	"Put point at beginning of this paragraph, mark at end.
	125	The paragraph marked is the one that contains point or follows point."
	126	(interactive)
	127	(forward-paragraph 1)
	128	(push-mark nil t)
	129	(backward-paragraph 1))
	130
	131	(defun kill-paragraph (arg)
	132	"Kill forward to end of paragraph.
	133	With arg N, kill forward to Nth end of paragraph;
	134	negative arg -N means kill backward to Nth start of paragraph."
23b34992	135	(interactive "p")
2247b0fc	136	(kill-region (point) (save-excursion (forward-paragraph arg) (point))))
a2535589 JA	137
	138	(defun backward-kill-paragraph (arg)
	139	"Kill back to start of paragraph.
	140	With arg N, kill back to Nth start of paragraph;
	141	negative arg -N means kill forward to Nth end of paragraph."
23b34992	142	(interactive "p")
2247b0fc	143	(kill-region (point) (save-excursion (backward-paragraph arg) (point))))
a2535589 JA	144
	145	(defun transpose-paragraphs (arg)
	146	"Interchange this (or next) paragraph with previous one."
	147	(interactive "*p")
	148	(transpose-subr 'forward-paragraph arg))
	149
	150	(defun start-of-paragraph-text ()
	151	(let ((opoint (point)) npoint)
	152	(forward-paragraph -1)
	153	(setq npoint (point))
	154	(skip-chars-forward " \t\n")
b4e6c391 RS	155	;; If the range of blank lines found spans the original start point,
	156	;; try again from the beginning of it.
	157	;; Must be careful to avoid infinite loop
	158	;; when following a single return at start of buffer.
	159	(if (and (>= (point) opoint) (< npoint opoint))
a2535589 JA	160	(progn
	161	(goto-char npoint)
	162	(if (> npoint (point-min))
	163	(start-of-paragraph-text))))))
	164
	165	(defun end-of-paragraph-text ()
	166	(let ((opoint (point)))
	167	(forward-paragraph 1)
	168	(if (eq (preceding-char) ?\n) (forward-char -1))
	169	(if (<= (point) opoint)
	170	(progn
	171	(forward-char 1)
	172	(if (< (point) (point-max))
	173	(end-of-paragraph-text))))))
	174
	175	(defun forward-sentence (&optional arg)
23b34992 BP	176	"Move forward to next`sentence-end'. With argument, repeat.
23b34992 BP	177	With negative argument, move backward repeatedly to `sentence-beginning'.
a2535589	178
23b34992 BP	179	The variable `sentence-end' is a regular expression that matches ends of
23b34992 BP	180	sentences. Also, every paragraph boundary terminates sentences as well."
a2535589 JA	181	(interactive "p")
	182	(or arg (setq arg 1))
	183	(while (< arg 0)
	184	(let ((par-beg (save-excursion (start-of-paragraph-text) (point))))
	185	(if (re-search-backward (concat sentence-end "[^ \t\n]") par-beg t)
	186	(goto-char (1- (match-end 0)))
	187	(goto-char par-beg)))
	188	(setq arg (1+ arg)))
	189	(while (> arg 0)
	190	(let ((par-end (save-excursion (end-of-paragraph-text) (point))))
	191	(if (re-search-forward sentence-end par-end t)
	192	(skip-chars-backward " \t\n")
	193	(goto-char par-end)))
	194	(setq arg (1- arg))))
	195
	196	(defun backward-sentence (&optional arg)
	197	"Move backward to start of sentence. With arg, do it arg times.
23b34992	198	See `forward-sentence' for more information."
a2535589 JA	199	(interactive "p")
	200	(or arg (setq arg 1))
	201	(forward-sentence (- arg)))
	202
	203	(defun kill-sentence (&optional arg)
	204	"Kill from point to end of sentence.
	205	With arg, repeat; negative arg -N means kill back to Nth start of sentence."
	206	(interactive "*p")
2247b0fc	207	(kill-region (point) (save-excursion (forward-sentence arg) (point))))
a2535589 JA	208
	209	(defun backward-kill-sentence (&optional arg)
	210	"Kill back from point to start of sentence.
	211	With arg, repeat, or kill forward to Nth end of sentence if negative arg -N."
	212	(interactive "*p")
7270bdb0	213	(kill-region (point) (save-excursion (backward-sentence arg) (point))))
a2535589 JA	214
a2535589 JA	215	(defun mark-end-of-sentence (arg)
23b34992	216	"Put mark at end of sentence. Arg works as in `forward-sentence'."
a2535589 JA	217	(interactive "p")
	218	(push-mark
	219	(save-excursion
	220	(forward-sentence arg)
	221	(point))))
	222
	223	(defun transpose-sentences (arg)
	224	"Interchange this (next) and previous sentence."
	225	(interactive "*p")
	226	(transpose-subr 'forward-sentence arg))
6594deb0 ER	227
6594deb0 ER	228	;;; paragraphs.el ends here