[bpt/emacs.git] / lisp / autorevert.el

;;; autorevert.el --- revert buffers when files on disk change

;; Copyright (C) 1997, 1998, 1999, 2001 Free Software Foundation, Inc.

;; Author: Anders Lindgren <andersl@andersl.com>
;; Keywords: convenience
;; Created: 1997-06-01
;; Date: 1999-11-30

;; This file is part of GNU Emacs.

;; GNU Emacs is free software; you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation; either version 2, or (at your option)
;; any later version.

;; GNU Emacs is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License
;; along with GNU Emacs; see the file COPYING.  If not, write to the
;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
;; Boston, MA 02111-1307, USA.

;;; Commentary:

;; Introduction:
;;
;; Whenever a file that Emacs is editing has been changed by another
;; program the user normally has to execute the command `revert-buffer'
;; to load the new content of the file into Emacs.
;;
;; This package contains two minor modes: Global Auto-Revert Mode and
;; Auto-Revert Mode.  Both modes automatically revert buffers
;; whenever the corresponding files have been changed on disk.
;;
;; Auto-Revert Mode can be activated for individual buffers.
;; Global Auto-Revert Mode applies to all file buffers.
;;
;; Both modes operate by checking the time stamp of all files at
;; intervals of `auto-revert-interval'.  The default is every five
;; seconds.  The check is aborted whenever the user actually uses
;; Emacs.  You should never even notice that this package is active
;; (except that your buffers will be reverted, of course).

;; Usage:
;;
;; Go to the appropriate buffer and press:
;;   M-x auto-revert-mode RET
;;
;; To activate Global Auto-Revert Mode, press:
;;   M-x global-auto-revert-mode RET
;;
;; To activate Global Auto-Revert Mode every time Emacs is started
;; customise the option `global-auto-revert-mode' or the following
;; line could be added to your ~/.emacs:
;;   (global-auto-revert-mode 1)
;;
;; The function `turn-on-auto-revert-mode' could be added to any major
;; mode hook to activate Auto-Revert Mode for all buffers in that
;; mode.  For example, the following line will activate Auto-Revert
;; Mode in all C mode buffers:
;;
;; (add-hook 'c-mode-hook 'turn-on-auto-revert-mode)

;;; Code:

;; Dependencies:

