Release coccinelle-0.1.2
[bpt/coccinelle.git] / parsing_cocci / .#unparse_ast0.ml.1.109
1 (*
2 * Copyright 2005-2008, Ecole des Mines de Nantes, University of Copenhagen
3 * Yoann Padioleau, Julia Lawall, Rene Rydhof Hansen, Henrik Stuart, Gilles Muller
4 * This file is part of Coccinelle.
5 *
6 * Coccinelle is free software: you can redistribute it and/or modify
7 * it under the terms of the GNU General Public License as published by
8 * the Free Software Foundation, according to version 2 of the License.
9 *
10 * Coccinelle is distributed in the hope that it will be useful,
11 * but WITHOUT ANY WARRANTY; without even the implied warranty of
12 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
13 * GNU General Public License for more details.
14 *
15 * You should have received a copy of the GNU General Public License
16 * along with Coccinelle. If not, see <http://www.gnu.org/licenses/>.
17 *
18 * The authors reserve the right to distribute this or future versions of
19 * Coccinelle under other licenses.
20 *)
21
22
23 open Format
24 module Ast0 = Ast0_cocci
25 module U = Pretty_print_cocci
26
27 let quiet = ref true (* true = no decoration on - context, etc *)
28
29 let start_block str =
30 force_newline(); print_string " "; open_box 0
31
32 let end_block str =
33 close_box(); force_newline ()
34
35 let print_option = Common.do_option
36 let print_between = Common.print_between
37
38 (* --------------------------------------------------------------------- *)
39 (* Positions *)
40
41 let meta_pos = function
42 Ast0.MetaPos(name,_,_) ->
43 print_string "@";
44 let (_,name) = Ast0.unwrap_mcode name in
45 print_string name
46 | Ast0.NoMetaPos -> ()
47
48 (* --------------------------------------------------------------------- *)
49 (* Modified code *)
50
51 let mcodekind brackets fn x info = function
52 Ast0.MINUS(plus_stream) ->
53 let (lb,rb) =
54 if !quiet
55 then ("","")
56 else
57 match brackets with
58 Some x -> ("[","]^"^(string_of_int x))
59 | None -> ("","") in
60 let (plus_stream,_) = !plus_stream in
61 if !quiet
62 then fn x
63 else (print_string "-";
64 print_string lb; fn x; print_string rb);
65 U.print_anything ">>> " plus_stream
66 | Ast0.CONTEXT(plus_streams) ->
67 let (lb,rb) =
68 if !quiet
69 then ("","")
70 else
71 match brackets with
72 Some x -> ("[",("]^"^(string_of_int x))) | None -> ("","") in
73 let (plus_streams,t1,t2) = !plus_streams in
74 U.print_around
75 (function x ->
76 print_string lb; fn x; print_string rb)
77 x plus_streams
78 | Ast0.PLUS ->
79 List.iter (function s -> print_string s; force_newline())
80 info.Ast0.strings_before;
81 fn x;
82 List.iter (function s -> force_newline(); print_string s)
83 info.Ast0.strings_after
84 | Ast0.MIXED(plus_streams) ->
85 let (lb,rb) =
86 if !quiet
87 then ("","")
88 else
89 let n =
90 match brackets with Some x -> "^"^(string_of_int x) | None -> "" in
91 ("§","½"^n) in
92 let (plus_streams,_,_) = !plus_streams in
93 U.print_around (function x -> print_string lb; fn x; print_string rb)
94 x plus_streams
95
96 let mcode fn (x,_,info,mc,pos) =
97 let fn x = fn x; meta_pos !pos in
98 mcodekind (Some info.Ast0.line_start)(*None*) fn x info mc
99
100 let print_context x fn =
101 mcodekind (Some (Ast0.get_line x)) fn () (Ast0.get_info x)
102 (Ast0.get_mcodekind x)
103
104 let print_meta (_,name) = print_string name
105
106 (* --------------------------------------------------------------------- *)
107 (* --------------------------------------------------------------------- *)
108 (* Dots *)
109
110 let dots between fn d =
111 print_context d
112 (function _ ->
113 match Ast0.unwrap d with
114 Ast0.DOTS(l) -> print_between between fn l
115 | Ast0.CIRCLES(l) -> print_between between fn l
116 | Ast0.STARS(l) -> print_between between fn l)
117
118 (* --------------------------------------------------------------------- *)
119
120 let print_types = function
121 None -> ()
122 | Some ty ->
123 print_string "/* ";
124 Format.print_flush();
125 print_between (function _ -> print_string ", ") Type_cocci.typeC ty;
126 Format.print_flush();
127 print_string " */"
128
129 (* --------------------------------------------------------------------- *)
130 (* Identifier *)
131
132 let rec ident i =
133 print_context i
134 (function _ ->
135 match Ast0.unwrap i with
136 Ast0.Id(name) -> mcode print_string name
137 | Ast0.MetaId(name,_,_) -> mcode print_meta name
138 | Ast0.MetaFunc(name,_,_) -> mcode print_meta name
139 | Ast0.MetaLocalFunc(name,_,_) -> mcode print_meta name
140 | Ast0.OptIdent(id) -> print_string "?"; ident id
141 | Ast0.UniqueIdent(id) -> print_string "!"; ident id)
142
143 (* --------------------------------------------------------------------- *)
144 (* Expression *)
145
146 let print_string_box s = print_string s; open_box 0
147
148 let rec expression e =
149 print_option Type_cocci.typeC (Ast0.get_type e);
150 print_context e
151 (function _ ->
152 match Ast0.unwrap e with
153 Ast0.Ident(id) -> ident id
154 | Ast0.Constant(const) -> mcode U.constant const
155 | Ast0.FunCall(fn,lp,args,rp) ->
156 expression fn; mcode print_string_box lp;
157 let _ = dots (function _ -> ()) expression args in
158 close_box(); mcode print_string rp
159 | Ast0.Assignment(left,op,right,_) ->
160 expression left; print_string " "; mcode U.assignOp op;
161 print_string " "; expression right
162 | Ast0.CondExpr(exp1,why,exp2,colon,exp3) ->
163 expression exp1; print_string " "; mcode print_string why;
164 print_option (function e -> print_string " "; expression e) exp2;
165 print_string " "; mcode print_string colon; expression exp3
166 | Ast0.Postfix(exp,op) -> expression exp; mcode U.fixOp op
167 | Ast0.Infix(exp,op) -> mcode U.fixOp op; expression exp
168 | Ast0.Unary(exp,op) -> mcode U.unaryOp op; expression exp
169 | Ast0.Binary(left,op,right) ->
170 print_string "(";
171 expression left; print_string " "; mcode U.binaryOp op;
172 print_string " "; expression right;
173 print_string ")"
174 | Ast0.Nested(left,op,right) ->
175 print_string "(";
176 expression left; print_string " "; mcode U.binaryOp op;
177 print_string " "; expression right;
178 print_string ")"
179 | Ast0.Paren(lp,exp,rp) ->
180 mcode print_string_box lp; expression exp; close_box();
181 mcode print_string rp
182 | Ast0.ArrayAccess(exp1,lb,exp2,rb) ->
183 expression exp1; mcode print_string_box lb; expression exp2;
184 close_box(); mcode print_string rb
185 | Ast0.RecordAccess(exp,pt,field) ->
186 expression exp; mcode print_string pt; ident field
187 | Ast0.RecordPtAccess(exp,ar,field) ->
188 expression exp; mcode print_string ar; ident field
189 | Ast0.Cast(lp,ty,rp,exp) ->
190 mcode print_string_box lp; typeC ty; close_box();
191 mcode print_string rp; expression exp
192 | Ast0.SizeOfExpr(szf,exp) ->
193 mcode print_string szf; expression exp
194 | Ast0.SizeOfType(szf,lp,ty,rp) ->
195 mcode print_string szf;
196 mcode print_string_box lp; typeC ty; close_box();
197 mcode print_string rp
198 | Ast0.TypeExp(ty) -> typeC ty
199 | Ast0.MetaErr(name,_,_) -> mcode print_meta name
200 | Ast0.MetaExpr(name,_,ty,_,_) ->
201 mcode print_meta name; print_types ty
202 | Ast0.MetaExprList(name,_,_) -> mcode print_meta name
203 | Ast0.EComma(cm) -> mcode print_string cm; print_space()
204 | Ast0.DisjExpr(_,exp_list,_,_) ->
205 print_string "\n("; force_newline();
206 print_between
207 (function _ -> print_string "\n|"; force_newline())
208 expression exp_list;
209 print_string "\n)"
210 | Ast0.NestExpr(starter,expr_dots,ender,None,multi) ->
211 mcode print_string starter;
212 start_block(); dots force_newline expression expr_dots; end_block();
213 mcode print_string ender
214 | Ast0.NestExpr(starter,expr_dots,ender,Some whencode,multi) ->
215 mcode print_string starter; print_string " WHEN != ";
216 expression whencode;
217 start_block(); dots force_newline expression expr_dots; end_block();
218 mcode print_string ender
219 | Ast0.Edots(dots,Some whencode)
220 | Ast0.Ecircles(dots,Some whencode)
221 | Ast0.Estars(dots,Some whencode) ->
222 mcode print_string dots; print_string " WHEN != ";
223 expression whencode
224 | Ast0.Edots(dots,None)
225 | Ast0.Ecircles(dots,None)
226 | Ast0.Estars(dots,None) -> mcode print_string dots
227 | Ast0.OptExp(exp) -> print_string "?"; expression exp
228 | Ast0.UniqueExp(exp) -> print_string "!"; expression exp)
229
230 and expression_dots x = dots (function _ -> ()) expression x
231
232 (* --------------------------------------------------------------------- *)
233 (* Types *)
234
235 and print_function_pointer (ty,lp1,star,rp1,lp2,params,rp2) fn =
236 typeC ty; mcode print_string lp1; mcode print_string star; fn();
237 mcode print_string rp1; mcode print_string lp2;
238 parameter_list params; mcode print_string rp2
239
240 and print_function_type (ty,lp1,params,rp1) fn =
241 print_option typeC ty; fn(); mcode print_string lp1;
242 parameter_list params; mcode print_string rp1
243
244 and typeC t =
245 print_context t
246 (function _ ->
247 match Ast0.unwrap t with
248 Ast0.ConstVol(cv,ty) ->
249 mcode U.const_vol cv; print_string " "; typeC ty
250 | Ast0.BaseType(ty,sgn) ->
251 print_option (mcode U.sign) sgn; mcode U.baseType ty
252 | Ast0.ImplicitInt(sgn) -> mcode U.sign sgn
253 | Ast0.Pointer(ty,star) -> typeC ty; mcode print_string star
254 | Ast0.FunctionPointer(ty,lp1,star,rp1,lp2,params,rp2) ->
255 print_function_pointer (ty,lp1,star,rp1,lp2,params,rp2)
256 (function _ -> ())
257 | Ast0.FunctionType(ty,lp1,params,rp1) ->
258 print_function_type (ty,lp1,params,rp1) (function _ -> ())
259 | Ast0.Array(ty,lb,size,rb) ->
260 typeC ty; mcode print_string lb; print_option expression size;
261 mcode print_string rb
262 | Ast0.StructUnionName(kind,name) ->
263 mcode U.structUnion kind;
264 print_option (function x -> ident x; print_string " ") name
265 | Ast0.StructUnionDef(ty,lb,decls,rb) ->
266 typeC ty; mcode print_string lb;
267 dots force_newline declaration decls;
268 mcode print_string rb
269 | Ast0.TypeName(name)-> mcode print_string name; print_string " "
270 | Ast0.MetaType(name,_)-> mcode print_meta name; print_string " "
271 | Ast0.DisjType(lp,types,mids,rp) ->
272 print_string "\n"; mcode print_string lp; force_newline();
273 print_between
274 (function _ -> print_string "\n|"; force_newline())
275 typeC types;
276 print_string "\n"; mcode print_string rp
277 | Ast0.OptType(ty) -> print_string "?"; typeC ty
278 | Ast0.UniqueType(ty) -> print_string "!"; typeC ty)
279
280 (* --------------------------------------------------------------------- *)
281 (* Variable declaration *)
282 (* Even if the Cocci program specifies a list of declarations, they are
283 split out into multiple declarations of a single variable each. *)
284
285 and print_named_type ty id =
286 match Ast0.unwrap ty with
287 Ast0.FunctionPointer(ty,lp1,star,rp1,lp2,params,rp2) ->
288 print_function_pointer (ty,lp1,star,rp1,lp2,params,rp2)
289 (function _ -> print_string " "; ident id)
290 | Ast0.FunctionType(ty,lp1,params,rp1) ->
291 print_function_type (ty,lp1,params,rp1)
292 (function _ -> print_string " "; ident id)
293 | Ast0.Array(ty,lb,size,rb) ->
294 let rec loop ty k =
295 match Ast0.unwrap ty with
296 Ast0.Array(ty,lb,size,rb) ->
297 loop ty
298 (function _ ->
299 k ();
300 mcode print_string lb;
301 print_option expression size;
302 mcode print_string rb)
303 | _ -> typeC ty; ident id; k () in
304 loop ty (function _ -> ())
305 | _ -> typeC ty; ident id
306
307 and declaration d =
308 print_context d
309 (function _ ->
310 match Ast0.unwrap d with
311 Ast0.Init(stg,ty,id,eq,ini,sem) ->
312 print_option (mcode U.storage) stg;
313 print_named_type ty id;
314 print_string " ";
315 mcode print_string eq; print_string " "; initialiser ini;
316 mcode print_string sem
317 | Ast0.UnInit(stg,ty,id,sem) ->
318 print_option (mcode U.storage) stg; print_named_type ty id;
319 mcode print_string sem
320 | Ast0.MacroDecl(name,lp,args,rp,sem) ->
321 ident name; mcode print_string_box lp;
322 let _ = dots (function _ -> ()) expression args in
323 close_box(); mcode print_string rp; mcode print_string sem
324 | Ast0.TyDecl(ty,sem) -> typeC ty; mcode print_string sem
325 | Ast0.Typedef(stg,ty,id,sem) ->
326 mcode print_string stg; typeC ty; typeC id;
327 mcode print_string sem
328 | Ast0.DisjDecl(_,decls,_,_) ->
329 print_string "\n("; force_newline();
330 print_between
331 (function _ -> print_string "\n|"; force_newline())
332 declaration decls;
333 print_string "\n)"
334 | Ast0.Ddots(dots,Some whencode) ->
335 mcode print_string dots; print_string " when != ";
336 declaration whencode
337 | Ast0.Ddots(dots,None) -> mcode print_string dots
338 | Ast0.OptDecl(decl) -> print_string "?"; declaration decl
339 | Ast0.UniqueDecl(decl) -> print_string "!"; declaration decl)
340
341 and declaration_dots l = dots (function _ -> ()) declaration l
342
343 (* --------------------------------------------------------------------- *)
344 (* Initialiser *)
345
346 and initialiser i =
347 print_context i
348 (function _ ->
349 match Ast0.unwrap i with
350 Ast0.InitExpr(exp) -> expression exp
351 | Ast0.InitList(lb,initlist,rb) ->
352 mcode print_string lb; open_box 0;
353 let _ = dots (function _ -> ()) initialiser initlist in
354 close_box(); mcode print_string rb
355 | Ast0.InitGccDotName(dot,name,eq,ini) ->
356 mcode print_string dot; ident name; print_string " ";
357 mcode print_string eq; print_string " "; initialiser ini
358 | Ast0.InitGccName(name,eq,ini) ->
359 ident name; mcode print_string eq; initialiser ini
360 | Ast0.InitGccIndex(lb,exp,rb,eq,ini) ->
361 mcode print_string lb; expression exp; mcode print_string rb;
362 print_string " "; mcode print_string eq; print_string " ";
363 initialiser ini
364 | Ast0.InitGccRange(lb,exp1,dots,exp2,rb,eq,ini) ->
365 mcode print_string lb; expression exp1; mcode print_string dots;
366 expression exp2; mcode print_string rb;
367 print_string " "; mcode print_string eq; print_string " ";
368 initialiser ini
369 | Ast0.IComma(cm) -> mcode print_string cm; force_newline()
370 | Ast0.Idots(d,Some whencode) ->
371 mcode print_string d; print_string " WHEN != ";
372 initialiser whencode
373 | Ast0.Idots(d,None) -> mcode print_string d
374 | Ast0.OptIni(ini) -> print_string "?"; initialiser ini
375 | Ast0.UniqueIni(ini) -> print_string "!"; initialiser ini)
376
377 and initialiser_list l = dots (function _ -> ()) initialiser l
378
379 (* --------------------------------------------------------------------- *)
380 (* Parameter *)
381
382 and parameterTypeDef p =
383 print_context p
384 (function _ ->
385 match Ast0.unwrap p with
386 Ast0.VoidParam(ty) -> typeC ty
387 | Ast0.Param(ty,Some id) -> print_named_type ty id
388 | Ast0.Param(ty,None) -> typeC ty
389 | Ast0.MetaParam(name,_) -> mcode print_meta name
390 | Ast0.MetaParamList(name,_,_) -> mcode print_meta name
391 | Ast0.PComma(cm) -> mcode print_string cm; print_space()
392 | Ast0.Pdots(dots) -> mcode print_string dots
393 | Ast0.Pcircles(dots) -> mcode print_string dots
394 | Ast0.OptParam(param) -> print_string "?"; parameterTypeDef param
395 | Ast0.UniqueParam(param) -> print_string "!"; parameterTypeDef param)
396
397 and parameter_list l = dots (function _ -> ()) parameterTypeDef l
398
399 (* --------------------------------------------------------------------- *)
400 (* Top-level code *)
401
402 and statement arity s =
403 print_context s
404 (function _ ->
405 match Ast0.unwrap s with
406 Ast0.FunDecl(_,fninfo,name,lp,params,rp,lbrace,body,rbrace) ->
407 print_string arity;
408 List.iter print_fninfo fninfo;
409 ident name; mcode print_string_box lp;
410 parameter_list params; close_box(); mcode print_string rp;
411 print_string " ";
412 print_string arity; mcode print_string lbrace; start_block();
413 dots force_newline (statement arity) body;
414 end_block(); print_string arity; mcode print_string rbrace
415 | Ast0.Decl(_,decl) -> print_string arity; declaration decl
416 | Ast0.Seq(lbrace,body,rbrace) ->
417 print_string arity; mcode print_string lbrace; start_block();
418 dots force_newline (statement arity) body;
419 end_block(); print_string arity; mcode print_string rbrace
420 | Ast0.ExprStatement(exp,sem) ->
421 print_string arity; expression exp; mcode print_string sem
422 | Ast0.IfThen(iff,lp,exp,rp,branch1,(info,aft)) ->
423 print_string arity;
424 mcode print_string iff; print_string " "; mcode print_string_box lp;
425 expression exp; close_box(); mcode print_string rp; print_string " ";
426 statement arity branch1;
427 mcode (function _ -> ()) ((),(),info,aft,ref Ast0.NoMetaPos)
428 | Ast0.IfThenElse(iff,lp,exp,rp,branch1,els,branch2,(info,aft)) ->
429 print_string arity;
430 mcode print_string iff; print_string " "; mcode print_string_box lp;
431 expression exp; close_box(); mcode print_string rp; print_string " ";
432 statement arity branch1;
433 print_string arity; mcode print_string els; print_string " ";
434 statement arity branch2;
435 mcode (function _ -> ()) ((),(),info,aft,ref Ast0.NoMetaPos)
436 | Ast0.While(whl,lp,exp,rp,body,(info,aft)) ->
437 print_string arity;
438 mcode print_string whl; print_string " "; mcode print_string_box lp;
439 expression exp; close_box(); mcode print_string rp; print_string " ";
440 statement arity body;
441 mcode (function _ -> ()) ((),(),info,aft,ref Ast0.NoMetaPos)
442 | Ast0.Do(d,body,whl,lp,exp,rp,sem) ->
443 print_string arity; mcode print_string d; print_string " ";
444 statement arity body;
445 print_string arity;
446 mcode print_string whl; print_string " "; mcode print_string_box lp;
447 expression exp; close_box(); mcode print_string rp;
448 mcode print_string sem
449 | Ast0.For(fr,lp,e1,sem1,e2,sem2,e3,rp,body,(info,aft)) ->
450 print_string arity;
451 mcode print_string fr; mcode print_string_box lp;
452 print_option expression e1; mcode print_string sem1;
453 print_option expression e2; mcode print_string sem2;
454 print_option expression e3; close_box();
455 mcode print_string rp; print_string " "; statement arity body;
456 mcode (function _ -> ()) ((),(),info,aft,ref Ast0.NoMetaPos)
457 | Ast0.Iterator(nm,lp,args,rp,body,(info,aft)) ->
458 print_string arity;
459 ident nm; print_string " "; mcode print_string_box lp;
460 let _ = dots (function _ -> ()) expression args in
461 close_box(); mcode print_string rp; print_string " ";
462 statement arity body;
463 mcode (function _ -> ()) ((),(),info,aft,ref Ast0.NoMetaPos)
464 | Ast0.Switch(switch,lp,exp,rp,lb,cases,rb) ->
465 print_string arity;
466 mcode print_string switch; print_string " ";
467 mcode print_string_box lp; expression exp; close_box();
468 mcode print_string rp; print_string " "; mcode print_string lb;
469 dots force_newline (case_line arity) cases;
470 mcode print_string rb
471 | Ast0.Break(br,sem) ->
472 print_string arity; mcode print_string br; mcode print_string sem
473 | Ast0.Continue(cont,sem) ->
474 print_string arity; mcode print_string cont; mcode print_string sem
475 | Ast0.Label(l,dd) -> ident l; print_string ":"
476 | Ast0.Goto(goto,l,sem) ->
477 mcode print_string goto; ident l; mcode print_string sem
478 | Ast0.Return(ret,sem) ->
479 print_string arity; mcode print_string ret; mcode print_string sem
480 | Ast0.ReturnExpr(ret,exp,sem) ->
481 print_string arity; mcode print_string ret; print_string " ";
482 expression exp; mcode print_string sem
483 | Ast0.MetaStmt(name,pure) ->
484 print_string arity; mcode print_meta name;(*
485 print_string "^";
486 (match pure with
487 Ast0.Pure -> print_string "pure"
488 | Ast0.Impure -> print_string "impure"
489 | Ast0.Context -> print_string "context"
490 | Ast0.PureContext -> print_string "pure_context")*)
491 | Ast0.MetaStmtList(name,_) ->
492 print_string arity; mcode print_meta name
493 | Ast0.Disj(_,statement_dots_list,_,_) ->
494 print_string arity;
495 print_string "\n("; force_newline();
496 print_between
497 (function _ -> print_string "\n|"; force_newline())
498 (dots force_newline (statement arity))
499 statement_dots_list;
500 print_string "\n)"
501 | Ast0.Nest(starter,stmt_dots,ender,whn,multi) ->
502 print_string arity;
503 mcode print_string starter;
504 open_box 0;
505 List.iter
506 (whencode (dots force_newline (statement "")) (statement ""))
507 whn;
508 close_box();
509 start_block();
510 dots force_newline (statement arity) stmt_dots;
511 end_block();
512 mcode print_string ender
513 | Ast0.Exp(exp) -> print_string arity; expression exp
514 | Ast0.TopExp(exp) -> print_string arity; expression exp
515 | Ast0.Ty(ty) -> print_string arity; typeC ty
516 | Ast0.TopInit(init) -> initialiser init
517 | Ast0.Dots(d,whn) | Ast0.Circles(d,whn) | Ast0.Stars(d,whn) ->
518 print_string arity; mcode print_string d;
519 List.iter
520 (whencode (dots force_newline (statement "")) (statement ""))
521 whn
522 | Ast0.Include(inc,s) ->
523 mcode print_string inc; print_string " "; mcode U.inc_file s
524 | Ast0.Define(def,id,params,body) ->
525 mcode print_string def; print_string " "; ident id;
526 print_define_parameters params;
527 print_string " ";
528 dots force_newline (statement arity) body
529 | Ast0.OptStm(re) -> statement "?" re
530 | Ast0.UniqueStm(re) -> statement "!" re)
531
532 and print_define_parameters params =
533 match Ast0.unwrap params with
534 Ast0.NoParams -> ()
535 | Ast0.DParams(lp,params,rp) ->
536 mcode print_string lp;
537 dots (function _ -> ()) print_define_param params; mcode print_string rp
538
539 and print_define_param param =
540 match Ast0.unwrap param with
541 Ast0.DParam(id) -> ident id
542 | Ast0.DPComma(comma) -> mcode print_string comma
543 | Ast0.DPdots(dots) -> mcode print_string dots
544 | Ast0.DPcircles(circles) -> mcode print_string circles
545 | Ast0.OptDParam(dp) -> print_string "?"; print_define_param dp
546 | Ast0.UniqueDParam(dp) -> print_string "!"; print_define_param dp
547
548 and print_fninfo = function
549 Ast0.FStorage(stg) -> mcode U.storage stg
550 | Ast0.FType(ty) -> typeC ty
551 | Ast0.FInline(inline) -> mcode print_string inline
552 | Ast0.FAttr(attr) -> mcode print_string attr
553
554 and whencode notfn alwaysfn = function
555 Ast0.WhenNot a ->
556 print_string " WHEN != "; open_box 0; notfn a; close_box()
557 | Ast0.WhenAlways a ->
558 print_string " WHEN = "; open_box 0; alwaysfn a; close_box()
559 | Ast0.WhenModifier x -> print_string " WHEN "; U.print_when_modif x
560 | Ast0.WhenNotTrue a ->
561 print_string " WHEN != TRUE "; open_box 0; expression a; close_box()
562 | Ast0.WhenNotFalse a ->
563 print_string " WHEN != FALSE "; open_box 0; expression a; close_box()
564
565 and case_line arity c =
566 print_context c
567 (function _ ->
568 match Ast0.unwrap c with
569 Ast0.Default(def,colon,code) ->
570 print_string arity;
571 mcode print_string def; mcode print_string colon; print_string " ";
572 dots force_newline (statement arity) code
573 | Ast0.Case(case,exp,colon,code) ->
574 print_string arity;
575 mcode print_string case; print_string " "; expression exp;
576 mcode print_string colon; print_string " ";
577 dots force_newline (statement arity) code
578 | Ast0.OptCase(case) -> case_line "?" case)
579
580 and statement_dots l = dots (function _ -> ()) (statement "") l
581 and case_dots l = dots (function _ -> ()) (case_line "") l
582
583 (* --------------------------------------------------------------------- *)
584 (* Top level code *)
585
586 let top_level t =
587 print_context t
588 (function _ ->
589 match Ast0.unwrap t with
590 Ast0.FILEINFO(old_file,new_file) ->
591 print_string "--- "; mcode print_string old_file; force_newline();
592 print_string "+++ "; mcode print_string new_file
593 | Ast0.DECL(stmt) -> statement "" stmt
594 | Ast0.CODE(stmt_dots) ->
595 dots force_newline (statement "") stmt_dots
596 | Ast0.ERRORWORDS(exps) ->
597 print_string "error words = [";
598 print_between (function _ -> print_string ", ") expression exps;
599 print_string "]"
600 | Ast0.OTHER(s) ->
601 print_string "OTHER("; statement "" s; print_string ")")
602
603 let rule =
604 print_between (function _ -> force_newline(); force_newline()) top_level
605
606 let unparse_anything x =
607 let q = !quiet in
608 quiet := true;
609 (match x with
610 Ast0.DotsExprTag(d) ->
611 print_string "ExpDots:"; force_newline();
612 expression_dots d
613 | Ast0.DotsParamTag(d) ->
614 parameter_list d
615 | Ast0.DotsInitTag(d) ->
616 initialiser_list d
617 | Ast0.DotsStmtTag(d) ->
618 print_string "StmDots:"; force_newline();
619 statement_dots d
620 | Ast0.DotsDeclTag(d) ->
621 declaration_dots d
622 | Ast0.DotsCaseTag(d) ->
623 case_dots d
624 | Ast0.IdentTag(d) ->
625 ident d
626 | Ast0.ExprTag(d) | Ast0.ArgExprTag(d) | Ast0.TestExprTag(d) ->
627 print_string "Exp:"; force_newline();
628 expression d
629 | Ast0.TypeCTag(d) ->
630 typeC d
631 | Ast0.ParamTag(d) ->
632 parameterTypeDef d
633 | Ast0.InitTag(d) ->
634 initialiser d
635 | Ast0.DeclTag(d) ->
636 declaration d
637 | Ast0.StmtTag(d) ->
638 print_string "Stm:"; force_newline();
639 statement "" d
640 | Ast0.CaseLineTag(d) ->
641 case_line "" d
642 | Ast0.TopTag(d) ->
643 top_level d
644 | Ast0.IsoWhenTag(x) -> U.print_when_modif x
645 | Ast0.IsoWhenTTag(e) -> expression e
646 | Ast0.IsoWhenFTag(e) -> expression e
647 | Ast0.MetaPosTag(var) -> meta_pos var);
648 quiet := q;
649 print_newline()
650
651 let unparse x =
652 print_string "\n@@\n@@";
653 force_newline();
654 force_newline();
655 rule x;
656 print_newline()
657
658 let unparse_to_string x = Common.format_to_string (function _ -> unparse x)