Commit | Line | Data |
---|---|---|
c5772569 | 1 | ;;; face-remap.el --- Functions for managing `face-remapping-alist' -*- lexical-binding: t -*- |
9d3d42fb | 2 | ;; |
ab422c4d | 3 | ;; Copyright (C) 2008-2013 Free Software Foundation, Inc. |
9d3d42fb MB |
4 | ;; |
5 | ;; Author: Miles Bader <miles@gnu.org> | |
88f4758e | 6 | ;; Keywords: faces, face remapping, display, user commands |
9d3d42fb MB |
7 | ;; |
8 | ;; This file is part of GNU Emacs. | |
9 | ;; | |
10 | ;; GNU Emacs is free software: you can redistribute it and/or modify | |
11 | ;; it under the terms of the GNU General Public License as published by | |
12 | ;; the Free Software Foundation, either version 3 of the License, or | |
13 | ;; (at your option) any later version. | |
14 | ;; | |
15 | ;; GNU Emacs is distributed in the hope that it will be useful, | |
16 | ;; but WITHOUT ANY WARRANTY; without even the implied warranty of | |
17 | ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the | |
18 | ;; GNU General Public License for more details. | |
19 | ;; | |
20 | ;; You should have received a copy of the GNU General Public License | |
21 | ;; along with GNU Emacs. If not, see <http://www.gnu.org/licenses/>. | |
22 | ;; | |
23 | ||
24 | ;;; Commentary: | |
25 | ||
26 | ;; | |
27 | ;; This file defines some simple operations that can be used for | |
28 | ;; maintaining the `face-remapping-alist' in a cooperative way. This is | |
29 | ;; especially important for the `default' face. | |
30 | ;; | |
31 | ;; Each face-remapping definition in `face-remapping-alist' added by | |
32 | ;; this code uses the form: | |
33 | ;; | |
34 | ;; (face RELATIVE_SPECS_1 RELATIVE_SPECS_2 ... BASE_SPECS) | |
35 | ;; | |
36 | ;; The "specs" values are a lists of face names or face attribute-value | |
37 | ;; pairs, and are merged together, with earlier values taking precedence. | |
38 | ;; | |
e40a85cd MB |
39 | ;; The RELATIVE_SPECS_* values are added by `face-remap-add-relative' |
40 | ;; (and removed by `face-remap-remove-relative', and are intended for | |
9d3d42fb MB |
41 | ;; face "modifications" (such as increasing the size). Typical users of |
42 | ;; relative specs would be minor modes. | |
43 | ;; | |
44 | ;; BASE_SPECS is the lowest-priority value, and by default is just the | |
45 | ;; face name, which causes the global definition of that face to be used. | |
46 | ;; | |
47 | ;; A non-default value of BASE_SPECS may also be set using | |
e40a85cd | 48 | ;; `face-remap-set-base'. Because this _overwrites_ the default |
9d3d42fb | 49 | ;; value inheriting from the global face definition, it is up to the |
e40a85cd MB |
50 | ;; caller of face-remap-set-base to add such inheritance if it is |
51 | ;; desired. A typical use of face-remap-set-base would be a major | |
9d3d42fb MB |
52 | ;; mode setting face remappings, e.g., of the default face. |
53 | ;; | |
54 | ;; All modifications cause face-remapping-alist to be made buffer-local. | |
55 | ;; | |
56 | ||
57 | ||
58 | ;;; Code: | |
59 | ||
60 | \f | |
61 | ;; ---------------------------------------------------------------- | |
62 | ;; Utility functions | |
63 | ||
d03d411d MB |
64 | ;; Names of face attributes corresponding to lisp face-vector positions. |
65 | ;; This variable should probably be defined in C code where the actual | |
66 | ;; definitions are available. | |
67 | ;; | |
68 | (defvar internal-lisp-face-attributes | |
69 | [nil | |
70 | :family :foundry :swidth :height :weight :slant :underline :inverse | |
71 | :foreground :background :stipple :overline :strike :box | |
72 | :font :inherit :fontset :vector]) | |
73 | ||
74 | (defun face-attrs-more-relative-p (attrs1 attrs2) | |
58aa805b | 75 | "Return true if ATTRS1 contains a greater number of relative |
d03d411d MB |
76 | face-attributes than ATTRS2. A face attribute is considered |
77 | relative if `face-attribute-relative-p' returns non-nil. | |
78 | ||
79 | ATTRS1 and ATTRS2 may be any value suitable for a `face' text | |
80 | property, including face names, lists of face names, | |
81 | face-attribute plists, etc. | |
82 | ||
83 | This function can be used as a predicate with `sort', to sort | |
84 | face lists so that more specific faces are located near the end." | |
85 | (unless (vectorp attrs1) | |
86 | (setq attrs1 (face-attributes-as-vector attrs1))) | |
87 | (unless (vectorp attrs2) | |
88 | (setq attrs2 (face-attributes-as-vector attrs2))) | |
89 | (let ((rel1-count 0) (rel2-count 0)) | |
90 | (dotimes (i (length attrs1)) | |
91 | (let ((attr (aref internal-lisp-face-attributes i))) | |
92 | (when attr | |
93 | (when (face-attribute-relative-p attr (aref attrs1 i)) | |
94 | (setq rel1-count (+ rel1-count 1))) | |
95 | (when (face-attribute-relative-p attr (aref attrs2 i)) | |
96 | (setq rel2-count (+ rel2-count 1)))))) | |
97 | (< rel1-count rel2-count))) | |
98 | ||
99 | (defun face-remap-order (entry) | |
100 | "Order ENTRY so that more relative face specs are near the beginning. | |
101 | The list structure of ENTRY may be destructively modified." | |
102 | (setq entry (nreverse entry)) | |
103 | (setcdr entry (sort (cdr entry) 'face-attrs-more-relative-p)) | |
104 | (nreverse entry)) | |
105 | ||
23b77eee | 106 | ;;;###autoload |
e40a85cd | 107 | (defun face-remap-add-relative (face &rest specs) |
9d3d42fb | 108 | "Add a face remapping entry of FACE to SPECS in the current buffer. |
fb5b8aca | 109 | Return a cookie which can be used to delete this remapping with |
e40a85cd | 110 | `face-remap-remove-relative'. |
9d3d42fb | 111 | |
6175e34b CY |
112 | The remaining arguments, SPECS, should form a list of faces. |
113 | Each list element should be either a face name or a property list | |
114 | of face attribute/value pairs. If more than one face is listed, | |
115 | that specifies an aggregate face, in the same way as in a `face' | |
116 | text property, except for possible priority changes noted below. | |
117 | ||
118 | The face remapping specified by SPECS takes effect alongside the | |
119 | remappings from other calls to `face-remap-add-relative' for the | |
120 | same FACE, as well as the normal definition of FACE (at lowest | |
121 | priority). This function tries to sort multiple remappings for | |
122 | the same face, so that remappings specifying relative face | |
123 | attributes are applied after remappings specifying absolute face | |
124 | attributes. | |
fb5b8aca CY |
125 | |
126 | The base (lowest priority) remapping may be set to something | |
127 | other than the normal definition of FACE via `face-remap-set-base'." | |
cece37cf MB |
128 | (while (and (consp specs) (null (cdr specs))) |
129 | (setq specs (car specs))) | |
9d3d42fb MB |
130 | (make-local-variable 'face-remapping-alist) |
131 | (let ((entry (assq face face-remapping-alist))) | |
132 | (when (null entry) | |
133 | (setq entry (list face face)) ; explicitly merge with global def | |
134 | (push entry face-remapping-alist)) | |
894b9dd9 CY |
135 | (let ((faces (cdr entry))) |
136 | (if (symbolp faces) | |
137 | (setq faces (list faces))) | |
138 | (setcdr entry (face-remap-order (cons specs faces)))) | |
9d3d42fb MB |
139 | (cons face specs))) |
140 | ||
e40a85cd MB |
141 | (defun face-remap-remove-relative (cookie) |
142 | "Remove a face remapping previously added by `face-remap-add-relative'. | |
9d3d42fb MB |
143 | COOKIE should be the return value from that function." |
144 | (let ((remapping (assq (car cookie) face-remapping-alist))) | |
145 | (when remapping | |
146 | (let ((updated-entries (remq (cdr cookie) (cdr remapping)))) | |
147 | (unless (eq updated-entries (cdr remapping)) | |
148 | (setcdr remapping updated-entries) | |
149 | (when (or (null updated-entries) | |
150 | (and (eq (car-safe updated-entries) (car cookie)) | |
151 | (null (cdr updated-entries)))) | |
152 | (setq face-remapping-alist | |
153 | (remq remapping face-remapping-alist))) | |
154 | (cdr cookie)))))) | |
155 | ||
23b77eee | 156 | ;;;###autoload |
e40a85cd | 157 | (defun face-remap-reset-base (face) |
fb5b8aca CY |
158 | "Set the base remapping of FACE to the normal definition of FACE. |
159 | This causes the remappings specified by `face-remap-add-relative' | |
160 | to apply on top of the normal definition of FACE." | |
9d3d42fb MB |
161 | (let ((entry (assq face face-remapping-alist))) |
162 | (when entry | |
163 | ;; If there's nothing except a base remapping, we simply remove | |
164 | ;; the entire remapping entry, as setting the base to the default | |
165 | ;; would be the same as the global definition. Otherwise, we | |
166 | ;; modify the base remapping. | |
167 | (if (null (cddr entry)) ; nothing except base remapping | |
168 | (setq face-remapping-alist ; so remove entire entry | |
169 | (remq entry face-remapping-alist)) | |
170 | (setcar (last entry) face))))) ; otherwise, just inherit global def | |
171 | ||
23b77eee | 172 | ;;;###autoload |
e40a85cd | 173 | (defun face-remap-set-base (face &rest specs) |
9d3d42fb | 174 | "Set the base remapping of FACE in the current buffer to SPECS. |
fb5b8aca | 175 | This causes the remappings specified by `face-remap-add-relative' |
6175e34b CY |
176 | to apply on top of the face specification given by SPECS. |
177 | ||
178 | The remaining arguments, SPECS, should form a list of faces. | |
179 | Each list element should be either a face name or a property list | |
180 | of face attribute/value pairs, like in a `face' text property. | |
fb5b8aca CY |
181 | |
182 | If SPECS is empty, call `face-remap-reset-base' to use the normal | |
183 | definition of FACE as the base remapping; note that this is | |
184 | different from SPECS containing a single value `nil', which means | |
185 | not to inherit from the global definition of FACE at all." | |
cece37cf MB |
186 | (while (and (consp specs) (not (null (car specs))) (null (cdr specs))) |
187 | (setq specs (car specs))) | |
9d3d42fb MB |
188 | (if (or (null specs) |
189 | (and (eq (car specs) face) (null (cdr specs)))) ; default | |
190 | ;; Set entry back to default | |
e40a85cd | 191 | (face-remap-reset-base face) |
9d3d42fb MB |
192 | ;; Set the base remapping |
193 | (make-local-variable 'face-remapping-alist) | |
194 | (let ((entry (assq face face-remapping-alist))) | |
195 | (if entry | |
196 | (setcar (last entry) specs) ; overwrite existing base entry | |
197 | (push (list face specs) face-remapping-alist))))) | |
12de5099 | 198 | |
9d3d42fb MB |
199 | \f |
200 | ;; ---------------------------------------------------------------- | |
201 | ;; text-scale-mode | |
202 | ||
203 | (defcustom text-scale-mode-step 1.2 | |
204 | "Scale factor used by `text-scale-mode'. | |
205 | Each positive or negative step scales the default face height by this amount." | |
206 | :group 'display | |
af09cfd7 JB |
207 | :type 'number |
208 | :version "23.1") | |
9d3d42fb MB |
209 | |
210 | ;; current remapping cookie for text-scale-mode | |
211 | (defvar text-scale-mode-remapping nil) | |
212 | (make-variable-buffer-local 'text-scale-mode-remapping) | |
213 | ||
214 | ;; Lighter displayed for text-scale-mode in mode-line minor-mode list | |
215 | (defvar text-scale-mode-lighter "+0") | |
216 | (make-variable-buffer-local 'text-scale-mode-lighter) | |
217 | ||
218 | ;; Number of steps that text-scale-mode will increase/decrease text height | |
219 | (defvar text-scale-mode-amount 0) | |
220 | (make-variable-buffer-local 'text-scale-mode-amount) | |
221 | ||
222 | (define-minor-mode text-scale-mode | |
06e21633 | 223 | "Minor mode for displaying buffer text in a larger/smaller font. |
e1ac4066 GM |
224 | With a prefix argument ARG, enable the mode if ARG is positive, |
225 | and disable it otherwise. If called from Lisp, enable the mode | |
226 | if ARG is omitted or nil. | |
9d3d42fb MB |
227 | |
228 | The amount of scaling is determined by the variable | |
12de5099 JB |
229 | `text-scale-mode-amount': one step scales the global default |
230 | face size by the value of the variable `text-scale-mode-step' | |
231 | \(a negative amount shrinks the text). | |
232 | ||
05fbc4a9 MB |
233 | The `text-scale-increase', `text-scale-decrease', and |
234 | `text-scale-set' functions may be used to interactively modify | |
235 | the variable `text-scale-mode-amount' (they also enable or | |
236 | disable `text-scale-mode' as necessary)." | |
9d3d42fb MB |
237 | :lighter (" " text-scale-mode-lighter) |
238 | (when text-scale-mode-remapping | |
e40a85cd | 239 | (face-remap-remove-relative text-scale-mode-remapping)) |
9d3d42fb MB |
240 | (setq text-scale-mode-lighter |
241 | (format (if (>= text-scale-mode-amount 0) "+%d" "%d") | |
242 | text-scale-mode-amount)) | |
243 | (setq text-scale-mode-remapping | |
244 | (and text-scale-mode | |
e40a85cd | 245 | (face-remap-add-relative 'default |
9d3d42fb MB |
246 | :height |
247 | (expt text-scale-mode-step | |
248 | text-scale-mode-amount)))) | |
249 | (force-window-update (current-buffer))) | |
250 | ||
05fbc4a9 MB |
251 | ;;;###autoload |
252 | (defun text-scale-set (level) | |
253 | "Set the scale factor of the default face in the current buffer to LEVEL. | |
254 | If LEVEL is non-zero, `text-scale-mode' is enabled, otherwise it is disabled. | |
255 | ||
256 | LEVEL is a number of steps, with 0 representing the default size. | |
257 | Each step scales the height of the default face by the variable | |
258 | `text-scale-mode-step' (a negative number decreases the height by | |
259 | the same amount)." | |
260 | (interactive "p") | |
261 | (setq text-scale-mode-amount level) | |
262 | (text-scale-mode (if (zerop text-scale-mode-amount) -1 1))) | |
263 | ||
9d3d42fb | 264 | ;;;###autoload |
16c1ddc2 | 265 | (defun text-scale-increase (inc) |
9d3d42fb MB |
266 | "Increase the height of the default face in the current buffer by INC steps. |
267 | If the new height is other than the default, `text-scale-mode' is enabled. | |
268 | ||
269 | Each step scales the height of the default face by the variable | |
270 | `text-scale-mode-step' (a negative number of steps decreases the | |
271 | height by the same amount). As a special case, an argument of 0 | |
272 | will remove any scaling currently active." | |
56c73dec | 273 | (interactive "p") |
dced1efd MB |
274 | (setq text-scale-mode-amount |
275 | (if (= inc 0) 0 (+ (if text-scale-mode text-scale-mode-amount 0) inc))) | |
9d3d42fb MB |
276 | (text-scale-mode (if (zerop text-scale-mode-amount) -1 1))) |
277 | ||
9d3d42fb | 278 | ;;;###autoload |
16c1ddc2 | 279 | (defun text-scale-decrease (dec) |
9d3d42fb | 280 | "Decrease the height of the default face in the current buffer by DEC steps. |
e40a85cd | 281 | See `text-scale-increase' for more details." |
56c73dec | 282 | (interactive "p") |
e40a85cd | 283 | (text-scale-increase (- dec))) |
9d3d42fb | 284 | |
e40a85cd MB |
285 | ;;;###autoload (define-key ctl-x-map [(control ?+)] 'text-scale-adjust) |
286 | ;;;###autoload (define-key ctl-x-map [(control ?-)] 'text-scale-adjust) | |
287 | ;;;###autoload (define-key ctl-x-map [(control ?=)] 'text-scale-adjust) | |
288 | ;;;###autoload (define-key ctl-x-map [(control ?0)] 'text-scale-adjust) | |
56c73dec | 289 | ;;;###autoload |
16c1ddc2 | 290 | (defun text-scale-adjust (inc) |
c5772569 B |
291 | "Adjust the height of the default face by INC. |
292 | ||
293 | INC may be passed as a numeric prefix argument. | |
56c73dec MB |
294 | |
295 | The actual adjustment made depends on the final component of the | |
12de5099 | 296 | key-binding used to invoke the command, with all modifiers removed: |
56c73dec MB |
297 | |
298 | +, = Increase the default face height by one step | |
299 | - Decrease the default face height by one step | |
300 | 0 Reset the default face height to the global default | |
301 | ||
b22d0686 GM |
302 | After adjusting, continue to read input events and further adjust |
303 | the face height as long as the input event read | |
304 | \(with all modifiers removed) is one of the above characters. | |
56c73dec MB |
305 | |
306 | Each step scales the height of the default face by the variable | |
307 | `text-scale-mode-step' (a negative number of steps decreases the | |
308 | height by the same amount). As a special case, an argument of 0 | |
309 | will remove any scaling currently active. | |
310 | ||
311 | This command is a special-purpose wrapper around the | |
e40a85cd MB |
312 | `text-scale-increase' command which makes repetition convenient |
313 | even when it is bound in a non-top-level keymap. For binding in | |
314 | a top-level keymap, `text-scale-increase' or | |
315 | `text-scale-decrease' may be more appropriate." | |
56c73dec | 316 | (interactive "p") |
c5772569 | 317 | (let ((ev last-command-event) |
fed7c4f5 | 318 | (echo-keystrokes nil)) |
df96ab1e SM |
319 | (let* ((base (event-basic-type ev)) |
320 | (step | |
321 | (pcase base | |
f58e0fd5 SM |
322 | ((or ?+ ?=) inc) |
323 | (?- (- inc)) | |
324 | (?0 0) | |
df96ab1e SM |
325 | (t inc)))) |
326 | (text-scale-increase step) | |
c5772569 B |
327 | ;; (unless (zerop step) |
328 | (message "Use +,-,0 for further adjustment") | |
8cd22a08 | 329 | (set-transient-map |
df96ab1e SM |
330 | (let ((map (make-sparse-keymap))) |
331 | (dolist (mods '(() (control))) | |
c5772569 B |
332 | (dolist (key '(?- ?+ ?= ?0)) ;; = is often unshifted +. |
333 | (define-key map (vector (append mods (list key))) | |
334 | (lambda () (interactive) (text-scale-adjust (abs inc)))))) | |
335 | map))))) ;; ) | |
56c73dec | 336 | |
9d3d42fb MB |
337 | \f |
338 | ;; ---------------------------------------------------------------- | |
d7ed971d | 339 | ;; buffer-face-mode |
9d3d42fb | 340 | |
d7ed971d MB |
341 | (defcustom buffer-face-mode-face 'variable-pitch |
342 | "The face specification used by `buffer-face-mode'. | |
343 | It may contain any value suitable for a `face' text property, | |
344 | including a face name, a list of face names, a face-attribute | |
345 | plist, etc." | |
af09cfd7 JB |
346 | :group 'display |
347 | :version "23.1") | |
9d3d42fb | 348 | |
d7ed971d MB |
349 | ;; current remapping cookie for buffer-face-mode |
350 | (defvar buffer-face-mode-remapping nil) | |
351 | (make-variable-buffer-local 'buffer-face-mode-remapping) | |
9d3d42fb | 352 | |
15252ee9 | 353 | ;;;###autoload |
d7ed971d MB |
354 | (define-minor-mode buffer-face-mode |
355 | "Minor mode for a buffer-specific default face. | |
e1ac4066 GM |
356 | With a prefix argument ARG, enable the mode if ARG is positive, |
357 | and disable it otherwise. If called from Lisp, enable the mode | |
358 | if ARG is omitted or nil. When enabled, the face specified by the | |
359 | variable `buffer-face-mode-face' is used to display the buffer text." | |
d7ed971d MB |
360 | :lighter " BufFace" |
361 | (when buffer-face-mode-remapping | |
362 | (face-remap-remove-relative buffer-face-mode-remapping)) | |
363 | (setq buffer-face-mode-remapping | |
364 | (and buffer-face-mode | |
365 | (face-remap-add-relative 'default buffer-face-mode-face))) | |
9d3d42fb MB |
366 | (force-window-update (current-buffer))) |
367 | ||
d7ed971d | 368 | ;;;###autoload |
cece37cf MB |
369 | (defun buffer-face-set (&rest specs) |
370 | "Enable `buffer-face-mode', using face specs SPECS. | |
6175e34b CY |
371 | Each argument in SPECS should be a face, i.e. either a face name |
372 | or a property list of face attributes and values. If more than | |
373 | one face is listed, that specifies an aggregate face, like in a | |
374 | `face' text property. If SPECS is nil or omitted, disable | |
375 | `buffer-face-mode'. | |
376 | ||
377 | This function makes the variable `buffer-face-mode-face' buffer | |
378 | local, and sets it to FACE." | |
011cddd6 | 379 | (interactive (list (read-face-name "Set buffer face" (face-at-point t)))) |
cece37cf MB |
380 | (while (and (consp specs) (null (cdr specs))) |
381 | (setq specs (car specs))) | |
382 | (if (null specs) | |
d7ed971d | 383 | (buffer-face-mode 0) |
cece37cf | 384 | (set (make-local-variable 'buffer-face-mode-face) specs) |
d7ed971d MB |
385 | (buffer-face-mode t))) |
386 | ||
387 | ;;;###autoload | |
cece37cf MB |
388 | (defun buffer-face-toggle (&rest specs) |
389 | "Toggle `buffer-face-mode', using face specs SPECS. | |
6175e34b CY |
390 | Each argument in SPECS should be a face, i.e. either a face name |
391 | or a property list of face attributes and values. If more than | |
392 | one face is listed, that specifies an aggregate face, like in a | |
393 | `face' text property. | |
d7ed971d MB |
394 | |
395 | If `buffer-face-mode' is already enabled, and is currently using | |
58aa805b JB |
396 | the face specs SPECS, then it is disabled; if `buffer-face-mode' |
397 | is disabled, or is enabled and currently displaying some other | |
398 | face, then is left enabled, but the face changed to reflect SPECS. | |
cece37cf MB |
399 | |
400 | This function will make the variable `buffer-face-mode-face' | |
401 | buffer local, and set it to SPECS." | |
d7ed971d | 402 | (interactive (list buffer-face-mode-face)) |
cece37cf MB |
403 | (while (and (consp specs) (null (cdr specs))) |
404 | (setq specs (car specs))) | |
405 | (if (or (null specs) | |
406 | (and buffer-face-mode (equal buffer-face-mode-face specs))) | |
d7ed971d | 407 | (buffer-face-mode 0) |
cece37cf | 408 | (set (make-local-variable 'buffer-face-mode-face) specs) |
d7ed971d MB |
409 | (buffer-face-mode t))) |
410 | ||
cece37cf | 411 | (defun buffer-face-mode-invoke (specs arg &optional interactive) |
58aa805b | 412 | "Enable or disable `buffer-face-mode' using face specs SPECS. |
cece37cf MB |
413 | ARG controls whether the mode is enabled or disabled, and is |
414 | interpreted in the usual manner for minor-mode commands. | |
415 | ||
6175e34b | 416 | SPECS can be any value suitable for a `face' text property, |
58aa805b JB |
417 | including a face name, a plist of face attributes and values, |
418 | or a list of faces. | |
cece37cf | 419 | |
6175e34b CY |
420 | If INTERACTIVE is non-nil, display a message describing the |
421 | result. | |
cece37cf | 422 | |
23b77eee | 423 | This is a wrapper function which calls `buffer-face-set' or |
cece37cf MB |
424 | `buffer-face-toggle' (depending on ARG), and prints a status |
425 | message in the echo area. In many cases one of those functions | |
426 | may be more appropriate." | |
d7ed971d MB |
427 | (let ((last-message (current-message))) |
428 | (if (or (eq arg 'toggle) (not arg)) | |
2875c646 MB |
429 | (buffer-face-toggle specs) |
430 | (buffer-face-set (and (> (prefix-numeric-value arg) 0) specs))) | |
d7ed971d MB |
431 | (when interactive |
432 | (unless (and (current-message) | |
433 | (not (equal last-message (current-message)))) | |
434 | (message "Buffer-Face mode %sabled" | |
435 | (if buffer-face-mode "en" "dis")))))) | |
436 | ||
437 | \f | |
438 | ;; ---------------------------------------------------------------- | |
439 | ;; variable-pitch-mode | |
440 | ||
441 | ;;;###autoload | |
442 | (defun variable-pitch-mode (&optional arg) | |
443 | "Variable-pitch default-face mode. | |
444 | An interface to `buffer-face-mode' which uses the `variable-pitch' face. | |
445 | Besides the choice of face, it is the same as `buffer-face-mode'." | |
446 | (interactive (list (or current-prefix-arg 'toggle))) | |
32226619 JB |
447 | (buffer-face-mode-invoke 'variable-pitch arg |
448 | (called-interactively-p 'interactive))) | |
d7ed971d | 449 | |
9d3d42fb MB |
450 | |
451 | (provide 'face-remap) | |
452 | ||
9d3d42fb | 453 | ;;; face-remap.el ends here |