[bpt/emacs.git] / lisp / eshell / em-glob.el

;;; em-glob.el --- extended file name globbing

;; Copyright (C) 1999, 2000, 2001, 2002, 2003, 2004,
;;   2005, 2006, 2007 Free Software Foundation, Inc.

;; Author: John Wiegley <johnw@gnu.org>

;; This file is part of GNU Emacs.

;; GNU Emacs is free software; you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation; either version 2, or (at your option)
;; any later version.

;; GNU Emacs is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License
;; along with GNU Emacs; see the file COPYING.  If not, write to the
;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
;; Boston, MA 02110-1301, USA.

;;; Code:

(provide 'em-glob)

(eval-when-compile (require 'esh-maint))
(require 'esh-util)

(defgroup eshell-glob nil
  "This module provides extended globbing syntax, similar what is used
by zsh for filename generation."
  :tag "Extended filename globbing"
  :group 'eshell-module)

;;; Commentary:

;; The globbing code used by Eshell closely follows the syntax used by
;; zsh.  Basically, here is a summary of examples:
;;
;;   echo a*       ; anything starting with 'a'
;;   echo a#b      ; zero or more 'a's, then 'b'
;;   echo a##b     ; one or more 'a's, then 'b'
;;   echo a?       ; a followed by any character
;;   echo a*~ab    ; 'a', then anything, but not 'ab'
;;   echo c*~*~    ; all files beginning with 'c', except backups (*~)
;;
;; Recursive globbing is also supported:
;;
;;   echo **/*.c   ; all '.c' files at or under current directory
;;   echo ***/*.c  ; same as above, but traverse symbolic links
;;
;; Using argument predication, the recursive globbing syntax is
;; sufficient to replace the use of 'find <expr> | xargs <cmd>' in
;; most cases.  For example, to change the readership of all files
;; belonging to 'johnw' in the '/tmp' directory or lower, use:
;;
;;   chmod go-r /tmp/**/*(u'johnw')
;;
;; The glob above matches all of the files beneath '/tmp' that are
;; owned by the user 'johnw'.  See [Value modifiers and predicates],
;; for more information about argument predication.

;;; User Variables:

(defcustom eshell-glob-load-hook '(eshell-glob-initialize)
  "*A list of functions to run when `eshell-glob' is loaded."
  :type 'hook
  :group 'eshell-glob)

(defcustom eshell-glob-include-dot-files nil
  "*If non-nil, glob patterns will match files beginning with a dot."
  :type 'boolean
  :group 'eshell-glob)

(defcustom eshell-glob-include-dot-dot t
  "*If non-nil, glob patterns that match dots will match . and .."
  :type 'boolean
  :group 'eshell-glob)

(defcustom eshell-glob-case-insensitive (eshell-under-windows-p)
  "*If non-nil, glob pattern matching will ignore case."
  :type 'boolean
  :group 'eshell-glob)

(defcustom eshell-glob-show-progress nil
  "*If non-nil, display progress messages during a recursive glob.
This option slows down recursive glob processing by quite a bit."
  :type 'boolean
  :group 'eshell-glob)

(defcustom eshell-error-if-no-glob nil
  "*If non-nil, it is an error for a glob pattern not to match.
 This mimcs the behavior of zsh if non-nil, but bash if nil."
  :type 'boolean
  :group 'eshell-glob)

(defcustom eshell-glob-chars-list '(?\] ?\[ ?* ?? ?~ ?\( ?\) ?| ?# ?^)
  "*List of additional characters used in extended globbing."
  :type '(repeat character)
  :group 'eshell-glob)

(defcustom eshell-glob-translate-alist
  '((?\] . "]")
    (?\[ . "[")
    (?^  . "^")
    (??  . ".")
    (?*  . ".*")
    (?~  . "~")
    (?\( . "\\(")
    (?\) . "\\)")
    (?\| . "\\|")
    (?#  . (lambda (str pos)
	     (if (and (< (1+ pos) (length str))
		      (memq (aref str (1+ pos)) '(?* ?# ?+ ??)))
		 (cons (if (eq (aref str (1+ pos)) ??)
			   "?"
			 (if (eq (aref str (1+ pos)) ?*)
			     "*" "+")) (+ pos 2))
	       (cons "*" (1+ pos))))))
  "*An alist for translation of extended globbing characters."
  :type '(repeat (cons character (choice regexp function)))
  :group 'eshell-glob)

;;; Functions:

(defun eshell-glob-initialize ()
  "Initialize the extended globbing code."
  ;; it's important that `eshell-glob-chars-list' come first
  (when (boundp 'eshell-special-chars-outside-quoting)
    (set (make-local-variable 'eshell-special-chars-outside-quoting)
	 (append eshell-glob-chars-list eshell-special-chars-outside-quoting)))
  (add-hook 'eshell-parse-argument-hook 'eshell-parse-glob-chars t t)
  (add-hook 'eshell-pre-rewrite-command-hook
	    'eshell-no-command-globbing nil t))

(defun eshell-no-command-globbing (terms)
  "Don't glob the command argument.  Reflect this by modifying TERMS."
  (ignore
   (when (and (listp (car terms))
	      (eq (caar terms) 'eshell-extended-glob))
     (setcar terms (cadr (car terms))))))

(defun eshell-add-glob-modifier ()
  "Add `eshell-extended-glob' to the argument modifier list."
  (when (memq 'expand-file-name eshell-current-modifiers)
    (setq eshell-current-modifiers
	  (delq 'expand-file-name eshell-current-modifiers))
    ;; if this is a glob pattern than needs to be expanded, then it
    ;; will need to expand each member of the resulting glob list
    (add-to-list 'eshell-current-modifiers
		 '(lambda (list)
		    (if (listp list)
			(mapcar 'expand-file-name list)
		      (expand-file-name list)))))
  (add-to-list 'eshell-current-modifiers 'eshell-extended-glob))

(defun eshell-parse-glob-chars ()
  "Parse a globbing delimiter.
The character is not advanced for ordinary globbing characters, so
that other function may have a chance to override the globbing
interpretation."
  (when (memq (char-after) eshell-glob-chars-list)
    (if (not (memq (char-after) '(?\( ?\[)))
	(ignore (eshell-add-glob-modifier))
      (let ((here (point)))
	(forward-char)
	(let* ((delim (char-before))
	       (end (eshell-find-delimiter
		     delim (if (eq delim ?\[) ?\] ?\)))))
	  (if (not end)
	      (throw 'eshell-incomplete delim)
	    (if (and (eshell-using-module 'eshell-pred)
		     (eshell-arg-delimiter (1+ end)))
		(ignore (goto-char here))
	      (eshell-add-glob-modifier)
	      (prog1
		  (buffer-substring-no-properties (1- (point)) (1+ end))
		(goto-char (1+ end))))))))))

(defvar eshell-glob-chars-regexp nil)

(defun eshell-glob-regexp (pattern)
  "Convert glob-pattern PATTERN to a regular expression.
The basic syntax is:

  glob  regexp   meaning
  ----  ------   -------
  ?      .       matches any single character
  *      .*      matches any group of characters (or none)
  #      *       matches zero or more occurrences of preceding
  ##     +       matches one or more occurrences of preceding
  (x)    \(x\)   makes 'x' a regular expression group
  |      \|      boolean OR within an expression group
  [a-b]  [a-b]   matches a character or range
  [^a]   [^a]    excludes a character or range

If any characters in PATTERN have the text property `eshell-escaped'
set to true, then these characters will match themselves in the
resulting regular expression."
  (let ((matched-in-pattern 0)          ; How much of PATTERN handled
	regexp)
    (while (string-match
	    (or eshell-glob-chars-regexp
		(set (make-local-variable 'eshell-glob-chars-regexp)
		     (format "[%s]+" (apply 'string eshell-glob-chars-list))))
	    pattern matched-in-pattern)
      (let* ((op-begin (match-beginning 0))
	     (op-char (aref pattern op-begin)))
	(setq regexp
	      (concat regexp
		      (regexp-quote
		       (substring pattern matched-in-pattern op-begin))))
	(if (get-text-property op-begin 'escaped pattern)
	    (setq regexp (concat regexp
				 (regexp-quote (char-to-string op-char)))
		  matched-in-pattern (1+ op-begin))
	  (let ((xlat (assq op-char eshell-glob-translate-alist)))
	    (if (not xlat)
		(error "Unrecognized globbing character '%c'" op-char)
	      (if (stringp (cdr xlat))
		  (setq regexp (concat regexp (cdr xlat))
			matched-in-pattern (1+ op-begin))
		(let ((result (funcall (cdr xlat) pattern op-begin)))
		  (setq regexp (concat regexp (car result))
			matched-in-pattern (cdr result)))))))))
    (concat "\\`"
	    regexp
	    (regexp-quote (substring pattern matched-in-pattern))
	    "\\'")))

(defun eshell-extended-glob (glob)
  "Return a list of files generated from GLOB, perhaps looking for DIRS-ONLY.
This function almost fully supports zsh style filename generation
syntax.  Things that are not supported are:

   ^foo        for matching everything but foo
   (foo~bar)   tilde within a parenthesis group
   foo<1-10>   numeric ranges
   foo~x(a|b)  (a|b) will be interpreted as a predicate/modifier list

Mainly they are not supported because file matching is done with Emacs
regular expressions, and these cannot support the above constructs.

If this routine fails, it returns nil.  Otherwise, it returns a list
the form:

   (INCLUDE-REGEXP EXCLUDE-REGEXP (PRED-FUNC-LIST) (MOD-FUNC-LIST))"
  (let ((paths (eshell-split-path glob))
	matches message-shown ange-cache)
    (unwind-protect
	(if (and (cdr paths)
		 (file-name-absolute-p (car paths)))
	    (eshell-glob-entries (file-name-as-directory (car paths))
				 (cdr paths))
	  (eshell-glob-entries (file-name-as-directory ".") paths))
      (if message-shown
	  (message nil)))
    (or (and matches (nreverse matches))
	(if eshell-error-if-no-glob
	    (error "No matches found: %s" glob)
	  glob))))

(eval-when-compile
  (defvar matches)
  (defvar message-shown))

(defun eshell-glob-entries (path globs &optional recurse-p)
  "Glob the entries in PATHS, possibly recursing if RECURSE-P is non-nil."
  (let* ((entries (ignore-errors
		    (file-name-all-completions "" path)))
	 (case-fold-search eshell-glob-case-insensitive)
	 (glob (car globs))
	 (len (length glob))
	 dirs rdirs
	 incl excl
	 name isdir pathname)
    (while (cond
	    ((and (= len 3) (equal glob "**/"))
	     (setq recurse-p 2
		   globs (cdr globs)
		   glob (car globs)
		   len (length glob)))
	    ((and (= len 4) (equal glob "***/"))
	     (setq recurse-p 3
		   globs (cdr globs)
		   glob (car globs)
		   len (length glob)))))
    (if (and recurse-p (not glob))
	(error "'**' cannot end a globbing pattern"))
    (let ((index 1))
      (setq incl glob)
      (while (and (eq incl glob)
		  (setq index (string-match "~" glob index)))
	(if (or (get-text-property index 'escaped glob)
		(or (= (1+ index) len)))
	    (setq index (1+ index))
	  (setq incl (substring glob 0 index)
		excl (substring glob (1+ index))))))
    ;; can't use `directory-file-name' because it strips away text
    ;; properties in the string
    (let ((len (1- (length incl))))
      (if (eq (aref incl len) ?/)
	  (setq incl (substring incl 0 len)))
      (when excl
	(setq len (1- (length excl)))
	(if (eq (aref excl len) ?/)
	    (setq excl (substring excl 0 len)))))
    (setq incl (eshell-glob-regexp incl)
	  excl (and excl (eshell-glob-regexp excl)))
    (if (or eshell-glob-include-dot-files
	    (eq (aref glob 0) ?.))
	(unless (or eshell-glob-include-dot-dot
		    (cdr globs))
	  (setq excl (if excl
			 (concat "\\(\\`\\.\\.?\\'\\|" excl "\\)")
		       "\\`\\.\\.?\\'")))
      (setq excl (if excl
		     (concat "\\(\\`\\.\\|" excl "\\)")
		   "\\`\\.")))
    (when (and recurse-p eshell-glob-show-progress)
      (message "Building file list...%d so far: %s"
	       (length matches) path)
      (setq message-shown t))
    (if (equal path "./") (setq path ""))
    (while entries
      (setq name (car entries)
	    len (length name)
	    isdir (eq (aref name (1- len)) ?/))
      (if (let ((fname (directory-file-name name)))
	    (and (not (and excl (string-match excl fname)))
		 (string-match incl fname)))
	  (if (cdr globs)
	      (if isdir
		  (setq dirs (cons (concat path name) dirs)))
	    (setq matches (cons (concat path name) matches))))
      (if (and recurse-p isdir
	       (or (> len 3)
		   (not (or (and (= len 2) (equal name "./"))
			    (and (= len 3) (equal name "../")))))
	       (setq pathname (concat path name))
	       (not (and (= recurse-p 2)
			 (file-symlink-p
			  (directory-file-name pathname)))))
	  (setq rdirs (cons pathname rdirs)))
      (setq entries (cdr entries)))
    (setq dirs (nreverse dirs)
	  rdirs (nreverse rdirs))
    (while dirs
      (eshell-glob-entries (car dirs) (cdr globs))
      (setq dirs (cdr dirs)))
    (while rdirs
      (eshell-glob-entries (car rdirs) globs recurse-p)
      (setq rdirs (cdr rdirs)))))

;;; arch-tag: d0548f54-fb7c-4978-a88e-f7c26f7f68ca
;;; em-glob.el ends here
Commit	Line	Data
60370d40	1	;;; em-glob.el --- extended file name globbing
affbf647	2
f2e3589a	3	;; Copyright (C) 1999, 2000, 2001, 2002, 2003, 2004,
f0fa15c5	4	;; 2005, 2006, 2007 Free Software Foundation, Inc.
affbf647	5
7de5b421 GM	6	;; Author: John Wiegley <johnw@gnu.org>
7de5b421 GM	7
affbf647 GM	8	;; This file is part of GNU Emacs.
	9
	10	;; GNU Emacs is free software; you can redistribute it and/or modify
	11	;; it under the terms of the GNU General Public License as published by
	12	;; the Free Software Foundation; either version 2, or (at your option)
	13	;; any later version.
	14
	15	;; GNU Emacs is distributed in the hope that it will be useful,
	16	;; but WITHOUT ANY WARRANTY; without even the implied warranty of
	17	;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
	18	;; GNU General Public License for more details.
	19
	20	;; You should have received a copy of the GNU General Public License
	21	;; along with GNU Emacs; see the file COPYING. If not, write to the
3a35cf56 LK	22	;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
3a35cf56 LK	23	;; Boston, MA 02110-1301, USA.
affbf647	24
6d736b08 SM	25	;;; Code:
6d736b08 SM	26
affbf647 GM	27	(provide 'em-glob)
	28
	29	(eval-when-compile (require 'esh-maint))
6d736b08	30	(require 'esh-util)
affbf647 GM	31
	32	(defgroup eshell-glob nil
	33	"This module provides extended globbing syntax, similar what is used
	34	by zsh for filename generation."
	35	:tag "Extended filename globbing"
	36	:group 'eshell-module)
	37
	38	;;; Commentary:
	39
	40	;; The globbing code used by Eshell closely follows the syntax used by
	41	;; zsh. Basically, here is a summary of examples:
	42	;;
	43	;; echo a* ; anything starting with 'a'
	44	;; echo a#b ; zero or more 'a's, then 'b'
	45	;; echo a##b ; one or more 'a's, then 'b'
	46	;; echo a? ; a followed by any character
	47	;; echo a*~ab ; 'a', then anything, but not 'ab'
	48	;; echo c~~ ; all files beginning with 'c', except backups (*~)
	49	;;
	50	;; Recursive globbing is also supported:
	51	;;
	52	;; echo */.c ; all '.c' files at or under current directory
	53	;; echo **/.c ; same as above, but traverse symbolic links
	54	;;
	55	;; Using argument predication, the recursive globbing syntax is
	56	;; sufficient to replace the use of 'find <expr> \| xargs <cmd>' in
	57	;; most cases. For example, to change the readership of all files
	58	;; belonging to 'johnw' in the '/tmp' directory or lower, use:
	59	;;
	60	;; chmod go-r /tmp/*/(u'johnw')
	61	;;
	62	;; The glob above matches all of the files beneath '/tmp' that are
	63	;; owned by the user 'johnw'. See [Value modifiers and predicates],
	64	;; for more information about argument predication.
	65
	66	;;; User Variables:
	67
	68	(defcustom eshell-glob-load-hook '(eshell-glob-initialize)
	69	"*A list of functions to run when `eshell-glob' is loaded."
	70	:type 'hook
	71	:group 'eshell-glob)
	72
	73	(defcustom eshell-glob-include-dot-files nil
	74	"*If non-nil, glob patterns will match files beginning with a dot."
	75	:type 'boolean
	76	:group 'eshell-glob)
	77
	78	(defcustom eshell-glob-include-dot-dot t
	79	"*If non-nil, glob patterns that match dots will match . and .."
	80	:type 'boolean
	81	:group 'eshell-glob)
	82
70a06174	83	(defcustom eshell-glob-case-insensitive (eshell-under-windows-p)
affbf647 GM	84	"*If non-nil, glob pattern matching will ignore case."
	85	:type 'boolean
	86	:group 'eshell-glob)
	87
dace60cf JW	88	(defcustom eshell-glob-show-progress nil
	89	"*If non-nil, display progress messages during a recursive glob.
	90	This option slows down recursive glob processing by quite a bit."
affbf647 GM	91	:type 'boolean
	92	:group 'eshell-glob)
	93
	94	(defcustom eshell-error-if-no-glob nil
	95	"*If non-nil, it is an error for a glob pattern not to match.
	96	This mimcs the behavior of zsh if non-nil, but bash if nil."
	97	:type 'boolean
	98	:group 'eshell-glob)
	99
f80c9382	100	(defcustom eshell-glob-chars-list '(?\] ?\[ ?* ?? ?~ ?\( ?\) ?\| ?# ?^)
affbf647 GM	101	"*List of additional characters used in extended globbing."
	102	:type '(repeat character)
	103	:group 'eshell-glob)
	104
	105	(defcustom eshell-glob-translate-alist
	106	'((?\] . "]")
	107	(?\[ . "[")
f80c9382	108	(?^ . "^")
affbf647 GM	109	(?? . ".")
	110	(?* . ".*")
	111	(?~ . "~")
	112	(?\( . "\\(")
	113	(?\) . "\\)")
	114	(?\\| . "\\\|")
	115	(?# . (lambda (str pos)
	116	(if (and (< (1+ pos) (length str))
	117	(memq (aref str (1+ pos)) '(?* ?# ?+ ??)))
	118	(cons (if (eq (aref str (1+ pos)) ??)
	119	"?"
	120	(if (eq (aref str (1+ pos)) ?*)
	121	"*" "+")) (+ pos 2))
	122	(cons "*" (1+ pos))))))
	123	"*An alist for translation of extended globbing characters."
	124	:type '(repeat (cons character (choice regexp function)))
	125	:group 'eshell-glob)
	126
affbf647 GM	127	;;; Functions:
	128
	129	(defun eshell-glob-initialize ()
	130	"Initialize the extended globbing code."
	131	;; it's important that `eshell-glob-chars-list' come first
6d736b08 SM	132	(when (boundp 'eshell-special-chars-outside-quoting)
	133	(set (make-local-variable 'eshell-special-chars-outside-quoting)
	134	(append eshell-glob-chars-list eshell-special-chars-outside-quoting)))
affbf647	135	(add-hook 'eshell-parse-argument-hook 'eshell-parse-glob-chars t t)
affbf647 GM	136	(add-hook 'eshell-pre-rewrite-command-hook
	137	'eshell-no-command-globbing nil t))
	138
	139	(defun eshell-no-command-globbing (terms)
	140	"Don't glob the command argument. Reflect this by modifying TERMS."
	141	(ignore
	142	(when (and (listp (car terms))
	143	(eq (caar terms) 'eshell-extended-glob))
	144	(setcar terms (cadr (car terms))))))
	145
	146	(defun eshell-add-glob-modifier ()
	147	"Add `eshell-extended-glob' to the argument modifier list."
	148	(when (memq 'expand-file-name eshell-current-modifiers)
	149	(setq eshell-current-modifiers
	150	(delq 'expand-file-name eshell-current-modifiers))
	151	;; if this is a glob pattern than needs to be expanded, then it
	152	;; will need to expand each member of the resulting glob list
	153	(add-to-list 'eshell-current-modifiers
	154	'(lambda (list)
	155	(if (listp list)
	156	(mapcar 'expand-file-name list)
	157	(expand-file-name list)))))
	158	(add-to-list 'eshell-current-modifiers 'eshell-extended-glob))
	159
	160	(defun eshell-parse-glob-chars ()
	161	"Parse a globbing delimiter.
	162	The character is not advanced for ordinary globbing characters, so
	163	that other function may have a chance to override the globbing
	164	interpretation."
	165	(when (memq (char-after) eshell-glob-chars-list)
	166	(if (not (memq (char-after) '(?\( ?\[)))
	167	(ignore (eshell-add-glob-modifier))
	168	(let ((here (point)))
	169	(forward-char)
	170	(let* ((delim (char-before))
	171	(end (eshell-find-delimiter
	172	delim (if (eq delim ?\[) ?\] ?\)))))
	173	(if (not end)
	174	(throw 'eshell-incomplete delim)
	175	(if (and (eshell-using-module 'eshell-pred)
	176	(eshell-arg-delimiter (1+ end)))
	177	(ignore (goto-char here))
	178	(eshell-add-glob-modifier)
	179	(prog1
	180	(buffer-substring-no-properties (1- (point)) (1+ end))
	181	(goto-char (1+ end))))))))))
	182
4403b1e1 JW	183	(defvar eshell-glob-chars-regexp nil)
4403b1e1 JW	184
affbf647 GM	185	(defun eshell-glob-regexp (pattern)
	186	"Convert glob-pattern PATTERN to a regular expression.
	187	The basic syntax is:
	188
	189	glob regexp meaning
	190	---- ------ -------
	191	? . matches any single character
	192	* .* matches any group of characters (or none)
	193	# * matches zero or more occurrences of preceding
	194	## + matches one or more occurrences of preceding
	195	(x) \(x\) makes 'x' a regular expression group
	196	\| \\| boolean OR within an expression group
	197	[a-b] [a-b] matches a character or range
	198	[^a] [^a] excludes a character or range
	199
	200	If any characters in PATTERN have the text property `eshell-escaped'
	201	set to true, then these characters will match themselves in the
	202	resulting regular expression."
	203	(let ((matched-in-pattern 0) ; How much of PATTERN handled
	204	regexp)
4403b1e1 JW	205	(while (string-match
	206	(or eshell-glob-chars-regexp
	207	(set (make-local-variable 'eshell-glob-chars-regexp)
	208	(format "[%s]+" (apply 'string eshell-glob-chars-list))))
	209	pattern matched-in-pattern)
affbf647 GM	210	(let* ((op-begin (match-beginning 0))
	211	(op-char (aref pattern op-begin)))
	212	(setq regexp
	213	(concat regexp
	214	(regexp-quote
	215	(substring pattern matched-in-pattern op-begin))))
	216	(if (get-text-property op-begin 'escaped pattern)
	217	(setq regexp (concat regexp
	218	(regexp-quote (char-to-string op-char)))
	219	matched-in-pattern (1+ op-begin))
	220	(let ((xlat (assq op-char eshell-glob-translate-alist)))
	221	(if (not xlat)
	222	(error "Unrecognized globbing character '%c'" op-char)
	223	(if (stringp (cdr xlat))
	224	(setq regexp (concat regexp (cdr xlat))
	225	matched-in-pattern (1+ op-begin))
	226	(let ((result (funcall (cdr xlat) pattern op-begin)))
	227	(setq regexp (concat regexp (car result))
	228	matched-in-pattern (cdr result)))))))))
	229	(concat "\\`"
	230	regexp
	231	(regexp-quote (substring pattern matched-in-pattern))
	232	"\\'")))
	233
	234	(defun eshell-extended-glob (glob)
	235	"Return a list of files generated from GLOB, perhaps looking for DIRS-ONLY.
6d736b08 SM	236	This function almost fully supports zsh style filename generation
6d736b08 SM	237	syntax. Things that are not supported are:
affbf647 GM	238
	239	^foo for matching everything but foo
	240	(foo~bar) tilde within a parenthesis group
	241	foo<1-10> numeric ranges
	242	foo~x(a\|b) (a\|b) will be interpreted as a predicate/modifier list
	243
6d736b08 SM	244	Mainly they are not supported because file matching is done with Emacs
6d736b08 SM	245	regular expressions, and these cannot support the above constructs.
affbf647	246
6d736b08 SM	247	If this routine fails, it returns nil. Otherwise, it returns a list
6d736b08 SM	248	the form:
affbf647 GM	249
	250	(INCLUDE-REGEXP EXCLUDE-REGEXP (PRED-FUNC-LIST) (MOD-FUNC-LIST))"
	251	(let ((paths (eshell-split-path glob))
8c6b1d83	252	matches message-shown ange-cache)
affbf647 GM	253	(unwind-protect
	254	(if (and (cdr paths)
	255	(file-name-absolute-p (car paths)))
	256	(eshell-glob-entries (file-name-as-directory (car paths))
	257	(cdr paths))
dbc56a8b	258	(eshell-glob-entries (file-name-as-directory ".") paths))
affbf647 GM	259	(if message-shown
	260	(message nil)))
	261	(or (and matches (nreverse matches))
	262	(if eshell-error-if-no-glob
	263	(error "No matches found: %s" glob)
	264	glob))))
	265
	266	(eval-when-compile
	267	(defvar matches)
	268	(defvar message-shown))
	269
affbf647 GM	270	(defun eshell-glob-entries (path globs &optional recurse-p)
	271	"Glob the entries in PATHS, possibly recursing if RECURSE-P is non-nil."
	272	(let* ((entries (ignore-errors
	273	(file-name-all-completions "" path)))
	274	(case-fold-search eshell-glob-case-insensitive)
	275	(glob (car globs))
	276	(len (length glob))
	277	dirs rdirs
	278	incl excl
	279	name isdir pathname)
	280	(while (cond
	281	((and (= len 3) (equal glob "**/"))
	282	(setq recurse-p 2
	283	globs (cdr globs)
	284	glob (car globs)
	285	len (length glob)))
	286	((and (= len 4) (equal glob "***/"))
	287	(setq recurse-p 3
	288	globs (cdr globs)
	289	glob (car globs)
	290	len (length glob)))))
	291	(if (and recurse-p (not glob))
	292	(error "'**' cannot end a globbing pattern"))
	293	(let ((index 1))
	294	(setq incl glob)
	295	(while (and (eq incl glob)
	296	(setq index (string-match "~" glob index)))
	297	(if (or (get-text-property index 'escaped glob)
	298	(or (= (1+ index) len)))
	299	(setq index (1+ index))
	300	(setq incl (substring glob 0 index)
	301	excl (substring glob (1+ index))))))
	302	;; can't use `directory-file-name' because it strips away text
	303	;; properties in the string
	304	(let ((len (1- (length incl))))
6b0e3e4d	305	(if (eq (aref incl len) ?/)
affbf647 GM	306	(setq incl (substring incl 0 len)))
	307	(when excl
	308	(setq len (1- (length excl)))
6b0e3e4d	309	(if (eq (aref excl len) ?/)
affbf647 GM	310	(setq excl (substring excl 0 len)))))
	311	(setq incl (eshell-glob-regexp incl)
	312	excl (and excl (eshell-glob-regexp excl)))
	313	(if (or eshell-glob-include-dot-files
	314	(eq (aref glob 0) ?.))
	315	(unless (or eshell-glob-include-dot-dot
	316	(cdr globs))
	317	(setq excl (if excl
	318	(concat "\\(\\`\\.\\.?\\'\\\|" excl "\\)")
	319	"\\`\\.\\.?\\'")))
	320	(setq excl (if excl
	321	(concat "\\(\\`\\.\\\|" excl "\\)")
	322	"\\`\\.")))
	323	(when (and recurse-p eshell-glob-show-progress)
	324	(message "Building file list...%d so far: %s"
	325	(length matches) path)
	326	(setq message-shown t))
	327	(if (equal path "./") (setq path ""))
	328	(while entries
	329	(setq name (car entries)
	330	len (length name)
6b0e3e4d	331	isdir (eq (aref name (1- len)) ?/))
affbf647 GM	332	(if (let ((fname (directory-file-name name)))
	333	(and (not (and excl (string-match excl fname)))
	334	(string-match incl fname)))
	335	(if (cdr globs)
	336	(if isdir
	337	(setq dirs (cons (concat path name) dirs)))
	338	(setq matches (cons (concat path name) matches))))
	339	(if (and recurse-p isdir
	340	(or (> len 3)
	341	(not (or (and (= len 2) (equal name "./"))
	342	(and (= len 3) (equal name "../")))))
	343	(setq pathname (concat path name))
	344	(not (and (= recurse-p 2)
	345	(file-symlink-p
	346	(directory-file-name pathname)))))
	347	(setq rdirs (cons pathname rdirs)))
	348	(setq entries (cdr entries)))
	349	(setq dirs (nreverse dirs)
	350	rdirs (nreverse rdirs))
	351	(while dirs
	352	(eshell-glob-entries (car dirs) (cdr globs))
	353	(setq dirs (cdr dirs)))
	354	(while rdirs
	355	(eshell-glob-entries (car rdirs) globs recurse-p)
	356	(setq rdirs (cdr rdirs)))))
	357
ab5796a9	358	;;; arch-tag: d0548f54-fb7c-4978-a88e-f7c26f7f68ca
affbf647	359	;;; em-glob.el ends here