tests/pk-crypto.scm

   1 ;;; GNU Guix --- Functional package management for GNU
   2 ;;; Copyright © 2013 Ludovic Courtès <ludo@gnu.org>
   3 ;;;
   4 ;;; This file is part of GNU Guix.
   5 ;;;
   6 ;;; GNU Guix is free software; you can redistribute it and/or modify it
   7 ;;; under the terms of the GNU General Public License as published by
   8 ;;; the Free Software Foundation; either version 3 of the License, or (at
   9 ;;; your option) any later version.
  10 ;;;
  11 ;;; GNU Guix is distributed in the hope that it will be useful, but
  12 ;;; WITHOUT ANY WARRANTY; without even the implied warranty of
  13 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 ;;; GNU General Public License for more details.
  15 ;;;
  16 ;;; You should have received a copy of the GNU General Public License
  17 ;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 (define-module (test-pk-crypto)
  20   #:use-module (guix pk-crypto)
  21   #:use-module (guix utils)
  22   #:use-module (guix hash)
  23   #:use-module (srfi srfi-1)
  24   #:use-module (srfi srfi-11)
  25   #:use-module (srfi srfi-26)
  26   #:use-module (srfi srfi-64)
  27   #:use-module (rnrs bytevectors)
  28   #:use-module (rnrs io ports)
  29   #:use-module (ice-9 match))
  30
  31 ;; Test the (guix pk-crypto) module.
  32
  33 (define %key-pair
  34   ;; Key pair that was generated with:
  35   ;;   (generate-key (string->canonical-sexp "(genkey (rsa (nbits 4:1024)))"))
  36   ;; which takes a bit of time.
  37   "(key-data
  38     (public-key
  39      (rsa
  40       (n #00C1F764069F54FFE93A126B02328903E984E4AE3AF6DF402B5B6B3907911B88C385F1BA76A002EC9DEA109A5228EF0E62EE31A06D1A5861CAB474F6C857AC66EB65A1905F25BBA1869579E73A3B7FED13AF5A1667326F88CDFC2FF24B03C14FD1384AA7E73CA89572880B606E3A974E15347963FC7B6378574936A47580DBCB45#)
  41       (e #010001#)))
  42     (private-key
  43      (rsa
  44       (n #00C1F764069F54FFE93A126B02328903E984E4AE3AF6DF402B5B6B3907911B88C385F1BA76A002EC9DEA109A5228EF0E62EE31A06D1A5861CAB474F6C857AC66EB65A1905F25BBA1869579E73A3B7FED13AF5A1667326F88CDFC2FF24B03C14FD1384AA7E73CA89572880B606E3A974E15347963FC7B6378574936A47580DBCB45#)
  45       (e #010001#)
  46       (d #58CAD84653D0046A8EC3F9AA82D9C829B145422109FC3F12DA01A694B92FA296E70D366FB166454D30E632CEE3A033B4C41781BA10325F69FCDC0250CA19C8EEB352FA085992494098DB133E682ED38A931701F0DED1A1E508F4341A4FB446A04F019427C7CB3C44F251EEA9D386100DA80F125E0FD5CE1B0DFEC6D21516EACD#)
  47       (p #00D47F185147EC39393CCDA4E7323FFC20FC8B8073E2A54DD63BA392A66975E4204CA48572496A9DFD7522436B852C07472A5AB25B7706F7C14E6F33FBC420FF3B#)
  48       (q #00E9AD22F158060BC9AE3601DA623AFC60FFF3058795802CA92371C00097335CF9A23D7782DE353C9DBA93D7BB99E6A24A411107605E722481C5C191F80D7EB77F#)
  49       (u #59B45B95AE01A7A7370FAFDB08FE73A4793CE37F228961B09B1B1E7DDAD9F8D3E28F5C5E8B4B067E6B8E0BBF3F690B42991A79E46108DDCDA2514323A66964DE#))))")
  50
  51 (test-begin "pk-crypto")
  52
  53 (let ((sexps '("(foo bar)"
  54
  55                ;; In Libgcrypt 1.5.3 the following integer is rendered as
  56                ;; binary, whereas in 1.6.0 it's rendered as is (hexadecimal.)
  57                ;;"#C0FFEE#"
  58
  59                "(genkey \n (rsa \n  (nbits \"1024\")\n  )\n )")))
  60   (test-equal "string->canonical-sexp->string"
  61     sexps
  62     (let ((sexps (map string->canonical-sexp sexps)))
  63       (and (every canonical-sexp? sexps)
  64            (map (compose string-trim-both canonical-sexp->string) sexps)))))
  65
  66 (gc)                                              ; stress test!
  67
  68 (let ((sexps `(("(foo bar)" foo -> "(foo bar)")
  69                ("(foo (bar (baz 3:123)))" baz -> "(baz \"123\")")
  70                ("(foo (bar 3:123))" baz -> #f))))
  71   (test-equal "find-sexp-token"
  72     (map (match-lambda
  73           ((_ _ '-> expected)
  74            expected))
  75          sexps)
  76     (map (match-lambda
  77           ((input token '-> _)
  78            (let ((sexp (find-sexp-token (string->canonical-sexp input) token)))
  79              (and sexp
  80                   (string-trim-both (canonical-sexp->string sexp))))))
  81          sexps)))
  82
  83 (gc)
  84
  85 (test-equal "canonical-sexp-car + cdr"
  86   '("(b \n (c xyz)\n )")
  87   (let ((lst (string->canonical-sexp "(a (b (c xyz)))")))
  88     (map (lambda (sexp)
  89            (and sexp (string-trim-both (canonical-sexp->string sexp))))
  90          ;; Note: 'car' returns #f when the first element is an atom.
  91          (list (canonical-sexp-car (canonical-sexp-cdr lst))))))
  92
  93 (gc)
  94
  95 (test-equal "canonical-sexp-nth"
  96   '("(b pqr)" "(c \"456\")" "(d xyz)" #f #f)
  97
  98   (let ((lst (string->canonical-sexp "(a (b 3:pqr) (c 3:456) (d 3:xyz))")))
  99     ;; XXX: In Libgcrypt 1.5.3, (canonical-sexp-nth lst 0) returns LST, whereas in
 100     ;; 1.6.0 it returns #f.
 101     (map (lambda (sexp)
 102            (and sexp (string-trim-both (canonical-sexp->string sexp))))
 103          (unfold (cut > <> 5)
 104                  (cut canonical-sexp-nth lst <>)
 105                  1+
 106                  1))))
 107
 108 (gc)
 109
 110 (test-equal "canonical-sexp-nth-data"
 111   '("Name" "Otto" "Meier" #f #f #f)
 112   (let ((lst (string->canonical-sexp "(Name Otto Meier (address Burgplatz))")))
 113     (unfold (cut > <> 5)
 114             (cut canonical-sexp-nth-data lst <>)
 115             1+
 116             0)))
 117
 118 (gc)
 119
 120 ;; XXX: The test below is typically too long as it needs to gather enough entropy.
 121
 122 ;; (test-assert "generate-key"
 123 ;;   (let ((key (generate-key (string->canonical-sexp
 124 ;;                             "(genkey (rsa (nbits 3:128)))"))))
 125 ;;     (and (canonical-sexp? key)
 126 ;;          (find-sexp-token key 'key-data)
 127 ;;          (find-sexp-token key 'public-key)
 128 ;;          (find-sexp-token key 'private-key))))
 129
 130 (test-assert "bytevector->hash-data->bytevector"
 131   (let* ((bv   (sha256 (string->utf8 "Hello, world.")))
 132          (data (bytevector->hash-data bv "sha256")))
 133     (and (canonical-sexp? data)
 134          (let-values (((value algo) (hash-data->bytevector data)))
 135            (and (string=? algo "sha256")
 136                 (bytevector=? value bv))))))
 137
 138 (test-assert "sign + verify"
 139   (let* ((pair   (string->canonical-sexp %key-pair))
 140          (secret (find-sexp-token pair 'private-key))
 141          (public (find-sexp-token pair 'public-key))
 142          (data   (bytevector->hash-data
 143                   (sha256 (string->utf8 "Hello, world."))))
 144          (sig    (sign data secret)))
 145     (and (verify sig data public)
 146          (not (verify sig
 147                       (bytevector->hash-data
 148                        (sha256 (string->utf8 "Hi!")))
 149                       public)))))
 150
 151 (gc)
 152
 153 (test-end)
 154
 155 \f
 156 (exit (= (test-runner-fail-count (test-runner-current)) 0))