popl/popltoctl.ml

   1 (*
   2  * Copyright 2010, INRIA, University of Copenhagen
   3  * Julia Lawall, Rene Rydhof Hansen, Gilles Muller, Nicolas Palix
   4  * Copyright 2005-2009, Ecole des Mines de Nantes, University of Copenhagen
   5  * Yoann Padioleau, Julia Lawall, Rene Rydhof Hansen, Henrik Stuart, Gilles Muller, Nicolas Palix
   6  * This file is part of Coccinelle.
   7  *
   8  * Coccinelle is free software: you can redistribute it and/or modify
   9  * it under the terms of the GNU General Public License as published by
  10  * the Free Software Foundation, according to version 2 of the License.
  11  *
  12  * Coccinelle is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with Coccinelle.  If not, see <http://www.gnu.org/licenses/>.
  19  *
  20  * The authors reserve the right to distribute this or future versions of
  21  * Coccinelle under other licenses.
  22  *)
  23
  24
  25 module Past = Ast_popl
  26 module Ast = Ast_cocci
  27 module V = Visitor_ast
  28 module CTL  = Ast_ctl
  29
  30 (* --------------------------------------------------------------------- *)
  31 (* result type *)
  32
  33 type cocci_predicate = Lib_engine.predicate * Ast.meta_name Ast_ctl.modif
  34 type formula =
  35     (cocci_predicate,Ast_cocci.meta_name, Wrapper_ctl.info) Ast_ctl.generic_ctl
  36
  37 (* --------------------------------------------------------------------- *)
  38
  39 let contains_modif =
  40   let bind x y = x or y in
  41   let option_default = false in
  42   let mcode r (_,_,kind,_) =
  43     match kind with
  44       Ast.MINUS(_,_) -> true
  45     | Ast.PLUS -> failwith "not possible"
  46     | Ast.CONTEXT(_,info) -> not (info = Ast.NOTHING) in
  47   let do_nothing r k e = k e in
  48   let rule_elem r k re =
  49     let res = k re in
  50     match Ast.unwrap re with
  51       Ast.FunHeader(bef,_,fninfo,name,lp,params,rp) ->
  52       bind (mcode r ((),(),bef,[])) res
  53     | Ast.Decl(bef,_,decl) -> bind (mcode r ((),(),bef,[])) res
  54     | _ -> res in
  55   let recursor =
  56     V.combiner bind option_default
  57       mcode mcode mcode mcode mcode mcode mcode mcode mcode mcode mcode mcode
  58       mcode
  59       do_nothing do_nothing do_nothing do_nothing
  60       do_nothing do_nothing do_nothing do_nothing do_nothing do_nothing
  61       do_nothing rule_elem do_nothing do_nothing do_nothing do_nothing in
  62   recursor.V.combiner_rule_elem
  63
  64 let ctl_exists v x keep_wit = CTL.Exists(v,x,keep_wit)
  65
  66 let predmaker guard term =
  67   let pos = ("","_p") in
  68   ctl_exists true pos
  69     (if guard && contains_modif term
  70     then
  71       let v = ("","_v") in
  72       ctl_exists true v
  73         (CTL.Pred (Lib_engine.Match(term),CTL.Modif v))
  74     else CTL.Pred (Lib_engine.Match(term),CTL.Control))
  75
  76 (* --------------------------------------------------------------------- *)
  77
  78 let is_true = function CTL.True -> true | _ -> false
  79
  80 let is_false = function CTL.False -> true | _ -> false
  81
  82 let ctl_true       = CTL.True
  83
  84 let ctl_false      = CTL.False
  85
  86 let ctl_and x y    =
  87   if is_true x then y
  88   else if is_true y then x else CTL.And(CTL.STRICT,x,y)
  89
  90 let ctl_or x y     =
  91   if is_false x then y
  92   else if is_false y then x else CTL.Or(x,y)
  93
  94 let ctl_seqor x y  = CTL.SeqOr(x,y)
  95
  96 let ctl_not x      = CTL.Not(x)
  97
  98 let ctl_ax x       =
  99   if is_true x then CTL.True
 100   else CTL.AX(CTL.FORWARD,CTL.STRICT,x)
 101
 102 let after          = CTL.Pred(Lib_engine.After, CTL.Control)
 103 let exit           = CTL.Pred(Lib_engine.Exit, CTL.Control)
 104 let truepred       = CTL.Pred(Lib_engine.TrueBranch, CTL.Control)
 105 let retpred        = CTL.Pred(Lib_engine.Return, CTL.Control)
 106
 107 let string2var x = ("",x)
 108
 109 let labelctr = ref 0
 110 let get_label_ctr _ =
 111   let cur = !labelctr in
 112   labelctr := cur + 1;
 113   string2var (Printf.sprintf "l%d" cur)
 114
 115 let ctl_au x seq_after y =
 116   let lv = get_label_ctr() in
 117   let labelpred = CTL.Pred(Lib_engine.Label lv,CTL.Control) in
 118   let preflabelpred = CTL.Pred(Lib_engine.PrefixLabel lv,CTL.Control) in
 119   let matchgoto = CTL.Pred(Lib_engine.Goto,CTL.Control) in
 120   let matchbreak =
 121     predmaker false
 122       (Ast.make_term
 123          (Ast.Break(Ast.make_mcode "break",Ast.make_mcode ";"))) in
 124   let matchcontinue =
 125     predmaker false
 126       (Ast.make_term
 127          (Ast.Continue(Ast.make_mcode "continue",Ast.make_mcode ";"))) in
 128   let stop_early =
 129     ctl_or after
 130       (ctl_and (ctl_and truepred labelpred)
 131          (CTL.AU
 132             (CTL.FORWARD,CTL.STRICT,preflabelpred,
 133              ctl_and preflabelpred
 134                (ctl_or retpred
 135                   (ctl_and (ctl_or (ctl_or matchgoto matchbreak) matchcontinue)
 136                         (CTL.AG
 137                            (CTL.FORWARD,CTL.STRICT,
 138                             ctl_not seq_after))))))) in
 139   CTL.AU(CTL.FORWARD,CTL.STRICT,x,ctl_or y stop_early)
 140
 141 let ctl_uncheck x  = CTL.Uncheck(x)
 142
 143 (* --------------------------------------------------------------------- *)
 144
 145 let rec ctl_seq keep_wit a = function
 146     Past.Seq(elem,seq) ->
 147       ctl_element keep_wit (ctl_seq keep_wit a seq) elem
 148   | Past.Empty -> a
 149   | Past.SExists(var,seq) -> ctl_exists keep_wit var (ctl_seq keep_wit a seq)
 150
 151 and ctl_element keep_wit a = function
 152     Past.Term(term) -> ctl_and (predmaker keep_wit term) (ctl_ax a)
 153   | Past.Or(seq1,seq2) ->
 154       ctl_seqor (ctl_seq keep_wit a seq1) (ctl_seq keep_wit a seq2)
 155   | Past.DInfo(dots,seq_bef,seq_aft) ->
 156       let shortest l =
 157         List.fold_left ctl_or ctl_false
 158           (List.map (ctl_element false ctl_true) l) in
 159       let s = shortest (Common.union_set seq_bef seq_aft) in
 160       ctl_au (ctl_and (guard_ctl_dots keep_wit dots) (ctl_not s))
 161         (shortest seq_aft) a
 162   | Past.EExists(var,elem) ->
 163       ctl_exists keep_wit var (ctl_element keep_wit a elem)
 164
 165 (* --------------------------------------------------------------------- *)
 166
 167 and guard_ctl_seq keep_wit = function
 168     Past.Seq(elem,Past.Empty) -> guard_ctl_element keep_wit elem
 169   | Past.Seq(elem,seq) ->
 170       ctl_element keep_wit (guard_ctl_seq keep_wit seq) elem
 171   | Past.Empty -> ctl_true
 172   | Past.SExists(var,seq) ->
 173       ctl_exists keep_wit var (guard_ctl_seq keep_wit seq)
 174
 175 and guard_ctl_element keep_wit = function
 176     Past.Term(term) -> predmaker keep_wit term
 177   | Past.Or(seq1,seq2) ->
 178       ctl_seqor (guard_ctl_seq keep_wit seq1) (guard_ctl_seq keep_wit seq2)
 179   | Past.DInfo(dots,seq_bef,seq_aft) ->
 180       let shortest l =
 181         List.fold_left ctl_or ctl_false
 182           (List.map (ctl_element false ctl_true) l) in
 183       let s = shortest (Common.union_set seq_bef seq_aft) in
 184       let aft = ctl_or s exit in
 185       ctl_au (ctl_and (guard_ctl_dots keep_wit dots) (ctl_not s))
 186         (shortest seq_aft) aft
 187   | Past.EExists(var,elem) ->
 188       ctl_exists keep_wit var (guard_ctl_element keep_wit elem)
 189
 190 and guard_ctl_dots keep_wit = function
 191     Past.Dots -> ctl_true
 192   | Past.Nest(_) when not keep_wit -> ctl_true
 193   | Past.Nest(seq) ->
 194       ctl_or (guard_ctl_seq true seq) (ctl_not (guard_ctl_seq false seq))
 195   | Past.When(dots,seq) ->
 196       ctl_and
 197         (guard_ctl_dots keep_wit dots)
 198         (ctl_not (ctl_seq false ctl_true seq))
 199   | Past.DExists(var,dots) ->
 200       ctl_exists keep_wit var (guard_ctl_dots keep_wit dots)
 201
 202 (* --------------------------------------------------------------------- *)
 203
 204 let toctl sl = ctl_seq true ctl_true sl