[bpt/emacs.git] / lisp / gnus / gnus-demon.el

;;; gnus-demon.el --- daemonic Gnus behaviour
;; Copyright (C) 1995,96,97,98,99 Free Software Foundation, Inc.

;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
;; Keywords: news

;; This file is part of GNU Emacs.

;; GNU Emacs is free software; you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation; either version 2, or (at your option)
;; any later version.

;; GNU Emacs is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License
;; along with GNU Emacs; see the file COPYING.  If not, write to the
;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
;; Boston, MA 02111-1307, USA.

;;; Commentary:

;;; Code:

(eval-when-compile (require 'cl))

(require 'gnus)
(require 'gnus-int)
(require 'nnheader)
(require 'nntp)
(require 'nnmail)
(require 'gnus-util)
(eval-and-compile
  (if (featurep 'xemacs)
      (require 'itimer)
    (require 'timer)))

(defgroup gnus-demon nil
  "Demonic behaviour."
  :group 'gnus)

(defcustom gnus-demon-handlers nil
  "Alist of daemonic handlers to be run at intervals.
Each handler is a list on the form

\(FUNCTION TIME IDLE)

FUNCTION is the function to be called.
TIME is the number of `gnus-demon-timestep's between each call.
If nil, never call.  If t, call each `gnus-demon-timestep'.
If IDLE is t, only call if Emacs has been idle for a while.  If IDLE
is a number, only call when Emacs has been idle more than this number
of `gnus-demon-timestep's.  If IDLE is nil, don't care about
idleness.  If IDLE is a number and TIME is nil, then call once each
time Emacs has been idle for IDLE `gnus-demon-timestep's."
  :group 'gnus-demon
  :type '(repeat (list function
		       (choice :tag "Time"
			       (const :tag "never" nil)
			       (const :tag "one" t)
			       (integer :tag "steps" 1))
		       (choice :tag "Idle"
			       (const :tag "don't care" nil)
			       (const :tag "for a while" t)
			       (integer :tag "steps" 1)))))

(defcustom gnus-demon-timestep 60
  "*Number of seconds in each demon timestep."
  :group 'gnus-demon
  :type 'integer)

;;; Internal variables.

(defvar gnus-demon-timer nil)
(defvar gnus-demon-idle-has-been-called nil)
(defvar gnus-demon-idle-time 0)
(defvar gnus-demon-handler-state nil)
(defvar gnus-demon-last-keys nil)
(defvar gnus-inhibit-demon nil
  "*If non-nil, no daemonic function will be run.")

;;; Functions.

(defun gnus-demon-add-handler (function time idle)
  "Add the handler FUNCTION to be run at TIME and IDLE."
  ;; First remove any old handlers that use this function.
  (gnus-demon-remove-handler function)
  ;; Then add the new one.
  (push (list function time idle) gnus-demon-handlers)
  (gnus-demon-init))

(defun gnus-demon-remove-handler (function &optional no-init)
  "Remove the handler FUNCTION from the list of handlers."
  (gnus-pull function gnus-demon-handlers)
  (unless no-init
    (gnus-demon-init)))

(defun gnus-demon-init ()
  "Initialize the Gnus daemon."
  (interactive)
  (gnus-demon-cancel)
  (when gnus-demon-handlers
    ;; Set up the timer.
    (setq gnus-demon-timer
	  (nnheader-run-at-time
	   gnus-demon-timestep gnus-demon-timestep 'gnus-demon))
    ;; Reset control variables.
    (setq gnus-demon-handler-state
	  (mapcar
	   (lambda (handler)
	     (list (car handler) (gnus-demon-time-to-step (nth 1 handler))
		   (nth 2 handler)))
	   gnus-demon-handlers))
    (setq gnus-demon-idle-time 0)
    (setq gnus-demon-idle-has-been-called nil)))

(gnus-add-shutdown 'gnus-demon-cancel 'gnus)

(defun gnus-demon-cancel ()
  "Cancel any Gnus daemons."
  (interactive)
  (when gnus-demon-timer
    (nnheader-cancel-timer gnus-demon-timer))
  (setq gnus-demon-timer nil
	gnus-demon-idle-has-been-called nil)
  (condition-case ()
      (nnheader-cancel-function-timers 'gnus-demon)
    (error t)))

(defun gnus-demon-is-idle-p ()
  "Whether Emacs is idle or not."
  ;; We do this simply by comparing the 100 most recent keystrokes
  ;; with the ones we had last time.  If they are the same, one might
  ;; guess that Emacs is indeed idle.  This only makes sense if one
  ;; calls this function seldom -- like once a minute, which is what
  ;; we do here.
  (let ((keys (recent-keys)))
    (or (equal keys gnus-demon-last-keys)
	(progn
	  (setq gnus-demon-last-keys keys)
	  nil))))

(defun gnus-demon-time-to-step (time)
  "Find out how many seconds to TIME, which is on the form \"17:43\"."
  (if (not (stringp time))
      time
    (let* ((now (current-time))
           ;; obtain NOW as discrete components -- make a vector for speed
           (nowParts (decode-time now))
           ;; obtain THEN as discrete components
           (thenParts (parse-time-string time))
           (thenHour (elt thenParts 2))
           (thenMin (elt thenParts 1))
           ;; convert time as elements into number of seconds since EPOCH.
           (then (encode-time 0
                              thenMin
                              thenHour
                              ;; If THEN is earlier than NOW, make it
                              ;; same time tomorrow.  Doc for encode-time
                              ;; says that this is OK.
                              (+ (elt nowParts 3)
                                 (if (or (< thenHour (elt nowParts 2))
                                         (and (= thenHour (elt nowParts 2))
                                              (<= thenMin (elt nowParts 1))))
                                     1 0))
                              (elt nowParts 4)
                              (elt nowParts 5)
                              (elt nowParts 6)
                              (elt nowParts 7)
                              (elt nowParts 8)))
           ;; calculate number of seconds between NOW and THEN
           (diff (+ (* 65536 (- (car then) (car now)))
                    (- (cadr then) (cadr now)))))
      ;; return number of timesteps in the number of seconds
      (round (/ diff gnus-demon-timestep)))))

(defun gnus-demon ()
  "The Gnus daemon that takes care of running all Gnus handlers."
  ;; Increase or reset the time Emacs has been idle.
  (if (gnus-demon-is-idle-p)
      (incf gnus-demon-idle-time)
    (setq gnus-demon-idle-time 0)
    (setq gnus-demon-idle-has-been-called nil))
  ;; Disable all daemonic stuff if we're in the minibuffer
  (when (and (not (window-minibuffer-p (selected-window)))
	     (not gnus-inhibit-demon))
    ;; Then we go through all the handler and call those that are
    ;; sufficiently ripe.
    (let ((handlers gnus-demon-handler-state)
	  (gnus-inhibit-demon t)
	  ;; Try to avoid dialog boxes, e.g. by Mailcrypt.
	  ;; Unfortunately, Emacs 20's `message-or-box...' doesn't
	  ;; obey `use-dialog-box'.
	  use-dialog-box (last-nonmenu-event 10)
	  handler time idle)
      (while handlers
	(setq handler (pop handlers))
	(cond
	 ((numberp (setq time (nth 1 handler)))
	  ;; These handlers use a regular timeout mechanism.  We decrease
	  ;; the timer if it hasn't reached zero yet.
	  (unless (zerop time)
	    (setcar (nthcdr 1 handler) (decf time)))
	  (and (zerop time)		; If the timer now is zero...
	       ;; Test for appropriate idleness
	       (progn
		 (setq idle (nth 2 handler))
		 (cond
		  ((null idle) t)	; Don't care about idle.
		  ((numberp idle)	; Numerical idle...
		   (< idle gnus-demon-idle-time)) ; Idle timed out.
		  (t (< 0 gnus-demon-idle-time)))) ; Or just need to be idle.
	       ;; So we call the handler.
	       (progn
		 (ignore-errors (funcall (car handler)))
		 ;; And reset the timer.
		 (setcar (nthcdr 1 handler)
			 (gnus-demon-time-to-step
			  (nth 1 (assq (car handler) gnus-demon-handlers)))))))
	 ;; These are only supposed to be called when Emacs is idle.
	 ((null (setq idle (nth 2 handler)))
	  ;; We do nothing.
	  )
	 ((and (not (numberp idle))
	       (gnus-demon-is-idle-p))
	  ;; We want to call this handler each and every time that
	  ;; Emacs is idle.
	  (ignore-errors (funcall (car handler))))
	 (t
	  ;; We want to call this handler only if Emacs has been idle
	  ;; for a specified number of timesteps.
	  (and (not (memq (car handler) gnus-demon-idle-has-been-called))
	       (< idle gnus-demon-idle-time)
	       (gnus-demon-is-idle-p)
	       (progn
		 (ignore-errors (funcall (car handler)))
		 ;; Make sure the handler won't be called once more in
		 ;; this idle-cycle.
		 (push (car handler) gnus-demon-idle-has-been-called)))))))))

(defun gnus-demon-add-nocem ()
  "Add daemonic NoCeM handling to Gnus."
  (gnus-demon-add-handler 'gnus-demon-scan-nocem 60 30))

(defun gnus-demon-scan-nocem ()
  "Scan NoCeM groups for NoCeM messages."
  (save-window-excursion
    (gnus-nocem-scan-groups)))

(defun gnus-demon-add-disconnection ()
  "Add daemonic server disconnection to Gnus."
  (gnus-demon-add-handler 'gnus-demon-close-connections nil 30))

(defun gnus-demon-close-connections ()
  (save-window-excursion
    (gnus-close-backends)))

(defun gnus-demon-add-nntp-close-connection ()
  "Add daemonic nntp server disconnection to Gnus.
If no commands have gone out via nntp during the last five
minutes, the connection is closed."
  (gnus-demon-add-handler 'gnus-demon-nntp-close-connections 5 nil))

(defun gnus-demon-nntp-close-connection ()
  (save-window-excursion
    (when (time-less-p '(0 300) (time-since nntp-last-command-time))
      (nntp-close-server))))

(defun gnus-demon-add-scanmail ()
  "Add daemonic scanning of mail from the mail backends."
  (gnus-demon-add-handler 'gnus-demon-scan-mail 120 60))

(defun gnus-demon-scan-mail ()
  (save-window-excursion
    (let ((servers gnus-opened-servers)
	  server
	  (nnmail-fetched-sources (list t)))
      (while (setq server (car (pop servers)))
	(and (gnus-check-backend-function 'request-scan (car server))
	     (or (gnus-server-opened server)
		 (gnus-open-server server))
	     (gnus-request-scan nil server))))))

(defun gnus-demon-add-rescan ()
  "Add daemonic scanning of new articles from all backends."
  (gnus-demon-add-handler 'gnus-demon-scan-news 120 60))

(defun gnus-demon-scan-news ()
  (let ((win (current-window-configuration)))
    (unwind-protect
	(save-window-excursion
	  (save-excursion
	    (when (gnus-alive-p)
	      (save-excursion
		(set-buffer gnus-group-buffer)
		(gnus-group-get-new-news)))))
      (set-window-configuration win))))

(defun gnus-demon-add-scan-timestamps ()
  "Add daemonic updating of timestamps in empty newgroups."
  (gnus-demon-add-handler 'gnus-demon-scan-timestamps nil 30))

(defun gnus-demon-scan-timestamps ()
  "Set the timestamp on all newsgroups with no unread and no ticked articles."
  (when (gnus-alive-p)
    (let ((cur-time (current-time))
	  (newsrc (cdr gnus-newsrc-alist))
	  info group unread has-ticked)
      (while (setq info (pop newsrc))
	(setq group (gnus-info-group info)
	      unread (gnus-group-unread group)
	      has-ticked (cdr (assq 'tick (gnus-info-marks info))))
	(when (and (numberp unread)
		   (= unread 0)
		   (not has-ticked))
	  (gnus-group-set-parameter group 'timestamp cur-time))))))

(provide 'gnus-demon)

;;; arch-tag: 8dd5cd3d-6ae4-46b4-9b15-f5fca09fd392
;;; gnus-demon.el ends here
Commit	Line	Data
eec82323	1	;;; gnus-demon.el --- daemonic Gnus behaviour
16409b0b	2	;; Copyright (C) 1995,96,97,98,99 Free Software Foundation, Inc.
eec82323	3
6748645f	4	;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
eec82323 LMI	5	;; Keywords: news
	6
	7	;; This file is part of GNU Emacs.
	8
	9	;; GNU Emacs is free software; you can redistribute it and/or modify
	10	;; it under the terms of the GNU General Public License as published by
	11	;; the Free Software Foundation; either version 2, or (at your option)
	12	;; any later version.
	13
	14	;; GNU Emacs is distributed in the hope that it will be useful,
	15	;; but WITHOUT ANY WARRANTY; without even the implied warranty of
	16	;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
	17	;; GNU General Public License for more details.
	18
	19	;; You should have received a copy of the GNU General Public License
	20	;; along with GNU Emacs; see the file COPYING. If not, write to the
	21	;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
	22	;; Boston, MA 02111-1307, USA.
	23
	24	;;; Commentary:
	25
	26	;;; Code:
	27
7df7482d RS	28	(eval-when-compile (require 'cl))
7df7482d RS	29
eec82323 LMI	30	(require 'gnus)
	31	(require 'gnus-int)
	32	(require 'nnheader)
6748645f LMI	33	(require 'nntp)
	34	(require 'nnmail)
	35	(require 'gnus-util)
eec82323	36	(eval-and-compile
a211301f	37	(if (featurep 'xemacs)
eec82323 LMI	38	(require 'itimer)
	39	(require 'timer)))
	40
	41	(defgroup gnus-demon nil
	42	"Demonic behaviour."
	43	:group 'gnus)
	44
	45	(defcustom gnus-demon-handlers nil
	46	"Alist of daemonic handlers to be run at intervals.
	47	Each handler is a list on the form
	48
	49	\(FUNCTION TIME IDLE)
	50
	51	FUNCTION is the function to be called.
	52	TIME is the number of `gnus-demon-timestep's between each call.
	53	If nil, never call. If t, call each `gnus-demon-timestep'.
	54	If IDLE is t, only call if Emacs has been idle for a while. If IDLE
	55	is a number, only call when Emacs has been idle more than this number
	56	of `gnus-demon-timestep's. If IDLE is nil, don't care about
	57	idleness. If IDLE is a number and TIME is nil, then call once each
	58	time Emacs has been idle for IDLE `gnus-demon-timestep's."
	59	:group 'gnus-demon
	60	:type '(repeat (list function
	61	(choice :tag "Time"
	62	(const :tag "never" nil)
	63	(const :tag "one" t)
	64	(integer :tag "steps" 1))
	65	(choice :tag "Idle"
	66	(const :tag "don't care" nil)
	67	(const :tag "for a while" t)
	68	(integer :tag "steps" 1)))))
	69
	70	(defcustom gnus-demon-timestep 60
	71	"*Number of seconds in each demon timestep."
	72	:group 'gnus-demon
	73	:type 'integer)
	74
	75	;;; Internal variables.
	76
	77	(defvar gnus-demon-timer nil)
	78	(defvar gnus-demon-idle-has-been-called nil)
	79	(defvar gnus-demon-idle-time 0)
	80	(defvar gnus-demon-handler-state nil)
	81	(defvar gnus-demon-last-keys nil)
	82	(defvar gnus-inhibit-demon nil
	83	"*If non-nil, no daemonic function will be run.")
	84
eec82323 LMI	85	;;; Functions.
	86
	87	(defun gnus-demon-add-handler (function time idle)
	88	"Add the handler FUNCTION to be run at TIME and IDLE."
	89	;; First remove any old handlers that use this function.
	90	(gnus-demon-remove-handler function)
	91	;; Then add the new one.
	92	(push (list function time idle) gnus-demon-handlers)
	93	(gnus-demon-init))
	94
	95	(defun gnus-demon-remove-handler (function &optional no-init)
	96	"Remove the handler FUNCTION from the list of handlers."
6748645f	97	(gnus-pull function gnus-demon-handlers)
eec82323 LMI	98	(unless no-init
	99	(gnus-demon-init)))
	100
	101	(defun gnus-demon-init ()
	102	"Initialize the Gnus daemon."
	103	(interactive)
	104	(gnus-demon-cancel)
6748645f LMI	105	(when gnus-demon-handlers
6748645f LMI	106	;; Set up the timer.
eec82323 LMI	107	(setq gnus-demon-timer
	108	(nnheader-run-at-time
	109	gnus-demon-timestep gnus-demon-timestep 'gnus-demon))
	110	;; Reset control variables.
	111	(setq gnus-demon-handler-state
	112	(mapcar
	113	(lambda (handler)
	114	(list (car handler) (gnus-demon-time-to-step (nth 1 handler))
	115	(nth 2 handler)))
	116	gnus-demon-handlers))
	117	(setq gnus-demon-idle-time 0)
16409b0b	118	(setq gnus-demon-idle-has-been-called nil)))
eec82323 LMI	119
	120	(gnus-add-shutdown 'gnus-demon-cancel 'gnus)
	121
	122	(defun gnus-demon-cancel ()
	123	"Cancel any Gnus daemons."
	124	(interactive)
	125	(when gnus-demon-timer
	126	(nnheader-cancel-timer gnus-demon-timer))
	127	(setq gnus-demon-timer nil
6748645f	128	gnus-demon-idle-has-been-called nil)
eec82323 LMI	129	(condition-case ()
	130	(nnheader-cancel-function-timers 'gnus-demon)
	131	(error t)))
	132
	133	(defun gnus-demon-is-idle-p ()
	134	"Whether Emacs is idle or not."
	135	;; We do this simply by comparing the 100 most recent keystrokes
	136	;; with the ones we had last time. If they are the same, one might
	137	;; guess that Emacs is indeed idle. This only makes sense if one
	138	;; calls this function seldom -- like once a minute, which is what
	139	;; we do here.
	140	(let ((keys (recent-keys)))
	141	(or (equal keys gnus-demon-last-keys)
	142	(progn
	143	(setq gnus-demon-last-keys keys)
	144	nil))))
	145
	146	(defun gnus-demon-time-to-step (time)
	147	"Find out how many seconds to TIME, which is on the form \"17:43\"."
	148	(if (not (stringp time))
	149	time
a8151ef7 LMI	150	(let* ((now (current-time))
a8151ef7 LMI	151	;; obtain NOW as discrete components -- make a vector for speed
16409b0b	152	(nowParts (decode-time now))
a8151ef7	153	;; obtain THEN as discrete components
16409b0b	154	(thenParts (parse-time-string time))
a211301f	155	(thenHour (elt thenParts 2))
16409b0b	156	(thenMin (elt thenParts 1))
a8151ef7 LMI	157	;; convert time as elements into number of seconds since EPOCH.
	158	(then (encode-time 0
	159	thenMin
	160	thenHour
	161	;; If THEN is earlier than NOW, make it
16409b0b	162	;; same time tomorrow. Doc for encode-time
a8151ef7 LMI	163	;; says that this is OK.
	164	(+ (elt nowParts 3)
	165	(if (or (< thenHour (elt nowParts 2))
	166	(and (= thenHour (elt nowParts 2))
	167	(<= thenMin (elt nowParts 1))))
	168	1 0))
	169	(elt nowParts 4)
	170	(elt nowParts 5)
	171	(elt nowParts 6)
	172	(elt nowParts 7)
	173	(elt nowParts 8)))
	174	;; calculate number of seconds between NOW and THEN
	175	(diff (+ (* 65536 (- (car then) (car now)))
	176	(- (cadr then) (cadr now)))))
	177	;; return number of timesteps in the number of seconds
	178	(round (/ diff gnus-demon-timestep)))))
eec82323 LMI	179
	180	(defun gnus-demon ()
	181	"The Gnus daemon that takes care of running all Gnus handlers."
	182	;; Increase or reset the time Emacs has been idle.
	183	(if (gnus-demon-is-idle-p)
	184	(incf gnus-demon-idle-time)
	185	(setq gnus-demon-idle-time 0)
	186	(setq gnus-demon-idle-has-been-called nil))
	187	;; Disable all daemonic stuff if we're in the minibuffer
	188	(when (and (not (window-minibuffer-p (selected-window)))
	189	(not gnus-inhibit-demon))
	190	;; Then we go through all the handler and call those that are
	191	;; sufficiently ripe.
	192	(let ((handlers gnus-demon-handler-state)
	193	(gnus-inhibit-demon t)
16409b0b GM	194	;; Try to avoid dialog boxes, e.g. by Mailcrypt.
	195	;; Unfortunately, Emacs 20's `message-or-box...' doesn't
	196	;; obey `use-dialog-box'.
	197	use-dialog-box (last-nonmenu-event 10)
eec82323 LMI	198	handler time idle)
	199	(while handlers
	200	(setq handler (pop handlers))
	201	(cond
	202	((numberp (setq time (nth 1 handler)))
	203	;; These handlers use a regular timeout mechanism. We decrease
	204	;; the timer if it hasn't reached zero yet.
	205	(unless (zerop time)
	206	(setcar (nthcdr 1 handler) (decf time)))
	207	(and (zerop time) ; If the timer now is zero...
	208	;; Test for appropriate idleness
	209	(progn
	210	(setq idle (nth 2 handler))
	211	(cond
	212	((null idle) t) ; Don't care about idle.
	213	((numberp idle) ; Numerical idle...
	214	(< idle gnus-demon-idle-time)) ; Idle timed out.
	215	(t (< 0 gnus-demon-idle-time)))) ; Or just need to be idle.
	216	;; So we call the handler.
	217	(progn
a8151ef7	218	(ignore-errors (funcall (car handler)))
eec82323 LMI	219	;; And reset the timer.
	220	(setcar (nthcdr 1 handler)
	221	(gnus-demon-time-to-step
	222	(nth 1 (assq (car handler) gnus-demon-handlers)))))))
	223	;; These are only supposed to be called when Emacs is idle.
	224	((null (setq idle (nth 2 handler)))
	225	;; We do nothing.
	226	)
a8151ef7 LMI	227	((and (not (numberp idle))
a8151ef7 LMI	228	(gnus-demon-is-idle-p))
eec82323 LMI	229	;; We want to call this handler each and every time that
eec82323 LMI	230	;; Emacs is idle.
a8151ef7	231	(ignore-errors (funcall (car handler))))
eec82323 LMI	232	(t
	233	;; We want to call this handler only if Emacs has been idle
	234	;; for a specified number of timesteps.
	235	(and (not (memq (car handler) gnus-demon-idle-has-been-called))
	236	(< idle gnus-demon-idle-time)
a8151ef7	237	(gnus-demon-is-idle-p)
eec82323	238	(progn
a8151ef7	239	(ignore-errors (funcall (car handler)))
eec82323 LMI	240	;; Make sure the handler won't be called once more in
	241	;; this idle-cycle.
	242	(push (car handler) gnus-demon-idle-has-been-called)))))))))
	243
	244	(defun gnus-demon-add-nocem ()
	245	"Add daemonic NoCeM handling to Gnus."
a8151ef7	246	(gnus-demon-add-handler 'gnus-demon-scan-nocem 60 30))
eec82323 LMI	247
	248	(defun gnus-demon-scan-nocem ()
	249	"Scan NoCeM groups for NoCeM messages."
	250	(save-window-excursion
	251	(gnus-nocem-scan-groups)))
	252
	253	(defun gnus-demon-add-disconnection ()
	254	"Add daemonic server disconnection to Gnus."
	255	(gnus-demon-add-handler 'gnus-demon-close-connections nil 30))
	256
	257	(defun gnus-demon-close-connections ()
	258	(save-window-excursion
	259	(gnus-close-backends)))
	260
6748645f LMI	261	(defun gnus-demon-add-nntp-close-connection ()
	262	"Add daemonic nntp server disconnection to Gnus.
	263	If no commands have gone out via nntp during the last five
	264	minutes, the connection is closed."
16409b0b	265	(gnus-demon-add-handler 'gnus-demon-nntp-close-connections 5 nil))
6748645f LMI	266
	267	(defun gnus-demon-nntp-close-connection ()
	268	(save-window-excursion
16409b0b	269	(when (time-less-p '(0 300) (time-since nntp-last-command-time))
6748645f LMI	270	(nntp-close-server))))
6748645f LMI	271
eec82323 LMI	272	(defun gnus-demon-add-scanmail ()
	273	"Add daemonic scanning of mail from the mail backends."
	274	(gnus-demon-add-handler 'gnus-demon-scan-mail 120 60))
	275
	276	(defun gnus-demon-scan-mail ()
	277	(save-window-excursion
	278	(let ((servers gnus-opened-servers)
16409b0b GM	279	server
16409b0b GM	280	(nnmail-fetched-sources (list t)))
eec82323 LMI	281	(while (setq server (car (pop servers)))
	282	(and (gnus-check-backend-function 'request-scan (car server))
	283	(or (gnus-server-opened server)
	284	(gnus-open-server server))
	285	(gnus-request-scan nil server))))))
	286
	287	(defun gnus-demon-add-rescan ()
	288	"Add daemonic scanning of new articles from all backends."
	289	(gnus-demon-add-handler 'gnus-demon-scan-news 120 60))
	290
	291	(defun gnus-demon-scan-news ()
6748645f LMI	292	(let ((win (current-window-configuration)))
	293	(unwind-protect
	294	(save-window-excursion
	295	(save-excursion
	296	(when (gnus-alive-p)
	297	(save-excursion
	298	(set-buffer gnus-group-buffer)
	299	(gnus-group-get-new-news)))))
	300	(set-window-configuration win))))
eec82323 LMI	301
	302	(defun gnus-demon-add-scan-timestamps ()
	303	"Add daemonic updating of timestamps in empty newgroups."
	304	(gnus-demon-add-handler 'gnus-demon-scan-timestamps nil 30))
	305
	306	(defun gnus-demon-scan-timestamps ()
	307	"Set the timestamp on all newsgroups with no unread and no ticked articles."
	308	(when (gnus-alive-p)
	309	(let ((cur-time (current-time))
	310	(newsrc (cdr gnus-newsrc-alist))
	311	info group unread has-ticked)
	312	(while (setq info (pop newsrc))
	313	(setq group (gnus-info-group info)
	314	unread (gnus-group-unread group)
	315	has-ticked (cdr (assq 'tick (gnus-info-marks info))))
	316	(when (and (numberp unread)
	317	(= unread 0)
	318	(not has-ticked))
	319	(gnus-group-set-parameter group 'timestamp cur-time))))))
	320
	321	(provide 'gnus-demon)
	322
ab5796a9	323	;;; arch-tag: 8dd5cd3d-6ae4-46b4-9b15-f5fca09fd392
eec82323	324	;;; gnus-demon.el ends here