| 1 | ad |
| 2 | dnl Process this file with autoconf to produce a configure script. |
| 3 | dnl The ONLY thing this is used for is to configure for different |
| 4 | dnl linux architectures and configurations, it is not used to make the |
| 5 | dnl code more portable |
| 6 | |
| 7 | dnl You MUST have an environment that has all the POSIX functions and |
| 8 | dnl some of the more populare bsd/sysv ones (like select). You'll also |
| 9 | dnl need a C++ compiler that is semi-standard conformant, exceptions are |
| 10 | dnl not used but STL is. |
| 11 | |
| 12 | dnl 'make -f Makefile startup' will generate the configure file from |
| 13 | dnl configure.in correctly and can be run at any time |
| 14 | |
| 15 | AC_INIT(configure.in) |
| 16 | AC_CONFIG_AUX_DIR(buildlib) |
| 17 | AC_CONFIG_HEADER(include/config.h:buildlib/config.h.in include/apti18n.h:buildlib/apti18n.h.in) |
| 18 | |
| 19 | dnl -- SET THIS TO THE RELEASE VERSION -- |
| 20 | AC_DEFINE_UNQUOTED(VERSION,"0.4.11") |
| 21 | AC_DEFINE_UNQUOTED(PACKAGE,"apt") |
| 22 | |
| 23 | dnl Check the archs, we want the target type. |
| 24 | AC_CANONICAL_SYSTEM |
| 25 | |
| 26 | dnl Check our C compiler |
| 27 | AC_CHECK_TOOL_PREFIX |
| 28 | AC_PROG_CC |
| 29 | AC_ISC_POSIX |
| 30 | |
| 31 | dnl Check for other programs |
| 32 | AC_PROG_CXX |
| 33 | AC_PROG_CPP |
| 34 | AC_PROG_RANLIB |
| 35 | AC_CHECK_TOOL(AR,ar,"ar") |
| 36 | |
| 37 | dnl Checks for sockets |
| 38 | SAVE_LIBS="$LIBS" |
| 39 | LIBS="" |
| 40 | AC_SEARCH_LIBS(gethostbyname,nsl) |
| 41 | AC_SEARCH_LIBS(connect,socket) |
| 42 | SOCKETLIBS="$LIBS" |
| 43 | AC_SUBST(SOCKETLIBS) |
| 44 | LIBS="$SAVE_LIBS" |
| 45 | |
| 46 | dnl Checks for pthread -- disabled due to glibc bugs jgg |
| 47 | dnl AC_CHECK_LIB(pthread, pthread_create,[AC_DEFINE(HAVE_PTHREAD) PTHREADLIB="-lpthread"]) |
| 48 | AC_SUBST(PTHREADLIB) |
| 49 | dnl if test "$PTHREADLIB" != "-lpthread"; then |
| 50 | dnl AC_MSG_ERROR(failed: I need posix threads, pthread) |
| 51 | dnl fi |
| 52 | |
| 53 | dnl Find the version of python we are using and ensure the library and header |
| 54 | dnl are available.. Also get all the paths and options from the python setup |
| 55 | dnl makefile. |
| 56 | AC_CACHE_CHECK("python version", ac_cv_ver_python, [ac_cv_ver_python=`python -c 'import sys;print sys.version[[:3]]' 2> /dev/null`]) |
| 57 | AC_CACHE_CHECK("python prefix", ac_cv_prefix_python, [ac_cv_prefix_python=`python -c 'import sys;print sys.prefix' 2> /dev/null`]) |
| 58 | AC_CACHE_CHECK("python exec prefix", ac_cv_execprefix_python, [ac_cv_execprefix_python=`python -c 'import sys;print sys.exec_prefix' 2> /dev/null`]) |
| 59 | if test "x$ac_cv_ver_python" != "x"; then |
| 60 | |
| 61 | cat > pytest << EOF |
| 62 | include $ac_cv_execprefix_python/lib/python$ac_cv_ver_python/config/Makefile |
| 63 | .PHONY: libs include |
| 64 | libs: |
| 65 | @echo \$(MODLIBS) \$(LIBS) \$(SYSLIBS) |
| 66 | include: |
| 67 | @echo \$(INCLUDEPY) |
| 68 | EOF |
| 69 | AC_CACHE_CHECK("python libs", ac_cv_libs_python, [ac_cv_libs_python=`make -s -f pytest libs 2> /dev/null`]) |
| 70 | AC_CACHE_CHECK("python include", ac_cv_include_python, [ac_cv_include_python=`make -s -f pytest include 2> /dev/null`]) |
| 71 | AC_CHECK_HEADER(python$ac_cv_ver_python/Python.h, |
| 72 | [AC_CHECK_LIB(python$ac_cv_ver_python,PyArg_ParseTuple, |
| 73 | [AC_DEFINE(HAVE_PYTHONLIB) PYTHONLIB="-lpython$ac_cv_ver_python $ac_cv_libs_python"],[],$ac_cv_libs_python)]) |
| 74 | AC_SUBST(PYTHONLIB) |
| 75 | |
| 76 | PYTHONVER=$ac_cv_ver_python |
| 77 | PYTHONPREFIX=$ac_cv_prefix_python |
| 78 | PYTHONEXECPREFIX=$ac_cv_execprefix_python |
| 79 | PYTHONINCLUDE=$ac_cv_include_python |
| 80 | AC_SUBST(PYTHONVER) |
| 81 | AC_SUBST(PYTHONPREFIX) |
| 82 | AC_SUBST(PYTHONEXECPREFIX) |
| 83 | AC_SUBST(PYTHONINCLUDE) |
| 84 | fi |
| 85 | |
| 86 | dnl Check for DB2 |
| 87 | AC_CHECK_HEADER(db2/db.h, |
| 88 | [AC_CHECK_LIB(db2,db_open, |
| 89 | [AC_DEFINE(HAVE_DB2) DB2LIB="-ldb2"])]) |
| 90 | AC_SUBST(DB2LIB) |
| 91 | |
| 92 | dnl Converts the ARCH to be something singular for this general CPU family |
| 93 | dnl This is often the dpkg architecture string. |
| 94 | AC_MSG_CHECKING(system architecture) |
| 95 | archset="`awk \" ! /^#|^\\\$/ { if(match(\\\"$target_cpu\\\",\\\"^\\\"\\\$1\\\"\\\$\\\")) {print \\\$2; exit}}\" $srcdir/buildlib/archtable`" |
| 96 | if test "x$archset" = "x"; then |
| 97 | AC_MSG_ERROR(failed: use --host=) |
| 98 | fi |
| 99 | AC_MSG_RESULT($archset) |
| 100 | AC_DEFINE_UNQUOTED(COMMON_CPU,"$archset") |
| 101 | |
| 102 | dnl Get a common name for the host OS - this is primarily only for HURD and is |
| 103 | dnl non fatal if it fails |
| 104 | AC_MSG_CHECKING(system OS) |
| 105 | osset="`awk \" ! /^#|^\\\$/ {if (match(\\\"$target_vendor-$target_os\\\",\\\$1)) {print \\\$2; exit}}\" $srcdir/buildlib/ostable`" |
| 106 | AC_MSG_RESULT($osset) |
| 107 | AC_DEFINE_UNQUOTED(COMMON_OS,"$osset") |
| 108 | |
| 109 | dnl We use C99 types if at all possible |
| 110 | AC_CACHE_CHECK([for C99 integer types],c9x_ints,[ |
| 111 | AC_TRY_COMPILE([#include <inttypes.h>], |
| 112 | [uint8_t Foo1;uint16_t Foo2;uint32_t Foo3;], |
| 113 | c9x_ints=yes,c9x_ints=no)]) |
| 114 | |
| 115 | dnl Single Unix Spec statvfs |
| 116 | AC_CHECK_FUNC(statvfs,[HAVE_STATVFS=yes]) |
| 117 | AC_SUBST(HAVE_STATVFS) |
| 118 | |
| 119 | dnl Arg, linux and bsd put their statfs function in different places |
| 120 | if test x"$HAVE_STATVFS" != x"yes"; then |
| 121 | AC_EGREP_HEADER(statfs,sys/vfs.h,[AC_DEFINE(HAVE_VFS_H)],[ |
| 122 | AC_EGREP_HEADER(statfs,sys/mount.h,[AC_DEFINE(HAVE_MOUNT_H)],[AC_MSG_ERROR(failed: Need statvfs)]) |
| 123 | ]) |
| 124 | fi |
| 125 | |
| 126 | dnl Check the sizes etc. of the architecture |
| 127 | dnl This is stupid, it should just use the AC macros like it does below |
| 128 | dnl Cross compilers can either get a real C library or preload the cache |
| 129 | dnl with their size values. |
| 130 | changequote(,) |
| 131 | archline="`awk \" ! /^#|^\\\$/ {if (match(\\\"$archset\\\",\\\$1)) {print; exit}}\" $srcdir/buildlib/sizetable | cut -f 2- -d ' '`" |
| 132 | if test "x$archline" != "x"; then |
| 133 | changequote([,]) |
| 134 | set $archline |
| 135 | if test "$1" = "little"; then |
| 136 | ac_cv_c_bigendian=no |
| 137 | else |
| 138 | ac_cv_c_bigendian=yes |
| 139 | fi |
| 140 | size_char=$2 |
| 141 | size_int=$3 |
| 142 | size_short=$4 |
| 143 | size_long=$5 |
| 144 | fi |
| 145 | |
| 146 | dnl I wonder what AC_C_BIGENDIAN does if you cross compile... |
| 147 | dnl This is probably bogus, as above we only care if we have to build our own |
| 148 | dnl C9x types. |
| 149 | if test "$cross_compiling" = "yes" -a "x$archline" = "x"; then |
| 150 | AC_MSG_ERROR(When cross compiling, architecture must be present in sizetable) |
| 151 | fi |
| 152 | AC_C_BIGENDIAN |
| 153 | |
| 154 | dnl We do not need this if we have inttypes! |
| 155 | HAVE_C9X=yes |
| 156 | if test x"$c9x_ints" = x"no"; then |
| 157 | AC_CHECK_SIZEOF(char,$size_char) |
| 158 | AC_CHECK_SIZEOF(int,$size_int) |
| 159 | AC_CHECK_SIZEOF(short,$size_short) |
| 160 | AC_CHECK_SIZEOF(long,$size_long) |
| 161 | |
| 162 | HAVE_C9X= |
| 163 | AC_SUBST(HAVE_C9X) |
| 164 | fi |
| 165 | |
| 166 | dnl HP-UX sux.. |
| 167 | AC_MSG_CHECKING(for missing socklen_t) |
| 168 | AC_EGREP_HEADER(socklen_t, sys/socket.h,[AC_MSG_RESULT(no)],[ |
| 169 | AC_DEFINE(NEED_SOCKLEN_T_DEFINE) |
| 170 | NEED_SOCKLEN_T_DEFINE=yes |
| 171 | AC_MSG_RESULT(missing.)]) |
| 172 | AC_SUBST(NEED_SOCKLEN_T_DEFINE) |
| 173 | |
| 174 | dnl HP-UX needs -d_XOPEN_SOURCE_EXTENDED for h_errno |
| 175 | AC_MSG_CHECKING(for h_errno) |
| 176 | AC_EGREP_HEADER(h_errno, netdb.h, [AC_MSG_RESULT(normal)], |
| 177 | [CPPFLAGS="$CPPFLAGS -D_XOPEN_SOURCE_EXTENDED" |
| 178 | AC_EGREP_HEADER(h_errno, netdb.h, |
| 179 | [AC_MSG_RESULT(needs _XOPEN_SOURCE_EXTENDED)], |
| 180 | [AC_MSG_ERROR("not found.")]) |
| 181 | ]) |
| 182 | |
| 183 | dnl Check for debiandoc |
| 184 | AC_PATH_PROG(DEBIANDOC_HTML,debiandoc2html) |
| 185 | AC_PATH_PROG(DEBIANDOC_TEXT,debiandoc2text) |
| 186 | |
| 187 | dnl Check for the SGML tools needed to build man pages |
| 188 | AC_PATH_PROG(NSGMLS,nsgmls) |
| 189 | AC_PATH_PROG(SGMLSPL,sgmlspl) |
| 190 | |
| 191 | dnl Check for YODL |
| 192 | dnl AC_CHECK_PROG(YODL_MAN,yodl2man,"yes","") |
| 193 | |
| 194 | ah_NUM_PROCS |
| 195 | |
| 196 | AC_OUTPUT(environment.mak:buildlib/environment.mak.in makefile:buildlib/makefile.in,make -s dirs) |