(require 'timer)
(eval-when-compile (require 'cl))


;; Custom Group:
;;
;; The two modes will be placed next to Auto Save Mode under the
;; Files group under Emacs.

(defgroup auto-revert nil
  "Revert individual buffers when files on disk change.

Auto-Revert Mode can be activated for individual buffer.
Global Auto-Revert Mode applies to all buffers."
  :group 'files
  :group 'convenience)


;; Variables:

;; Autoload for the benefit of `make-mode-line-mouse-sensitive'.
;;;###autoload
(defvar auto-revert-mode nil
  "*Non-nil when Auto-Revert Mode is active.
Never set this variable directly, use the command `auto-revert-mode' instead.")
(put 'auto-revert-mode 'permanent-local t)

(defcustom auto-revert-interval 5
  "Time, in seconds, between Auto-Revert Mode file checks."
  :group 'auto-revert
  :type 'integer)

(defcustom auto-revert-stop-on-user-input t
  "When non-nil Auto-Revert Mode stops checking files on user input."
  :group 'auto-revert
  :type 'boolean)

(defcustom auto-revert-verbose t
  "When nil, Auto-Revert Mode will not generate any messages.

Currently, messages are generated when the mode is activated or
deactivated, and whenever a file is reverted."
  :group 'auto-revert
  :type 'boolean)

(defcustom auto-revert-mode-text " ARev"
  "String to display in the mode line when Auto-Revert Mode is active.

\(When the string is not empty, make sure that it has a leading space.)"
  :tag "Auto Revert Mode Text"		; To separate it from `global-...'
  :group 'auto-revert
  :type 'string)

(defcustom auto-revert-mode-hook nil
  "Functions to run when Auto-Revert Mode is activated."
  :tag "Auto Revert Mode Hook"		; To separate it from `global-...'
  :group 'auto-revert
  :type 'hook)

(defcustom global-auto-revert-mode-text ""
  "String to display when Global Auto-Revert Mode is active.

The default is nothing since when this mode is active this text doesn't
vary over time, or between buffers.  Hence mode line text
would only waste precious space."
  :group 'auto-revert
  :type 'string)

(defcustom global-auto-revert-mode-hook nil
  "Hook called when Global Auto-Revert Mode is activated."
  :group 'auto-revert
  :type 'hook)

(defcustom global-auto-revert-non-file-buffers nil
  "When nil only file buffers are reverted by Global Auto-Revert Mode.

When non-nil, both file buffers and buffers with a custom
`revert-buffer-function' are reverted by Global Auto-Revert Mode.

Use this option with care since it could lead to excessive reverts."
  :group 'auto-revert
  :type 'boolean)

(defcustom global-auto-revert-ignore-modes '()
  "List of major modes Global Auto-Revert Mode should not check."
  :group 'auto-revert
  :type '(repeat sexp))

(defcustom auto-revert-load-hook nil
  "Functions to run when Auto-Revert Mode is first loaded."
  :tag "Load Hook"
  :group 'auto-revert
  :type 'hook)

(defvar global-auto-revert-ignore-buffer nil
  "*When non-nil, Global Auto-Revert Mode will not revert this buffer.

This variable becomes buffer local when set in any fashion.")
(make-variable-buffer-local 'global-auto-revert-ignore-buffer)


;; Internal variables:

(defvar auto-revert-buffer-list '()
  "List of buffers in Auto-Revert Mode.

Note that only Auto-Revert Mode, never Global Auto-Revert Mode, adds
buffers to this list.

The timer function `auto-revert-buffers' is responsible for purging
the list of old buffers.")

(defvar auto-revert-timer nil
  "Timer used by Auto-Revert Mode.")

(defvar auto-revert-remaining-buffers '()
  "Buffers not checked when user input stopped execution.")


;; Functions:

;;;###autoload
(define-minor-mode auto-revert-mode
  "Toggle reverting buffer when file on disk changes.

With arg, turn Auto Revert mode on if and only if arg is positive.
This is a minor mode that affects only the current buffer.
Use `global-auto-revert-mode' to automatically revert all buffers."
  nil auto-revert-mode-text nil
  (if auto-revert-mode
      (if (not (memq (current-buffer) auto-revert-buffer-list))
	  (push (current-buffer) auto-revert-buffer-list))
    (setq auto-revert-buffer-list
	  (delq (current-buffer) auto-revert-buffer-list)))
  (auto-revert-set-timer)
  (when auto-revert-mode
    (auto-revert-buffers)))


;;;###autoload
(defun turn-on-auto-revert-mode ()
  "Turn on Auto-Revert Mode.

This function is designed to be added to hooks, for example:
  (add-hook 'c-mode-hook 'turn-on-auto-revert-mode)"
  (auto-revert-mode 1))


;;;###autoload
(define-minor-mode global-auto-revert-mode
  "Revert any buffer when file on disk change.

With arg, turn Auto Revert mode on globally if and only if arg is positive.
This is a minor mode that affects all buffers.
Use `auto-revert-mode' to revert a particular buffer."
  :global t :group 'auto-revert :lighter global-auto-revert-mode-text
  (auto-revert-set-timer)
  (when global-auto-revert-mode
    (auto-revert-buffers)))


(defun auto-revert-set-timer ()
  "Restart or cancel the timer."
  (if (timerp auto-revert-timer)
      (cancel-timer auto-revert-timer))
  (setq auto-revert-timer
	(if (or global-auto-revert-mode auto-revert-buffer-list)
	    (run-with-timer auto-revert-interval
			    auto-revert-interval
			    'auto-revert-buffers)
	  nil)))

(defun auto-revert-buffers ()
  "Revert buffers as specified by Auto-Revert and Global Auto-Revert Mode.

Should `global-auto-revert-mode' be active all file buffers are checked.

Should `auto-revert-mode' be active in some buffers, those buffers
are checked.

Non-file buffers that have a custom `revert-buffer-function' are
reverted either when Auto-Revert Mode is active in that buffer, or
when the variable `global-auto-revert-non-file-buffers' is non-nil
and Global Auto-Revert Mode is active.

This function stops whenever there is user input.  The buffers not
checked are stored in the variable `auto-revert-remaining-buffers'.

To avoid starvation, the buffers in `auto-revert-remaining-buffers'
are checked first the next time this function is called.

This function is also responsible for removing buffers no longer in
Auto-Revert mode from `auto-revert-buffer-list', and for canceling
the timer when no buffers need to be checked."
  (let ((bufs (if global-auto-revert-mode
		  (buffer-list)
		auto-revert-buffer-list))
	(remaining '())
	(new '()))
    ;; Partition `bufs' into two halves depending on whether or not
    ;; the buffers are in `auto-revert-remaining-buffers'.  The two
    ;; halves are then re-joined with the "remaining" buffers at the
    ;; head of the list.
    (dolist (buf auto-revert-remaining-buffers)
      (if (memq buf bufs)
	  (push buf remaining)))
    (dolist (buf bufs)
      (if (not (memq buf remaining))
	  (push buf new)))
    (setq bufs (nreverse (nconc new remaining)))
    (while (and bufs
		(not (and auto-revert-stop-on-user-input
			  (input-pending-p))))
      (let ((buf (car bufs)))
	(if (buffer-name buf)		; Buffer still alive?
	    (with-current-buffer buf
	      ;; Test if someone has turned off Auto-Revert Mode in a
	      ;; non-standard way, for example by changing major mode.
	      (if (and (not auto-revert-mode)
		       (memq buf auto-revert-buffer-list))
		  (setq auto-revert-buffer-list
			(delq buf auto-revert-buffer-list)))
	      (when (and
		     (or auto-revert-mode
			 (and
			  global-auto-revert-mode
			  (not global-auto-revert-ignore-buffer)
			  (not (memq major-mode
				     global-auto-revert-ignore-modes))))
		     (not (buffer-modified-p))
		     (if (buffer-file-name)
			 (and (file-readable-p (buffer-file-name))
			      (not (verify-visited-file-modtime buf)))
		       (and revert-buffer-function
			    (or (and global-auto-revert-mode
				     global-auto-revert-non-file-buffers)
				auto-revert-mode))))
		(if auto-revert-verbose
		    (message "Reverting buffer `%s'." buf))
		(revert-buffer 'ignore-auto 'dont-ask 'preserve-modes)
		;; `preserve-modes' avoids changing the (minor) modes.  But we
		;; do want to reset the mode for VC, so we do it explicitly.
		(vc-find-file-hook)))
	  ;; Remove dead buffer from `auto-revert-buffer-list'.
	  (setq auto-revert-buffer-list
		(delq buf auto-revert-buffer-list))))
      (setq bufs (cdr bufs)))
    (setq auto-revert-remaining-buffers bufs)
    ;; Check if we should cancel the timer.
    (when (and (not global-auto-revert-mode)
	       (null auto-revert-buffer-list))
      (cancel-timer auto-revert-timer)
      (setq auto-revert-timer nil))))


;; The end:
(provide 'autorevert)

(run-hooks 'auto-revert-load-hook)

;;; arch-tag: f6bcb07b-4841-477e-9e44-b18678e58876
;;; autorevert.el ends here
Commit	Line	Data
e8af40ee	1	;;; autorevert.el --- revert buffers when files on disk change
4a35aff3	2
bf2150fa	3	;; Copyright (C) 1997, 1998, 1999, 2001 Free Software Foundation, Inc.
4a35aff3	4
a468671a	5	;; Author: Anders Lindgren <andersl@andersl.com>
f5f727f8	6	;; Keywords: convenience
a468671a GM	7	;; Created: 1997-06-01
a468671a GM	8	;; Date: 1999-11-30
4a35aff3 RS	9
	10	;; This file is part of GNU Emacs.
	11
	12	;; GNU Emacs is free software; you can redistribute it and/or modify
	13	;; it under the terms of the GNU General Public License as published by
	14	;; the Free Software Foundation; either version 2, or (at your option)
	15	;; any later version.
	16
	17	;; GNU Emacs is distributed in the hope that it will be useful,
	18	;; but WITHOUT ANY WARRANTY; without even the implied warranty of
	19	;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
	20	;; GNU General Public License for more details.
	21
	22	;; You should have received a copy of the GNU General Public License
	23	;; along with GNU Emacs; see the file COPYING. If not, write to the
	24	;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
	25	;; Boston, MA 02111-1307, USA.
	26
	27	;;; Commentary:
	28
	29	;; Introduction:
	30	;;
	31	;; Whenever a file that Emacs is editing has been changed by another
48764ae2	32	;; program the user normally has to execute the command `revert-buffer'
4a35aff3 RS	33	;; to load the new content of the file into Emacs.
	34	;;
	35	;; This package contains two minor modes: Global Auto-Revert Mode and
48764ae2	36	;; Auto-Revert Mode. Both modes automatically revert buffers
4a35aff3 RS	37	;; whenever the corresponding files have been changed on disk.
	38	;;
	39	;; Auto-Revert Mode can be activated for individual buffers.
	40	;; Global Auto-Revert Mode applies to all file buffers.
	41	;;
48764ae2 DL	42	;; Both modes operate by checking the time stamp of all files at
	43	;; intervals of `auto-revert-interval'. The default is every five
	44	;; seconds. The check is aborted whenever the user actually uses
	45	;; Emacs. You should never even notice that this package is active
	46	;; (except that your buffers will be reverted, of course).
4a35aff3 RS	47
	48	;; Usage:
	49	;;
	50	;; Go to the appropriate buffer and press:
	51	;; M-x auto-revert-mode RET
	52	;;
	53	;; To activate Global Auto-Revert Mode, press:
	54	;; M-x global-auto-revert-mode RET
	55	;;
48764ae2 DL	56	;; To activate Global Auto-Revert Mode every time Emacs is started
	57	;; customise the option `global-auto-revert-mode' or the following
	58	;; line could be added to your ~/.emacs:
4a35aff3 RS	59	;; (global-auto-revert-mode 1)
	60	;;
	61	;; The function `turn-on-auto-revert-mode' could be added to any major
	62	;; mode hook to activate Auto-Revert Mode for all buffers in that
	63	;; mode. For example, the following line will activate Auto-Revert
	64	;; Mode in all C mode buffers:
	65	;;
	66	;; (add-hook 'c-mode-hook 'turn-on-auto-revert-mode)
	67
	68	;;; Code:
	69
	70	;; Dependencies:
	71
	72	(require 'timer)
	73	(eval-when-compile (require 'cl))
	74
	75
	76	;; Custom Group:
	77	;;
	78	;; The two modes will be placed next to Auto Save Mode under the
	79	;; Files group under Emacs.
	80
	81	(defgroup auto-revert nil
48764ae2	82	"Revert individual buffers when files on disk change.
4a35aff3 RS	83
	84	Auto-Revert Mode can be activated for individual buffer.
	85	Global Auto-Revert Mode applies to all buffers."
f5f727f8 DN	86	:group 'files
f5f727f8 DN	87	:group 'convenience)
4a35aff3 RS	88
	89
	90	;; Variables:
	91
00d0fda8 DL	92	;; Autoload for the benefit of `make-mode-line-mouse-sensitive'.
00d0fda8 DL	93	;;;###autoload
4a35aff3 RS	94	(defvar auto-revert-mode nil
4a35aff3 RS	95	"*Non-nil when Auto-Revert Mode is active.
0e4f9468 SM	96	Never set this variable directly, use the command `auto-revert-mode' instead.")
0e4f9468 SM	97	(put 'auto-revert-mode 'permanent-local t)
4a35aff3 RS	98
	99	(defcustom auto-revert-interval 5
	100	"Time, in seconds, between Auto-Revert Mode file checks."
	101	:group 'auto-revert
	102	:type 'integer)
	103
	104	(defcustom auto-revert-stop-on-user-input t
	105	"When non-nil Auto-Revert Mode stops checking files on user input."
	106	:group 'auto-revert
	107	:type 'boolean)
	108
	109	(defcustom auto-revert-verbose t
	110	"When nil, Auto-Revert Mode will not generate any messages.
	111
	112	Currently, messages are generated when the mode is activated or
	113	deactivated, and whenever a file is reverted."
	114	:group 'auto-revert
	115	:type 'boolean)
	116
	117	(defcustom auto-revert-mode-text " ARev"
	118	"String to display in the mode line when Auto-Revert Mode is active.
	119
	120	\(When the string is not empty, make sure that it has a leading space.)"
	121	:tag "Auto Revert Mode Text" ; To separate it from `global-...'
	122	:group 'auto-revert
	123	:type 'string)
	124
	125	(defcustom auto-revert-mode-hook nil
	126	"Functions to run when Auto-Revert Mode is activated."
	127	:tag "Auto Revert Mode Hook" ; To separate it from `global-...'
	128	:group 'auto-revert
	129	:type 'hook)
	130
	131	(defcustom global-auto-revert-mode-text ""
	132	"String to display when Global Auto-Revert Mode is active.
	133
	134	The default is nothing since when this mode is active this text doesn't
48764ae2	135	vary over time, or between buffers. Hence mode line text
4a35aff3 RS	136	would only waste precious space."
	137	:group 'auto-revert
	138	:type 'string)
	139
	140	(defcustom global-auto-revert-mode-hook nil
	141	"Hook called when Global Auto-Revert Mode is activated."
	142	:group 'auto-revert
	143	:type 'hook)
	144
	145	(defcustom global-auto-revert-non-file-buffers nil
0e4f9468	146	"When nil only file buffers are reverted by Global Auto-Revert Mode.
4a35aff3 RS	147
4a35aff3 RS	148	When non-nil, both file buffers and buffers with a custom
0e4f9468 SM	149	`revert-buffer-function' are reverted by Global Auto-Revert Mode.
	150
	151	Use this option with care since it could lead to excessive reverts."
4a35aff3 RS	152	:group 'auto-revert
	153	:type 'boolean)
	154
4a35aff3 RS	155	(defcustom global-auto-revert-ignore-modes '()
	156	"List of major modes Global Auto-Revert Mode should not check."
	157	:group 'auto-revert
	158	:type '(repeat sexp))
	159
	160	(defcustom auto-revert-load-hook nil
	161	"Functions to run when Auto-Revert Mode is first loaded."
	162	:tag "Load Hook"
	163	:group 'auto-revert
	164	:type 'hook)
	165
	166	(defvar global-auto-revert-ignore-buffer nil
f1e3ff80	167	"*When non-nil, Global Auto-Revert Mode will not revert this buffer.
4a35aff3	168
48764ae2	169	This variable becomes buffer local when set in any fashion.")
4a35aff3 RS	170	(make-variable-buffer-local 'global-auto-revert-ignore-buffer)
	171
	172
	173	;; Internal variables:
	174
	175	(defvar auto-revert-buffer-list '()
	176	"List of buffers in Auto-Revert Mode.
	177
	178	Note that only Auto-Revert Mode, never Global Auto-Revert Mode, adds
	179	buffers to this list.
	180
	181	The timer function `auto-revert-buffers' is responsible for purging
	182	the list of old buffers.")
	183
	184	(defvar auto-revert-timer nil
	185	"Timer used by Auto-Revert Mode.")
	186
	187	(defvar auto-revert-remaining-buffers '()
	188	"Buffers not checked when user input stopped execution.")
	189
	190
	191	;; Functions:
	192
	193	;;;###autoload
0e4f9468	194	(define-minor-mode auto-revert-mode
48764ae2	195	"Toggle reverting buffer when file on disk changes.
4a35aff3	196
48764ae2 DL	197	With arg, turn Auto Revert mode on if and only if arg is positive.
48764ae2 DL	198	This is a minor mode that affects only the current buffer.
4a35aff3	199	Use `global-auto-revert-mode' to automatically revert all buffers."
0e4f9468	200	nil auto-revert-mode-text nil
4a35aff3 RS	201	(if auto-revert-mode
	202	(if (not (memq (current-buffer) auto-revert-buffer-list))
	203	(push (current-buffer) auto-revert-buffer-list))
	204	(setq auto-revert-buffer-list
	205	(delq (current-buffer) auto-revert-buffer-list)))
	206	(auto-revert-set-timer)
	207	(when auto-revert-mode
0e4f9468	208	(auto-revert-buffers)))
4a35aff3 RS	209
	210
	211	;;;###autoload
	212	(defun turn-on-auto-revert-mode ()
	213	"Turn on Auto-Revert Mode.
	214
	215	This function is designed to be added to hooks, for example:
	216	(add-hook 'c-mode-hook 'turn-on-auto-revert-mode)"
	217	(auto-revert-mode 1))
	218
	219
	220	;;;###autoload
0e4f9468	221	(define-minor-mode global-auto-revert-mode
4a35aff3 RS	222	"Revert any buffer when file on disk change.
4a35aff3 RS	223
48764ae2 DL	224	With arg, turn Auto Revert mode on globally if and only if arg is positive.
48764ae2 DL	225	This is a minor mode that affects all buffers.
4a35aff3	226	Use `auto-revert-mode' to revert a particular buffer."
0e4f9468	227	:global t :group 'auto-revert :lighter global-auto-revert-mode-text
4a35aff3 RS	228	(auto-revert-set-timer)
4a35aff3 RS	229	(when global-auto-revert-mode
0e4f9468	230	(auto-revert-buffers)))
4a35aff3 RS	231
	232
	233	(defun auto-revert-set-timer ()
	234	"Restart or cancel the timer."
	235	(if (timerp auto-revert-timer)
	236	(cancel-timer auto-revert-timer))
0e4f9468 SM	237	(setq auto-revert-timer
	238	(if (or global-auto-revert-mode auto-revert-buffer-list)
	239	(run-with-timer auto-revert-interval
	240	auto-revert-interval
	241	'auto-revert-buffers)
	242	nil)))
4a35aff3 RS	243
	244	(defun auto-revert-buffers ()
	245	"Revert buffers as specified by Auto-Revert and Global Auto-Revert Mode.
	246
	247	Should `global-auto-revert-mode' be active all file buffers are checked.
	248
	249	Should `auto-revert-mode' be active in some buffers, those buffers
	250	are checked.
	251
	252	Non-file buffers that have a custom `revert-buffer-function' are
	253	reverted either when Auto-Revert Mode is active in that buffer, or
	254	when the variable `global-auto-revert-non-file-buffers' is non-nil
	255	and Global Auto-Revert Mode is active.
	256
48764ae2	257	This function stops whenever there is user input. The buffers not
4a35aff3 RS	258	checked are stored in the variable `auto-revert-remaining-buffers'.
	259
	260	To avoid starvation, the buffers in `auto-revert-remaining-buffers'
	261	are checked first the next time this function is called.
	262
48764ae2	263	This function is also responsible for removing buffers no longer in
4a35aff3 RS	264	Auto-Revert mode from `auto-revert-buffer-list', and for canceling
	265	the timer when no buffers need to be checked."
	266	(let ((bufs (if global-auto-revert-mode
	267	(buffer-list)
	268	auto-revert-buffer-list))
	269	(remaining '())
	270	(new '()))
	271	;; Partition `bufs' into two halves depending on whether or not
	272	;; the buffers are in `auto-revert-remaining-buffers'. The two
	273	;; halves are then re-joined with the "remaining" buffers at the
	274	;; head of the list.
	275	(dolist (buf auto-revert-remaining-buffers)
	276	(if (memq buf bufs)
	277	(push buf remaining)))
	278	(dolist (buf bufs)
	279	(if (not (memq buf remaining))
	280	(push buf new)))
	281	(setq bufs (nreverse (nconc new remaining)))
	282	(while (and bufs
	283	(not (and auto-revert-stop-on-user-input
	284	(input-pending-p))))
	285	(let ((buf (car bufs)))
	286	(if (buffer-name buf) ; Buffer still alive?
0e4f9468	287	(with-current-buffer buf
4a35aff3 RS	288	;; Test if someone has turned off Auto-Revert Mode in a
	289	;; non-standard way, for example by changing major mode.
	290	(if (and (not auto-revert-mode)
	291	(memq buf auto-revert-buffer-list))
	292	(setq auto-revert-buffer-list
	293	(delq buf auto-revert-buffer-list)))
	294	(when (and
	295	(or auto-revert-mode
	296	(and
	297	global-auto-revert-mode
	298	(not global-auto-revert-ignore-buffer)
	299	(not (memq major-mode
	300	global-auto-revert-ignore-modes))))
	301	(not (buffer-modified-p))
	302	(if (buffer-file-name)
	303	(and (file-readable-p (buffer-file-name))
	304	(not (verify-visited-file-modtime buf)))
	305	(and revert-buffer-function
	306	(or (and global-auto-revert-mode
	307	global-auto-revert-non-file-buffers)
	308	auto-revert-mode))))
	309	(if auto-revert-verbose
	310	(message "Reverting buffer `%s'." buf))
0e4f9468 SM	311	(revert-buffer 'ignore-auto 'dont-ask 'preserve-modes)
	312	;; `preserve-modes' avoids changing the (minor) modes. But we
	313	;; do want to reset the mode for VC, so we do it explicitly.
	314	(vc-find-file-hook)))
4a35aff3 RS	315	;; Remove dead buffer from `auto-revert-buffer-list'.
	316	(setq auto-revert-buffer-list
	317	(delq buf auto-revert-buffer-list))))
	318	(setq bufs (cdr bufs)))
	319	(setq auto-revert-remaining-buffers bufs)
	320	;; Check if we should cancel the timer.
	321	(when (and (not global-auto-revert-mode)
	322	(null auto-revert-buffer-list))
	323	(cancel-timer auto-revert-timer)
	324	(setq auto-revert-timer nil))))
	325
	326
	327	;; The end:
4a35aff3 RS	328	(provide 'autorevert)
	329
	330	(run-hooks 'auto-revert-load-hook)
	331
ab5796a9	332	;;; arch-tag: f6bcb07b-4841-477e-9e44-b18678e58876
e8af40ee	333	;;; autorevert.el ends here