[bpt/emacs.git] / lisp / textmodes / paragraphs.el

;;; paragraphs.el --- paragraph and sentence parsing.

;; Copyright (C) 1985-1991 Free Software Foundation, Inc.

;; This file is part of GNU Emacs.

;; GNU Emacs is free software; you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation; either version 1, or (at your option)
;; any later version.

;; GNU Emacs is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License
;; along with GNU Emacs; see the file COPYING.  If not, write to
;; the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.


;;;###autoload
(defconst paragraph-start "^[ \t\n\f]" "\
*Regexp for beginning of a line that starts OR separates paragraphs.")

;;;###autoload
(defconst paragraph-separate "^[ \t\f]*$" "\
*Regexp for beginning of a line that separates paragraphs.
If you change this, you may have to change paragraph-start also.")

;;;###autoload
(defconst sentence-end (purecopy "[.?!][]\"')}]*\\($\\| $\\|\t\\|  \\)[ \t\n]*") "\
*Regexp describing the end of a sentence.
All paragraph boundaries also end sentences, regardless.")

;;;###autoload
(defconst page-delimiter "^\014" "\
*Regexp describing line-beginnings that separate pages.")

;;;###autoload
(defvar paragraph-ignore-fill-prefix nil "\
Non-nil means the paragraph commands are not affected by `fill-prefix'.
This is desirable in modes where blank lines are the paragraph delimiters.")


(defun forward-paragraph (&optional arg)
  "Move forward to end of paragraph.
With arg N, do it N times; negative arg -N means move forward N paragraphs.

A line which `paragraph-start' matches either separates paragraphs
\(if `paragraph-separate' matches it also) or is the first line of a paragraph.
A paragraph end is the beginning of a line which is not part of the paragraph
to which the end of the previous line belongs, or the end of the buffer."
  (interactive "p")
  (or arg (setq arg 1))
  (let* ((fill-prefix-regexp
	  (and fill-prefix (not (equal fill-prefix ""))
	       (not paragraph-ignore-fill-prefix)
	       (regexp-quote fill-prefix)))
	 (paragraph-separate
	  (if fill-prefix-regexp
	      (concat paragraph-separate "\\|^"
		      fill-prefix-regexp "[ \t]*$")
	    paragraph-separate)))
    (while (< arg 0)
      (if (and (not (looking-at paragraph-separate))
	       (re-search-backward "^\n" (max (1- (point)) (point-min)) t))
	  nil
	(forward-char -1) (beginning-of-line)
	(while (and (not (bobp)) (looking-at paragraph-separate))
	  (forward-line -1))
	(end-of-line)
	;; Search back for line that starts or separates paragraphs.
	(if (if fill-prefix-regexp
		;; There is a fill prefix; it overrides paragraph-start.
		(progn
		 (while (progn (beginning-of-line)
			       (and (not (bobp))
				    (not (looking-at paragraph-separate))
				    (looking-at fill-prefix-regexp)))
		   (forward-line -1))
		 (not (bobp)))
	      (re-search-backward paragraph-start nil t))
	    ;; Found one.
	    (progn
	      (while (and (not (eobp)) (looking-at paragraph-separate))
		(forward-line 1))
	      (if (eq (char-after (- (point) 2)) ?\n)
		  (forward-line -1)))
	  ;; No starter or separator line => use buffer beg.
	  (goto-char (point-min))))
      (setq arg (1+ arg)))
    (while (> arg 0)
      (beginning-of-line)
      (while (prog1 (and (not (eobp))
			 (looking-at paragraph-separate))
		    (forward-line 1)))
      (if fill-prefix-regexp
	  ;; There is a fill prefix; it overrides paragraph-start.
	  (while (and (not (eobp))
		      (not (looking-at paragraph-separate))
		      (looking-at fill-prefix-regexp))
	    (forward-line 1))
	(if (re-search-forward paragraph-start nil t)
	    (goto-char (match-beginning 0))
	  (goto-char (point-max))))
      (setq arg (1- arg)))))

(defun backward-paragraph (&optional arg)
  "Move backward to start of paragraph.
With arg N, do it N times; negative arg -N means move forward N paragraphs.

A paragraph start is the beginning of a line which is a
`first-line-of-paragraph' or which is ordinary text and follows a
paragraph-separating line; except: if the first real line of a
paragraph is preceded by a blank line, the paragraph starts at that
blank line.

See `forward-paragraph' for more information."
  (interactive "p")
  (or arg (setq arg 1))
  (forward-paragraph (- arg)))

(defun mark-paragraph ()
  "Put point at beginning of this paragraph, mark at end.
The paragraph marked is the one that contains point or follows point."
  (interactive)
  (forward-paragraph 1)
  (push-mark nil t)
  (backward-paragraph 1))

(defun kill-paragraph (arg)
  "Kill forward to end of paragraph.
With arg N, kill forward to Nth end of paragraph;
negative arg -N means kill backward to Nth start of paragraph."
  (interactive "p")
  (kill-region (point) (progn (forward-paragraph arg) (point))))

(defun backward-kill-paragraph (arg)
  "Kill back to start of paragraph.
With arg N, kill back to Nth start of paragraph;
negative arg -N means kill forward to Nth end of paragraph."
  (interactive "p")
  (kill-region (point) (progn (backward-paragraph arg) (point))))

(defun transpose-paragraphs (arg)
  "Interchange this (or next) paragraph with previous one."
  (interactive "*p")
  (transpose-subr 'forward-paragraph arg))

(defun start-of-paragraph-text ()
  (let ((opoint (point)) npoint)
    (forward-paragraph -1)
    (setq npoint (point))
    (skip-chars-forward " \t\n")
    ;; If the range of blank lines found spans the original start point,
    ;; try again from the beginning of it.
    ;; Must be careful to avoid infinite loop
    ;; when following a single return at start of buffer.
    (if (and (>= (point) opoint) (< npoint opoint))
	(progn
	  (goto-char npoint)
	  (if (> npoint (point-min))
	      (start-of-paragraph-text))))))

(defun end-of-paragraph-text ()
  (let ((opoint (point)))
    (forward-paragraph 1)
    (if (eq (preceding-char) ?\n) (forward-char -1))
    (if (<= (point) opoint)
	(progn
	  (forward-char 1)
	  (if (< (point) (point-max))
	      (end-of-paragraph-text))))))

(defun forward-sentence (&optional arg)
  "Move forward to next`sentence-end'.  With argument, repeat.
With negative argument, move backward repeatedly to `sentence-beginning'.

The variable `sentence-end' is a regular expression that matches ends of
sentences.  Also, every paragraph boundary terminates sentences as well."
  (interactive "p")
  (or arg (setq arg 1))
  (while (< arg 0)
    (let ((par-beg (save-excursion (start-of-paragraph-text) (point))))
      (if (re-search-backward (concat sentence-end "[^ \t\n]") par-beg t)
	  (goto-char (1- (match-end 0)))
	(goto-char par-beg)))
    (setq arg (1+ arg)))
  (while (> arg 0)
    (let ((par-end (save-excursion (end-of-paragraph-text) (point))))
      (if (re-search-forward sentence-end par-end t)
	  (skip-chars-backward " \t\n")
	(goto-char par-end)))
    (setq arg (1- arg))))

(defun backward-sentence (&optional arg)
  "Move backward to start of sentence.  With arg, do it arg times.
See `forward-sentence' for more information."
  (interactive "p")
  (or arg (setq arg 1))
  (forward-sentence (- arg)))

(defun kill-sentence (&optional arg)
  "Kill from point to end of sentence.
With arg, repeat; negative arg -N means kill back to Nth start of sentence."
  (interactive "*p")
  (let ((beg (point)))
    (forward-sentence arg)
    (kill-region beg (point))))

(defun backward-kill-sentence (&optional arg)
  "Kill back from point to start of sentence.
With arg, repeat, or kill forward to Nth end of sentence if negative arg -N."
  (interactive "*p")
  (let ((beg (point)))
    (backward-sentence arg)
    (kill-region beg (point))))

(defun mark-end-of-sentence (arg)
  "Put mark at end of sentence.  Arg works as in `forward-sentence'."
  (interactive "p")
  (push-mark
    (save-excursion
      (forward-sentence arg)
      (point))))

(defun transpose-sentences (arg)
  "Interchange this (next) and previous sentence."
  (interactive "*p")
  (transpose-subr 'forward-sentence arg))

;;; paragraphs.el ends here
Commit	Line	Data
6594deb0 ER	1	;;; paragraphs.el --- paragraph and sentence parsing.
6594deb0 ER	2
77176e73	3	;; Copyright (C) 1985-1991 Free Software Foundation, Inc.
a2535589 JA	4
	5	;; This file is part of GNU Emacs.
	6
	7	;; GNU Emacs is free software; you can redistribute it and/or modify
	8	;; it under the terms of the GNU General Public License as published by
	9	;; the Free Software Foundation; either version 1, or (at your option)
	10	;; any later version.
	11
	12	;; GNU Emacs is distributed in the hope that it will be useful,
	13	;; but WITHOUT ANY WARRANTY; without even the implied warranty of
	14	;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
	15	;; GNU General Public License for more details.
	16
	17	;; You should have received a copy of the GNU General Public License
	18	;; along with GNU Emacs; see the file COPYING. If not, write to
	19	;; the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.
	20
	21
6503cec3 JB	22	;;;###autoload
	23	(defconst paragraph-start "^[ \t\n\f]" "\
	24	*Regexp for beginning of a line that starts OR separates paragraphs.")
	25
	26	;;;###autoload
	27	(defconst paragraph-separate "^[ \t\f]*$" "\
	28	*Regexp for beginning of a line that separates paragraphs.
	29	If you change this, you may have to change paragraph-start also.")
	30
	31	;;;###autoload
	32	(defconst sentence-end (purecopy "[.?!][]\"')}]\\($\\\| $\\\|\t\\\| \\)[ \t\n]") "\
	33	*Regexp describing the end of a sentence.
	34	All paragraph boundaries also end sentences, regardless.")
	35
	36	;;;###autoload
	37	(defconst page-delimiter "^\014" "\
	38	*Regexp describing line-beginnings that separate pages.")
	39
	40	;;;###autoload
	41	(defvar paragraph-ignore-fill-prefix nil "\
	42	Non-nil means the paragraph commands are not affected by `fill-prefix'.
	43	This is desirable in modes where blank lines are the paragraph delimiters.")
77176e73	44
a2535589 JA	45
	46	(defun forward-paragraph (&optional arg)
	47	"Move forward to end of paragraph.
	48	With arg N, do it N times; negative arg -N means move forward N paragraphs.
	49
	50	A line which `paragraph-start' matches either separates paragraphs
	51	\(if `paragraph-separate' matches it also) or is the first line of a paragraph.
	52	A paragraph end is the beginning of a line which is not part of the paragraph
	53	to which the end of the previous line belongs, or the end of the buffer."
	54	(interactive "p")
	55	(or arg (setq arg 1))
	56	(let* ((fill-prefix-regexp
	57	(and fill-prefix (not (equal fill-prefix ""))
	58	(not paragraph-ignore-fill-prefix)
	59	(regexp-quote fill-prefix)))
	60	(paragraph-separate
	61	(if fill-prefix-regexp
	62	(concat paragraph-separate "\\\|^"
	63	fill-prefix-regexp "[ \t]*$")
	64	paragraph-separate)))
	65	(while (< arg 0)
	66	(if (and (not (looking-at paragraph-separate))
	67	(re-search-backward "^\n" (max (1- (point)) (point-min)) t))
	68	nil
	69	(forward-char -1) (beginning-of-line)
	70	(while (and (not (bobp)) (looking-at paragraph-separate))
	71	(forward-line -1))
	72	(end-of-line)
	73	;; Search back for line that starts or separates paragraphs.
	74	(if (if fill-prefix-regexp
	75	;; There is a fill prefix; it overrides paragraph-start.
	76	(progn
	77	(while (progn (beginning-of-line)
	78	(and (not (bobp))
	79	(not (looking-at paragraph-separate))
	80	(looking-at fill-prefix-regexp)))
	81	(forward-line -1))
	82	(not (bobp)))
	83	(re-search-backward paragraph-start nil t))
	84	;; Found one.
	85	(progn
	86	(while (and (not (eobp)) (looking-at paragraph-separate))
	87	(forward-line 1))
	88	(if (eq (char-after (- (point) 2)) ?\n)
	89	(forward-line -1)))
	90	;; No starter or separator line => use buffer beg.
	91	(goto-char (point-min))))
	92	(setq arg (1+ arg)))
	93	(while (> arg 0)
	94	(beginning-of-line)
	95	(while (prog1 (and (not (eobp))
	96	(looking-at paragraph-separate))
	97	(forward-line 1)))
	98	(if fill-prefix-regexp
	99	;; There is a fill prefix; it overrides paragraph-start.
	100	(while (and (not (eobp))
	101	(not (looking-at paragraph-separate))
	102	(looking-at fill-prefix-regexp))
	103	(forward-line 1))
	104	(if (re-search-forward paragraph-start nil t)
	105	(goto-char (match-beginning 0))
	106	(goto-char (point-max))))
	107	(setq arg (1- arg)))))
	108
109	(defun backward-paragraph (&optional arg)
110	"Move backward to start of paragraph.
111	With arg N, do it N times; negative arg -N means move forward N paragraphs.
112
23b34992 BP	113	A paragraph start is the beginning of a line which is a
	114	`first-line-of-paragraph' or which is ordinary text and follows a
	115	paragraph-separating line; except: if the first real line of a
	116	paragraph is preceded by a blank line, the paragraph starts at that
	117	blank line.
	118
	119	See `forward-paragraph' for more information."
a2535589 JA	120	(interactive "p")
	121	(or arg (setq arg 1))
	122	(forward-paragraph (- arg)))
	123
	124	(defun mark-paragraph ()
	125	"Put point at beginning of this paragraph, mark at end.
	126	The paragraph marked is the one that contains point or follows point."
	127	(interactive)
	128	(forward-paragraph 1)
	129	(push-mark nil t)
	130	(backward-paragraph 1))
	131
	132	(defun kill-paragraph (arg)
	133	"Kill forward to end of paragraph.
	134	With arg N, kill forward to Nth end of paragraph;
	135	negative arg -N means kill backward to Nth start of paragraph."
23b34992	136	(interactive "p")
a2535589 JA	137	(kill-region (point) (progn (forward-paragraph arg) (point))))
	138
	139	(defun backward-kill-paragraph (arg)
	140	"Kill back to start of paragraph.
	141	With arg N, kill back to Nth start of paragraph;
	142	negative arg -N means kill forward to Nth end of paragraph."
23b34992	143	(interactive "p")
a2535589 JA	144	(kill-region (point) (progn (backward-paragraph arg) (point))))
	145
	146	(defun transpose-paragraphs (arg)
	147	"Interchange this (or next) paragraph with previous one."
	148	(interactive "*p")
	149	(transpose-subr 'forward-paragraph arg))
	150
	151	(defun start-of-paragraph-text ()
	152	(let ((opoint (point)) npoint)
	153	(forward-paragraph -1)
	154	(setq npoint (point))
	155	(skip-chars-forward " \t\n")
b4e6c391 RS	156	;; If the range of blank lines found spans the original start point,
	157	;; try again from the beginning of it.
	158	;; Must be careful to avoid infinite loop
	159	;; when following a single return at start of buffer.
	160	(if (and (>= (point) opoint) (< npoint opoint))
a2535589 JA	161	(progn
	162	(goto-char npoint)
	163	(if (> npoint (point-min))
	164	(start-of-paragraph-text))))))
	165
	166	(defun end-of-paragraph-text ()
	167	(let ((opoint (point)))
	168	(forward-paragraph 1)
	169	(if (eq (preceding-char) ?\n) (forward-char -1))
	170	(if (<= (point) opoint)
	171	(progn
	172	(forward-char 1)
	173	(if (< (point) (point-max))
	174	(end-of-paragraph-text))))))
	175
	176	(defun forward-sentence (&optional arg)
23b34992 BP	177	"Move forward to next`sentence-end'. With argument, repeat.
23b34992 BP	178	With negative argument, move backward repeatedly to `sentence-beginning'.
a2535589	179
23b34992 BP	180	The variable `sentence-end' is a regular expression that matches ends of
23b34992 BP	181	sentences. Also, every paragraph boundary terminates sentences as well."
a2535589 JA	182	(interactive "p")
	183	(or arg (setq arg 1))
	184	(while (< arg 0)
	185	(let ((par-beg (save-excursion (start-of-paragraph-text) (point))))
	186	(if (re-search-backward (concat sentence-end "[^ \t\n]") par-beg t)
	187	(goto-char (1- (match-end 0)))
	188	(goto-char par-beg)))
	189	(setq arg (1+ arg)))
	190	(while (> arg 0)
	191	(let ((par-end (save-excursion (end-of-paragraph-text) (point))))
	192	(if (re-search-forward sentence-end par-end t)
	193	(skip-chars-backward " \t\n")
	194	(goto-char par-end)))
	195	(setq arg (1- arg))))
	196
	197	(defun backward-sentence (&optional arg)
	198	"Move backward to start of sentence. With arg, do it arg times.
23b34992	199	See `forward-sentence' for more information."
a2535589 JA	200	(interactive "p")
	201	(or arg (setq arg 1))
	202	(forward-sentence (- arg)))
	203
	204	(defun kill-sentence (&optional arg)
	205	"Kill from point to end of sentence.
	206	With arg, repeat; negative arg -N means kill back to Nth start of sentence."
	207	(interactive "*p")
	208	(let ((beg (point)))
	209	(forward-sentence arg)
	210	(kill-region beg (point))))
	211
	212	(defun backward-kill-sentence (&optional arg)
	213	"Kill back from point to start of sentence.
	214	With arg, repeat, or kill forward to Nth end of sentence if negative arg -N."
	215	(interactive "*p")
	216	(let ((beg (point)))
	217	(backward-sentence arg)
	218	(kill-region beg (point))))
	219
	220	(defun mark-end-of-sentence (arg)
23b34992	221	"Put mark at end of sentence. Arg works as in `forward-sentence'."
a2535589 JA	222	(interactive "p")
	223	(push-mark
	224	(save-excursion
	225	(forward-sentence arg)
	226	(point))))
	227
	228	(defun transpose-sentences (arg)
	229	"Interchange this (next) and previous sentence."
	230	(interactive "*p")
	231	(transpose-subr 'forward-sentence arg))
6594deb0 ER	232
6594deb0 ER	233	;;; paragraphs.el ends here