(fontset_font): If we know there is no font, don't do any work.

[bpt/emacs.git] / test / icalendar-testsuite.el

;; icalendar-testsuite.el --- Test suite for icalendar.el

;; Copyright (C) 2005, 2008, 2009  Free Software Foundation, Inc.

;; Author:         Ulf Jasper <ulf.jasper@web.de>
;; Created:        March 2005
;; Keywords:       calendar
;; Human-Keywords: calendar, diary, iCalendar, vCalendar

;; This file is part of GNU Emacs.

;; GNU Emacs is free software: you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation, either version 3 of the License, or
;; (at your option) any later version.

;; GNU Emacs is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License
;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.

;;; Commentary:

;; TODO:
;; - Add more unit tests for functions, timezone etc.

;; Note: Watch the trailing blank that is added on import.

;;; Code:
(defun icalendar-testsuite-run ()
  "Run icalendar test suite."
  (interactive)
  (icalendar-testsuite--run-function-tests)
  (icalendar-testsuite--run-import-tests)
  (icalendar-testsuite--run-export-tests)
  (icalendar-testsuite--run-cycle-tests)
  (icalendar-testsuite--run-real-world-tests)
  (message "All icalendar tests finished successfully."))

;; ======================================================================
;; Test methods for functions
;; ======================================================================
(defun icalendar-testsuite--run-function-tests ()
  "Perform tests for single icalendar functions."
  (icalendar-testsuite--test-parse-summary-and-rest)
  (icalendar-testsuite--test-format-ical-event)
  (icalendar-testsuite--test-import-format-sample)
  (icalendar-testsuite--test-first-weekday-of-year)
  (icalendar-testsuite--test-datestring-to-isodate)
  (icalendar-testsuite--test-datetime-to-diary-date)
  (icalendar-testsuite--test-calendar-style)
  (icalendar-testsuite--test-create-uid))

