[bpt/emacs.git] / lisp / ebuff-menu.el

;;; ebuff-menu.el --- electric-buffer-list mode

;; Copyright (C) 1985-1986, 1994, 2001-2014 Free Software Foundation,
;; Inc.

;; Author: Richard Mlynarik <mly@ai.mit.edu>
;; Maintainer: emacs-devel@gnu.org
;; Keywords: convenience

;; This file is part of GNU Emacs.

;; GNU Emacs is free software: you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation, either version 3 of the License, or
;; (at your option) any later version.

;; GNU Emacs is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License
;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.

;;; Commentary:

;; Who says one can't have typeout windows in GNU Emacs?   The entry
;; point, `electric-buffer-list' works like ^r select buffer from the
;; ITS Emacs lunar or tmacs libraries.

;;; Code:

(require 'electric)

(defvar electric-buffer-menu-mode-map
  (let ((map (make-keymap)))
    (fillarray (car (cdr map)) 'Electric-buffer-menu-undefined)
    (define-key map "\e" nil)
    (define-key map "\C-z" 'suspend-frame)
    (define-key map "v" 'Electric-buffer-menu-mode-view-buffer)
    (define-key map (char-to-string help-char) 'Helper-help)
    (define-key map "?" 'Helper-describe-bindings)
    (define-key map "\C-c" nil)
    (define-key map "\C-c\C-c" 'Electric-buffer-menu-quit)
    (define-key map "\C-]" 'Electric-buffer-menu-quit)
    (define-key map "q" 'Electric-buffer-menu-quit)
    (define-key map " " 'Electric-buffer-menu-select)
    (define-key map "\C-m" 'Electric-buffer-menu-select)
    (define-key map "\C-l" 'recenter)
    (define-key map "s" 'Buffer-menu-save)
    (define-key map "d" 'Buffer-menu-delete)
    (define-key map "k" 'Buffer-menu-delete)
    (define-key map "\C-d" 'Buffer-menu-delete-backwards)
    ;; (define-key map "\C-k" 'Buffer-menu-delete)
    (define-key map "\177" 'Buffer-menu-backup-unmark)
    (define-key map "~" 'Buffer-menu-not-modified)
    (define-key map "u" 'Buffer-menu-unmark)
    (let ((i ?0))
      (while (<= i ?9)
	(define-key map (char-to-string i) 'digit-argument)
	(define-key map (concat "\e" (char-to-string i)) 'digit-argument)
	(setq i (1+ i))))
    (define-key map "-" 'negative-argument)
    (define-key map "\e-" 'negative-argument)
    (define-key map "m" 'Buffer-menu-mark)
    (define-key map "\C-u" 'universal-argument)
    (define-key map "\C-p" 'previous-line)
    (define-key map "\C-n" 'next-line)
    (define-key map "p" 'previous-line)
    (define-key map "n" 'next-line)
    (define-key map "\C-v" 'scroll-up-command)
    (define-key map "\ev" 'scroll-down-command)
    (define-key map ">" 'scroll-right)
    (define-key map "<" 'scroll-left)
    (define-key map "\e\C-v" 'scroll-other-window)
    (define-key map "\e>" 'end-of-buffer)
    (define-key map "\e<" 'beginning-of-buffer)
    (define-key map "\e\e" nil)
    (define-key map "\e\e\e" 'Electric-buffer-menu-quit)
    ;; This binding prevents the "escape => ESC" function-key-map mapping from
    ;; kicking in!
    ;; (define-key map [escape escape escape] 'Electric-buffer-menu-quit)
    (define-key map [mouse-2] 'Electric-buffer-menu-mouse-select)
    map))

(put 'Electric-buffer-menu-quit :advertised-binding "\C-c\C-c")
(put 'Electric-buffer-menu-select :advertised-binding " ")
(put 'Helper-help :advertised-binding (char-to-string help-char))
(put 'Helper-describe-bindings :advertised-binding "?")

(defvar electric-buffer-menu-mode-hook nil
  "Normal hook run by `electric-buffer-menu-mode'.")

