[bpt/emacs.git] / lisp / vc-git.el

;;; vc-git.el --- VC backend for the git version control system

;; Copyright (C) 2006, 2007 Free Software Foundation, Inc.

;; Author: Alexandre Julliard <julliard@winehq.org>
;; Keywords: tools

;; This file is part of GNU Emacs.

;; GNU Emacs is free software; you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation; either version 3, or (at your option)
;; any later version.

;; GNU Emacs is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License
;; along with GNU Emacs; see the file COPYING.  If not, write to the
;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
;; Boston, MA 02110-1301, USA.

;;; Commentary:

;; This file contains a VC backend for the git version control
;; system.
;;

;;; Installation:

;; To install: put this file on the load-path and add Git to the list
;; of supported backends in `vc-handled-backends'; the following line,
;; placed in your ~/.emacs, will accomplish this:
;;
;;     (add-to-list 'vc-handled-backends 'Git)

;;; Todo:
;;  - check if more functions could use vc-git-command instead
;;     of start-process.
;;  - changelog generation

;; Implement the rest of the vc interface. See the comment at the
;; beginning of vc.el. The current status is:
;; ("??" means: "figure out what to do about it")
;;
;; FUNCTION NAME                                   STATUS
;; BACKEND PROPERTIES
;; * revision-granularity                          OK
;; STATE-QUERYING FUNCTIONS
;; * registered (file)				   OK
;; * state (file)				   OK
;; - state-heuristic (file)			   NOT NEEDED
;; - dir-state (dir)				   OK
;; * working-revision (file)			   OK
;; - latest-on-branch-p (file)			   NOT NEEDED
;; * checkout-model (file)			   OK
;; - workfile-unchanged-p (file)		   OK
;; - mode-line-string (file)			   OK
;; - dired-state-info (file)			   OK
;; STATE-CHANGING FUNCTIONS
;; * create-repo ()				   OK
;; * register (files &optional rev comment)	   OK
;; - init-revision (file)			   NOT NEEDED
;; - responsible-p (file)			   OK
;; - could-register (file)			   NOT NEEDED, DEFAULT IS GOOD
;; - receive-file (file rev)			   NOT NEEDED
;; - unregister (file)				   OK
;; * checkin (files rev comment)		   OK
;; * find-revision (file rev buffer)		   OK
;; * checkout (file &optional editable rev)	   OK
;; * revert (file &optional contents-done)	   OK
;; - rollback (files)				   COULD BE SUPPORTED
;; - merge (file rev1 rev2)			   It would be possible to merge changes into
;;                                                 a single file, but when committing they
;;                                                 wouldn't be identified as a merge by git,
;;                                                 so it's probably not a good idea.
;; - merge-news (file)				   see `merge'
;; - steal-lock (file &optional revision)	   NOT NEEDED
;; HISTORY FUNCTIONS
;; * print-log (files &optional buffer)		   OK
;; - log-view-mode ()				   OK
;; - show-log-entry (revision)			   OK
;; - wash-log (file)				   COULD BE SUPPORTED
;; - logentry-check ()				   NOT NEEDED
;; - comment-history (file)			   ??
;; - update-changelog (files)			   COULD BE SUPPORTED
;; * diff (file &optional rev1 rev2 buffer)	   OK
;; - revision-completion-table (files)		   NEEDED?
;; - annotate-command (file buf &optional rev)	   OK
;; - annotate-time ()				   OK
;; - annotate-current-time ()			   NOT NEEDED
;; - annotate-extract-revision-at-line ()	   OK
;; SNAPSHOT SYSTEM
;; - create-snapshot (dir name branchp)		   OK
;; - assign-name (file name)			   NOT NEEDED
;; - retrieve-snapshot (dir name update)	   OK, needs to update buffers
;; MISCELLANEOUS
;; - make-version-backups-p (file)		   NOT NEEDED
;; - repository-hostname (dirname)		   NOT NEEDED
;; - previous-revision (file rev)		   OK
;; - next-revision (file rev)			   OK
;; - check-headers ()				   COULD BE SUPPORTED
;; - clear-headers ()				   NOT NEEDED
;; - delete-file (file)				   OK
;; - rename-file (old new)			   OK
;; - find-file-hook ()				   NOT NEEDED
;; - find-file-not-found-hook ()                   NOT NEEDED

(eval-when-compile (require 'cl) (require 'vc))

(defvar git-commits-coding-system 'utf-8
  "Default coding system for git commits.")

;;; BACKEND PROPERTIES