(defun icalendar-testsuite--test-format-ical-event ()
  "Test `icalendar--format-ical-event'."
  (let ((icalendar-import-format "%s%d%l%o%t%u%c")
        (icalendar-import-format-summary "SUM %s")
        (icalendar-import-format-location " LOC %s")
        (icalendar-import-format-description " DES %s")
        (icalendar-import-format-organizer " ORG %s")
        (icalendar-import-format-status " STA %s")
        (icalendar-import-format-url " URL %s")
        (icalendar-import-format-class " CLA %s")
        (event (icalendar-testsuite--get-ical-event "BEGIN:VEVENT
DTSTAMP:20030509T043439Z
DTSTART:20030509T103000
SUMMARY:sum
ORGANIZER:org
LOCATION:loc
DTEND:20030509T153000
DESCRIPTION:des
END:VEVENT
")))
    (assert (string= (icalendar--format-ical-event event)
                     "SUM sum DES des LOC loc ORG org") t)
    (setq icalendar-import-format (lambda (&rest ignore)
                                    "helloworld"))
    (assert (string= (icalendar--format-ical-event event)
                     "helloworld") t)
    (setq icalendar-import-format
          (lambda (e)
            (format "-%s-%s-%s-%s-%s-%s-%s-"
                    (icalendar--get-event-property event 'SUMMARY)
                    (icalendar--get-event-property event 'DESCRIPTION)
                    (icalendar--get-event-property event 'LOCATION)
                    (icalendar--get-event-property event 'ORGANIZER)
                    (icalendar--get-event-property event 'STATUS)
                    (icalendar--get-event-property event 'URL)
                    (icalendar--get-event-property event 'CLASS))))
    (assert (string= (icalendar--format-ical-event event)
                     "-sum-des-loc-org-nil-nil-nil-") t)))

(defun icalendar-testsuite--test-parse-summary-and-rest ()
  "Test `icalendar--parse-summary-and-rest'."
  (let ((icalendar-import-format "%s%d%l%o%t%u%c")
        (icalendar-import-format-summary "SUM %s")
        (icalendar-import-format-location " LOC %s")
        (icalendar-import-format-description " DES %s")
        (icalendar-import-format-organizer " ORG %s")
        (icalendar-import-format-status " STA %s")
        (icalendar-import-format-url " URL %s")
        (icalendar-import-format-class " CLA %s")
        (result))
    ;; FIXME: need a trailing blank char!
    (setq result (icalendar--parse-summary-and-rest "SUM sum ORG org "))
    (assert (string= (cdr (assoc 'org result)) "org"))

    (setq result (icalendar--parse-summary-and-rest
                  "SUM sum DES des LOC loc ORG org STA sta URL url CLA cla "))
    (assert (string= (cdr (assoc 'des result)) "des"))
    (assert (string= (cdr (assoc 'loc result)) "loc"))
    (assert (string= (cdr (assoc 'org result)) "org"))
    (assert (string= (cdr (assoc 'sta result)) "sta"))
    (assert (string= (cdr (assoc 'cla result)) "cla"))

    (setq icalendar-import-format (lambda () "Hello world"))
    (setq result (icalendar--parse-summary-and-rest
                  "blah blah "))
    (assert (not result))
    ))

(defun icalendar-testsuite--get-ical-event (ical-string)
  "Helper function for testing `icalendar-testsuite--test-format-ical-event'.
Return icalendar event for ICAL-STRING."
  (save-excursion
    (with-temp-buffer
      (insert ical-string)
      (goto-char (point-min))
      (car (icalendar--read-element nil nil)))))

(defun icalendar-testsuite--test-import-format-sample ()
  "Test method for `icalendar-import-format-sample'."
  (assert (string= (icalendar-import-format-sample
                    (icalendar-testsuite--get-ical-event "BEGIN:VEVENT
DTSTAMP:20030509T043439Z
DTSTART:20030509T103000
SUMMARY:a
ORGANIZER:d
LOCATION:c
DTEND:20030509T153000
DESCRIPTION:b
END:VEVENT
"))
                   (concat "SUMMARY=`a' DESCRIPTION=`b' LOCATION=`c' "
                           "ORGANIZER=`d' STATUS=`' URL=`' CLASS=`'"))))

(defun icalendar-testsuite--test-first-weekday-of-year ()
  "Test method for `icalendar-first-weekday-of-year'."
  (assert (eq 1 (icalendar-first-weekday-of-year "TU" 2008)))
  (assert (eq 3 (icalendar-first-weekday-of-year "WE" 2007)))
  (assert (eq 5 (icalendar-first-weekday-of-year "TH" 2006)))
  (assert (eq 7 (icalendar-first-weekday-of-year "FR" 2005)))
  (assert (eq 3 (icalendar-first-weekday-of-year "SA" 2004)))
  (assert (eq 5 (icalendar-first-weekday-of-year "SU" 2003)))
  (assert (eq 7 (icalendar-first-weekday-of-year "MO" 2002)))
  (assert (eq 3 (icalendar-first-weekday-of-year "MO" 2000)))
  (assert (eq 1 (icalendar-first-weekday-of-year "TH" 1970))))

(defun icalendar-testsuite--test-datestring-to-isodate ()
  "Test method for `icalendar--datestring-to-isodate'."
  (let ((calendar-date-style 'iso))
    ;; numeric iso
    (assert (string= (icalendar--datestring-to-isodate "2008 05 11")
                     "20080511"))
    (assert (string= (icalendar--datestring-to-isodate "2008 05 31")
                     "20080531"))
    (assert (string= (icalendar--datestring-to-isodate "2008 05 31" 2)
                     "20080602"))

    ;; numeric european
    (setq calendar-date-style 'european)
    (assert (string= (icalendar--datestring-to-isodate "11 05 2008")
                     "20080511"))
    (assert (string= (icalendar--datestring-to-isodate "31 05 2008")
                     "20080531"))
    (assert (string= (icalendar--datestring-to-isodate "31 05 2008" 2)
                     "20080602"))

    ;; numeric american
    (setq calendar-date-style 'american)
    (assert (string= (icalendar--datestring-to-isodate "11 05 2008")
                     "20081105"))
    (assert (string= (icalendar--datestring-to-isodate "12 30 2008")
                     "20081230"))
    (assert (string= (icalendar--datestring-to-isodate "12 30 2008" 2)
                     "20090101"))

    ;; non-numeric
    (setq calendar-date-style nil)      ;not necessary for conversion
    (assert (string= (icalendar--datestring-to-isodate "Nov 05 2008")
                     "20081105"))
    (assert (string= (icalendar--datestring-to-isodate "05 Nov 2008")
                     "20081105"))
    (assert (string= (icalendar--datestring-to-isodate "2008 Nov 05")
                     "20081105"))))

(defun icalendar-testsuite--test-datetime-to-diary-date ()
  "Test method for `icalendar--datetime-to-diary-date'."
  (let* ((datetime '(59 59 23 31 12 2008))
         (calendar-date-style 'iso))
    (assert (string= (icalendar--datetime-to-diary-date datetime)
                     "2008 12 31"))
    (setq calendar-date-style 'european)
    (assert (string= (icalendar--datetime-to-diary-date datetime)
                     "31 12 2008"))
    (setq calendar-date-style 'american)
    (assert (string= (icalendar--datetime-to-diary-date datetime)
                     "12 31 2008"))))

(defun icalendar-testsuite--test-calendar-style ()
  "Test method for `icalendar--date-style'."
  (dolist (calendar-date-style '(iso american european))
    (assert (eq (icalendar--date-style) calendar-date-style)))
  (let ((cds calendar-date-style)
        (european-calendar-style t))
    (makunbound 'calendar-date-style)
    (assert (eq (icalendar--date-style) 'european))
    (with-no-warnings (setq european-calendar-style nil)) ;still get warning!?! FIXME
    (assert (eq (icalendar--date-style) 'american))
    (setq calendar-date-style cds)))

(defun icalendar-testsuite--test-create-uid ()
  "Test method for `icalendar--create-uid'."
  (let (t-ct
        (icalendar--uid-count 77))
    ;; FIXME! If a test fails 'current-time is screwed. FIXME!
    (fset 't-ct (symbol-function 'current-time))
    (fset 'current-time (lambda () '(1 2 3)))
    (assert (= 77 icalendar--uid-count))
    (assert (string=  "emacs12378" (icalendar--create-uid)))
    (assert (= 78 icalendar--uid-count))
    (fset 'current-time (symbol-function 't-ct))
    ))

;; ======================================================================
;; Test methods for exporting from diary to icalendar
;; ======================================================================

(defun icalendar-testsuite--test-export (input-iso input-european input-american
                                                   expected-output)
  "Perform an export test.
Argument INPUT-ISO iso style diary string.
Argument INPUT-EUROPEAN european style diary string.
Argument INPUT-AMERICAN american style diary string.
Argument EXPECTED-OUTPUT expected icalendar result string.

European style input data must use german month names.  American
and ISO style input data must use english month names."
  (message "--- icalendar-testsuite--test-export ---")
  (let ((calendar-date-style 'iso)
        (icalendar-recurring-start-year 2000))
    (set-time-zone-rule "CET") ;;FIXME: reset timezone!
    (when input-iso
      (let ((calendar-month-name-array
             ["January" "February" "March" "April" "May" "June" "July" "August"
              "September" "October" "November" "December"])
            (calendar-day-name-array
             ["Sunday" "Monday" "Tuesday" "Wednesday" "Thursday" "Friday"
              "Saturday"]))
        (setq calendar-date-style 'iso)
        (icalendar-testsuite--do-test-export input-iso expected-output)))
    (when input-european
      (let ((calendar-month-name-array