[bpt/emacs.git] / lisp / scroll-bar.el

;;; scroll-bar.el --- window system-independent scroll bar support

;; Copyright (C) 1993, 1994, 1995, 1999, 2000, 2001, 2002, 2003,
;;   2004, 2005, 2006, 2007, 2008, 2009, 2010, 2011 Free Software Foundation, Inc.

;; Maintainer: FSF
;; Keywords: hardware

;; This file is part of GNU Emacs.

;; GNU Emacs is free software: you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation, either version 3 of the License, or
;; (at your option) any later version.

;; GNU Emacs is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License
;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.

;;; Commentary:

;; Window-system-independent bindings of mouse clicks on the scroll bar.
;; Presently emulates the scroll-bar behavior of xterm.

;;; Code:

(require 'mouse)

\f
;;;; Utilities.

(defun scroll-bar-event-ratio (event)
  "Given a scroll bar event EVENT, return the scroll bar position as a ratio.
The value is a cons cell (PORTION . WHOLE) containing two integers
whose ratio gives the event's vertical position in the scroll bar, with 0
referring to the top and 1 to the bottom."
  (nth 2 event))

(defun scroll-bar-scale (num-denom whole)
  "Given a pair (NUM . DENOM) and WHOLE, return (/ (* NUM WHOLE) DENOM).
This is handy for scaling a position on a scroll bar into real units,
like buffer positions.  If SCROLL-BAR-POS is the (PORTION . WHOLE) pair
from a scroll bar event, then (scroll-bar-scale SCROLL-BAR-POS
\(buffer-size)) is the position in the current buffer corresponding to
that scroll bar position."
  ;; We multiply before we divide to maintain precision.
  ;; We use floating point because the product of a large buffer size
  ;; with a large scroll bar portion can easily overflow a lisp int.
  (truncate (/ (* (float (car num-denom)) whole) (cdr num-denom))))

(defun scroll-bar-columns (side)
  "Return the width, measured in columns, of the vertical scrollbar on SIDE.
SIDE must be the symbol `left' or `right'."
  (let* ((wsb   (window-scroll-bars))
         (vtype (nth 2 wsb))
         (cols  (nth 1 wsb)))
    (cond
     ((not (memq side '(left right)))
      (error "`left' or `right' expected instead of %S" side))
     ((and (eq vtype side) cols))
     ((eq (frame-parameter nil 'vertical-scroll-bars) side)
      ;; nil means it's a non-toolkit scroll bar, and its width in
      ;; columns is 14 pixels rounded up.
      (ceiling (or (frame-parameter nil 'scroll-bar-width) 14)
               (frame-char-width)))
     (0))))

\f
;;;; Helpful functions for enabling and disabling scroll bars.

(defvar scroll-bar-mode)
(defvar previous-scroll-bar-mode nil)

(defvar scroll-bar-mode-explicit nil
  "Non-nil means `set-scroll-bar-mode' should really do something.
This is nil while loading `scroll-bar.el', and t afterward.")

(defun set-scroll-bar-mode-1 (ignore value)
  (set-scroll-bar-mode value))

(defun set-scroll-bar-mode (value)
  "Set `scroll-bar-mode' to VALUE and put the new value into effect."
  (if scroll-bar-mode
      (setq previous-scroll-bar-mode scroll-bar-mode))

  (setq scroll-bar-mode value)

  (when scroll-bar-mode-explicit
    (modify-all-frames-parameters (list (cons 'vertical-scroll-bars
					      scroll-bar-mode)))))

(defcustom scroll-bar-mode default-frame-scroll-bars
  "Specify whether to have vertical scroll bars, and on which side.
Possible values are nil (no scroll bars), `left' (scroll bars on left)
and `right' (scroll bars on right).
To set this variable in a Lisp program, use `set-scroll-bar-mode'
to make it take real effect.
Setting the variable with a customization buffer also takes effect."
  :type '(choice (const :tag "none (nil)" nil)
		 (const left)
		 (const right))
  :group 'frames
  ;; The default value for :initialize would try to use :set
  ;; when processing the file in cus-dep.el.
  :initialize 'custom-initialize-default
  :set 'set-scroll-bar-mode-1)

;; We just set scroll-bar-mode, but that was the default.
;; If it is set again, that is for real.
(setq scroll-bar-mode-explicit t)

(defun scroll-bar-mode (&optional flag)
  "Toggle display of vertical scroll bars on all frames.
This command applies to all frames that exist and frames to be
created in the future.
With a numeric argument, if the argument is positive
turn on scroll bars; otherwise turn off scroll bars."
  (interactive "P")

  ;; Tweedle the variable according to the argument.
  (set-scroll-bar-mode (if (if (null flag)
			       (not scroll-bar-mode)
			     (setq flag (prefix-numeric-value flag))
			     (or (not (numberp flag)) (> flag 0)))
			   (or previous-scroll-bar-mode
			       default-frame-scroll-bars))))

(defun toggle-scroll-bar (arg)
  "Toggle whether or not the selected frame has vertical scroll bars.
With arg, turn vertical scroll bars on if and only if arg is positive.
The variable `scroll-bar-mode' controls which side the scroll bars are on
when they are turned on; if it is nil, they go on the left."
  (interactive "P")
  (if (null arg)
      (setq arg
	    (if (cdr (assq 'vertical-scroll-bars
			   (frame-parameters (selected-frame))))
		-1 1))
    (setq arg (prefix-numeric-value arg)))
  (modify-frame-parameters
   (selected-frame)
   (list (cons 'vertical-scroll-bars
	       (if (> arg 0)
		   (or scroll-bar-mode default-frame-scroll-bars))))))

(defun toggle-horizontal-scroll-bar (arg)
  "Toggle whether or not the selected frame has horizontal scroll bars.
With arg, turn horizontal scroll bars on if and only if arg is positive.
Horizontal scroll bars aren't implemented yet."
  (interactive "P")
  (error "Horizontal scroll bars aren't implemented yet"))
\f
;;;; Buffer navigation using the scroll bar.

;; This was used for up-events on button 2, but no longer.
(defun scroll-bar-set-window-start (event)
  "Set the window start according to where the scroll bar is dragged.
EVENT should be a scroll bar click or drag event."
  (interactive "e")
  (let* ((end-position (event-end event))
	 (window (nth 0 end-position))
	 (portion-whole (nth 2 end-position)))
    (with-current-buffer (window-buffer window)
      (save-excursion
	(goto-char (+ (point-min)
		      (scroll-bar-scale portion-whole
					(- (point-max) (point-min)))))
	(beginning-of-line)
	(set-window-start window (point))))))

(defun scroll-bar-drag-position (portion-whole)
  "Calculate new window start for drag event."
  (save-excursion
    (goto-char (+ (point-min)
		  (scroll-bar-scale portion-whole
				    (- (point-max) (point-min)))))
    (beginning-of-line)
    (point)))

(defun scroll-bar-maybe-set-window-start (event)
  "Set the window start according to where the scroll bar is dragged.
Only change window start if the new start is substantially different.
EVENT should be a scroll bar click or drag event."
  (interactive "e")
  (let* ((end-position (event-end event))
	 (window (nth 0 end-position))
	 (portion-whole (nth 2 end-position))
	 (next-portion-whole (cons (1+ (car portion-whole))
				   (cdr portion-whole)))
	 portion-start
	 next-portion-start
	 (current-start (window-start window)))
    (with-current-buffer (window-buffer window)
      (setq portion-start (scroll-bar-drag-position portion-whole))
      (setq next-portion-start (max
				(scroll-bar-drag-position next-portion-whole)
				(1+ portion-start)))
      (if (or (>= current-start next-portion-start)
	      (< current-start portion-start))
	  (set-window-start window portion-start)
	;; Always set window start, to ensure scroll bar position is updated.
	(set-window-start window current-start)))))

;; Scroll the window to the proper position for EVENT.
(defun scroll-bar-drag-1 (event)
  (let* ((start-position (event-start event))
	 (window (nth 0 start-position))
	 (portion-whole (nth 2 start-position)))
    (save-excursion 
      (with-current-buffer (window-buffer window)
	;; Calculate position relative to the accessible part of the buffer.
	(goto-char (+ (point-min)
		      (scroll-bar-scale portion-whole
					(- (point-max) (point-min)))))
	(vertical-motion 0 window)
	(set-window-start window (point))))))

(defun scroll-bar-drag (event)
  "Scroll the window by dragging the scroll bar slider.
If you click outside the slider, the window scrolls to bring the slider there."
  (interactive "e")
  (let* (done
	 (echo-keystrokes 0)
	 (end-position (event-end event))
	 (window (nth 0 end-position))
	 (before-scroll))
    (with-current-buffer (window-buffer window)
      (setq before-scroll point-before-scroll))
    (save-selected-window
      (select-window window)
      (setq before-scroll
	    (or before-scroll (point))))
    (scroll-bar-drag-1 event)
    (track-mouse
      (while (not done)
	(setq event (read-event))
	(if (eq (car-safe event) 'mouse-movement)
	    (setq event (read-event)))
	(cond ((eq (car-safe event) 'scroll-bar-movement)
	       (scroll-bar-drag-1 event))
	      (t
	       ;; Exit when we get the drag event; ignore that event.
	       (setq done t)))))
    (sit-for 0)
    (with-current-buffer (window-buffer window)
      (setq point-before-scroll before-scroll))))

(defun scroll-bar-scroll-down (event)
  "Scroll the window's top line down to the location of the scroll bar click.
EVENT should be a scroll bar click."
  (interactive "e")
  (let* ((end-position (event-end event))
	 (window (nth 0 end-position))
	 (before-scroll))
    (with-current-buffer (window-buffer window)
      (setq before-scroll point-before-scroll))
    (unwind-protect
	(save-selected-window
	  (let ((portion-whole (nth 2 end-position)))
	    (select-window window)
	    (setq before-scroll
		  (or before-scroll (point)))
	    (scroll-down
	     (scroll-bar-scale portion-whole (1- (window-height)))))
	  (sit-for 0))
      (with-current-buffer (window-buffer window)
	(setq point-before-scroll before-scroll)))))

(defun scroll-bar-scroll-up (event)
  "Scroll the line next to the scroll bar click to the top of the window.
EVENT should be a scroll bar click."
  (interactive "e")
  (let* ((end-position (event-end event))
	 (window (nth 0 end-position))
	 (before-scroll))
    (with-current-buffer (window-buffer window)
      (setq before-scroll point-before-scroll))
    (unwind-protect
	(save-selected-window
	  (let ((portion-whole (nth 2 end-position)))
	    (select-window window)
	    (setq before-scroll
		  (or before-scroll (point)))
	    (scroll-up
	     (scroll-bar-scale portion-whole (1- (window-height)))))
	  (sit-for 0))
      (with-current-buffer (window-buffer window)
	(setq point-before-scroll before-scroll)))))

\f
;;; Tookit scroll bars.

(defun scroll-bar-toolkit-scroll (event)
  (interactive "e")
  (let* ((end-position (event-end event))
	 (window (nth 0 end-position))
	 (part (nth 4 end-position))
	 before-scroll)
    (cond ((eq part 'end-scroll))
	  (t
	   (with-current-buffer (window-buffer window)
	     (setq before-scroll point-before-scroll))
	   (save-selected-window
	     (select-window window)
	     (setq before-scroll (or before-scroll (point)))
	     (cond ((eq part 'above-handle)
		    (scroll-up '-))
		   ((eq part 'below-handle)
		    (scroll-up nil))
		   ((eq part 'ratio)
		    (let* ((portion-whole (nth 2 end-position))
			   (lines (scroll-bar-scale portion-whole
						    (1- (window-height)))))
		      (scroll-up (cond ((not (zerop lines)) lines)
				       ((< (car portion-whole) 0) -1)
				       (t 1)))))
		   ((eq part 'up)
		    (scroll-up -1))
		   ((eq part 'down)
		    (scroll-up 1))
		   ((eq part 'top)
		    (set-window-start window (point-min)))
		   ((eq part 'bottom)
		    (goto-char (point-max))
		    (recenter))
		   ((eq part 'handle)
		    (scroll-bar-drag-1 event))))
	   (sit-for 0)
	   (with-current-buffer (window-buffer window)
	     (setq point-before-scroll before-scroll))))))


\f
;;;; Bindings.

;; For now, we'll set things up to work like xterm.
(cond ((and (boundp 'x-toolkit-scroll-bars) x-toolkit-scroll-bars)
       (global-set-key [vertical-scroll-bar mouse-1]
		       'scroll-bar-toolkit-scroll))
      (t
       (global-set-key [vertical-scroll-bar mouse-1]
		       'scroll-bar-scroll-up)
       (global-set-key [vertical-scroll-bar drag-mouse-1]
		       'scroll-bar-scroll-up)
       (global-set-key [vertical-scroll-bar down-mouse-2]
		       'scroll-bar-drag)
       (global-set-key [vertical-scroll-bar mouse-3]
		       'scroll-bar-scroll-down)
       (global-set-key [vertical-scroll-bar drag-mouse-3]
		       'scroll-bar-scroll-down)))

\f
(provide 'scroll-bar)

;; arch-tag: 6f1d01d0-0b1e-4bf8-86db-d491e0f399f3
;;; scroll-bar.el ends here
Commit	Line	Data
55535639	1	;;; scroll-bar.el --- window system-independent scroll bar support
6d62a90e	2
0d30b337	3	;; Copyright (C) 1993, 1994, 1995, 1999, 2000, 2001, 2002, 2003,
5df4f04c	4	;; 2004, 2005, 2006, 2007, 2008, 2009, 2010, 2011 Free Software Foundation, Inc.
6d62a90e JB	5
	6	;; Maintainer: FSF
	7	;; Keywords: hardware
	8
b578f267	9	;; This file is part of GNU Emacs.
6d62a90e	10
eb3fa2cf	11	;; GNU Emacs is free software: you can redistribute it and/or modify
b578f267	12	;; it under the terms of the GNU General Public License as published by
eb3fa2cf GM	13	;; the Free Software Foundation, either version 3 of the License, or
eb3fa2cf GM	14	;; (at your option) any later version.
6d62a90e	15
b578f267 EN	16	;; GNU Emacs is distributed in the hope that it will be useful,
	17	;; but WITHOUT ANY WARRANTY; without even the implied warranty of
	18	;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
	19	;; GNU General Public License for more details.
6d62a90e	20
b578f267	21	;; You should have received a copy of the GNU General Public License
eb3fa2cf	22	;; along with GNU Emacs. If not, see <http://www.gnu.org/licenses/>.
76550a57	23
d9ecc911 ER	24	;;; Commentary:
	25
	26	;; Window-system-independent bindings of mouse clicks on the scroll bar.
	27	;; Presently emulates the scroll-bar behavior of xterm.
b578f267	28
d9ecc911 ER	29	;;; Code:
d9ecc911 ER	30
dbc4e1c1 JB	31	(require 'mouse)
dbc4e1c1 JB	32
6d62a90e JB	33	\f
	34	;;;; Utilities.
	35
86828678 RS	36	(defun scroll-bar-event-ratio (event)
	37	"Given a scroll bar event EVENT, return the scroll bar position as a ratio.
	38	The value is a cons cell (PORTION . WHOLE) containing two integers
	39	whose ratio gives the event's vertical position in the scroll bar, with 0
	40	referring to the top and 1 to the bottom."
	41	(nth 2 event))
	42
bf3c8a70	43	(defun scroll-bar-scale (num-denom whole)
6d62a90e	44	"Given a pair (NUM . DENOM) and WHOLE, return (/ (* NUM WHOLE) DENOM).
bf3c8a70 JB	45	This is handy for scaling a position on a scroll bar into real units,
	46	like buffer positions. If SCROLL-BAR-POS is the (PORTION . WHOLE) pair
	47	from a scroll bar event, then (scroll-bar-scale SCROLL-BAR-POS
6d62a90e	48	\(buffer-size)) is the position in the current buffer corresponding to
bf3c8a70	49	that scroll bar position."
6d62a90e JB	50	;; We multiply before we divide to maintain precision.
6d62a90e JB	51	;; We use floating point because the product of a large buffer size
bf3c8a70	52	;; with a large scroll bar portion can easily overflow a lisp int.
6d62a90e JB	53	(truncate (/ (* (float (car num-denom)) whole) (cdr num-denom))))
6d62a90e JB	54
9fd76d04 MY	55	(defun scroll-bar-columns (side)
	56	"Return the width, measured in columns, of the vertical scrollbar on SIDE.
	57	SIDE must be the symbol `left' or `right'."
	58	(let* ((wsb (window-scroll-bars))
	59	(vtype (nth 2 wsb))
	60	(cols (nth 1 wsb)))
	61	(cond
	62	((not (memq side '(left right)))
	63	(error "`left' or `right' expected instead of %S" side))
	64	((and (eq vtype side) cols))
	65	((eq (frame-parameter nil 'vertical-scroll-bars) side)
	66	;; nil means it's a non-toolkit scroll bar, and its width in
	67	;; columns is 14 pixels rounded up.
	68	(ceiling (or (frame-parameter nil 'scroll-bar-width) 14)
	69	(frame-char-width)))
	70	(0))))
	71
6d62a90e	72	\f
fe48f821	73	;;;; Helpful functions for enabling and disabling scroll bars.
fe48f821	74
1064fe38	75	(defvar scroll-bar-mode)
f62c3ee2	76	(defvar previous-scroll-bar-mode nil)
1064fe38	77
2124851f RS	78	(defvar scroll-bar-mode-explicit nil
	79	"Non-nil means `set-scroll-bar-mode' should really do something.
	80	This is nil while loading `scroll-bar.el', and t afterward.")
	81
e4b201bb KH	82	(defun set-scroll-bar-mode-1 (ignore value)
	83	(set-scroll-bar-mode value))
	84
	85	(defun set-scroll-bar-mode (value)
04c34f2e	86	"Set `scroll-bar-mode' to VALUE and put the new value into effect."
f62c3ee2 JD	87	(if scroll-bar-mode
	88	(setq previous-scroll-bar-mode scroll-bar-mode))
	89
04c34f2e RS	90	(setq scroll-bar-mode value)
04c34f2e RS	91
2124851f	92	(when scroll-bar-mode-explicit
095fe281 KL	93	(modify-all-frames-parameters (list (cons 'vertical-scroll-bars
095fe281 KL	94	scroll-bar-mode)))))
04c34f2e	95
61f2fe7b	96	(defcustom scroll-bar-mode default-frame-scroll-bars
9201cc28	97	"Specify whether to have vertical scroll bars, and on which side.
04c34f2e RS	98	Possible values are nil (no scroll bars), `left' (scroll bars on left)
04c34f2e RS	99	and `right' (scroll bars on right).
463deb66 RS	100	To set this variable in a Lisp program, use `set-scroll-bar-mode'
	101	to make it take real effect.
	102	Setting the variable with a customization buffer also takes effect."
64453f32	103	:type '(choice (const :tag "none (nil)" nil)
04c34f2e RS	104	(const left)
	105	(const right))
	106	:group 'frames
2669fbfb RS	107	;; The default value for :initialize would try to use :set
	108	;; when processing the file in cus-dep.el.
	109	:initialize 'custom-initialize-default
e4b201bb	110	:set 'set-scroll-bar-mode-1)
04c34f2e	111
2124851f RS	112	;; We just set scroll-bar-mode, but that was the default.
	113	;; If it is set again, that is for real.
	114	(setq scroll-bar-mode-explicit t)
	115
b1ad7c13	116	(defun scroll-bar-mode (&optional flag)
04c34f2e	117	"Toggle display of vertical scroll bars on all frames.
fe48f821 JB	118	This command applies to all frames that exist and frames to be
fe48f821 JB	119	created in the future.
5f0e32ea JB	120	With a numeric argument, if the argument is positive
5f0e32ea JB	121	turn on scroll bars; otherwise turn off scroll bars."
fe48f821	122	(interactive "P")
ada464a7	123
04c34f2e	124	;; Tweedle the variable according to the argument.
9201cc28	125	(set-scroll-bar-mode (if (if (null flag)
61f2fe7b KS	126	(not scroll-bar-mode)
61f2fe7b KS	127	(setq flag (prefix-numeric-value flag))
5f0e32ea	128	(or (not (numberp flag)) (> flag 0)))
f62c3ee2 JD	129	(or previous-scroll-bar-mode
f62c3ee2 JD	130	default-frame-scroll-bars))))
04c34f2e RS	131
	132	(defun toggle-scroll-bar (arg)
	133	"Toggle whether or not the selected frame has vertical scroll bars.
	134	With arg, turn vertical scroll bars on if and only if arg is positive.
	135	The variable `scroll-bar-mode' controls which side the scroll bars are on
	136	when they are turned on; if it is nil, they go on the left."
	137	(interactive "P")
	138	(if (null arg)
	139	(setq arg
	140	(if (cdr (assq 'vertical-scroll-bars
	141	(frame-parameters (selected-frame))))
19c6feac KH	142	-1 1))
19c6feac KH	143	(setq arg (prefix-numeric-value arg)))
1032e793 GV	144	(modify-frame-parameters
	145	(selected-frame)
	146	(list (cons 'vertical-scroll-bars
	147	(if (> arg 0)
61f2fe7b	148	(or scroll-bar-mode default-frame-scroll-bars))))))
04c34f2e RS	149
	150	(defun toggle-horizontal-scroll-bar (arg)
	151	"Toggle whether or not the selected frame has horizontal scroll bars.
	152	With arg, turn horizontal scroll bars on if and only if arg is positive.
	153	Horizontal scroll bars aren't implemented yet."
	154	(interactive "P")
	155	(error "Horizontal scroll bars aren't implemented yet"))
fe48f821	156	\f
bf3c8a70	157	;;;; Buffer navigation using the scroll bar.
6d62a90e	158
7fdbcd83	159	;; This was used for up-events on button 2, but no longer.
bf3c8a70 JB	160	(defun scroll-bar-set-window-start (event)
	161	"Set the window start according to where the scroll bar is dragged.
	162	EVENT should be a scroll bar click or drag event."
6d62a90e	163	(interactive "e")
dbc4e1c1	164	(let* ((end-position (event-end event))
6d62a90e JB	165	(window (nth 0 end-position))
6d62a90e JB	166	(portion-whole (nth 2 end-position)))
7fdbcd83	167	(with-current-buffer (window-buffer window)
6d62a90e	168	(save-excursion
4cad38d5 JB	169	(goto-char (+ (point-min)
	170	(scroll-bar-scale portion-whole
	171	(- (point-max) (point-min)))))
6d62a90e JB	172	(beginning-of-line)
	173	(set-window-start window (point))))))
	174
aeee66be RS	175	(defun scroll-bar-drag-position (portion-whole)
	176	"Calculate new window start for drag event."
	177	(save-excursion
	178	(goto-char (+ (point-min)
	179	(scroll-bar-scale portion-whole
	180	(- (point-max) (point-min)))))
	181	(beginning-of-line)
	182	(point)))
	183
	184	(defun scroll-bar-maybe-set-window-start (event)
	185	"Set the window start according to where the scroll bar is dragged.
	186	Only change window start if the new start is substantially different.
	187	EVENT should be a scroll bar click or drag event."
	188	(interactive "e")
	189	(let* ((end-position (event-end event))
	190	(window (nth 0 end-position))
	191	(portion-whole (nth 2 end-position))
	192	(next-portion-whole (cons (1+ (car portion-whole))
	193	(cdr portion-whole)))
	194	portion-start
	195	next-portion-start
	196	(current-start (window-start window)))
7fdbcd83	197	(with-current-buffer (window-buffer window)
aeee66be RS	198	(setq portion-start (scroll-bar-drag-position portion-whole))
	199	(setq next-portion-start (max
	200	(scroll-bar-drag-position next-portion-whole)
	201	(1+ portion-start)))
15655694	202	(if (or (>= current-start next-portion-start)
aeee66be	203	(< current-start portion-start))
9c005c65 KH	204	(set-window-start window portion-start)
	205	;; Always set window start, to ensure scroll bar position is updated.
	206	(set-window-start window current-start)))))
aeee66be	207
e532b016 RS	208	;; Scroll the window to the proper position for EVENT.
	209	(defun scroll-bar-drag-1 (event)
	210	(let* ((start-position (event-start event))
	211	(window (nth 0 start-position))
	212	(portion-whole (nth 2 start-position)))
71572c03 JD	213	(save-excursion
	214	(with-current-buffer (window-buffer window)
	215	;; Calculate position relative to the accessible part of the buffer.
	216	(goto-char (+ (point-min)
	217	(scroll-bar-scale portion-whole
	218	(- (point-max) (point-min)))))
	219	(vertical-motion 0 window)
	220	(set-window-start window (point))))))
e532b016 RS	221
	222	(defun scroll-bar-drag (event)
	223	"Scroll the window by dragging the scroll bar slider.
	224	If you click outside the slider, the window scrolls to bring the slider there."
	225	(interactive "e")
c782bea5	226	(let* (done
cb183ca0 RS	227	(echo-keystrokes 0)
	228	(end-position (event-end event))
	229	(window (nth 0 end-position))
	230	(before-scroll))
	231	(with-current-buffer (window-buffer window)
	232	(setq before-scroll point-before-scroll))
	233	(save-selected-window
	234	(select-window window)
	235	(setq before-scroll
	236	(or before-scroll (point))))
	237	(scroll-bar-drag-1 event)
	238	(track-mouse
	239	(while (not done)
	240	(setq event (read-event))
	241	(if (eq (car-safe event) 'mouse-movement)
	242	(setq event (read-event)))
	243	(cond ((eq (car-safe event) 'scroll-bar-movement)
	244	(scroll-bar-drag-1 event))
	245	(t
	246	;; Exit when we get the drag event; ignore that event.
	247	(setq done t)))))
	248	(sit-for 0)
	249	(with-current-buffer (window-buffer window)
	250	(setq point-before-scroll before-scroll))))
e532b016	251
bf3c8a70 JB	252	(defun scroll-bar-scroll-down (event)
	253	"Scroll the window's top line down to the location of the scroll bar click.
	254	EVENT should be a scroll bar click."
6d62a90e	255	(interactive "e")
cb183ca0 RS	256	(let* ((end-position (event-end event))
	257	(window (nth 0 end-position))
	258	(before-scroll))
	259	(with-current-buffer (window-buffer window)
	260	(setq before-scroll point-before-scroll))
def7db1d KH	261	(unwind-protect
	262	(save-selected-window
	263	(let ((portion-whole (nth 2 end-position)))
	264	(select-window window)
	265	(setq before-scroll
	266	(or before-scroll (point)))
	267	(scroll-down
	268	(scroll-bar-scale portion-whole (1- (window-height)))))
	269	(sit-for 0))
	270	(with-current-buffer (window-buffer window)
	271	(setq point-before-scroll before-scroll)))))
6d62a90e	272
bf3c8a70 JB	273	(defun scroll-bar-scroll-up (event)
	274	"Scroll the line next to the scroll bar click to the top of the window.
	275	EVENT should be a scroll bar click."
6d62a90e	276	(interactive "e")
cb183ca0 RS	277	(let* ((end-position (event-end event))
	278	(window (nth 0 end-position))
	279	(before-scroll))
	280	(with-current-buffer (window-buffer window)
	281	(setq before-scroll point-before-scroll))
def7db1d KH	282	(unwind-protect
	283	(save-selected-window
	284	(let ((portion-whole (nth 2 end-position)))
	285	(select-window window)
	286	(setq before-scroll
	287	(or before-scroll (point)))
	288	(scroll-up
	289	(scroll-bar-scale portion-whole (1- (window-height)))))
	290	(sit-for 0))
	291	(with-current-buffer (window-buffer window)
	292	(setq point-before-scroll before-scroll)))))
6d62a90e JB	293
6d62a90e JB	294	\f
cf4eb316	295	;;; Tookit scroll bars.
6d62a90e	296
cf4eb316 GM	297	(defun scroll-bar-toolkit-scroll (event)
	298	(interactive "e")
	299	(let* ((end-position (event-end event))
	300	(window (nth 0 end-position))
	301	(part (nth 4 end-position))
	302	before-scroll)
2088cd64	303	(cond ((eq part 'end-scroll))
cf4eb316 GM	304	(t
	305	(with-current-buffer (window-buffer window)
	306	(setq before-scroll point-before-scroll))
	307	(save-selected-window
	308	(select-window window)
	309	(setq before-scroll (or before-scroll (point)))
	310	(cond ((eq part 'above-handle)
	311	(scroll-up '-))
	312	((eq part 'below-handle)
	313	(scroll-up nil))
d294c01f SM	314	((eq part 'ratio)
	315	(let* ((portion-whole (nth 2 end-position))
	316	(lines (scroll-bar-scale portion-whole
	317	(1- (window-height)))))
	318	(scroll-up (cond ((not (zerop lines)) lines)
	319	((< (car portion-whole) 0) -1)
	320	(t 1)))))
cf4eb316 GM	321	((eq part 'up)
	322	(scroll-up -1))
	323	((eq part 'down)
	324	(scroll-up 1))
	325	((eq part 'top)
	326	(set-window-start window (point-min)))
	327	((eq part 'bottom)
	328	(goto-char (point-max))
	329	(recenter))
	330	((eq part 'handle)
	331	(scroll-bar-drag-1 event))))
	332	(sit-for 0)
cf4eb316 GM	333	(with-current-buffer (window-buffer window)
cf4eb316 GM	334	(setq point-before-scroll before-scroll))))))
e532b016	335
cf4eb316 GM	336
	337	\f
	338	;;;; Bindings.
	339
7fdbcd83	340	;; For now, we'll set things up to work like xterm.
d08947c5	341	(cond ((and (boundp 'x-toolkit-scroll-bars) x-toolkit-scroll-bars)
cf4eb316 GM	342	(global-set-key [vertical-scroll-bar mouse-1]
	343	'scroll-bar-toolkit-scroll))
	344	(t
	345	(global-set-key [vertical-scroll-bar mouse-1]
	346	'scroll-bar-scroll-up)
	347	(global-set-key [vertical-scroll-bar drag-mouse-1]
	348	'scroll-bar-scroll-up)
	349	(global-set-key [vertical-scroll-bar down-mouse-2]
	350	'scroll-bar-drag)
	351	(global-set-key [vertical-scroll-bar mouse-3]
	352	'scroll-bar-scroll-down)
	353	(global-set-key [vertical-scroll-bar drag-mouse-3]
	354	'scroll-bar-scroll-down)))
6d62a90e JB	355
6d62a90e JB	356	\f
dc14eed2	357	(provide 'scroll-bar)
6d62a90e	358
cbee283d	359	;; arch-tag: 6f1d01d0-0b1e-4bf8-86db-d491e0f399f3
bf3c8a70	360	;;; scroll-bar.el ends here