[bpt/emacs.git] / lisp / toolbar / tool-bar.el

;;; tool-bar.el --- setting up the tool bar
;;
;; Copyright (C) 2000, 2001, 2002, 2003, 2004,
;;   2005 Free Software Foundation, Inc.
;;
;; Author: Dave Love <fx@gnu.org>
;; Keywords: mouse frames

;; This file is part of GNU Emacs.

;; GNU Emacs is free software; you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation; either version 2, or (at your option)
;; any later version.

;; GNU Emacs is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License
;; along with GNU Emacs; see the file COPYING.  If not, write to the
;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
;; Boston, MA 02110-1301, USA.

;;; Commentary:

;; Provides `tool-bar-mode' to control display of the tool-bar and
;; bindings for the global tool bar with convenience functions
;; `tool-bar-add-item' and `tool-bar-add-item-from-menu'.

;; The normal global binding for [tool-bar] (below) uses the value of
;; `tool-bar-map' as the actual keymap to define the tool bar.  Modes
;; may either bind items under the [tool-bar] prefix key of the local
;; map to add to the global bar or may set `tool-bar-map'
;; buffer-locally to override it.  (Some items are removed from the
;; global bar in modes which have `special' as their `mode-class'
;; property.)

;; Todo: Somehow make tool bars easily customizable by the naive?

;;; Code:

