Commit | Line | Data |
---|---|---|
55535639 | 1 | ;;; picture.el --- "Picture mode" -- editing using quarter-plane screen model |
6594deb0 | 2 | |
8f1204db | 3 | ;; Copyright (C) 1985, 1994 Free Software Foundation, Inc. |
3a801d0c | 4 | |
e5167999 ER |
5 | ;; Author: K. Shane Hartman |
6 | ;; Maintainer: FSF | |
82168689 | 7 | ;; Keywords: convenience wp |
695d13c7 BP |
8 | |
9 | ;; This file is part of GNU Emacs. | |
10 | ||
11 | ;; GNU Emacs is free software; you can redistribute it and/or modify | |
12 | ;; it under the terms of the GNU General Public License as published by | |
e5167999 | 13 | ;; the Free Software Foundation; either version 2, or (at your option) |
695d13c7 BP |
14 | ;; any later version. |
15 | ||
16 | ;; GNU Emacs is distributed in the hope that it will be useful, | |
17 | ;; but WITHOUT ANY WARRANTY; without even the implied warranty of | |
18 | ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the | |
19 | ;; GNU General Public License for more details. | |
20 | ||
21 | ;; You should have received a copy of the GNU General Public License | |
b578f267 EN |
22 | ;; along with GNU Emacs; see the file COPYING. If not, write to the |
23 | ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330, | |
24 | ;; Boston, MA 02111-1307, USA. | |
695d13c7 | 25 | |
edbd2f74 ER |
26 | ;;; Commentary: |
27 | ||
eaae8106 | 28 | ;; This code provides the picture-mode commands documented in the Emacs |
edbd2f74 ER |
29 | ;; manual. The screen is treated as a semi-infinite quarter-plane with |
30 | ;; support for rectangle operations and `etch-a-sketch' character | |
31 | ;; insertion in any of eight directions. | |
32 | ||
e5167999 | 33 | ;;; Code: |
695d13c7 | 34 | |
d1ebc62e | 35 | (defgroup picture nil |
381194d0 | 36 | "Picture mode --- editing using quarter-plane screen model." |
d1ebc62e SE |
37 | :prefix "picture-" |
38 | :group 'editing) | |
39 | ||
40 | (defcustom picture-rectangle-ctl ?+ | |
41 | "*Character `picture-draw-rectangle' uses for top left corners." | |
42 | :type 'character | |
43 | :group 'picture) | |
44 | (defcustom picture-rectangle-ctr ?+ | |
45 | "*Character `picture-draw-rectangle' uses for top right corners." | |
46 | :type 'character | |
47 | :group 'picture) | |
48 | (defcustom picture-rectangle-cbr ?+ | |
49 | "*Character `picture-draw-rectangle' uses for bottom right corners." | |
50 | :type 'character | |
51 | :group 'picture) | |
52 | (defcustom picture-rectangle-cbl ?+ | |
53 | "*Character `picture-draw-rectangle' uses for bottom left corners." | |
54 | :type 'character | |
55 | :group 'picture) | |
56 | (defcustom picture-rectangle-v ?| | |
57 | "*Character `picture-draw-rectangle' uses for vertical lines." | |
58 | :type 'character | |
59 | :group 'picture) | |
60 | (defcustom picture-rectangle-h ?- | |
61 | "*Character `picture-draw-rectangle' uses for horizontal lines." | |
62 | :type 'character | |
63 | :group 'picture) | |
64 | ||
695d13c7 | 65 | |
695d13c7 BP |
66 | ;; Picture Movement Commands |
67 | ||
2697c1f3 KH |
68 | ;; When a cursor is on a wide-column character (e.g. Chinese, |
69 | ;; Japanese, Korean), this variable tells the desired current column | |
70 | ;; which may be different from (current-column). | |
71 | (defvar picture-desired-column 0) | |
72 | ||
73 | ;; If the value of picture-desired-column is far from the current | |
74 | ;; column, or if the arg ADJUST-TO-CURRENT is non-nil, set it to the | |
75 | ;; current column. Return the current column. | |
76 | (defun picture-update-desired-column (adjust-to-current) | |
77 | (let ((current-column (current-column))) | |
78 | (if (or adjust-to-current | |
79 | (< picture-desired-column (1- current-column)) | |
80 | (> picture-desired-column (1+ current-column))) | |
81 | (setq picture-desired-column current-column)) | |
82 | current-column)) | |
83 | ||
ca9c7579 ER |
84 | (defun picture-beginning-of-line (&optional arg) |
85 | "Position point at the beginning of the line. | |
86 | With ARG not nil, move forward ARG - 1 lines first. | |
87 | If scan reaches end of buffer, stop there without error." | |
88 | (interactive "P") | |
89 | (if arg (forward-line (1- (prefix-numeric-value arg)))) | |
90 | (beginning-of-line) | |
5f6a0375 | 91 | (setq picture-desired-column 0)) |
ca9c7579 | 92 | |
695d13c7 BP |
93 | (defun picture-end-of-line (&optional arg) |
94 | "Position point after last non-blank character on current line. | |
95 | With ARG not nil, move forward ARG - 1 lines first. | |
96 | If scan reaches end of buffer, stop there without error." | |
97 | (interactive "P") | |
98 | (if arg (forward-line (1- (prefix-numeric-value arg)))) | |
99 | (beginning-of-line) | |
ca9c7579 | 100 | (skip-chars-backward " \t" (prog1 (point) (end-of-line))) |
5f6a0375 | 101 | (setq picture-desired-column (current-column))) |
695d13c7 BP |
102 | |
103 | (defun picture-forward-column (arg) | |
104 | "Move cursor right, making whitespace if necessary. | |
105 | With argument, move that many columns." | |
106 | (interactive "p") | |
2697c1f3 KH |
107 | (picture-update-desired-column (interactive-p)) |
108 | (setq picture-desired-column (max 0 (+ picture-desired-column arg))) | |
109 | (let ((current-column (move-to-column picture-desired-column t))) | |
110 | (if (and (> current-column picture-desired-column) | |
111 | (< arg 0)) | |
112 | ;; It seems that we have just tried to move to the right | |
113 | ;; column of a multi-column character. | |
114 | (forward-char -1)))) | |
695d13c7 BP |
115 | |
116 | (defun picture-backward-column (arg) | |
117 | "Move cursor left, making whitespace if necessary. | |
118 | With argument, move that many columns." | |
119 | (interactive "p") | |
2697c1f3 | 120 | (picture-update-desired-column (interactive-p)) |
ad8fb8ae | 121 | (picture-forward-column (- arg))) |
695d13c7 BP |
122 | |
123 | (defun picture-move-down (arg) | |
124 | "Move vertically down, making whitespace if necessary. | |
125 | With argument, move that many lines." | |
126 | (interactive "p") | |
2697c1f3 KH |
127 | (picture-update-desired-column nil) |
128 | (picture-newline arg) | |
129 | (let ((current-column (move-to-column picture-desired-column t))) | |
130 | (if (> current-column picture-desired-column) | |
131 | (forward-char -1)))) | |
695d13c7 | 132 | |
99b3bc61 | 133 | (defvar picture-vertical-step 0 |
695d13c7 BP |
134 | "Amount to move vertically after text character in Picture mode.") |
135 | ||
99b3bc61 | 136 | (defvar picture-horizontal-step 1 |
695d13c7 BP |
137 | "Amount to move horizontally after text character in Picture mode.") |
138 | ||
139 | (defun picture-move-up (arg) | |
140 | "Move vertically up, making whitespace if necessary. | |
141 | With argument, move that many lines." | |
142 | (interactive "p") | |
2697c1f3 | 143 | (picture-update-desired-column nil) |
695d13c7 BP |
144 | (picture-move-down (- arg))) |
145 | ||
146 | (defun picture-movement-right () | |
147 | "Move right after self-inserting character in Picture mode." | |
148 | (interactive) | |
149 | (picture-set-motion 0 1)) | |
150 | ||
151 | (defun picture-movement-left () | |
152 | "Move left after self-inserting character in Picture mode." | |
153 | (interactive) | |
154 | (picture-set-motion 0 -1)) | |
155 | ||
156 | (defun picture-movement-up () | |
157 | "Move up after self-inserting character in Picture mode." | |
158 | (interactive) | |
159 | (picture-set-motion -1 0)) | |
160 | ||
161 | (defun picture-movement-down () | |
162 | "Move down after self-inserting character in Picture mode." | |
163 | (interactive) | |
164 | (picture-set-motion 1 0)) | |
165 | ||
2697c1f3 KH |
166 | (defun picture-movement-nw (&optional arg) |
167 | "Move up and left after self-inserting character in Picture mode. | |
168 | With prefix argument, move up and two-column left." | |
169 | (interactive "P") | |
170 | (picture-set-motion -1 (if arg -2 -1))) | |
695d13c7 | 171 | |
2697c1f3 KH |
172 | (defun picture-movement-ne (&optional arg) |
173 | "Move up and right after self-inserting character in Picture mode. | |
174 | With prefix argument, move up and two-column right." | |
175 | (interactive "P") | |
176 | (picture-set-motion -1 (if arg 2 1))) | |
695d13c7 | 177 | |
2697c1f3 KH |
178 | (defun picture-movement-sw (&optional arg) |
179 | "Move down and left after self-inserting character in Picture mode. | |
180 | With prefix argument, move down and two-column left." | |
181 | (interactive "P") | |
182 | (picture-set-motion 1 (if arg -2 -1))) | |
695d13c7 | 183 | |
2697c1f3 KH |
184 | (defun picture-movement-se (&optional arg) |
185 | "Move down and right after self-inserting character in Picture mode. | |
186 | With prefix argument, move down and two-column right." | |
187 | (interactive "P") | |
188 | (picture-set-motion 1 (if arg 2 1))) | |
695d13c7 BP |
189 | |
190 | (defun picture-set-motion (vert horiz) | |
191 | "Set VERTICAL and HORIZONTAL increments for movement in Picture mode. | |
192 | The mode line is updated to reflect the current direction." | |
193 | (setq picture-vertical-step vert | |
194 | picture-horizontal-step horiz) | |
195 | (setq mode-name | |
196 | (format "Picture:%s" | |
2697c1f3 KH |
197 | (nth (+ 2 (% horiz 3) (* 5 (1+ (% vert 2)))) |
198 | '(wnw nw up ne ene Left left none right Right | |
199 | wsw sw down se ese)))) | |
00dbaf0a | 200 | (force-mode-line-update) |
695d13c7 BP |
201 | (message "")) |
202 | ||
203 | (defun picture-move () | |
204 | "Move in direction of `picture-vertical-step' and `picture-horizontal-step'." | |
2697c1f3 KH |
205 | (if (/= picture-vertical-step 0) |
206 | (picture-move-down picture-vertical-step)) | |
207 | (if (/= picture-horizontal-step 0) | |
208 | (picture-forward-column picture-horizontal-step))) | |
695d13c7 BP |
209 | |
210 | (defun picture-motion (arg) | |
211 | "Move point in direction of current picture motion in Picture mode. | |
212 | With ARG do it that many times. Useful for delineating rectangles in | |
213 | conjunction with diagonal picture motion. | |
214 | Do \\[command-apropos] picture-movement to see commands which control motion." | |
215 | (interactive "p") | |
216 | (picture-move-down (* arg picture-vertical-step)) | |
217 | (picture-forward-column (* arg picture-horizontal-step))) | |
218 | ||
219 | (defun picture-motion-reverse (arg) | |
220 | "Move point in direction opposite of current picture motion in Picture mode. | |
221 | With ARG do it that many times. Useful for delineating rectangles in | |
222 | conjunction with diagonal picture motion. | |
223 | Do \\[command-apropos] `picture-movement' to see commands which control motion." | |
224 | (interactive "p") | |
225 | (picture-motion (- arg))) | |
226 | ||
227 | \f | |
228 | ;; Picture insertion and deletion. | |
229 | ||
d792910f | 230 | (defun picture-insert (ch arg) |
2697c1f3 KH |
231 | (let* ((width (char-width ch)) |
232 | ;; We must be sure that the succeeding insertion won't delete | |
233 | ;; the just inserted character. | |
234 | (picture-horizontal-step | |
235 | (if (and (= picture-vertical-step 0) | |
236 | (> width 1) | |
237 | (< (abs picture-horizontal-step) 2)) | |
238 | (* picture-horizontal-step 2) | |
239 | picture-horizontal-step))) | |
240 | (while (> arg 0) | |
241 | (setq arg (1- arg)) | |
242 | (if (/= picture-desired-column (current-column)) | |
243 | (move-to-column-force picture-desired-column)) | |
244 | (let ((col (+ picture-desired-column width))) | |
245 | (or (eolp) | |
246 | (let ((pos (point))) | |
247 | (move-to-column-force col) | |
248 | (delete-region pos (point))))) | |
249 | (insert ch) | |
250 | (forward-char -1) | |
251 | (picture-move)))) | |
d792910f | 252 | |
695d13c7 BP |
253 | (defun picture-self-insert (arg) |
254 | "Insert this character in place of character previously at the cursor. | |
255 | The cursor then moves in the direction you previously specified | |
256 | with the commands `picture-movement-right', `picture-movement-up', etc. | |
257 | Do \\[command-apropos] `picture-movement' to see those commands." | |
258 | (interactive "p") | |
2697c1f3 | 259 | (picture-update-desired-column (not (eq this-command last-command))) |
d792910f | 260 | (picture-insert last-command-event arg)) ; Always a character in this case. |
695d13c7 BP |
261 | |
262 | (defun picture-clear-column (arg) | |
263 | "Clear out ARG columns after point without moving." | |
264 | (interactive "p") | |
2697c1f3 KH |
265 | (let* ((original-col (current-column)) |
266 | (target-col (max 0 (+ original-col arg))) | |
267 | pos) | |
268 | (move-to-column-force target-col) | |
269 | (setq pos (point)) | |
270 | (move-to-column original-col) | |
271 | (delete-region pos (point)) | |
695d13c7 | 272 | (save-excursion |
2697c1f3 KH |
273 | (indent-to (max target-col original-col)))) |
274 | (setq picture-desired-column (current-column))) | |
695d13c7 BP |
275 | |
276 | (defun picture-backward-clear-column (arg) | |
277 | "Clear out ARG columns before point, moving back over them." | |
278 | (interactive "p") | |
279 | (picture-clear-column (- arg))) | |
280 | ||
281 | (defun picture-clear-line (arg) | |
282 | "Clear out rest of line; if at end of line, advance to next line. | |
283 | Cleared-out line text goes into the kill ring, as do newlines that are | |
284 | advanced over. With argument, clear out (and save in kill ring) that | |
285 | many lines." | |
286 | (interactive "P") | |
287 | (if arg | |
288 | (progn | |
289 | (setq arg (prefix-numeric-value arg)) | |
290 | (kill-line arg) | |
291 | (newline (if (> arg 0) arg (- arg)))) | |
292 | (if (looking-at "[ \t]*$") | |
293 | (kill-ring-save (point) (progn (forward-line 1) (point))) | |
294 | (kill-region (point) (progn (end-of-line) (point)))))) | |
295 | ||
296 | (defun picture-newline (arg) | |
297 | "Move to the beginning of the following line. | |
298 | With argument, moves that many lines (up, if negative argument); | |
299 | always moves to the beginning of a line." | |
300 | (interactive "p") | |
301 | (if (< arg 0) | |
302 | (forward-line arg) | |
303 | (while (> arg 0) | |
304 | (end-of-line) | |
305 | (if (eobp) (newline) (forward-char 1)) | |
5f6a0375 | 306 | (setq arg (1- arg))))) |
695d13c7 BP |
307 | |
308 | (defun picture-open-line (arg) | |
309 | "Insert an empty line after the current line. | |
310 | With positive argument insert that many lines." | |
311 | (interactive "p") | |
312 | (save-excursion | |
313 | (end-of-line) | |
5f6a0375 | 314 | (open-line arg))) |
695d13c7 BP |
315 | |
316 | (defun picture-duplicate-line () | |
317 | "Insert a duplicate of the current line, below it." | |
318 | (interactive) | |
319 | (save-excursion | |
320 | (let ((contents | |
321 | (buffer-substring | |
322 | (progn (beginning-of-line) (point)) | |
323 | (progn (picture-newline 1) (point))))) | |
324 | (forward-line -1) | |
325 | (insert contents)))) | |
326 | ||
5c927015 RS |
327 | ;; Like replace-match, but overwrites. |
328 | (defun picture-replace-match (newtext fixedcase literal) | |
329 | (let (ocolumn change pos) | |
330 | (goto-char (setq pos (match-end 0))) | |
331 | (setq ocolumn (current-column)) | |
332 | ;; Make the replacement and undo it, to see how it changes the length. | |
333 | (let ((buffer-undo-list nil) | |
334 | list1) | |
335 | (replace-match newtext fixedcase literal) | |
336 | (setq change (- (current-column) ocolumn)) | |
337 | (setq list1 buffer-undo-list) | |
338 | (while list1 | |
339 | (setq list1 (primitive-undo 1 list1)))) | |
340 | (goto-char pos) | |
341 | (if (> change 0) | |
342 | (delete-region (point) | |
343 | (progn | |
d792910f | 344 | (move-to-column (+ change (current-column)) t) |
5c927015 RS |
345 | (point)))) |
346 | (replace-match newtext fixedcase literal) | |
347 | (if (< change 0) | |
348 | (insert-char ?\ (- change))))) | |
695d13c7 BP |
349 | \f |
350 | ;; Picture Tabs | |
351 | ||
d1ebc62e SE |
352 | (defcustom picture-tab-chars "!-~" |
353 | "*A character set which controls behavior of commands. | |
695d13c7 BP |
354 | \\[picture-set-tab-stops] and \\[picture-tab-search]. It is NOT a |
355 | regular expression, any regexp special characters will be quoted. | |
356 | It defines a set of \"interesting characters\" to look for when setting | |
357 | \(or searching for) tab stops, initially \"!-~\" (all printing characters). | |
358 | For example, suppose that you are editing a table which is formatted thus: | |
359 | | foo | bar + baz | 23 * | |
360 | | bubbles | and + etc | 97 * | |
361 | and that `picture-tab-chars' is \"|+*\". Then invoking | |
362 | \\[picture-set-tab-stops] on either of the previous lines would result | |
363 | in the following tab stops | |
364 | : : : : | |
365 | Another example - \"A-Za-z0-9\" would produce the tab stops | |
366 | : : : : | |
367 | ||
368 | Note that if you want the character `-' to be in the set, it must be | |
369 | included in a range or else appear in a context where it cannot be | |
370 | taken for indicating a range (e.g. \"-A-Z\" declares the set to be the | |
371 | letters `A' through `Z' and the character `-'). If you want the | |
372 | character `\\' in the set it must be preceded by itself: \"\\\\\". | |
373 | ||
374 | The command \\[picture-tab-search] is defined to move beneath (or to) a | |
d1ebc62e SE |
375 | character belonging to this set independent of the tab stops list." |
376 | :type 'string | |
377 | :group 'picture) | |
695d13c7 BP |
378 | |
379 | (defun picture-set-tab-stops (&optional arg) | |
380 | "Set value of `tab-stop-list' according to context of this line. | |
381 | This controls the behavior of \\[picture-tab]. A tab stop is set at | |
382 | every column occupied by an \"interesting character\" that is preceded | |
383 | by whitespace. Interesting characters are defined by the variable | |
384 | `picture-tab-chars', see its documentation for an example of usage. | |
385 | With ARG, just (re)set `tab-stop-list' to its default value. The tab | |
386 | stops computed are displayed in the minibuffer with `:' at each stop." | |
387 | (interactive "P") | |
388 | (save-excursion | |
389 | (let (tabs) | |
390 | (if arg | |
391 | (setq tabs (default-value 'tab-stop-list)) | |
392 | (let ((regexp (concat "[ \t]+[" (regexp-quote picture-tab-chars) "]"))) | |
393 | (beginning-of-line) | |
394 | (let ((bol (point))) | |
395 | (end-of-line) | |
396 | (while (re-search-backward regexp bol t) | |
397 | (skip-chars-forward " \t") | |
398 | (setq tabs (cons (current-column) tabs))) | |
399 | (if (null tabs) | |
55535639 | 400 | (error "No characters in set %s on this line" |
695d13c7 BP |
401 | (regexp-quote picture-tab-chars)))))) |
402 | (setq tab-stop-list tabs) | |
403 | (let ((blurb (make-string (1+ (nth (1- (length tabs)) tabs)) ?\ ))) | |
404 | (while tabs | |
405 | (aset blurb (car tabs) ?:) | |
406 | (setq tabs (cdr tabs))) | |
407 | (message blurb))))) | |
408 | ||
409 | (defun picture-tab-search (&optional arg) | |
410 | "Move to column beneath next interesting char in previous line. | |
411 | With ARG move to column occupied by next interesting character in this | |
412 | line. The character must be preceded by whitespace. | |
413 | \"interesting characters\" are defined by variable `picture-tab-chars'. | |
414 | If no such character is found, move to beginning of line." | |
415 | (interactive "P") | |
416 | (let ((target (current-column))) | |
417 | (save-excursion | |
418 | (if (and (not arg) | |
419 | (progn | |
420 | (beginning-of-line) | |
421 | (skip-chars-backward | |
422 | (concat "^" (regexp-quote picture-tab-chars)) | |
423 | (point-min)) | |
424 | (not (bobp)))) | |
425 | (move-to-column target)) | |
426 | (if (re-search-forward | |
427 | (concat "[ \t]+[" (regexp-quote picture-tab-chars) "]") | |
428 | (save-excursion (end-of-line) (point)) | |
429 | 'move) | |
430 | (setq target (1- (current-column))) | |
431 | (setq target nil))) | |
432 | (if target | |
d792910f | 433 | (move-to-column target t) |
695d13c7 BP |
434 | (beginning-of-line)))) |
435 | ||
436 | (defun picture-tab (&optional arg) | |
437 | "Tab transparently (just move point) to next tab stop. | |
438 | With prefix arg, overwrite the traversed text with spaces. The tab stop | |
439 | list can be changed by \\[picture-set-tab-stops] and \\[edit-tab-stops]. | |
440 | See also documentation for variable `picture-tab-chars'." | |
441 | (interactive "P") | |
442 | (let* ((opoint (point))) | |
443 | (move-to-tab-stop) | |
444 | (if arg | |
445 | (let (indent-tabs-mode | |
446 | (column (current-column))) | |
447 | (delete-region opoint (point)) | |
448 | (indent-to column))))) | |
449 | \f | |
450 | ;; Picture Rectangles | |
451 | ||
238b647a | 452 | (defvar picture-killed-rectangle nil |
695d13c7 BP |
453 | "Rectangle killed or copied by \\[picture-clear-rectangle] in Picture mode. |
454 | The contents can be retrieved by \\[picture-yank-rectangle]") | |
455 | ||
456 | (defun picture-clear-rectangle (start end &optional killp) | |
457 | "Clear and save rectangle delineated by point and mark. | |
458 | The rectangle is saved for yanking by \\[picture-yank-rectangle] and replaced | |
459 | with whitespace. The previously saved rectangle, if any, is lost. With | |
460 | prefix argument, the rectangle is actually killed, shifting remaining text." | |
461 | (interactive "r\nP") | |
462 | (setq picture-killed-rectangle (picture-snarf-rectangle start end killp))) | |
463 | ||
464 | (defun picture-clear-rectangle-to-register (start end register &optional killp) | |
465 | "Clear rectangle delineated by point and mark into REGISTER. | |
466 | The rectangle is saved in REGISTER and replaced with whitespace. With | |
467 | prefix argument, the rectangle is actually killed, shifting remaining text." | |
468 | (interactive "r\ncRectangle to register: \nP") | |
469 | (set-register register (picture-snarf-rectangle start end killp))) | |
470 | ||
471 | (defun picture-snarf-rectangle (start end &optional killp) | |
472 | (let ((column (current-column)) | |
473 | (indent-tabs-mode nil)) | |
474 | (prog1 (save-excursion | |
475 | (if killp | |
476 | (delete-extract-rectangle start end) | |
477 | (prog1 (extract-rectangle start end) | |
478 | (clear-rectangle start end)))) | |
d792910f | 479 | (move-to-column column t)))) |
695d13c7 BP |
480 | |
481 | (defun picture-yank-rectangle (&optional insertp) | |
482 | "Overlay rectangle saved by \\[picture-clear-rectangle] | |
483 | The rectangle is positioned with upper left corner at point, overwriting | |
484 | existing text. With prefix argument, the rectangle is inserted instead, | |
485 | shifting existing text. Leaves mark at one corner of rectangle and | |
486 | point at the other (diagonally opposed) corner." | |
487 | (interactive "P") | |
488 | (if (not (consp picture-killed-rectangle)) | |
55535639 | 489 | (error "No rectangle saved") |
695d13c7 BP |
490 | (picture-insert-rectangle picture-killed-rectangle insertp))) |
491 | ||
2ee658c3 RS |
492 | (defun picture-yank-at-click (click arg) |
493 | "Insert the last killed rectangle at the position clicked on. | |
494 | Also move point to one end of the text thus inserted (normally the end). | |
495 | Prefix arguments are interpreted as with \\[yank]. | |
496 | If `mouse-yank-at-point' is non-nil, insert at point | |
497 | regardless of where you click." | |
498 | (interactive "e\nP") | |
499 | (or mouse-yank-at-point (mouse-set-point click)) | |
500 | (picture-yank-rectangle arg)) | |
501 | ||
695d13c7 BP |
502 | (defun picture-yank-rectangle-from-register (register &optional insertp) |
503 | "Overlay rectangle saved in REGISTER. | |
504 | The rectangle is positioned with upper left corner at point, overwriting | |
505 | existing text. With prefix argument, the rectangle is | |
506 | inserted instead, shifting existing text. Leaves mark at one corner | |
507 | of rectangle and point at the other (diagonally opposed) corner." | |
508 | (interactive "cRectangle from register: \nP") | |
509 | (let ((rectangle (get-register register))) | |
510 | (if (not (consp rectangle)) | |
55535639 | 511 | (error "Register %c does not contain a rectangle" register) |
695d13c7 BP |
512 | (picture-insert-rectangle rectangle insertp)))) |
513 | ||
514 | (defun picture-insert-rectangle (rectangle &optional insertp) | |
515 | "Overlay RECTANGLE with upper left corner at point. | |
516 | Optional argument INSERTP, if non-nil causes RECTANGLE to be inserted. | |
517 | Leaves the region surrounding the rectangle." | |
518 | (let ((indent-tabs-mode nil)) | |
519 | (if (not insertp) | |
520 | (save-excursion | |
521 | (delete-rectangle (point) | |
522 | (progn | |
523 | (picture-forward-column (length (car rectangle))) | |
524 | (picture-move-down (1- (length rectangle))) | |
525 | (point))))) | |
526 | (push-mark) | |
527 | (insert-rectangle rectangle))) | |
528 | ||
d792910f RS |
529 | (defun picture-current-line () |
530 | "Return the vertical position of point. Top line is 1." | |
531 | (+ (count-lines (point-min) (point)) | |
532 | (if (= (current-column) 0) 1 0))) | |
533 | ||
534 | (defun picture-draw-rectangle (start end) | |
535 | "Draw a rectangle around region." | |
536 | (interactive "*r") ; start will be less than end | |
537 | (let* ((sl (picture-current-line)) | |
538 | (sc (current-column)) | |
539 | (pvs picture-vertical-step) | |
540 | (phs picture-horizontal-step) | |
541 | (c1 (progn (goto-char start) (current-column))) | |
542 | (r1 (picture-current-line)) | |
543 | (c2 (progn (goto-char end) (current-column))) | |
544 | (r2 (picture-current-line)) | |
545 | (right (max c1 c2)) | |
546 | (left (min c1 c2)) | |
547 | (top (min r1 r2)) | |
548 | (bottom (max r1 r2))) | |
549 | (goto-line top) | |
2697c1f3 KH |
550 | (move-to-column-force left) |
551 | (picture-update-desired-column t) | |
d792910f RS |
552 | |
553 | (picture-movement-right) | |
554 | (picture-insert picture-rectangle-ctl 1) | |
2697c1f3 | 555 | (picture-insert picture-rectangle-h (- right picture-desired-column)) |
d792910f RS |
556 | |
557 | (picture-movement-down) | |
558 | (picture-insert picture-rectangle-ctr 1) | |
559 | (picture-insert picture-rectangle-v (- bottom (picture-current-line))) | |
560 | ||
561 | (picture-movement-left) | |
562 | (picture-insert picture-rectangle-cbr 1) | |
2697c1f3 | 563 | (picture-insert picture-rectangle-h (- picture-desired-column left)) |
d792910f RS |
564 | |
565 | (picture-movement-up) | |
566 | (picture-insert picture-rectangle-cbl 1) | |
567 | (picture-insert picture-rectangle-v (- (picture-current-line) top)) | |
568 | ||
569 | (picture-set-motion pvs phs) | |
570 | (goto-line sl) | |
571 | (move-to-column sc t))) | |
572 | ||
695d13c7 BP |
573 | \f |
574 | ;; Picture Keymap, entry and exit points. | |
575 | ||
576 | (defconst picture-mode-map nil) | |
577 | ||
ca9c7579 ER |
578 | (defun picture-substitute (oldfun newfun) |
579 | (substitute-key-definition oldfun newfun picture-mode-map global-map)) | |
580 | ||
695d13c7 | 581 | (if (not picture-mode-map) |
0ad0f28f | 582 | (progn |
2697c1f3 | 583 | (setq picture-mode-map (make-keymap)) |
0ad0f28f | 584 | (picture-substitute 'self-insert-command 'picture-self-insert) |
2ae00b00 RS |
585 | (picture-substitute 'completion-separator-self-insert-command |
586 | 'picture-self-insert) | |
587 | (picture-substitute 'completion-separator-self-insert-autofilling | |
588 | 'picture-self-insert) | |
ca9c7579 ER |
589 | (picture-substitute 'forward-char 'picture-forward-column) |
590 | (picture-substitute 'backward-char 'picture-backward-column) | |
591 | (picture-substitute 'delete-char 'picture-clear-column) | |
47bad81c | 592 | ;; There are two possibilities for what is normally on DEL. |
ca9c7579 | 593 | (picture-substitute 'backward-delete-char-untabify 'picture-backward-clear-column) |
47bad81c | 594 | (picture-substitute 'delete-backward-char 'picture-backward-clear-column) |
ca9c7579 ER |
595 | (picture-substitute 'kill-line 'picture-clear-line) |
596 | (picture-substitute 'open-line 'picture-open-line) | |
597 | (picture-substitute 'newline 'picture-newline) | |
0ad0f28f | 598 | (picture-substitute 'newline-and-indent 'picture-duplicate-line) |
ca9c7579 ER |
599 | (picture-substitute 'next-line 'picture-move-down) |
600 | (picture-substitute 'previous-line 'picture-move-up) | |
601 | (picture-substitute 'beginning-of-line 'picture-beginning-of-line) | |
602 | (picture-substitute 'end-of-line 'picture-end-of-line) | |
603 | ||
695d13c7 | 604 | (define-key picture-mode-map "\C-c\C-d" 'delete-char) |
695d13c7 BP |
605 | (define-key picture-mode-map "\e\t" 'picture-toggle-tab-state) |
606 | (define-key picture-mode-map "\t" 'picture-tab) | |
607 | (define-key picture-mode-map "\e\t" 'picture-tab-search) | |
608 | (define-key picture-mode-map "\C-c\t" 'picture-set-tab-stops) | |
609 | (define-key picture-mode-map "\C-c\C-k" 'picture-clear-rectangle) | |
610 | (define-key picture-mode-map "\C-c\C-w" 'picture-clear-rectangle-to-register) | |
611 | (define-key picture-mode-map "\C-c\C-y" 'picture-yank-rectangle) | |
612 | (define-key picture-mode-map "\C-c\C-x" 'picture-yank-rectangle-from-register) | |
d792910f | 613 | (define-key picture-mode-map "\C-c\C-r" 'picture-draw-rectangle) |
695d13c7 BP |
614 | (define-key picture-mode-map "\C-c\C-c" 'picture-mode-exit) |
615 | (define-key picture-mode-map "\C-c\C-f" 'picture-motion) | |
616 | (define-key picture-mode-map "\C-c\C-b" 'picture-motion-reverse) | |
617 | (define-key picture-mode-map "\C-c<" 'picture-movement-left) | |
618 | (define-key picture-mode-map "\C-c>" 'picture-movement-right) | |
619 | (define-key picture-mode-map "\C-c^" 'picture-movement-up) | |
620 | (define-key picture-mode-map "\C-c." 'picture-movement-down) | |
621 | (define-key picture-mode-map "\C-c`" 'picture-movement-nw) | |
622 | (define-key picture-mode-map "\C-c'" 'picture-movement-ne) | |
623 | (define-key picture-mode-map "\C-c/" 'picture-movement-sw) | |
624 | (define-key picture-mode-map "\C-c\\" 'picture-movement-se))) | |
625 | ||
d1ebc62e | 626 | (defcustom picture-mode-hook nil |
ca9c7579 | 627 | "If non-nil, its value is called on entry to Picture mode. |
d1ebc62e SE |
628 | Picture mode is invoked by the command \\[picture-mode]." |
629 | :type 'hook | |
630 | :group 'picture) | |
695d13c7 | 631 | |
c4fc49b6 RS |
632 | (defvar picture-mode-old-local-map) |
633 | (defvar picture-mode-old-mode-name) | |
634 | (defvar picture-mode-old-major-mode) | |
b9911289 | 635 | (defvar picture-mode-old-truncate-lines) |
c4fc49b6 | 636 | |
7229064d | 637 | ;;;###autoload |
ca9c7579 | 638 | (defun picture-mode () |
695d13c7 BP |
639 | "Switch to Picture mode, in which a quarter-plane screen model is used. |
640 | Printing characters replace instead of inserting themselves with motion | |
641 | afterwards settable by these commands: | |
642 | C-c < Move left after insertion. | |
643 | C-c > Move right after insertion. | |
644 | C-c ^ Move up after insertion. | |
645 | C-c . Move down after insertion. | |
646 | C-c ` Move northwest (nw) after insertion. | |
647 | C-c ' Move northeast (ne) after insertion. | |
648 | C-c / Move southwest (sw) after insertion. | |
649 | C-c \\ Move southeast (se) after insertion. | |
2697c1f3 KH |
650 | C-u C-c ` Move westnorthwest (wnw) after insertion. |
651 | C-u C-c ' Move eastnortheast (ene) after insertion. | |
652 | C-u C-c / Move westsouthwest (wsw) after insertion. | |
653 | C-u C-c \\ Move eastsoutheast (ese) after insertion. | |
695d13c7 BP |
654 | The current direction is displayed in the mode line. The initial |
655 | direction is right. Whitespace is inserted and tabs are changed to | |
656 | spaces when required by movement. You can move around in the buffer | |
657 | with these commands: | |
ca9c7579 ER |
658 | \\[picture-move-down] Move vertically to SAME column in previous line. |
659 | \\[picture-move-up] Move vertically to SAME column in next line. | |
660 | \\[picture-end-of-line] Move to column following last non-whitespace character. | |
661 | \\[picture-forward-column] Move right inserting spaces if required. | |
662 | \\[picture-backward-column] Move left changing tabs to spaces if required. | |
695d13c7 BP |
663 | C-c C-f Move in direction of current picture motion. |
664 | C-c C-b Move in opposite direction of current picture motion. | |
665 | Return Move to beginning of next line. | |
666 | You can edit tabular text with these commands: | |
667 | M-Tab Move to column beneath (or at) next interesting character. | |
668 | `Indents' relative to a previous line. | |
669 | Tab Move to next stop in tab stop list. | |
670 | C-c Tab Set tab stops according to context of this line. | |
671 | With ARG resets tab stops to default (global) value. | |
672 | See also documentation of variable picture-tab-chars | |
673 | which defines \"interesting character\". You can manually | |
674 | change the tab stop list with command \\[edit-tab-stops]. | |
675 | You can manipulate text with these commands: | |
676 | C-d Clear (replace) ARG columns after point without moving. | |
677 | C-c C-d Delete char at point - the command normally assigned to C-d. | |
ca9c7579 ER |
678 | \\[picture-backward-clear-column] Clear (replace) ARG columns before point, moving back over them. |
679 | \\[picture-clear-line] Clear ARG lines, advancing over them. The cleared | |
695d13c7 | 680 | text is saved in the kill ring. |
ca9c7579 | 681 | \\[picture-open-line] Open blank line(s) beneath current line. |
695d13c7 BP |
682 | You can manipulate rectangles with these commands: |
683 | C-c C-k Clear (or kill) a rectangle and save it. | |
684 | C-c C-w Like C-c C-k except rectangle is saved in named register. | |
685 | C-c C-y Overlay (or insert) currently saved rectangle at point. | |
686 | C-c C-x Like C-c C-y except rectangle is taken from named register. | |
d792910f | 687 | C-c C-r Draw a rectangular box around mark and point. |
695d13c7 BP |
688 | \\[copy-rectangle-to-register] Copies a rectangle to a register. |
689 | \\[advertised-undo] Can undo effects of rectangle overlay commands | |
690 | commands if invoked soon enough. | |
691 | You can return to the previous mode with: | |
692 | C-c C-c Which also strips trailing whitespace from every line. | |
693 | Stripping is suppressed by supplying an argument. | |
694 | ||
e444e0d6 | 695 | Entry to this mode calls the value of `picture-mode-hook' if non-nil. |
695d13c7 BP |
696 | |
697 | Note that Picture mode commands will work outside of Picture mode, but | |
698 | they are not defaultly assigned to keys." | |
699 | (interactive) | |
ca9c7579 | 700 | (if (eq major-mode 'picture-mode) |
55535639 | 701 | (error "You are already editing a picture") |
e444e0d6 | 702 | (set (make-local-variable 'picture-mode-old-local-map) (current-local-map)) |
695d13c7 | 703 | (use-local-map picture-mode-map) |
e444e0d6 SM |
704 | (set (make-local-variable 'picture-mode-old-mode-name) mode-name) |
705 | (set (make-local-variable 'picture-mode-old-major-mode) major-mode) | |
ca9c7579 | 706 | (setq major-mode 'picture-mode) |
e444e0d6 SM |
707 | (set (make-local-variable 'picture-killed-rectangle) nil) |
708 | (set (make-local-variable 'tab-stop-list) (default-value 'tab-stop-list)) | |
709 | (set (make-local-variable 'picture-tab-chars) | |
710 | (default-value 'picture-tab-chars)) | |
695d13c7 BP |
711 | (make-local-variable 'picture-vertical-step) |
712 | (make-local-variable 'picture-horizontal-step) | |
e444e0d6 | 713 | (set (make-local-variable 'picture-mode-old-truncate-lines) truncate-lines) |
ca9c7579 | 714 | (setq truncate-lines t) |
695d13c7 | 715 | (picture-set-motion 0 1) |
ca9c7579 | 716 | |
e0dad66e RS |
717 | ;; edit-picture-hook is what we used to run, picture-mode-hook is in doc. |
718 | (run-hooks 'edit-picture-hook 'picture-mode-hook) | |
d55235bb KH |
719 | (message "Type %s in this buffer to return it to %s mode." |
720 | (substitute-command-keys "\\[picture-mode-exit]") | |
721 | picture-mode-old-mode-name))) | |
695d13c7 | 722 | |
6503cec3 | 723 | ;;;###autoload |
ca9c7579 | 724 | (defalias 'edit-picture 'picture-mode) |
695d13c7 BP |
725 | |
726 | (defun picture-mode-exit (&optional nostrip) | |
ca9c7579 | 727 | "Undo picture-mode and return to previous major mode. |
695d13c7 BP |
728 | With no argument strips whitespace from end of every line in Picture buffer |
729 | otherwise just return to previous mode." | |
730 | (interactive "P") | |
ca9c7579 | 731 | (if (not (eq major-mode 'picture-mode)) |
55535639 | 732 | (error "You aren't editing a Picture") |
eaae8106 | 733 | (if (not nostrip) (delete-trailing-whitespace)) |
695d13c7 BP |
734 | (setq mode-name picture-mode-old-mode-name) |
735 | (use-local-map picture-mode-old-local-map) | |
736 | (setq major-mode picture-mode-old-major-mode) | |
737 | (kill-local-variable 'tab-stop-list) | |
b9911289 | 738 | (setq truncate-lines picture-mode-old-truncate-lines) |
00dbaf0a | 739 | (force-mode-line-update))) |
695d13c7 | 740 | |
49116ac0 JB |
741 | (provide 'picture) |
742 | ||
6594deb0 | 743 | ;;; picture.el ends here |