* doc/lispref/intro.texi (A Sample Variable Description): Use @dfn more.
[bpt/emacs.git] / m4 / sys_time_h.m4
CommitLineData
c8fff863
PE
1# Configure a replacement for <sys/time.h>.
2# serial 8
3
4# Copyright (C) 2007, 2009-2012 Free Software Foundation, Inc.
5# This file is free software; the Free Software Foundation
6# gives unlimited permission to copy and/or distribute it,
7# with or without modifications, as long as this notice is preserved.
8
9# Written by Paul Eggert and Martin Lambers.
10
11AC_DEFUN([gl_HEADER_SYS_TIME_H],
12[
13 dnl Use AC_REQUIRE here, so that the REPLACE_GETTIMEOFDAY=0 statement
14 dnl below is expanded once only, before all REPLACE_GETTIMEOFDAY=1
15 dnl statements that occur in other macros.
16 AC_REQUIRE([gl_HEADER_SYS_TIME_H_BODY])
17])
18
19AC_DEFUN([gl_HEADER_SYS_TIME_H_BODY],
20[
21 AC_REQUIRE([AC_C_RESTRICT])
22 AC_REQUIRE([gl_HEADER_SYS_TIME_H_DEFAULTS])
23 AC_CHECK_HEADERS_ONCE([sys/time.h])
24 gl_CHECK_NEXT_HEADERS([sys/time.h])
25
26 if test $ac_cv_header_sys_time_h != yes; then
27 HAVE_SYS_TIME_H=0
28 fi
29
30 dnl On native Windows with MSVC, 'struct timeval' is defined in <winsock2.h>
31 dnl only. So include that header in the list.
32 gl_PREREQ_SYS_H_WINSOCK2
33 AC_CACHE_CHECK([for struct timeval], [gl_cv_sys_struct_timeval],
34 [AC_COMPILE_IFELSE(
35 [AC_LANG_PROGRAM(
36 [[#if HAVE_SYS_TIME_H
37 #include <sys/time.h>
38 #endif
39 #include <time.h>
40 #if HAVE_WINSOCK2_H
41 # include <winsock2.h>
42 #endif
43 ]],
44 [[static struct timeval x; x.tv_sec = x.tv_usec;]])],
45 [gl_cv_sys_struct_timeval=yes],
46 [gl_cv_sys_struct_timeval=no])
47 ])
48 if test $gl_cv_sys_struct_timeval != yes; then
49 HAVE_STRUCT_TIMEVAL=0
50 else
51 dnl On native Windows with a 64-bit 'time_t', 'struct timeval' is defined
52 dnl (in <sys/time.h> and <winsock2.h> for mingw64, in <winsock2.h> only
53 dnl for MSVC) with a tv_sec field of type 'long' (32-bit!), which is
54 dnl smaller than the 'time_t' type mandated by POSIX.
55 AC_CACHE_CHECK([for correct struct timeval.tv_sec member],
56 [gl_cv_sys_struct_timeval_tv_sec],
57 [AC_COMPILE_IFELSE(
58 [AC_LANG_PROGRAM(
59 [[#if HAVE_SYS_TIME_H
60 #include <sys/time.h>
61 #endif
62 #include <time.h>
63 #if HAVE_WINSOCK2_H
64 # include <winsock2.h>
65 #endif
66 ]],
67 [[static struct timeval x;
68 typedef int verify_tv_sec_type[sizeof (x.tv_sec) == sizeof (time_t) ? 1 : -1];
69 ]])],
70 [gl_cv_sys_struct_timeval_tv_sec=yes],
71 [gl_cv_sys_struct_timeval_tv_sec=no])
72 ])
73 if test $gl_cv_sys_struct_timeval_tv_sec != yes; then
74 REPLACE_STRUCT_TIMEVAL=1
75 fi
76 fi
77
78 dnl Check for declarations of anything we want to poison if the
79 dnl corresponding gnulib module is not in use.
80 gl_WARN_ON_USE_PREPARE([[
81#if HAVE_SYS_TIME_H
82# include <sys/time.h>
83#endif
84#include <time.h>
85 ]], [gettimeofday])
86])
87
88AC_DEFUN([gl_SYS_TIME_MODULE_INDICATOR],
89[
90 dnl Use AC_REQUIRE here, so that the default settings are expanded once only.
91 AC_REQUIRE([gl_HEADER_SYS_TIME_H_DEFAULTS])
92 gl_MODULE_INDICATOR_SET_VARIABLE([$1])
93 dnl Define it also as a C macro, for the benefit of the unit tests.
94 gl_MODULE_INDICATOR_FOR_TESTS([$1])
95])
96
97AC_DEFUN([gl_HEADER_SYS_TIME_H_DEFAULTS],
98[
99 GNULIB_GETTIMEOFDAY=0; AC_SUBST([GNULIB_GETTIMEOFDAY])
100 dnl Assume POSIX behavior unless another module says otherwise.
101 HAVE_GETTIMEOFDAY=1; AC_SUBST([HAVE_GETTIMEOFDAY])
102 HAVE_STRUCT_TIMEVAL=1; AC_SUBST([HAVE_STRUCT_TIMEVAL])
103 HAVE_SYS_TIME_H=1; AC_SUBST([HAVE_SYS_TIME_H])
104 REPLACE_GETTIMEOFDAY=0; AC_SUBST([REPLACE_GETTIMEOFDAY])
105 REPLACE_STRUCT_TIMEVAL=0; AC_SUBST([REPLACE_STRUCT_TIMEVAL])
106])