(defun vc-git-revision-granularity ()
  'repository)

;;; STATE-QUERYING FUNCTIONS

;;;###autoload (defun vc-git-registered (file)
;;;###autoload   "Return non-nil if FILE is registered with git."
;;;###autoload   (if (vc-find-root file ".git")       ; short cut
;;;###autoload       (progn
;;;###autoload         (load "vc-git")
;;;###autoload         (vc-git-registered file))))

(defun vc-git-registered (file)
  "Check whether FILE is registered with git."
  (when (vc-git-root file)
    (with-temp-buffer
      (let* ((dir (file-name-directory file))
	     (name (file-relative-name file dir)))
	(and (ignore-errors
               (when dir (cd dir))
               (vc-git--out-ok "ls-files" "-c" "-z" "--" name))
	     (let ((str (buffer-string)))
	       (and (> (length str) (length name))
		    (string= (substring str 0 (1+ (length name)))
                             (concat name "\0")))))))))

(defun vc-git-state (file)
  "Git-specific version of `vc-state'."
  ;; FIXME: This can't set 'ignored yet
  (vc-git--call nil "add" "--refresh" "--" (file-relative-name file))
  (let ((diff (vc-git--run-command-string file "diff-index" "-z" "HEAD" "--")))
    (if (and diff (string-match ":[0-7]\\{6\\} [0-7]\\{6\\} [0-9a-f]\\{40\\} [0-9a-f]\\{40\\} [ADMU]\0[^\0]+\0"
                                diff))
        'edited
      'up-to-date)))

(defun vc-git-dir-state (dir)
  "Git-specific version of `dir-state'."
  ;; FIXME: This can't set 'ignored yet
  (with-temp-buffer
    (vc-git-command (current-buffer) nil nil "ls-files" "-t" "-c" "-m" "-o")
    (goto-char (point-min))
    (let ((status-char nil)
	  (file nil))
      (while (not (eobp))
	(setq status-char (char-after))
	(setq file
	      (expand-file-name
	       (buffer-substring-no-properties (+ (point) 2)
                                               (line-end-position))))
	(cond
	 ;; The rest of the possible states in "git ls-files -t" output:
	 ;;      K              to be killed
	 ;; should not show up in vc-dired, so don't deal with them
	 ;; here.
	 ((eq status-char ?H)
	  (vc-file-setprop file 'vc-backend 'Git)
	  (vc-file-setprop file 'vc-state 'up-to-date))
	 ((eq status-char ?R)
	  (vc-file-setprop file 'vc-backend 'Git)
	  (vc-file-setprop file 'vc-state 'removed))
	 ((eq status-char ?M)
	  (vc-file-setprop file 'vc-backend 'Git)
	  (vc-file-setprop file 'vc-state 'edited))
	 ((eq status-char ?C)
	  (vc-file-setprop file 'vc-backend 'Git)
	  (vc-file-setprop file 'vc-state 'edited))
	 ((eq status-char ??)
	  (vc-file-setprop file 'vc-backend 'none)
	  (vc-file-setprop file 'vc-state nil)))
	(forward-line)))))

(defun vc-git-working-revision (file)
  "Git-specific version of `vc-working-revision'."
  (let ((str (with-output-to-string
               (with-current-buffer standard-output
                 (vc-git--out-ok "symbolic-ref" "HEAD")))))
    (if (string-match "^\\(refs/heads/\\)?\\(.+\\)$" str)
        (match-string 2 str)
      str)))

(defun vc-git-checkout-model (file)
  'implicit)

(defun vc-git-workfile-unchanged-p (file)
  (eq 'up-to-date (vc-git-state file)))

(defun vc-git-mode-line-string (file)
  "Return string for placement into the modeline for FILE."
  (let* ((branch (vc-git-working-revision file))
         (def-ml (vc-default-mode-line-string 'Git file))
         (help-echo (get-text-property 0 'help-echo def-ml)))
    (if (zerop (length branch))
        (propertize
         (concat def-ml "!")
         'help-echo (concat help-echo "\nNo current branch (detached HEAD)"))
      (propertize def-ml
                  'help-echo (concat help-echo "\nCurrent branch: " branch)))))

(defun vc-git-dired-state-info (file)
  "Git-specific version of `vc-dired-state-info'."
  (let ((git-state (vc-state file)))
    (if (eq git-state 'edited)
	"(modified)"
      ;; fall back to the default VC representation
      (vc-default-dired-state-info 'Git file))))

;;; STATE-CHANGING FUNCTIONS

(defun vc-git-create-repo ()
  "Create a new Git repository."
  (vc-git-command nil 0 nil "init"))

(defun vc-git-register (files &optional rev comment)
  "Register FILE into the git version-control system."
  (vc-git-command nil 0 files "update-index" "--add" "--"))

(defalias 'vc-git-responsible-p 'vc-git-root)

(defun vc-git-unregister (file)
  (vc-git-command nil 0 file "rm" "-f" "--cached" "--"))


(defun vc-git-checkin (files rev comment)
  (let ((coding-system-for-write git-commits-coding-system))
    (vc-git-command nil 0 files "commit" "-m" comment "--only" "--")))

(defun vc-git-find-revision (file rev buffer)
  (let ((coding-system-for-read 'binary)
        (coding-system-for-write 'binary)
	(fullname (substring
		   (vc-git--run-command-string
		    file "ls-files" "-z" "--full-name" "--")
		   0 -1)))
    (vc-git-command
     buffer 0
     (concat (if rev rev "HEAD") ":" fullname) "cat-file" "blob")))

(defun vc-git-checkout (file &optional editable rev)
  (vc-git-command nil 0 file "checkout" (or rev "HEAD")))

(defun vc-git-revert (file &optional contents-done)
  "Revert FILE to the version stored in the git repository."
  (if contents-done
      (vc-git-command nil 0 file "update-index" "--")
    (vc-git-command nil 0 file "checkout" "HEAD")))

;;; HISTORY FUNCTIONS

(defun vc-git-print-log (files &optional buffer)
  "Get change log associated with FILES."
  (let ((coding-system-for-read git-commits-coding-system)
	;; Support both the old print-log interface that passes a
	;; single file, and the new one that passes a file list.
	(flist (if (listp files) files (list files))))
    ;; `vc-do-command' creates the buffer, but we need it before running
    ;; the command.
    (vc-setup-buffer buffer)
    ;; If the buffer exists from a previous invocation it might be
    ;; read-only.
    (let ((inhibit-read-only t))
      ;; XXX `log-view-mode' needs to have something to identify where
      ;; the log for each individual file starts. It seems that by
      ;; default git does not output this info. So loop here and call
      ;; "git rev-list" on each file separately to make sure that each
      ;; file gets a "File:" header before the corresponding
      ;; log. Maybe there is a way to do this with one command...
      (dolist (file flist)
	(with-current-buffer
	    buffer
	  (insert "File: " (file-name-nondirectory file) "\n"))
	(vc-git-command buffer 'async (file-relative-name file)
			"rev-list" "--pretty" "HEAD" "--")))))

(defvar log-view-message-re)
(defvar log-view-file-re)
(defvar log-view-font-lock-keywords)

(define-derived-mode vc-git-log-view-mode log-view-mode "Git-Log-View"
  (require 'add-log) ;; we need the faces add-log
  ;; Don't have file markers, so use impossible regexp.
  (set (make-local-variable 'log-view-file-re) "^File:[ \t]+\\(.+\\)")
  (set (make-local-variable 'log-view-message-re)
       "^commit *\\([0-9a-z]+\\)")
  (set (make-local-variable 'log-view-font-lock-keywords)
       (append
        `((,log-view-message-re  (1 'change-log-acknowledgement))
          (,log-view-file-re (1 'change-log-file-face)))
        ;; Handle the case:
        ;; user: foo@bar
        '(("^Author:[ \t]+\\([A-Za-z0-9_.+-]+@[A-Za-z0-9_.-]+\\)"
           (1 'change-log-email))
          ;; Handle the case:
          ;; user: FirstName LastName <foo@bar>
          ("^Author:[ \t]+\\([^<(]+?\\)[ \t]*[(<]\\([A-Za-z0-9_.+-]+@[A-Za-z0-9_.-]+\\)[>)]"
           (1 'change-log-name)
           (2 'change-log-email))
          ("^ +\\(?:\\(?:[Aa]cked\\|[Ss]igned-[Oo]ff\\)-[Bb]y:\\)[ \t]+\\([A-Za-z0-9_.+-]+@[A-Za-z0-9_.-]+\\)"
           (1 'change-log-name))
          ("^ +\\(?:\\(?:[Aa]cked\\|[Ss]igned-[Oo]ff\\)-[Bb]y:\\)[ \t]+\\([^<(]+?\\)[ \t]*[(<]\\([A-Za-z0-9_.+-]+@[A-Za-z0-9_.-]+\\)[>)]"
           (1 'change-log-name)
           (2 'change-log-email))
          ("^Merge: \\([0-9a-z]+\\) \\([0-9a-z]+\\)"
           (1 'change-log-acknowledgement)
           (2 'change-log-acknowledgement))
          ("^Date:   \\(.+\\)" (1 'change-log-date))
          ("^summary:[ \t]+\\(.+\\)" (1 'log-view-message))))))

(defun vc-git-show-log-entry (revision)
  "Move to the log entry for REVISION.
REVISION may have the form BRANCH, BRANCH~N,
or BRANCH^ (where \"^\" can be repeated)."
  (goto-char (point-min))
  (search-forward "\ncommit" nil t
                  (cond ((string-match "~\\([0-9]\\)$" revision)
                         (1+ (string-to-number (match-string 1 revision))))
                        ((string-match "\\^+$" revision)
                         (1+ (length (match-string 0 revision))))
                        (t nil)))
  (beginning-of-line))

(defun vc-git-diff (files &optional rev1 rev2 buffer)
  (let ((buf (or buffer "*vc-diff*")))
    (if (and rev1 rev2)
        (vc-git-command buf 1 files "diff-tree" "--exit-code" "-p"
                        rev1 rev2 "--")
      (vc-git-command buf 1 files "diff-index" "--exit-code" "-p"
                      (or rev1 "HEAD") "--"))))

(defun vc-git-revision-table (files)
  ;; What about `files'?!?  --Stef
  (let ((table (list "HEAD")))
    (with-temp-buffer
      (vc-git-command t nil nil "for-each-ref" "--format=%(refname)")
      (goto-char (point-min))
      (while (re-search-forward "^refs/\\(heads\\|tags\\)/\\(.*\\)$" nil t)
        (push (match-string 2) table)))
    table))

(defun vc-git-revision-completion-table (files)
  (lexical-let ((files files)
                table)
    (setq table (lazy-completion-table
                 table (lambda () (vc-git-revision-table files))))
    table))

(defun vc-git-annotate-command (file buf &optional rev)
  ;; FIXME: rev is ignored
  (let ((name (file-relative-name file)))
    (vc-git-command buf 0 name "blame" (if rev (concat "-r" rev)))))

(defun vc-git-annotate-time ()
  (and (re-search-forward "[0-9a-f]+[^()]+(.* \\([0-9]+\\)-\\([0-9]+\\)-\\([0-9]+\\) \\([0-9]+\\):\\([0-9]+\\):\\([0-9]+\\) \\([-+0-9]+\\) +[0-9]+) " nil t)
       (vc-annotate-convert-time
        (apply #'encode-time (mapcar (lambda (match)
                                       (string-to-number (match-string match)))
                                     '(6 5 4 3 2 1 7))))))

(defun vc-git-annotate-extract-revision-at-line ()
  (save-excursion
    (move-beginning-of-line 1)
    (and (looking-at "[0-9a-f]+")
         (buffer-substring-no-properties (match-beginning 0) (match-end 0)))))

;;; SNAPSHOT SYSTEM

(defun vc-git-create-snapshot (dir name branchp)
  (let ((default-directory dir))
    (and (vc-git-command nil 0 nil "update-index" "--refresh")
         (if branchp
             (vc-git-command nil 0 nil "checkout" "-b" name)
           (vc-git-command nil 0 nil "tag" name)))))

(defun vc-git-retrieve-snapshot (dir name update)
  (let ((default-directory dir))
    (vc-git-command nil 0 nil "checkout" name)
    ;; FIXME: update buffers if `update' is true
    ))


;;; MISCELLANEOUS

(defun vc-git-previous-revision (file rev)
  "Git-specific version of `vc-previous-revision'."
  (let ((default-directory (file-name-directory (expand-file-name file)))
	(file (file-name-nondirectory file)))
    (vc-git-symbolic-commit
     (with-temp-buffer
       (and
	(vc-git--out-ok "rev-list" "-2" rev "--" file)
	(goto-char (point-max))
	(bolp)
	(zerop (forward-line -1))
	(not (bobp))
	(buffer-substring-no-properties
         (point)
         (1- (point-max))))))))

(defun vc-git-next-revision (file rev)
  "Git-specific version of `vc-next-revision'."
  (let* ((default-directory (file-name-directory
			     (expand-file-name file)))
         (file (file-name-nondirectory file))
         (current-rev
          (with-temp-buffer
            (and
             (vc-git--out-ok "rev-list" "-1" rev "--" file)
             (goto-char (point-max))
             (bolp)
             (zerop (forward-line -1))
             (bobp)
             (buffer-substring-no-properties
              (point)
              (1- (point-max)))))))
    (and current-rev
	 (vc-git-symbolic-commit
	  (with-temp-buffer
	    (and
	     (vc-git--out-ok "rev-list" "HEAD" "--" file)
	     (goto-char (point-min))
	     (search-forward current-rev nil t)
	     (zerop (forward-line -1))
	     (buffer-substring-no-properties
	      (point)
	      (progn (forward-line 1) (1- (point))))))))))

(defun vc-git-delete-file (file)
  (vc-git-command nil 0 file "rm" "-f" "--"))

(defun vc-git-rename-file (old new)
  (vc-git-command nil 0 (list old new) "mv" "-f" "--"))

\f
;;; Internal commands

(defun vc-git-root (file)
  (vc-find-root file ".git"))

(defun vc-git-command (buffer okstatus file-or-list &rest flags)
  "A wrapper around `vc-do-command' for use in vc-git.el.
The difference to vc-do-command is that this function always invokes `git'."
  (apply 'vc-do-command buffer okstatus "git" file-or-list flags))

(defun vc-git--call (buffer command &rest args)
  (apply 'call-process "git" nil buffer nil command args))

(defun vc-git--out-ok (command &rest args)
  (zerop (apply 'vc-git--call '(t nil) command args)))

(defun vc-git--run-command-string (file &rest args)
  "Run a git command on FILE and return its output as string."
  (let* ((ok t)
         (str (with-output-to-string
                (with-current-buffer standard-output
                  (unless (apply 'vc-git--out-ok
                                 (append args (list (file-relative-name
                                                     file))))
                    (setq ok nil))))))
    (and ok str)))

(defun vc-git-symbolic-commit (commit)
  "Translate COMMIT string into symbolic form.
Returns nil if not possible."
  (and commit
       (with-temp-buffer
	 (and
	  (vc-git--out-ok "name-rev" "--name-only" "--tags" commit)
	  (goto-char (point-min))
	  (= (forward-line 2) 1)
	  (bolp)
	  (buffer-substring-no-properties (point-min) (1- (point-max)))))))

(provide 'vc-git)

;; arch-tag: bd10664a-0e5b-48f5-a877-6c17b135be12
;;; vc-git.el ends here
Commit	Line	Data
fff4a046 DN	1	;;; vc-git.el --- VC backend for the git version control system
	2
	3	;; Copyright (C) 2006, 2007 Free Software Foundation, Inc.
	4
8b38ce20	5	;; Author: Alexandre Julliard <julliard@winehq.org>
fff4a046 DN	6	;; Keywords: tools
	7
	8	;; This file is part of GNU Emacs.
	9
	10	;; GNU Emacs is free software; you can redistribute it and/or modify
	11	;; it under the terms of the GNU General Public License as published by
625f71cf	12	;; the Free Software Foundation; either version 3, or (at your option)
fff4a046 DN	13	;; any later version.
	14
	15	;; GNU Emacs is distributed in the hope that it will be useful,
	16	;; but WITHOUT ANY WARRANTY; without even the implied warranty of
	17	;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
	18	;; GNU General Public License for more details.
	19
	20	;; You should have received a copy of the GNU General Public License
	21	;; along with GNU Emacs; see the file COPYING. If not, write to the
	22	;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
	23	;; Boston, MA 02110-1301, USA.
	24
	25	;;; Commentary:
	26
	27	;; This file contains a VC backend for the git version control
	28	;; system.
	29	;;
	30
	31	;;; Installation:
	32
4211679b	33	;; To install: put this file on the load-path and add Git to the list
fff4a046 DN	34	;; of supported backends in `vc-handled-backends'; the following line,
	35	;; placed in your ~/.emacs, will accomplish this:
	36	;;
4211679b	37	;; (add-to-list 'vc-handled-backends 'Git)
fff4a046 DN	38
fff4a046 DN	39	;;; Todo:
53cc90ab DN	40	;; - check if more functions could use vc-git-command instead
53cc90ab DN	41	;; of start-process.
fff4a046	42	;; - changelog generation
53cc90ab DN	43
	44	;; Implement the rest of the vc interface. See the comment at the
	45	;; beginning of vc.el. The current status is:
7546c767	46	;; ("??" means: "figure out what to do about it")
fff4a046	47	;;
53cc90ab DN	48	;; FUNCTION NAME STATUS
	49	;; BACKEND PROPERTIES
	50	;; * revision-granularity OK
	51	;; STATE-QUERYING FUNCTIONS
	52	;; * registered (file) OK
	53	;; * state (file) OK
108607bc	54	;; - state-heuristic (file) NOT NEEDED
53cc90ab	55	;; - dir-state (dir) OK
ac3f4c6f	56	;; * working-revision (file) OK
108607bc	57	;; - latest-on-branch-p (file) NOT NEEDED
53cc90ab	58	;; * checkout-model (file) OK
7546c767	59	;; - workfile-unchanged-p (file) OK
6f222162	60	;; - mode-line-string (file) OK
53cc90ab DN	61	;; - dired-state-info (file) OK
	62	;; STATE-CHANGING FUNCTIONS
	63	;; * create-repo () OK
9143abff	64	;; * register (files &optional rev comment) OK
ac3f4c6f	65	;; - init-revision (file) NOT NEEDED
53cc90ab	66	;; - responsible-p (file) OK
108607bc DN	67	;; - could-register (file) NOT NEEDED, DEFAULT IS GOOD
108607bc DN	68	;; - receive-file (file rev) NOT NEEDED
d7009f45	69	;; - unregister (file) OK
9143abff	70	;; * checkin (files rev comment) OK
ac3f4c6f	71	;; * find-revision (file rev buffer) OK
53cc90ab DN	72	;; * checkout (file &optional editable rev) OK
53cc90ab DN	73	;; * revert (file &optional contents-done) OK
108607bc DN	74	;; - rollback (files) COULD BE SUPPORTED
	75	;; - merge (file rev1 rev2) It would be possible to merge changes into
	76	;; a single file, but when committing they
	77	;; wouldn't be identified as a merge by git,
b747d346 DN	78	;; so it's probably not a good idea.
b747d346 DN	79	;; - merge-news (file) see `merge'
5b5afd50	80	;; - steal-lock (file &optional revision) NOT NEEDED
53cc90ab	81	;; HISTORY FUNCTIONS
9143abff	82	;; * print-log (files &optional buffer) OK
53cc90ab	83	;; - log-view-mode () OK
b16bd82d	84	;; - show-log-entry (revision) OK
108607bc DN	85	;; - wash-log (file) COULD BE SUPPORTED
108607bc DN	86	;; - logentry-check () NOT NEEDED
53cc90ab	87	;; - comment-history (file) ??
108607bc	88	;; - update-changelog (files) COULD BE SUPPORTED
b747d346	89	;; * diff (file &optional rev1 rev2 buffer) OK
54a2247d	90	;; - revision-completion-table (files) NEEDED?
53cc90ab DN	91	;; - annotate-command (file buf &optional rev) OK
53cc90ab DN	92	;; - annotate-time () OK
108607bc	93	;; - annotate-current-time () NOT NEEDED
53cc90ab DN	94	;; - annotate-extract-revision-at-line () OK
53cc90ab DN	95	;; SNAPSHOT SYSTEM
b747d346	96	;; - create-snapshot (dir name branchp) OK
53cc90ab	97	;; - assign-name (file name) NOT NEEDED
40ed3f4f	98	;; - retrieve-snapshot (dir name update) OK, needs to update buffers
53cc90ab	99	;; MISCELLANEOUS
108607bc DN	100	;; - make-version-backups-p (file) NOT NEEDED
108607bc DN	101	;; - repository-hostname (dirname) NOT NEEDED
5b5afd50 ER	102	;; - previous-revision (file rev) OK
5b5afd50 ER	103	;; - next-revision (file rev) OK
108607bc DN	104	;; - check-headers () COULD BE SUPPORTED
108607bc DN	105	;; - clear-headers () NOT NEEDED
8b38ce20 DN	106	;; - delete-file (file) OK
8b38ce20 DN	107	;; - rename-file (old new) OK
108607bc DN	108	;; - find-file-hook () NOT NEEDED
108607bc DN	109	;; - find-file-not-found-hook () NOT NEEDED
fff4a046	110
b0f90937	111	(eval-when-compile (require 'cl) (require 'vc))
fff4a046 DN	112
	113	(defvar git-commits-coding-system 'utf-8
	114	"Default coding system for git commits.")
	115
53cc90ab DN	116	;;; BACKEND PROPERTIES
	117
	118	(defun vc-git-revision-granularity ()
2aa0736a	119	'repository)
53cc90ab DN	120
	121	;;; STATE-QUERYING FUNCTIONS
	122
	123	;;;###autoload (defun vc-git-registered (file)
	124	;;;###autoload "Return non-nil if FILE is registered with git."
	125	;;;###autoload (if (vc-find-root file ".git") ; short cut
	126	;;;###autoload (progn
	127	;;;###autoload (load "vc-git")
	128	;;;###autoload (vc-git-registered file))))
	129
fff4a046 DN	130	(defun vc-git-registered (file)
fff4a046 DN	131	"Check whether FILE is registered with git."
53cc90ab DN	132	(when (vc-git-root file)
	133	(with-temp-buffer
	134	(let* ((dir (file-name-directory file))
	135	(name (file-relative-name file dir)))
	136	(and (ignore-errors
2aa0736a	137	(when dir (cd dir))
5fdbecd8	138	(vc-git--out-ok "ls-files" "-c" "-z" "--" name))
53cc90ab DN	139	(let ((str (buffer-string)))
53cc90ab DN	140	(and (> (length str) (length name))
2aa0736a TTN	141	(string= (substring str 0 (1+ (length name)))
2aa0736a TTN	142	(concat name "\0")))))))))
108607bc	143
fff4a046	144	(defun vc-git-state (file)
53cc90ab	145	"Git-specific version of `vc-state'."
722f037f	146	;; FIXME: This can't set 'ignored yet
5fdbecd8	147	(vc-git--call nil "add" "--refresh" "--" (file-relative-name file))
fff4a046	148	(let ((diff (vc-git--run-command-string file "diff-index" "-z" "HEAD" "--")))
2aa0736a TTN	149	(if (and diff (string-match ":[0-7]\\{6\\} [0-7]\\{6\\} [0-9a-f]\\{40\\} [0-9a-f]\\{40\\} [ADMU]\0[^\0]+\0"
2aa0736a TTN	150	diff))
fff4a046 DN	151	'edited
	152	'up-to-date)))
	153
53cc90ab	154	(defun vc-git-dir-state (dir)
722f037f ER	155	"Git-specific version of `dir-state'."
722f037f ER	156	;; FIXME: This can't set 'ignored yet
53cc90ab	157	(with-temp-buffer
8d6d388d	158	(vc-git-command (current-buffer) nil nil "ls-files" "-t" "-c" "-m" "-o")
53cc90ab DN	159	(goto-char (point-min))
	160	(let ((status-char nil)
	161	(file nil))
	162	(while (not (eobp))
	163	(setq status-char (char-after))
	164	(setq file
	165	(expand-file-name
2aa0736a TTN	166	(buffer-substring-no-properties (+ (point) 2)
2aa0736a TTN	167	(line-end-position))))
53cc90ab DN	168	(cond
53cc90ab DN	169	;; The rest of the possible states in "git ls-files -t" output:
53cc90ab DN	170	;; K to be killed
	171	;; should not show up in vc-dired, so don't deal with them
	172	;; here.
	173	((eq status-char ?H)
21838dc0	174	(vc-file-setprop file 'vc-backend 'Git)
53cc90ab	175	(vc-file-setprop file 'vc-state 'up-to-date))
484c1b1f	176	((eq status-char ?R)
21838dc0	177	(vc-file-setprop file 'vc-backend 'Git)
484c1b1f	178	(vc-file-setprop file 'vc-state 'removed))
53cc90ab	179	((eq status-char ?M)
21838dc0	180	(vc-file-setprop file 'vc-backend 'Git)
53cc90ab DN	181	(vc-file-setprop file 'vc-state 'edited))
53cc90ab DN	182	((eq status-char ?C)
21838dc0	183	(vc-file-setprop file 'vc-backend 'Git)
53cc90ab DN	184	(vc-file-setprop file 'vc-state 'edited))
	185	((eq status-char ??)
	186	(vc-file-setprop file 'vc-backend 'none)
484c1b1f	187	(vc-file-setprop file 'vc-state nil)))
53cc90ab DN	188	(forward-line)))))
53cc90ab DN	189
ac3f4c6f ER	190	(defun vc-git-working-revision (file)
ac3f4c6f ER	191	"Git-specific version of `vc-working-revision'."
fff4a046 DN	192	(let ((str (with-output-to-string
fff4a046 DN	193	(with-current-buffer standard-output
5fdbecd8	194	(vc-git--out-ok "symbolic-ref" "HEAD")))))
fff4a046 DN	195	(if (string-match "^\\(refs/heads/\\)?\\(.+\\)$" str)
	196	(match-string 2 str)
	197	str)))
	198
	199	(defun vc-git-checkout-model (file)
	200	'implicit)
	201
	202	(defun vc-git-workfile-unchanged-p (file)
00d67080	203	(eq 'up-to-date (vc-git-state file)))
fff4a046	204
6f222162 DN	205	(defun vc-git-mode-line-string (file)
6f222162 DN	206	"Return string for placement into the modeline for FILE."
ac3f4c6f	207	(let* ((branch (vc-git-working-revision file))
6f222162 DN	208	(def-ml (vc-default-mode-line-string 'Git file))
	209	(help-echo (get-text-property 0 'help-echo def-ml)))
	210	(if (zerop (length branch))
	211	(propertize
	212	(concat def-ml "!")
	213	'help-echo (concat help-echo "\nNo current branch (detached HEAD)"))
	214	(propertize def-ml
	215	'help-echo (concat help-echo "\nCurrent branch: " branch)))))
	216
53cc90ab DN	217	(defun vc-git-dired-state-info (file)
	218	"Git-specific version of `vc-dired-state-info'."
	219	(let ((git-state (vc-state file)))
	220	(if (eq git-state 'edited)
	221	"(modified)"
	222	;; fall back to the default VC representation
4211679b	223	(vc-default-dired-state-info 'Git file))))
53cc90ab DN	224
	225	;;; STATE-CHANGING FUNCTIONS
	226
	227	(defun vc-git-create-repo ()
4211679b	228	"Create a new Git repository."
00d67080	229	(vc-git-command nil 0 nil "init"))
53cc90ab	230
8b9783e0	231	(defun vc-git-register (files &optional rev comment)
fff4a046	232	"Register FILE into the git version-control system."
8b9783e0	233	(vc-git-command nil 0 files "update-index" "--add" "--"))
fff4a046	234
53cc90ab DN	235	(defalias 'vc-git-responsible-p 'vc-git-root)
53cc90ab DN	236
d7009f45 DN	237	(defun vc-git-unregister (file)
d7009f45 DN	238	(vc-git-command nil 0 file "rm" "-f" "--cached" "--"))
108607bc	239
d7009f45	240
8b9783e0	241	(defun vc-git-checkin (files rev comment)
fff4a046	242	(let ((coding-system-for-write git-commits-coding-system))
8b9783e0	243	(vc-git-command nil 0 files "commit" "-m" comment "--only" "--")))
fff4a046	244
ac3f4c6f	245	(defun vc-git-find-revision (file rev buffer)
b0f90937	246	(let ((coding-system-for-read 'binary)
8b38ce20 DN	247	(coding-system-for-write 'binary)
8b38ce20 DN	248	(fullname (substring
108607bc	249	(vc-git--run-command-string
8b38ce20 DN	250	file "ls-files" "-z" "--full-name" "--")
8b38ce20 DN	251	0 -1)))
108607bc DN	252	(vc-git-command
108607bc DN	253	buffer 0
8b38ce20	254	(concat (if rev rev "HEAD") ":" fullname) "cat-file" "blob")))
b0f90937 DN	255
b0f90937 DN	256	(defun vc-git-checkout (file &optional editable rev)
7546c767	257	(vc-git-command nil 0 file "checkout" (or rev "HEAD")))
fff4a046 DN	258
	259	(defun vc-git-revert (file &optional contents-done)
	260	"Revert FILE to the version stored in the git repository."
	261	(if contents-done
b0f90937 DN	262	(vc-git-command nil 0 file "update-index" "--")
b0f90937 DN	263	(vc-git-command nil 0 file "checkout" "HEAD")))
fff4a046	264
53cc90ab DN	265	;;; HISTORY FUNCTIONS
53cc90ab DN	266
8b9783e0 DN	267	(defun vc-git-print-log (files &optional buffer)
8b9783e0 DN	268	"Get change log associated with FILES."
a0709d8d DN	269	(let ((coding-system-for-read git-commits-coding-system)
	270	;; Support both the old print-log interface that passes a
	271	;; single file, and the new one that passes a file list.
	272	(flist (if (listp files) files (list files))))
53cc90ab DN	273	;; `vc-do-command' creates the buffer, but we need it before running
	274	;; the command.
	275	(vc-setup-buffer buffer)
	276	;; If the buffer exists from a previous invocation it might be
	277	;; read-only.
	278	(let ((inhibit-read-only t))
64e3efd9 DN	279	;; XXX `log-view-mode' needs to have something to identify where
	280	;; the log for each individual file starts. It seems that by
	281	;; default git does not output this info. So loop here and call
	282	;; "git rev-list" on each file separately to make sure that each
	283	;; file gets a "File:" header before the corresponding
	284	;; log. Maybe there is a way to do this with one command...
a0709d8d	285	(dolist (file flist)
64e3efd9 DN	286	(with-current-buffer
	287	buffer
	288	(insert "File: " (file-name-nondirectory file) "\n"))
108607bc	289	(vc-git-command buffer 'async (file-relative-name file)
64e3efd9	290	"rev-list" "--pretty" "HEAD" "--")))))
53cc90ab DN	291
	292	(defvar log-view-message-re)
	293	(defvar log-view-file-re)
	294	(defvar log-view-font-lock-keywords)
	295
4211679b	296	(define-derived-mode vc-git-log-view-mode log-view-mode "Git-Log-View"
53cc90ab DN	297	(require 'add-log) ;; we need the faces add-log
	298	;; Don't have file markers, so use impossible regexp.
	299	(set (make-local-variable 'log-view-file-re) "^File:[ \t]+\\(.+\\)")
	300	(set (make-local-variable 'log-view-message-re)
	301	"^commit *\\([0-9a-z]+\\)")
	302	(set (make-local-variable 'log-view-font-lock-keywords)
	303	(append
2aa0736a TTN	304	`((,log-view-message-re (1 'change-log-acknowledgement))
	305	(,log-view-file-re (1 'change-log-file-face)))
	306	;; Handle the case:
	307	;; user: foo@bar
	308	'(("^Author:[ \t]+\\([A-Za-z0-9_.+-]+@[A-Za-z0-9_.-]+\\)"
	309	(1 'change-log-email))
	310	;; Handle the case:
	311	;; user: FirstName LastName <foo@bar>
	312	("^Author:[ \t]+\\([^<(]+?\\)[ \t]*[(<]\\([A-Za-z0-9_.+-]+@[A-Za-z0-9_.-]+\\)[>)]"
	313	(1 'change-log-name)
	314	(2 'change-log-email))
	315	("^ +\\(?:\\(?:[Aa]cked\\\|[Ss]igned-[Oo]ff\\)-[Bb]y:\\)[ \t]+\\([A-Za-z0-9_.+-]+@[A-Za-z0-9_.-]+\\)"
	316	(1 'change-log-name))
	317	("^ +\\(?:\\(?:[Aa]cked\\\|[Ss]igned-[Oo]ff\\)-[Bb]y:\\)[ \t]+\\([^<(]+?\\)[ \t]*[(<]\\([A-Za-z0-9_.+-]+@[A-Za-z0-9_.-]+\\)[>)]"
	318	(1 'change-log-name)
	319	(2 'change-log-email))
	320	("^Merge: \\([0-9a-z]+\\) \\([0-9a-z]+\\)"
	321	(1 'change-log-acknowledgement)
	322	(2 'change-log-acknowledgement))
	323	("^Date: \\(.+\\)" (1 'change-log-date))
	324	("^summary:[ \t]+\\(.+\\)" (1 'log-view-message))))))
fff4a046	325
b16bd82d TTN	326	(defun vc-git-show-log-entry (revision)
	327	"Move to the log entry for REVISION.
	328	REVISION may have the form BRANCH, BRANCH~N,
	329	or BRANCH^ (where \"^\" can be repeated)."
	330	(goto-char (point-min))
	331	(search-forward "\ncommit" nil t
	332	(cond ((string-match "~\\([0-9]\\)$" revision)
	333	(1+ (string-to-number (match-string 1 revision))))
	334	((string-match "\\^+$" revision)
	335	(1+ (length (match-string 0 revision))))
	336	(t nil)))
	337	(beginning-of-line))
	338
b747d346 DN	339	(defun vc-git-diff (files &optional rev1 rev2 buffer)
b747d346 DN	340	(let ((buf (or buffer "vc-diff")))
fff4a046	341	(if (and rev1 rev2)
2aa0736a TTN	342	(vc-git-command buf 1 files "diff-tree" "--exit-code" "-p"
	343	rev1 rev2 "--")
	344	(vc-git-command buf 1 files "diff-index" "--exit-code" "-p"
	345	(or rev1 "HEAD") "--"))))
fff4a046	346
9f11ce4e SM	347	(defun vc-git-revision-table (files)
9f11ce4e SM	348	;; What about `files'?!? --Stef
108607bc DN	349	(let ((table (list "HEAD")))
	350	(with-temp-buffer
	351	(vc-git-command t nil nil "for-each-ref" "--format=%(refname)")
	352	(goto-char (point-min))
	353	(while (re-search-forward "^refs/\\(heads\\\|tags\\)/\\(.*\\)$" nil t)
	354	(push (match-string 2) table)))
	355	table))
	356
9f11ce4e SM	357	(defun vc-git-revision-completion-table (files)
9f11ce4e SM	358	(lexical-let ((files files)
108607bc DN	359	table)
108607bc DN	360	(setq table (lazy-completion-table
9f11ce4e	361	table (lambda () (vc-git-revision-table files))))
108607bc DN	362	table))
108607bc DN	363
fff4a046	364	(defun vc-git-annotate-command (file buf &optional rev)
53cc90ab	365	;; FIXME: rev is ignored
fff4a046	366	(let ((name (file-relative-name file)))
53cc90ab	367	(vc-git-command buf 0 name "blame" (if rev (concat "-r" rev)))))
fff4a046 DN	368
fff4a046 DN	369	(defun vc-git-annotate-time ()
0bcc6163	370	(and (re-search-forward "[0-9a-f]+[^()]+(.* \\([0-9]+\\)-\\([0-9]+\\)-\\([0-9]+\\) \\([0-9]+\\):\\([0-9]+\\):\\([0-9]+\\) \\([-+0-9]+\\) +[0-9]+) " nil t)
fff4a046	371	(vc-annotate-convert-time
2aa0736a TTN	372	(apply #'encode-time (mapcar (lambda (match)
	373	(string-to-number (match-string match)))
	374	'(6 5 4 3 2 1 7))))))
fff4a046	375
53cc90ab	376	(defun vc-git-annotate-extract-revision-at-line ()
2aa0736a TTN	377	(save-excursion
	378	(move-beginning-of-line 1)
	379	(and (looking-at "[0-9a-f]+")
	380	(buffer-substring-no-properties (match-beginning 0) (match-end 0)))))
53cc90ab	381
b747d346 DN	382	;;; SNAPSHOT SYSTEM
	383
	384	(defun vc-git-create-snapshot (dir name branchp)
	385	(let ((default-directory dir))
	386	(and (vc-git-command nil 0 nil "update-index" "--refresh")
	387	(if branchp
	388	(vc-git-command nil 0 nil "checkout" "-b" name)
	389	(vc-git-command nil 0 nil "tag" name)))))
	390
	391	(defun vc-git-retrieve-snapshot (dir name update)
	392	(let ((default-directory dir))
	393	(vc-git-command nil 0 nil "checkout" name)
	394	;; FIXME: update buffers if `update' is true
	395	))
	396
	397
53cc90ab	398	;;; MISCELLANEOUS
fff4a046	399
5b5afd50 ER	400	(defun vc-git-previous-revision (file rev)
5b5afd50 ER	401	"Git-specific version of `vc-previous-revision'."
fff4a046 DN	402	(let ((default-directory (file-name-directory (expand-file-name file)))
	403	(file (file-name-nondirectory file)))
	404	(vc-git-symbolic-commit
	405	(with-temp-buffer
	406	(and
5fdbecd8	407	(vc-git--out-ok "rev-list" "-2" rev "--" file)
fff4a046 DN	408	(goto-char (point-max))
	409	(bolp)
	410	(zerop (forward-line -1))
	411	(not (bobp))
	412	(buffer-substring-no-properties
2aa0736a TTN	413	(point)
2aa0736a TTN	414	(1- (point-max))))))))
fff4a046	415
5b5afd50 ER	416	(defun vc-git-next-revision (file rev)
5b5afd50 ER	417	"Git-specific version of `vc-next-revision'."
fff4a046 DN	418	(let* ((default-directory (file-name-directory
fff4a046 DN	419	(expand-file-name file)))
2aa0736a TTN	420	(file (file-name-nondirectory file))
	421	(current-rev
	422	(with-temp-buffer
	423	(and
5fdbecd8	424	(vc-git--out-ok "rev-list" "-1" rev "--" file)
2aa0736a TTN	425	(goto-char (point-max))
	426	(bolp)
	427	(zerop (forward-line -1))
	428	(bobp)
	429	(buffer-substring-no-properties
	430	(point)
	431	(1- (point-max)))))))
fff4a046 DN	432	(and current-rev
	433	(vc-git-symbolic-commit
	434	(with-temp-buffer
	435	(and
5fdbecd8	436	(vc-git--out-ok "rev-list" "HEAD" "--" file)
fff4a046 DN	437	(goto-char (point-min))
	438	(search-forward current-rev nil t)
	439	(zerop (forward-line -1))
	440	(buffer-substring-no-properties
	441	(point)
	442	(progn (forward-line 1) (1- (point))))))))))
	443
8b38ce20 DN	444	(defun vc-git-delete-file (file)
8b38ce20 DN	445	(vc-git-command nil 0 file "rm" "-f" "--"))
b0f90937	446
8b38ce20 DN	447	(defun vc-git-rename-file (old new)
8b38ce20 DN	448	(vc-git-command nil 0 (list old new) "mv" "-f" "--"))
b0f90937	449
fff4a046	450	\f
b747d346	451	;;; Internal commands
fff4a046	452
53cc90ab DN	453	(defun vc-git-root (file)
	454	(vc-find-root file ".git"))
	455
8b9783e0	456	(defun vc-git-command (buffer okstatus file-or-list &rest flags)
53cc90ab DN	457	"A wrapper around `vc-do-command' for use in vc-git.el.
53cc90ab DN	458	The difference to vc-do-command is that this function always invokes `git'."
8b9783e0	459	(apply 'vc-do-command buffer okstatus "git" file-or-list flags))
53cc90ab	460
5fdbecd8 TTN	461	(defun vc-git--call (buffer command &rest args)
	462	(apply 'call-process "git" nil buffer nil command args))
	463
	464	(defun vc-git--out-ok (command &rest args)
	465	(zerop (apply 'vc-git--call '(t nil) command args)))
	466
fff4a046 DN	467	(defun vc-git--run-command-string (file &rest args)
	468	"Run a git command on FILE and return its output as string."
	469	(let* ((ok t)
	470	(str (with-output-to-string
	471	(with-current-buffer standard-output
5fdbecd8 TTN	472	(unless (apply 'vc-git--out-ok
	473	(append args (list (file-relative-name
	474	file))))
fff4a046 DN	475	(setq ok nil))))))
	476	(and ok str)))
	477
fff4a046 DN	478	(defun vc-git-symbolic-commit (commit)
	479	"Translate COMMIT string into symbolic form.
	480	Returns nil if not possible."
	481	(and commit
	482	(with-temp-buffer
	483	(and
5fdbecd8	484	(vc-git--out-ok "name-rev" "--name-only" "--tags" commit)
fff4a046 DN	485	(goto-char (point-min))
	486	(= (forward-line 2) 1)
	487	(bolp)
	488	(buffer-substring-no-properties (point-min) (1- (point-max)))))))
	489
	490	(provide 'vc-git)
53cc90ab	491
328471d9	492	;; arch-tag: bd10664a-0e5b-48f5-a877-6c17b135be12
53cc90ab	493	;;; vc-git.el ends here