;;;###autoload
(define-minor-mode tool-bar-mode
  "Toggle use of the tool bar.
With numeric ARG, display the tool bar if and only if ARG is positive.

See `tool-bar-add-item' and `tool-bar-add-item-from-menu' for
conveniently adding tool bar items."
  :init-value nil
  :global t
  :group 'mouse
  :group 'frames
  (and (display-images-p)
       (let ((lines (if tool-bar-mode 1 0)))
	 ;; Alter existing frames...
	 (mapc (lambda (frame)
		 (modify-frame-parameters frame
					  (list (cons 'tool-bar-lines lines))))
	       (frame-list))
	 ;; ...and future ones.
	 (let ((elt (assq 'tool-bar-lines default-frame-alist)))
	   (if elt
	       (setcdr elt lines)
	     (add-to-list 'default-frame-alist (cons 'tool-bar-lines lines)))))
       (if (and tool-bar-mode
		(display-graphic-p)
		(= 1 (length (default-value 'tool-bar-map)))) ; not yet setup
	   (tool-bar-setup))))

;;;###autoload
;; We want to pretend the toolbar by standard is on, as this will make
;; customize consider disabling the toolbar a customization, and save
;; that.  We could do this for real by setting :init-value above, but
;; that would turn on the toolbar in MS Windows where it is currently
;; useless, and it would overwrite disabling the tool bar from X
;; resources.  If anyone want to implement this in a cleaner way,
;; please do so.
;; -- Per Abrahamsen <abraham@dina.kvl.dk> 2002-02-21.
(put 'tool-bar-mode 'standard-value '(t))

(defvar tool-bar-map (make-sparse-keymap)
  "Keymap for the tool bar.
Define this locally to override the global tool bar.")

(global-set-key [tool-bar]
		'(menu-item "tool bar" ignore
			    :filter (lambda (ignore) tool-bar-map)))

;;;###autoload
(defun tool-bar-add-item (icon def key &rest props)
  "Add an item to the tool bar.
ICON names the image, DEF is the key definition and KEY is a symbol
for the fake function key in the menu keymap.  Remaining arguments
PROPS are additional items to add to the menu item specification.  See
Info node `(elisp)Tool Bar'.  Items are added from left to right.

ICON is the base name of a file containing the image to use.  The
function will first try to use lc-ICON.xpm if display-color-cells
is less or equal to 256, then ICON.xpm, then ICON.pbm, and finally
ICON.xbm, using `find-image'.

Use this function only to make bindings in the global value of `tool-bar-map'.
To define items in any other map, use `tool-bar-local-item'."
  (apply 'tool-bar-local-item icon def key tool-bar-map props))

;;;###autoload
(defun tool-bar-local-item (icon def key map &rest props)
  "Add an item to the tool bar in map MAP.
ICON names the image, DEF is the key definition and KEY is a symbol
for the fake function key in the menu keymap.  Remaining arguments
PROPS are additional items to add to the menu item specification.  See
Info node `(elisp)Tool Bar'.  Items are added from left to right.

ICON is the base name of a file containing the image to use.  The
function will first try to use lc-ICON.xpm if display-color-cells
is less or equal to 256, then ICON.xpm, then ICON.pbm, and finally
ICON.xbm, using `find-image'."
  (let* ((fg (face-attribute 'tool-bar :foreground))
	 (bg (face-attribute 'tool-bar :background))
	 (colors (nconc (if (eq fg 'unspecified) nil (list :foreground fg))
			(if (eq bg 'unspecified) nil (list :background bg))))
	 (xpm-spec (list :type 'xpm :file (concat icon ".xpm")))
	 (xpm-lo-spec (if (> (display-color-cells) 256)
			  nil
			(list :type 'xpm :file (concat "lc-" icon ".xpm"))))
	 (pbm-spec (append (list :type 'pbm :file (concat icon ".pbm")) colors))
	 (xbm-spec (append (list :type 'xbm :file (concat icon ".xbm")) colors))
	 (image (find-image
		(if (display-color-p)
		    (list xpm-lo-spec xpm-spec pbm-spec xbm-spec)
		  (list pbm-spec xbm-spec xpm-lo-spec xpm-spec)))))

    (when (and (display-images-p) image)
      (unless (image-mask-p image)
	(setq image (append image '(:mask heuristic))))
      (define-key-after map (vector key)
	`(menu-item ,(symbol-name key) ,def :image ,image ,@props)))))

;;;###autoload
(defun tool-bar-add-item-from-menu (command icon &optional map &rest props)
  "Define tool bar binding for COMMAND using the given ICON in keymap MAP.
This makes a binding for COMMAND in `tool-bar-map', copying its
binding from the menu bar in MAP (which defaults to `global-map'), but
modifies the binding by adding an image specification for ICON.  It
finds ICON just like `tool-bar-add-item'.  PROPS are additional
properties to add to the binding.

MAP must contain appropriate binding for `[menu-bar]' which holds a keymap.

Use this function only to make bindings in the global value of `tool-bar-map'.
To define items in any other map, use `tool-bar-local-item'."
  (apply 'tool-bar-local-item-from-menu command icon
	 (default-value 'tool-bar-map) map props))

;;;###autoload
(defun tool-bar-local-item-from-menu (command icon in-map &optional from-map &rest props)
  "Define tool bar binding for COMMAND using the given ICON in keymap MAP.
This makes a binding for COMMAND in IN-MAP, copying its binding from
the menu bar in FROM-MAP (which defaults to `global-map'), but
modifies the binding by adding an image specification for ICON.  It
finds ICON just like `tool-bar-add-item'.  PROPS are additional
properties to add to the binding.

MAP must contain appropriate binding for `[menu-bar]' which holds a keymap."
  (unless from-map
    (setq from-map global-map))
  (let* ((menu-bar-map (lookup-key from-map [menu-bar]))
	 (keys (where-is-internal command menu-bar-map))
	 (fg (face-attribute 'tool-bar :foreground))
	 (bg (face-attribute 'tool-bar :background))
	 (colors (nconc (if (eq fg 'unspecified) nil (list :foreground fg))
			(if (eq bg 'unspecified) nil (list :background bg))))
	 (xpm-spec (list :type 'xpm :file (concat icon ".xpm")))
	 (xpm-lo-spec (if (> (display-color-cells) 256)
			  nil
			(list :type 'xpm :file (concat "lc-" icon ".xpm"))))
	 (pbm-spec (append (list :type 'pbm :file (concat icon ".pbm")) colors))
	 (xbm-spec (append (list :type 'xbm :file (concat icon ".xbm")) colors))
	 (spec (if (display-color-p)
		   (list xpm-lo-spec xpm-spec pbm-spec xbm-spec)
		 (list pbm-spec xbm-spec xpm-lo-spec xpm-spec)))
	 (image (find-image spec))
	 submap key)
    (when (and (display-images-p) image)
      ;; We'll pick up the last valid entry in the list of keys if
      ;; there's more than one.
      (dolist (k keys)
	;; We're looking for a binding of the command in a submap of
	;; the menu bar map, so the key sequence must be two or more
	;; long.
	(if (and (vectorp k)
		 (> (length k) 1))
	    (let ((m (lookup-key menu-bar-map (substring k 0 -1)))
		  ;; Last element in the bound key sequence:
		  (kk (aref k (1- (length k)))))
	      (if (and (keymapp m)
		       (symbolp kk))
		  (setq submap m
			key kk)))))
      (when (and (symbolp submap) (boundp submap))
	(setq submap (eval submap)))
      (unless (image-mask-p image)
	(setq image (append image '(:mask heuristic))))
      (let ((defn (assq key (cdr submap))))
	(if (eq (cadr defn) 'menu-item)
	    (define-key-after in-map (vector key)
	      (append (cdr defn) (list :image image) props))
	  (setq defn (cdr defn))
	  (define-key-after in-map (vector key)
	    (let ((rest (cdr defn)))
	      ;; If the rest of the definition starts
	      ;; with a list of menu cache info, get rid of that.
	      (if (and (consp rest) (consp (car rest)))
		  (setq rest (cdr rest)))
	      (append `(menu-item ,(car defn) ,rest)
		      (list :image image) props))))))))

;;; Set up some global items.  Additions/deletions up for grabs.

(defun tool-bar-setup ()
  ;; People say it's bad to have EXIT on the tool bar, since users
  ;; might inadvertently click that button.
  ;;(tool-bar-add-item-from-menu 'save-buffers-kill-emacs "exit")
  (tool-bar-add-item-from-menu 'find-file "new")
  (tool-bar-add-item-from-menu 'find-file-existing "open")
  (tool-bar-add-item-from-menu 'dired "diropen")
  (tool-bar-add-item-from-menu 'kill-this-buffer "close")
  (tool-bar-add-item-from-menu 'save-buffer "save" nil
			       :visible '(or buffer-file-name
					     (not (eq 'special
						      (get major-mode
							   'mode-class)))))
  (tool-bar-add-item-from-menu 'write-file "saveas" nil
			       :visible '(or buffer-file-name
					     (not (eq 'special
						      (get major-mode
							   'mode-class)))))
  (tool-bar-add-item-from-menu 'undo "undo" nil
			       :visible '(not (eq 'special (get major-mode
								'mode-class))))
  (tool-bar-add-item-from-menu (lookup-key menu-bar-edit-menu [cut])
			       "cut" nil
			       :visible '(not (eq 'special (get major-mode
								'mode-class))))
  (tool-bar-add-item-from-menu (lookup-key menu-bar-edit-menu [copy])
			       "copy")
  (tool-bar-add-item-from-menu (lookup-key menu-bar-edit-menu [paste])
			       "paste" nil
			       :visible '(not (eq 'special (get major-mode
								'mode-class))))
  (tool-bar-add-item-from-menu 'nonincremental-search-forward "search")
  ;;(tool-bar-add-item-from-menu 'ispell-buffer "spell")

  ;; There's no icon appropriate for News and we need a command rather
  ;; than a lambda for Read Mail.
  ;;(tool-bar-add-item-from-menu 'compose-mail "mail_compose")

  (tool-bar-add-item-from-menu 'print-buffer "print")
  (tool-bar-add-item "preferences" 'customize 'customize
		     :help "Edit preferences (customize)")

  (tool-bar-add-item "help" (lambda ()
			      (interactive)
			      (popup-menu menu-bar-help-menu))
		     'help
		     :help "Pop up the Help menu")
  )

(provide 'tool-bar)

;;; arch-tag: 15f30f0a-d0d7-4d50-bbb7-f48fd0c8582f
;;; tool-bar.el ends here
Commit	Line	Data
e8af40ee	1	;;; tool-bar.el --- setting up the tool bar
ec7f4585	2	;;
5fd6d89f TTN	3	;; Copyright (C) 2000, 2001, 2002, 2003, 2004,
5fd6d89f TTN	4	;; 2005 Free Software Foundation, Inc.
ec7f4585 DL	5	;;
	6	;; Author: Dave Love <fx@gnu.org>
	7	;; Keywords: mouse frames
	8
	9	;; This file is part of GNU Emacs.
	10
	11	;; GNU Emacs is free software; you can redistribute it and/or modify
	12	;; it under the terms of the GNU General Public License as published by
	13	;; the Free Software Foundation; either version 2, or (at your option)
	14	;; any later version.
	15
	16	;; GNU Emacs is distributed in the hope that it will be useful,
	17	;; but WITHOUT ANY WARRANTY; without even the implied warranty of
	18	;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
	19	;; GNU General Public License for more details.
	20
	21	;; You should have received a copy of the GNU General Public License
	22	;; along with GNU Emacs; see the file COPYING. If not, write to the
086add15 LK	23	;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
086add15 LK	24	;; Boston, MA 02110-1301, USA.
ec7f4585 DL	25
	26	;;; Commentary:
	27
02d709c0	28	;; Provides `tool-bar-mode' to control display of the tool-bar and
ec7f4585 DL	29	;; bindings for the global tool bar with convenience functions
	30	;; `tool-bar-add-item' and `tool-bar-add-item-from-menu'.
	31
9a4b8870	32	;; The normal global binding for [tool-bar] (below) uses the value of
c129b5ef DL	33	;; `tool-bar-map' as the actual keymap to define the tool bar. Modes
	34	;; may either bind items under the [tool-bar] prefix key of the local
	35	;; map to add to the global bar or may set `tool-bar-map'
b28e72df	36	;; buffer-locally to override it. (Some items are removed from the
9a4b8870	37	;; global bar in modes which have `special' as their `mode-class'
b011dcb0	38	;; property.)
9a4b8870	39
adf7d3a8 DL	40	;; Todo: Somehow make tool bars easily customizable by the naive?
adf7d3a8 DL	41
ec7f4585 DL	42	;;; Code:
	43
	44	;;;###autoload
	45	(define-minor-mode tool-bar-mode
	46	"Toggle use of the tool bar.
a81fc510	47	With numeric ARG, display the tool bar if and only if ARG is positive.
ec7f4585 DL	48
	49	See `tool-bar-add-item' and `tool-bar-add-item-from-menu' for
	50	conveniently adding tool bar items."
929e8487	51	:init-value nil
ec7f4585 DL	52	:global t
	53	:group 'mouse
	54	:group 'frames
ef32aa02 EZ	55	(and (display-images-p)
	56	(let ((lines (if tool-bar-mode 1 0)))
	57	;; Alter existing frames...
	58	(mapc (lambda (frame)
	59	(modify-frame-parameters frame
	60	(list (cons 'tool-bar-lines lines))))
	61	(frame-list))
	62	;; ...and future ones.
	63	(let ((elt (assq 'tool-bar-lines default-frame-alist)))
	64	(if elt
	65	(setcdr elt lines)
	66	(add-to-list 'default-frame-alist (cons 'tool-bar-lines lines)))))
	67	(if (and tool-bar-mode
	68	(display-graphic-p)
	69	(= 1 (length (default-value 'tool-bar-map)))) ; not yet setup
	70	(tool-bar-setup))))
ec7f4585	71
929e8487 PA	72	;;;###autoload
	73	;; We want to pretend the toolbar by standard is on, as this will make
	74	;; customize consider disabling the toolbar a customization, and save
	75	;; that. We could do this for real by setting :init-value above, but
	76	;; that would turn on the toolbar in MS Windows where it is currently
	77	;; useless, and it would overwrite disabling the tool bar from X
	78	;; resources. If anyone want to implement this in a cleaner way,
	79	;; please do so.
	80	;; -- Per Abrahamsen <abraham@dina.kvl.dk> 2002-02-21.
	81	(put 'tool-bar-mode 'standard-value '(t))
	82
9a4b8870 DL	83	(defvar tool-bar-map (make-sparse-keymap)
	84	"Keymap for the tool bar.
	85	Define this locally to override the global tool bar.")
	86
	87	(global-set-key [tool-bar]
	88	'(menu-item "tool bar" ignore
	89	:filter (lambda (ignore) tool-bar-map)))
ec7f4585 DL	90
ec7f4585 DL	91	;;;###autoload
9a4b8870	92	(defun tool-bar-add-item (icon def key &rest props)
ec7f4585 DL	93	"Add an item to the tool bar.
ec7f4585 DL	94	ICON names the image, DEF is the key definition and KEY is a symbol
9a4b8870 DL	95	for the fake function key in the menu keymap. Remaining arguments
	96	PROPS are additional items to add to the menu item specification. See
	97	Info node `(elisp)Tool Bar'. Items are added from left to right.
ec7f4585	98
cb4aae04	99	ICON is the base name of a file containing the image to use. The
aa8a805e	100	function will first try to use lc-ICON.xpm if display-color-cells
968d6127	101	is less or equal to 256, then ICON.xpm, then ICON.pbm, and finally
cb4aae04	102	ICON.xbm, using `find-image'.
9a4b8870	103
ca1b34c8 RS	104	Use this function only to make bindings in the global value of `tool-bar-map'.
	105	To define items in any other map, use `tool-bar-local-item'."
	106	(apply 'tool-bar-local-item icon def key tool-bar-map props))
	107
	108	;;;###autoload
	109	(defun tool-bar-local-item (icon def key map &rest props)
	110	"Add an item to the tool bar in map MAP.
	111	ICON names the image, DEF is the key definition and KEY is a symbol
	112	for the fake function key in the menu keymap. Remaining arguments
	113	PROPS are additional items to add to the menu item specification. See
	114	Info node `(elisp)Tool Bar'. Items are added from left to right.
	115
	116	ICON is the base name of a file containing the image to use. The
aa8a805e	117	function will first try to use lc-ICON.xpm if display-color-cells
968d6127	118	is less or equal to 256, then ICON.xpm, then ICON.pbm, and finally
ca1b34c8	119	ICON.xbm, using `find-image'."
3fae165c GM	120	(let* ((fg (face-attribute 'tool-bar :foreground))
	121	(bg (face-attribute 'tool-bar :background))
	122	(colors (nconc (if (eq fg 'unspecified) nil (list :foreground fg))
	123	(if (eq bg 'unspecified) nil (list :background bg))))
cf545823 JD	124	(xpm-spec (list :type 'xpm :file (concat icon ".xpm")))
	125	(xpm-lo-spec (if (> (display-color-cells) 256)
	126	nil
aa8a805e	127	(list :type 'xpm :file (concat "lc-" icon ".xpm"))))
cf545823 JD	128	(pbm-spec (append (list :type 'pbm :file (concat icon ".pbm")) colors))
cf545823 JD	129	(xbm-spec (append (list :type 'xbm :file (concat icon ".xbm")) colors))
3b6d80f1	130	(image (find-image
34e86ea3	131	(if (display-color-p)
cf545823 JD	132	(list xpm-lo-spec xpm-spec pbm-spec xbm-spec)
	133	(list pbm-spec xbm-spec xpm-lo-spec xpm-spec)))))
	134
196de866	135	(when (and (display-images-p) image)
ec7f4585 DL	136	(unless (image-mask-p image)
ec7f4585 DL	137	(setq image (append image '(:mask heuristic))))
ca1b34c8	138	(define-key-after map (vector key)
ec7f4585 DL	139	`(menu-item ,(symbol-name key) ,def :image ,image ,@props)))))
ec7f4585 DL	140
c2156508	141	;;;###autoload
ec7f4585 DL	142	(defun tool-bar-add-item-from-menu (command icon &optional map &rest props)
ec7f4585 DL	143	"Define tool bar binding for COMMAND using the given ICON in keymap MAP.
ca1b34c8 RS	144	This makes a binding for COMMAND in `tool-bar-map', copying its
	145	binding from the menu bar in MAP (which defaults to `global-map'), but
	146	modifies the binding by adding an image specification for ICON. It
	147	finds ICON just like `tool-bar-add-item'. PROPS are additional
	148	properties to add to the binding.
	149
	150	MAP must contain appropriate binding for `[menu-bar]' which holds a keymap.
	151
	152	Use this function only to make bindings in the global value of `tool-bar-map'.
	153	To define items in any other map, use `tool-bar-local-item'."
03a8bf7d SM	154	(apply 'tool-bar-local-item-from-menu command icon
03a8bf7d SM	155	(default-value 'tool-bar-map) map props))
ca1b34c8 RS	156
	157	;;;###autoload
	158	(defun tool-bar-local-item-from-menu (command icon in-map &optional from-map &rest props)
	159	"Define tool bar binding for COMMAND using the given ICON in keymap MAP.
	160	This makes a binding for COMMAND in IN-MAP, copying its binding from
	161	the menu bar in FROM-MAP (which defaults to `global-map'), but
	162	modifies the binding by adding an image specification for ICON. It
	163	finds ICON just like `tool-bar-add-item'. PROPS are additional
	164	properties to add to the binding.
	165
	166	MAP must contain appropriate binding for `[menu-bar]' which holds a keymap."
	167	(unless from-map
	168	(setq from-map global-map))
	169	(let* ((menu-bar-map (lookup-key from-map [menu-bar]))
ec7f4585	170	(keys (where-is-internal command menu-bar-map))
3fae165c GM	171	(fg (face-attribute 'tool-bar :foreground))
	172	(bg (face-attribute 'tool-bar :background))
	173	(colors (nconc (if (eq fg 'unspecified) nil (list :foreground fg))
	174	(if (eq bg 'unspecified) nil (list :background bg))))
cf545823 JD	175	(xpm-spec (list :type 'xpm :file (concat icon ".xpm")))
	176	(xpm-lo-spec (if (> (display-color-cells) 256)
	177	nil
aa8a805e	178	(list :type 'xpm :file (concat "lc-" icon ".xpm"))))
cf545823 JD	179	(pbm-spec (append (list :type 'pbm :file (concat icon ".pbm")) colors))
cf545823 JD	180	(xbm-spec (append (list :type 'xbm :file (concat icon ".xbm")) colors))
7e636904	181	(spec (if (display-color-p)
cf545823 JD	182	(list xpm-lo-spec xpm-spec pbm-spec xbm-spec)
cf545823 JD	183	(list pbm-spec xbm-spec xpm-lo-spec xpm-spec)))
7e636904	184	(image (find-image spec))
ec7f4585	185	submap key)
196de866	186	(when (and (display-images-p) image)
ec7f4585 DL	187	;; We'll pick up the last valid entry in the list of keys if
	188	;; there's more than one.
	189	(dolist (k keys)
	190	;; We're looking for a binding of the command in a submap of
	191	;; the menu bar map, so the key sequence must be two or more
	192	;; long.
	193	(if (and (vectorp k)
	194	(> (length k) 1))
	195	(let ((m (lookup-key menu-bar-map (substring k 0 -1)))
	196	;; Last element in the bound key sequence:
	197	(kk (aref k (1- (length k)))))
	198	(if (and (keymapp m)
	199	(symbolp kk))
	200	(setq submap m
	201	key kk)))))
	202	(when (and (symbolp submap) (boundp submap))
	203	(setq submap (eval submap)))
ddba99ad MB	204	(unless (image-mask-p image)
ddba99ad MB	205	(setq image (append image '(:mask heuristic))))
98a8938c GM	206	(let ((defn (assq key (cdr submap))))
98a8938c GM	207	(if (eq (cadr defn) 'menu-item)
ca1b34c8	208	(define-key-after in-map (vector key)
98a8938c GM	209	(append (cdr defn) (list :image image) props))
98a8938c GM	210	(setq defn (cdr defn))
ca1b34c8	211	(define-key-after in-map (vector key)
2fab4328 RS	212	(let ((rest (cdr defn)))
	213	;; If the rest of the definition starts
	214	;; with a list of menu cache info, get rid of that.
	215	(if (and (consp rest) (consp (car rest)))
	216	(setq rest (cdr rest)))
	217	(append `(menu-item ,(car defn) ,rest)
	218	(list :image image) props))))))))
ec7f4585 DL	219
	220	;;; Set up some global items. Additions/deletions up for grabs.
	221
ebd4825d	222	(defun tool-bar-setup ()
7a03d9cd EZ	223	;; People say it's bad to have EXIT on the tool bar, since users
	224	;; might inadvertently click that button.
	225	;;(tool-bar-add-item-from-menu 'save-buffers-kill-emacs "exit")
ebd4825d	226	(tool-bar-add-item-from-menu 'find-file "new")
95ec60bc JD	227	(tool-bar-add-item-from-menu 'find-file-existing "open")
95ec60bc JD	228	(tool-bar-add-item-from-menu 'dired "diropen")
ebd4825d DL	229	(tool-bar-add-item-from-menu 'kill-this-buffer "close")
ebd4825d DL	230	(tool-bar-add-item-from-menu 'save-buffer "save" nil
5ec17636 DL	231	:visible '(or buffer-file-name
	232	(not (eq 'special
	233	(get major-mode
	234	'mode-class)))))
ebd4825d	235	(tool-bar-add-item-from-menu 'write-file "saveas" nil
5ec17636 DL	236	:visible '(or buffer-file-name
	237	(not (eq 'special
	238	(get major-mode
	239	'mode-class)))))
ebd4825d DL	240	(tool-bar-add-item-from-menu 'undo "undo" nil
	241	:visible '(not (eq 'special (get major-mode
	242	'mode-class))))
0928a1d8 JD	243	(tool-bar-add-item-from-menu (lookup-key menu-bar-edit-menu [cut])
0928a1d8 JD	244	"cut" nil
ebd4825d DL	245	:visible '(not (eq 'special (get major-mode
ebd4825d DL	246	'mode-class))))
0928a1d8 JD	247	(tool-bar-add-item-from-menu (lookup-key menu-bar-edit-menu [copy])
	248	"copy")
	249	(tool-bar-add-item-from-menu (lookup-key menu-bar-edit-menu [paste])
	250	"paste" nil
ebd4825d DL	251	:visible '(not (eq 'special (get major-mode
	252	'mode-class))))
	253	(tool-bar-add-item-from-menu 'nonincremental-search-forward "search")
	254	;;(tool-bar-add-item-from-menu 'ispell-buffer "spell")
	255
	256	;; There's no icon appropriate for News and we need a command rather
	257	;; than a lambda for Read Mail.
	258	;;(tool-bar-add-item-from-menu 'compose-mail "mail_compose")
	259
	260	(tool-bar-add-item-from-menu 'print-buffer "print")
9a4b8870	261	(tool-bar-add-item "preferences" 'customize 'customize
ebd4825d DL	262	:help "Edit preferences (customize)")
ebd4825d DL	263
9a4b8870 DL	264	(tool-bar-add-item "help" (lambda ()
	265	(interactive)
	266	(popup-menu menu-bar-help-menu))
	267	'help
	268	:help "Pop up the Help menu")
ebd4825d	269	)
ec7f4585 DL	270
	271	(provide 'tool-bar)
	272
ab5796a9	273	;;; arch-tag: 15f30f0a-d0d7-4d50-bbb7-f48fd0c8582f
ec7f4585	274	;;; tool-bar.el ends here