+AC_ARG_WITH([bash-completion-dir],
+ AC_HELP_STRING([--with-bash-completion-dir=DIR],
+ [name of the Bash completion directory]),
+ [bashcompletiondir="$withval"],
+ [bashcompletiondir='${sysconfdir}/bash_completion.d'])
+AC_SUBST([bashcompletiondir])
+
+AC_ARG_WITH([zsh-completion-dir],
+ AC_HELP_STRING([--with-zsh-completion-dir=DIR],
+ [name of the Zsh completion directory]),
+ [zshcompletiondir="$withval"],
+ [zshcompletiondir='${datadir}/zsh/site-functions'])
+AC_SUBST([zshcompletiondir])
+
+dnl Better be verbose.
+AC_MSG_CHECKING([for the store directory])
+AC_MSG_RESULT([$storedir])
+
+AC_ARG_ENABLE([daemon],
+ [AS_HELP_STRING([--disable-daemon], [do not build the Nix daemon (C++)])],
+ [guix_build_daemon="$enableval"],
+ [guix_build_daemon="yes"])
+
+# Prepare a version of $localstatedir & co. that does not contain references
+# to shell variables.
+guix_prefix="`eval echo $prefix | sed -e"s|NONE|/usr/local|g"`"
+guix_localstatedir="`eval echo $localstatedir | sed -e "s|NONE|$guix_prefix|g"`"
+guix_sysconfdir="`eval echo $sysconfdir | sed -e "s|NONE|$guix_prefix|g"`"
+guix_sbindir="`eval echo $sbindir | sed -e "s|NONE|$guix_prefix|g"`"
+AC_SUBST([guix_localstatedir])
+AC_SUBST([guix_sysconfdir])
+AC_SUBST([guix_sbindir])
+
+GUIX_CHECK_FILE_NAME_LIMITS([can_run_tests])
+AM_CONDITIONAL([CAN_RUN_TESTS], [test "x$can_run_tests" = "xyes"])
+
+dnl We require pkg.m4 (from pkg-config) and guile.m4 (from Guile.)
+dnl Make sure they are available.
+m4_pattern_forbid([PKG_CHECK_MODULES])
+m4_pattern_forbid([GUILE_MODULE_AVAILABLE])
+m4_pattern_forbid([^GUILE_P$])
+
+dnl Search for 'guile' and 'guild'. This macro defines
+dnl 'GUILE_EFFECTIVE_VERSION'.
+GUILE_PKG([2.2 2.0])
+GUILE_PROGS