;;;###autoload
(defun electric-buffer-list (arg)
  "Pop up the Buffer Menu in an \"electric\" window.
If you type SPC or RET (`Electric-buffer-menu-select'), that
selects the buffer at point and quits the \"electric\" window.
Otherwise, you can move around in the Buffer Menu, marking
buffers to be selected, saved or deleted; these other commands
are much like those of `Buffer-menu-mode'.

Run hooks in `electric-buffer-menu-mode-hook' on entry.

\\<electric-buffer-menu-mode-map>
\\[keyboard-quit] or \\[Electric-buffer-menu-quit] -- exit buffer menu, returning to previous window and buffer
  configuration.  If the very first character typed is a space, it
  also has this effect.
\\[Electric-buffer-menu-select] -- select buffer of line point is on.
  Also show buffers marked with m in other windows,
  deletes buffers marked with \"D\", and saves those marked with \"S\".
\\[Buffer-menu-mark] -- mark buffer to be displayed.
\\[Buffer-menu-not-modified] -- clear modified-flag on that buffer.
\\[Buffer-menu-save] -- mark that buffer to be saved.
\\[Buffer-menu-delete] or \\[Buffer-menu-delete-backwards] -- mark that buffer to be deleted.
\\[Buffer-menu-unmark] -- remove all kinds of marks from current line.
\\[Electric-buffer-menu-mode-view-buffer] -- view buffer, returning when done.
\\[Buffer-menu-backup-unmark] -- back up a line and remove marks."
  (interactive "P")
  (let (select buffer)
    (save-window-excursion
      (setq buffer (list-buffers-noselect arg))
      (Electric-pop-up-window buffer)
      (unwind-protect
	  (let ((header header-line-format))
	    (set-buffer buffer)
	    (electric-buffer-menu-mode)
	    (setq header-line-format header)
	    (goto-char (point-min))
	    (if (search-forward "\n." nil t)
		(forward-char -1))
	    (electric-buffer-update-highlight)
	    (setq select
		  (catch 'electric-buffer-menu-select
		    (message "<<< Type SPC or RET to bury the buffer list >>>")
		    (setq unread-command-events (list (read-event)))
		    (let ((start-point (point))
			  (first (progn (goto-char (point-min))
					(unless Buffer-menu-use-header-line
					  (forward-line 2))
					(point)))
			  (last (progn (goto-char (point-max))
				       (forward-line -1)
				       (point)))
			  (goal-column 0))
		      ;; Use start-point if it is meaningful.
		      (goto-char (if (or (< start-point first)
					 (> start-point last))
				     first
				   start-point))
		      (Electric-command-loop 'electric-buffer-menu-select
					     nil
					     t
					     'electric-buffer-menu-looper
					     (cons first last))))))
	(set-buffer buffer)
	(Buffer-menu-mode)
	(bury-buffer)                ;Get rid of window, if dedicated.
	(message "")))
    (when select
      (set-buffer buffer)
      (let ((opoint (point-marker)))
	(Buffer-menu-execute)
	(goto-char (point-min))
	(if (prog1 (search-forward "\n>" nil t)
	      (goto-char opoint)
	      (set-marker opoint nil))
	    (Buffer-menu-select)
	  (switch-to-buffer (Buffer-menu-buffer t)))))))

(defun electric-buffer-menu-looper (state condition)
  (cond ((and condition
	      (not (memq (car condition) '(buffer-read-only
					   end-of-buffer
					   beginning-of-buffer))))
	 (signal (car condition) (cdr condition)))
	((< (point) (car state))
	 (goto-char (point-min))
	 (unless Buffer-menu-use-header-line
	   (forward-line 2)))
	((> (point) (cdr state))
	 (goto-char (point-max))
	 (forward-line -1)
	 (if (pos-visible-in-window-p (point-max))
	     (recenter -1))))
  (electric-buffer-update-highlight))

(defvar Helper-return-blurb)

(define-derived-mode electric-buffer-menu-mode Buffer-menu-mode
  "Electric Buffer Menu"
  "Toggle Electric Buffer Menu mode in this buffer.
With a prefix argument ARG, enable Long Lines mode if ARG is
positive, and disable it otherwise.  If called from Lisp, enable
the mode if ARG is omitted or nil.

Electric Buffer Menu mode is a minor mode which is automatically
enabled and disabled by the \\[electric-buffer-list] command.
See the documentation of `electric-buffer-list' for details."
  (setq mode-line-buffer-identification "Electric Buffer List")
  (set (make-local-variable 'Helper-return-blurb)
       "return to buffer editing"))

(define-obsolete-function-alias 'Electric-buffer-menu-mode
  'electric-buffer-menu-mode "24.3")

;; generally the same as Buffer-menu-mode-map
;;  (except we don't indirect to global-map)
(put 'Electric-buffer-menu-undefined 'suppress-keymap t)

(defun Electric-buffer-menu-exit ()
  (interactive)
  (setq unread-command-events (listify-key-sequence (this-command-keys)))
  ;; for robustness
  (condition-case ()
      (throw 'electric-buffer-menu-select nil)
    (error (Buffer-menu-mode)
	   (other-buffer))))

(defun Electric-buffer-menu-select ()
  "Leave Electric Buffer Menu, selecting buffers and executing changes.
Save buffers marked \"S\".  Delete buffers marked \"K\".
Select buffer at point and display buffers marked \">\" in other windows."
  (interactive)
  (throw 'electric-buffer-menu-select (point)))

(defun Electric-buffer-menu-mouse-select (event)
  (interactive "e")
  (select-window (posn-window (event-end event)))
  (set-buffer (window-buffer))
  (goto-char (posn-point (event-end event)))
  (throw 'electric-buffer-menu-select (point)))

(defun Electric-buffer-menu-quit ()
  "Leave Electric Buffer Menu, restoring previous window configuration.
Skip execution of select, save, and delete commands."
  (interactive)
  (throw 'electric-buffer-menu-select nil))

(defun Electric-buffer-menu-undefined ()
  (interactive)
  (ding)
  (message "%s"
	   (substitute-command-keys "\
Type \\[Electric-buffer-menu-quit] to exit, \
\\[Electric-buffer-menu-select] to select, \
\\[Helper-help] for help, \\[Helper-describe-bindings] for commands."))
  (sit-for 4))

(defun Electric-buffer-menu-mode-view-buffer ()
  "View buffer on current line in Electric Buffer Menu.
Return to Electric Buffer Menu when done."
  (interactive)
  (let ((bufnam (Buffer-menu-buffer nil)))
    (if bufnam
	(view-buffer bufnam)
      (ding)
      (message "Buffer %s does not exist!" bufnam)
      (sit-for 4))))

(defvar electric-buffer-overlay nil)

(defun electric-buffer-update-highlight ()
  (when (derived-mode-p 'electric-buffer-menu-mode)
    ;; Make sure we have an overlay to use.
    (or electric-buffer-overlay
	(set (make-local-variable 'electric-buffer-overlay)
	     (make-overlay (point) (point))))
    (move-overlay electric-buffer-overlay
		  (line-beginning-position)
		  (line-end-position))
    (overlay-put electric-buffer-overlay 'face 'highlight)))

(provide 'ebuff-menu)

;;; ebuff-menu.el ends here
Commit	Line	Data
c0274f38 ER	1	;;; ebuff-menu.el --- electric-buffer-list mode
c0274f38 ER	2
ba318903	3	;; Copyright (C) 1985-1986, 1994, 2001-2014 Free Software Foundation,
ab422c4d	4	;; Inc.
2076c87c	5
3a801d0c	6	;; Author: Richard Mlynarik <mly@ai.mit.edu>
34dc21db	7	;; Maintainer: emacs-devel@gnu.org
3465cfd7	8	;; Keywords: convenience
3a801d0c	9
2076c87c JB	10	;; This file is part of GNU Emacs.
2076c87c JB	11
eb3fa2cf	12	;; GNU Emacs is free software: you can redistribute it and/or modify
2076c87c	13	;; it under the terms of the GNU General Public License as published by
eb3fa2cf GM	14	;; the Free Software Foundation, either version 3 of the License, or
eb3fa2cf GM	15	;; (at your option) any later version.
2076c87c JB	16
	17	;; GNU Emacs is distributed in the hope that it will be useful,
	18	;; but WITHOUT ANY WARRANTY; without even the implied warranty of
	19	;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
	20	;; GNU General Public License for more details.
	21
	22	;; You should have received a copy of the GNU General Public License
eb3fa2cf	23	;; along with GNU Emacs. If not, see <http://www.gnu.org/licenses/>.
2076c87c	24
e5167999 ER	25	;;; Commentary:
e5167999 ER	26
e41b2db1 ER	27	;; Who says one can't have typeout windows in GNU Emacs? The entry
	28	;; point, `electric-buffer-list' works like ^r select buffer from the
	29	;; ITS Emacs lunar or tmacs libraries.
e5167999 ER	30
e5167999 ER	31	;;; Code:
2076c87c JB	32
	33	(require 'electric)
	34
bb0bd45a SM	35	(defvar electric-buffer-menu-mode-map
	36	(let ((map (make-keymap)))
	37	(fillarray (car (cdr map)) 'Electric-buffer-menu-undefined)
	38	(define-key map "\e" nil)
	39	(define-key map "\C-z" 'suspend-frame)
	40	(define-key map "v" 'Electric-buffer-menu-mode-view-buffer)
	41	(define-key map (char-to-string help-char) 'Helper-help)
	42	(define-key map "?" 'Helper-describe-bindings)
	43	(define-key map "\C-c" nil)
	44	(define-key map "\C-c\C-c" 'Electric-buffer-menu-quit)
	45	(define-key map "\C-]" 'Electric-buffer-menu-quit)
	46	(define-key map "q" 'Electric-buffer-menu-quit)
	47	(define-key map " " 'Electric-buffer-menu-select)
	48	(define-key map "\C-m" 'Electric-buffer-menu-select)
	49	(define-key map "\C-l" 'recenter)
	50	(define-key map "s" 'Buffer-menu-save)
	51	(define-key map "d" 'Buffer-menu-delete)
	52	(define-key map "k" 'Buffer-menu-delete)
	53	(define-key map "\C-d" 'Buffer-menu-delete-backwards)
	54	;; (define-key map "\C-k" 'Buffer-menu-delete)
	55	(define-key map "\177" 'Buffer-menu-backup-unmark)
	56	(define-key map "~" 'Buffer-menu-not-modified)
	57	(define-key map "u" 'Buffer-menu-unmark)
	58	(let ((i ?0))
	59	(while (<= i ?9)
	60	(define-key map (char-to-string i) 'digit-argument)
	61	(define-key map (concat "\e" (char-to-string i)) 'digit-argument)
	62	(setq i (1+ i))))
	63	(define-key map "-" 'negative-argument)
	64	(define-key map "\e-" 'negative-argument)
	65	(define-key map "m" 'Buffer-menu-mark)
	66	(define-key map "\C-u" 'universal-argument)
	67	(define-key map "\C-p" 'previous-line)
	68	(define-key map "\C-n" 'next-line)
	69	(define-key map "p" 'previous-line)
	70	(define-key map "n" 'next-line)
ce3cefcc CY	71	(define-key map "\C-v" 'scroll-up-command)
ce3cefcc CY	72	(define-key map "\ev" 'scroll-down-command)
bb0bd45a SM	73	(define-key map ">" 'scroll-right)
	74	(define-key map "<" 'scroll-left)
	75	(define-key map "\e\C-v" 'scroll-other-window)
	76	(define-key map "\e>" 'end-of-buffer)
	77	(define-key map "\e<" 'beginning-of-buffer)
	78	(define-key map "\e\e" nil)
	79	(define-key map "\e\e\e" 'Electric-buffer-menu-quit)
	80	;; This binding prevents the "escape => ESC" function-key-map mapping from
	81	;; kicking in!
	82	;; (define-key map [escape escape escape] 'Electric-buffer-menu-quit)
	83	(define-key map [mouse-2] 'Electric-buffer-menu-mouse-select)
	84	map))
2076c87c	85
3cc99f68 CY	86	(put 'Electric-buffer-menu-quit :advertised-binding "\C-c\C-c")
	87	(put 'Electric-buffer-menu-select :advertised-binding " ")
	88	(put 'Helper-help :advertised-binding (char-to-string help-char))
	89	(put 'Helper-describe-bindings :advertised-binding "?")
	90
5f20b653	91	(defvar electric-buffer-menu-mode-hook nil
0ae03b6a	92	"Normal hook run by `electric-buffer-menu-mode'.")
5f20b653	93
2076c87c JB	94	;;;###autoload
2076c87c JB	95	(defun electric-buffer-list (arg)
0ae03b6a CY	96	"Pop up the Buffer Menu in an \"electric\" window.
	97	If you type SPC or RET (`Electric-buffer-menu-select'), that
	98	selects the buffer at point and quits the \"electric\" window.
	99	Otherwise, you can move around in the Buffer Menu, marking
	100	buffers to be selected, saved or deleted; these other commands
	101	are much like those of `Buffer-menu-mode'.
2076c87c	102
5f20b653	103	Run hooks in `electric-buffer-menu-mode-hook' on entry.
2076c87c	104
0ae03b6a CY	105	\\<electric-buffer-menu-mode-map>
	106	\\[keyboard-quit] or \\[Electric-buffer-menu-quit] -- exit buffer menu, returning to previous window and buffer
	107	configuration. If the very first character typed is a space, it
	108	also has this effect.
	109	\\[Electric-buffer-menu-select] -- select buffer of line point is on.
	110	Also show buffers marked with m in other windows,
	111	deletes buffers marked with \"D\", and saves those marked with \"S\".
	112	\\[Buffer-menu-mark] -- mark buffer to be displayed.
	113	\\[Buffer-menu-not-modified] -- clear modified-flag on that buffer.
	114	\\[Buffer-menu-save] -- mark that buffer to be saved.
	115	\\[Buffer-menu-delete] or \\[Buffer-menu-delete-backwards] -- mark that buffer to be deleted.
	116	\\[Buffer-menu-unmark] -- remove all kinds of marks from current line.
	117	\\[Electric-buffer-menu-mode-view-buffer] -- view buffer, returning when done.
	118	\\[Buffer-menu-backup-unmark] -- back up a line and remove marks."
2076c87c JB	119	(interactive "P")
	120	(let (select buffer)
	121	(save-window-excursion
cf6ce50b SM	122	(setq buffer (list-buffers-noselect arg))
cf6ce50b SM	123	(Electric-pop-up-window buffer)
2076c87c	124	(unwind-protect
4f5d2ba1	125	(let ((header header-line-format))
2076c87c	126	(set-buffer buffer)
0ae03b6a	127	(electric-buffer-menu-mode)
4f5d2ba1	128	(setq header-line-format header)
0ae03b6a CY	129	(goto-char (point-min))
	130	(if (search-forward "\n." nil t)
	131	(forward-char -1))
ede8f2fe	132	(electric-buffer-update-highlight)
2076c87c JB	133	(setq select
2076c87c JB	134	(catch 'electric-buffer-menu-select
0ae03b6a CY	135	(message "<<< Type SPC or RET to bury the buffer list >>>")
0ae03b6a CY	136	(setq unread-command-events (list (read-event)))
69adebeb KH	137	(let ((start-point (point))
69adebeb KH	138	(first (progn (goto-char (point-min))
a82c1267 JPW	139	(unless Buffer-menu-use-header-line
a82c1267 JPW	140	(forward-line 2))
2076c87c JB	141	(point)))
	142	(last (progn (goto-char (point-max))
	143	(forward-line -1)
	144	(point)))
	145	(goal-column 0))
69adebeb KH	146	;; Use start-point if it is meaningful.
	147	(goto-char (if (or (< start-point first)
	148	(> start-point last))
	149	first
	150	start-point))
2076c87c JB	151	(Electric-command-loop 'electric-buffer-menu-select
	152	nil
	153	t
	154	'electric-buffer-menu-looper
	155	(cons first last))))))
	156	(set-buffer buffer)
	157	(Buffer-menu-mode)
ba5bf5f0	158	(bury-buffer) ;Get rid of window, if dedicated.
2076c87c	159	(message "")))
0ae03b6a CY	160	(when select
	161	(set-buffer buffer)
	162	(let ((opoint (point-marker)))
	163	(Buffer-menu-execute)
	164	(goto-char (point-min))
	165	(if (prog1 (search-forward "\n>" nil t)
	166	(goto-char opoint)
	167	(set-marker opoint nil))
	168	(Buffer-menu-select)
	169	(switch-to-buffer (Buffer-menu-buffer t)))))))
2076c87c JB	170
	171	(defun electric-buffer-menu-looper (state condition)
	172	(cond ((and condition
	173	(not (memq (car condition) '(buffer-read-only
	174	end-of-buffer
	175	beginning-of-buffer))))
	176	(signal (car condition) (cdr condition)))
	177	((< (point) (car state))
	178	(goto-char (point-min))
a82c1267 JPW	179	(unless Buffer-menu-use-header-line
a82c1267 JPW	180	(forward-line 2)))
2076c87c JB	181	((> (point) (cdr state))
	182	(goto-char (point-max))
	183	(forward-line -1)
	184	(if (pos-visible-in-window-p (point-max))
ede8f2fe RS	185	(recenter -1))))
ede8f2fe RS	186	(electric-buffer-update-highlight))
2076c87c	187
784f8619 RS	188	(defvar Helper-return-blurb)
784f8619 RS	189
0ae03b6a CY	190	(define-derived-mode electric-buffer-menu-mode Buffer-menu-mode
	191	"Electric Buffer Menu"
	192	"Toggle Electric Buffer Menu mode in this buffer.
	193	With a prefix argument ARG, enable Long Lines mode if ARG is
	194	positive, and disable it otherwise. If called from Lisp, enable
	195	the mode if ARG is omitted or nil.
2076c87c	196
0ae03b6a CY	197	Electric Buffer Menu mode is a minor mode which is automatically
	198	enabled and disabled by the \\[electric-buffer-list] command.
	199	See the documentation of `electric-buffer-list' for details."
2076c87c	200	(setq mode-line-buffer-identification "Electric Buffer List")
0ae03b6a CY	201	(set (make-local-variable 'Helper-return-blurb)
	202	"return to buffer editing"))
	203
	204	(define-obsolete-function-alias 'Electric-buffer-menu-mode
2a1e2476	205	'electric-buffer-menu-mode "24.3")
2076c87c JB	206
	207	;; generally the same as Buffer-menu-mode-map
	208	;; (except we don't indirect to global-map)
	209	(put 'Electric-buffer-menu-undefined 'suppress-keymap t)
bb0bd45a	210
2076c87c JB	211	(defun Electric-buffer-menu-exit ()
2076c87c JB	212	(interactive)
d42cc509	213	(setq unread-command-events (listify-key-sequence (this-command-keys)))
2076c87c JB	214	;; for robustness
	215	(condition-case ()
	216	(throw 'electric-buffer-menu-select nil)
	217	(error (Buffer-menu-mode)
	218	(other-buffer))))
	219
	220	(defun Electric-buffer-menu-select ()
	221	"Leave Electric Buffer Menu, selecting buffers and executing changes.
5f20b653 TTN	222	Save buffers marked \"S\". Delete buffers marked \"K\".
5f20b653 TTN	223	Select buffer at point and display buffers marked \">\" in other windows."
2076c87c JB	224	(interactive)
	225	(throw 'electric-buffer-menu-select (point)))
	226
3c59c255 KH	227	(defun Electric-buffer-menu-mouse-select (event)
	228	(interactive "e")
	229	(select-window (posn-window (event-end event)))
290d5b58	230	(set-buffer (window-buffer))
3c59c255 KH	231	(goto-char (posn-point (event-end event)))
	232	(throw 'electric-buffer-menu-select (point)))
	233
2076c87c JB	234	(defun Electric-buffer-menu-quit ()
2076c87c JB	235	"Leave Electric Buffer Menu, restoring previous window configuration.
5f20b653	236	Skip execution of select, save, and delete commands."
2076c87c JB	237	(interactive)
	238	(throw 'electric-buffer-menu-select nil))
	239
	240	(defun Electric-buffer-menu-undefined ()
	241	(interactive)
	242	(ding)
2bb7c30c	243	(message "%s"
3cc99f68	244	(substitute-command-keys "\
2076c87c JB	245	Type \\[Electric-buffer-menu-quit] to exit, \
2076c87c JB	246	\\[Electric-buffer-menu-select] to select, \
3cc99f68	247	\\[Helper-help] for help, \\[Helper-describe-bindings] for commands."))
2076c87c JB	248	(sit-for 4))
	249
	250	(defun Electric-buffer-menu-mode-view-buffer ()
	251	"View buffer on current line in Electric Buffer Menu.
5f20b653	252	Return to Electric Buffer Menu when done."
2076c87c JB	253	(interactive)
	254	(let ((bufnam (Buffer-menu-buffer nil)))
	255	(if bufnam
	256	(view-buffer bufnam)
	257	(ding)
	258	(message "Buffer %s does not exist!" bufnam)
	259	(sit-for 4))))
	260
ede8f2fe	261	(defvar electric-buffer-overlay nil)
0ae03b6a	262
ede8f2fe	263	(defun electric-buffer-update-highlight ()
0ae03b6a	264	(when (derived-mode-p 'electric-buffer-menu-mode)
080314d3 JPW	265	;; Make sure we have an overlay to use.
080314d3 JPW	266	(or electric-buffer-overlay
0ae03b6a CY	267	(set (make-local-variable 'electric-buffer-overlay)
0ae03b6a CY	268	(make-overlay (point) (point))))
080314d3	269	(move-overlay electric-buffer-overlay
5ed619e0 GM	270	(line-beginning-position)
5ed619e0 GM	271	(line-end-position))
080314d3	272	(overlay-put electric-buffer-overlay 'face 'highlight)))
ede8f2fe	273
896546cd RS	274	(provide 'ebuff-menu)
896546cd RS	275
c0274f38	276	;;; ebuff-menu.el ends here