gnu/packages/linphone.scm

   1 ;;; GNU Guix --- Functional package management for GNU
   2 ;;;
   3 ;;; Copyright © 2020, 2021 Raghav Gururajan <raghavgururajan@disroot.org>
   4 ;;; Copyright © 2020, 2021 Maxim Cournoyer <maxim.cournoyer@gmail.com>
   5 ;;; Copyright © 2020 Tobias Geerinckx-Rice <me@tobias.gr>
   6 ;;;
   7 ;;; This file is part of GNU Guix.
   8 ;;;
   9 ;;; GNU Guix is free software; you can redistribute it and/or modify it
  10 ;;; under the terms of the GNU General Public License as published by
  11 ;;; the Free Software Foundation; either version 3 of the License, or (at
  12 ;;; your option) any later version.
  13 ;;;
  14 ;;; GNU Guix is distributed in the hope that it will be useful, but
  15 ;;; WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;;; GNU General Public License for more details.
  18 ;;;
  19 ;;; You should have received a copy of the GNU General Public License
  20 ;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.
  21
  22 (define-module (gnu packages linphone)
  23   #:use-module (gnu packages)
  24   #:use-module (gnu packages admin)
  25   #:use-module (gnu packages audio)
  26   #:use-module (gnu packages base)
  27   #:use-module (gnu packages compression)
  28   #:use-module (gnu packages crypto)
  29   #:use-module (gnu packages documentation)
  30   #:use-module (gnu packages gettext)
  31   #:use-module (gnu packages gl)
  32   #:use-module (gnu packages glib)
  33   #:use-module (gnu packages gnome)
  34   #:use-module (gnu packages gnome-xyz)
  35   #:use-module (gnu packages graphviz)
  36   #:use-module (gnu packages gtk)
  37   #:use-module (gnu packages image)
  38   #:use-module (gnu packages linux)
  39   #:use-module (gnu packages ncurses)
  40   #:use-module (gnu packages perl)
  41   #:use-module (gnu packages pulseaudio)
  42   #:use-module (gnu packages python)
  43   #:use-module (gnu packages python-xyz)
  44   #:use-module (gnu packages qt)
  45   #:use-module (gnu packages java)
  46   #:use-module (gnu packages sqlite)
  47   #:use-module (gnu packages telephony)
  48   #:use-module (gnu packages tls)
  49   #:use-module (gnu packages video)
  50   #:use-module (gnu packages xiph)
  51   #:use-module (gnu packages xml)
  52   #:use-module (gnu packages xorg)
  53   #:use-module ((guix licenses) #:prefix license:)
  54   #:use-module (guix packages)
  55   #:use-module (guix download)
  56   #:use-module (guix git-download)
  57   #:use-module (guix build-system cmake)
  58   #:use-module (guix build-system qt)
  59   #:use-module (guix build-system glib-or-gtk)
  60   #:use-module (guix build-system gnu))
  61
  62 (define-public bcunit
  63   (let ((commit "74021cc7cb20a4e177748dd2948173e1f9c270ae")
  64         (revision "0"))
  65     (package
  66       (name "bcunit")
  67       (version (git-version "3.0.2" revision commit))
  68       (source
  69        (origin
  70          (method git-fetch)
  71          (uri (git-reference
  72                (url "git://git.linphone.org/bcunit")
  73                (commit commit)))
  74          (file-name (git-file-name name version))
  75          (sha256
  76           (base32 "0npdwvanjkfg9vrqs5yi8vh6wliv50ycdli8pzavir84nb31nq1b"))))
  77       (build-system cmake-build-system)
  78       (outputs '("out" "doc"))
  79       (arguments
  80        `(#:configure-flags (list "-DENABLE_STATIC=NO"
  81                                  "-DENABLE_CURSES=ON"
  82                                  "-DENABLE_DOC=ON"
  83                                  "-DENABLE_EXAMPLES=ON"
  84                                  "-DENABLE_TEST=ON"
  85                                  "-DENABLE_MEMTRACE=ON")
  86          #:phases
  87          (modify-phases %standard-phases
  88            (add-after 'unpack 'patch-source
  89              (lambda _
  90                ;; Include BCunit headers for examples.
  91                (substitute* "Examples/CMakeLists.txt"
  92                  (("\\$\\{CMAKE_CURRENT_SOURCE_DIR\\}")
  93                   (string-append "${CMAKE_CURRENT_SOURCE_DIR} "
  94                                  "${PROJECT_SOURCE_DIR}/BCUnit/Headers "
  95                                  "${CMAKE_BINARY_DIR}/BCUnit/Headers")))
  96                ;; Link bcunit and bcunit_tests libraries.
  97                (substitute* "BCUnit/Sources/CMakeLists.txt"
  98                  (("target_include_directories\\(bcunit_test PUBLIC Test\\)")
  99                   (string-append
 100                    "target_include_directories(bcunit_test PUBLIC Test)\n"
 101                    "target_link_libraries(bcunit_test bcunit)")))))
 102            (replace 'check
 103              (lambda _
 104                (with-directory-excursion "BCUnit/Sources/Test"
 105                  (invoke "./test_bcunit"))))
 106            (add-after 'install 'move-doc
 107              (lambda* (#:key outputs #:allow-other-keys)
 108                (let ((out (assoc-ref outputs "out"))
 109                      (doc (assoc-ref outputs "doc")))
 110                  (for-each mkdir-p
 111                            `(,(string-append doc "/share/doc")
 112                              ,(string-append doc "/share/BCUnit")))
 113                  (rename-file
 114                   (string-append out "/share/doc/BCUnit")
 115                   (string-append doc "/share/doc/BCUnit"))
 116                  (rename-file
 117                   (string-append out "/share/BCUnit/Examples")
 118                   (string-append doc "/share/BCUnit/Examples"))))))))
 119       (inputs
 120        `(("ncurses" ,ncurses)))
 121       (synopsis "Belledonne Communications Unit Testing Framework")
 122       (description "BCUnit is a fork of the defunct project CUnit, with
 123 several fixes and patches applied.  It is a unit testing framework for
 124 writing, administering, and running unit tests in C.")
 125       (home-page "https://gitlab.linphone.org/BC/public/bcunit")
 126       (license license:lgpl2.0+))))
 127
 128 (define-public bctoolbox
 129   (package
 130     (name "bctoolbox")
 131     (version "4.4.34")
 132     (source
 133      (origin
 134        (method git-fetch)
 135        (uri (git-reference
 136              (url "https://gitlab.linphone.org/BC/public/bctoolbox.git")
 137              (commit version)))
 138        (file-name (git-file-name name version))
 139        (sha256
 140         (base32 "0bfswwvvdshaahg4jd2j10f0sci8809s4khajd0m6b059zwc7y25"))))
 141     (build-system cmake-build-system)
 142     (outputs '("out" "debug"))
 143     (arguments
 144      `(#:configure-flags '("-DENABLE_STATIC=OFF")
 145        #:phases
 146        (modify-phases %standard-phases
 147          (add-after 'unpack 'patch-cmake
 148            (lambda* (#:key inputs #:allow-other-keys)
 149              ;; Fix decaf dependency (see:
 150              ;; https://gitlab.linphone.org/BC/public/bctoolbox/-/issues/3).
 151              (let* ((decaf (assoc-ref inputs "decaf")))
 152                (substitute* (find-files "." "CMakeLists.txt")
 153                  (("find_package\\(Decaf CONFIG\\)")
 154                   "set(DECAF_FOUND 1)")
 155                  (("\\$\\{DECAF_INCLUDE_DIRS\\}")
 156                   (string-append decaf "/include/decaf"))
 157                  (("\\$\\{DECAF_TARGETNAME\\}")
 158                   "decaf")))))
 159          (add-after 'unpack 'skip-problematic-tests
 160            (lambda _
 161              ;; The following test relies on networking; disable it.
 162              (substitute* "tester/port.c"
 163                (("[ \t]*TEST_NO_TAG.*bctbx_addrinfo_sort_test\\)")
 164                 ""))))
 165          (add-after 'unpack 'fix-installed-resource-directory-detection
 166            (lambda _
 167              ;; There's some broken logic in tester.c that checks if CWD, or
 168              ;; if its parent exist, and if so, sets the prefix where the test
 169              ;; resources are looked up to; disable it (see:
 170              ;; https://gitlab.linphone.org/BC/public/bctoolbox/-/issues/4).
 171              (substitute* "src/tester.c"
 172                (("if \\(file_exists\\(\".\"\\)\\)")
 173                 "if (NULL)")
 174                (("if \\(file_exists\\(\"..\"\\)\\)")
 175                 "if (NULL)"))))
 176          (replace 'check
 177            (lambda _
 178              (with-directory-excursion "tester"
 179                (invoke "./bctoolbox_tester")))))))
 180     (inputs
 181      `(("bcunit" ,bcunit)
 182        ("decaf" ,libdecaf)
 183        ("mbedtls" ,mbedtls-apache)))
 184     (synopsis "Belledonne Communications Tool Box")
 185     (description "BcToolBox is an utilities library used by Belledonne
 186 Communications software like belle-sip, mediastreamer2 and linphone.")
 187     (home-page "https://gitlab.linphone.org/BC/public/bctoolbox")
 188     (license license:gpl3+)))
 189
 190 (define-public belr
 191   (package
 192     (name "belr")
 193     (version "4.4.34")
 194     (source
 195      (origin
 196        (method git-fetch)
 197        (uri (git-reference
 198              (url "https://gitlab.linphone.org/BC/public/belr.git")
 199              (commit version)))
 200        (file-name (git-file-name name version))
 201        (sha256
 202         (base32 "0w2canwwm0qb99whnangvaybvjzq8xg6vksqxykgr8fbx7clw03h"))))
 203     (build-system cmake-build-system)
 204     (outputs '("out" "debug" "tester"))
 205     (arguments
 206      `(#:configure-flags '("-DENABLE_STATIC=OFF")
 207        #:phases
 208        (modify-phases %standard-phases
 209          (delete 'check)                ;moved after the install phase
 210          (add-after 'install 'check
 211            (lambda* (#:key outputs #:allow-other-keys)
 212              (let* ((tester (assoc-ref outputs "tester"))
 213                     (belr_tester (string-append tester "/bin/belr_tester"))
 214                     (tester-share (string-append tester "/share/belr_tester")))
 215                (invoke belr_tester))))
 216          (add-after 'install 'move-tester
 217            (lambda* (#:key outputs #:allow-other-keys)
 218              (let* ((out (assoc-ref outputs "out"))
 219                     (tester (assoc-ref outputs "tester")))
 220                (for-each mkdir-p
 221                          (list (string-append tester "/bin")
 222                                (string-append tester "/share")))
 223                (rename-file
 224                 (string-append out "/bin/belr_tester")
 225                 (string-append tester "/bin/belr_tester"))
 226                (rename-file
 227                 (string-append out "/share/belr-tester")
 228                 ;; The detect_res_prefix procedure in bctoolbox's tester.c
 229                 ;; resolves the resource path based on the executable path and
 230                 ;; name, so have it match.
 231                 (string-append tester "/share/belr_tester"))))))))
 232     (inputs
 233      `(("bctoolbox" ,bctoolbox)))
 234     (synopsis "Belledonne Communications Language Recognition Library")
 235     (description "Belr is Belledonne Communications' language recognition
 236 library, written in C++11.  It parses text inputs formatted according to a
 237 language defined by an ABNF grammar, such as the protocols standardized at
 238 IETF.")
 239     (home-page "https://gitlab.linphone.org/BC/public/belr")
 240     (license license:gpl3+)))
 241
 242 (define-public belcard
 243   (package
 244     (name "belcard")
 245     (version "4.4.34")
 246     (source
 247      (origin
 248        (method git-fetch)
 249        (uri (git-reference
 250              (url "https://gitlab.linphone.org/BC/public/belcard.git")
 251              (commit version)))
 252        (file-name (git-file-name name version))
 253        (sha256
 254         (base32 "16x2xp8d0a115132zhy1kpxkyj86ia7vrsnpjdg78fnbvmvysc8m"))))
 255     (build-system cmake-build-system)
 256     (outputs '("out" "debug" "tester"))
 257     (arguments
 258      `(#:tests? #t
 259        #:configure-flags '("-DENABLE_STATIC=OFF")
 260        #:phases
 261        (modify-phases %standard-phases
 262          (add-after 'unpack 'patch-vcard-grammar-location
 263            (lambda* (#:key outputs #:allow-other-keys)
 264              (let* ((out (assoc-ref outputs "out"))
 265                     (vcard-grammar
 266                      (string-append out "/share/belr/grammars/vcard_grammar")))
 267                (substitute* "include/belcard/vcard_grammar.hpp"
 268                  (("define VCARD_GRAMMAR \"vcard_grammar\"")
 269                   (format #f "define VCARD_GRAMMAR ~s" vcard-grammar))))))
 270          (add-after 'install 'install-tester
 271            (lambda* (#:key inputs outputs #:allow-other-keys)
 272              (let ((out (assoc-ref outputs "out"))
 273                    (tester (assoc-ref outputs "tester"))
 274                    (test-name (string-append ,name "_tester")))
 275                (for-each mkdir-p
 276                          (list (string-append tester "/bin")
 277                                (string-append tester "/share")))
 278                (rename-file (string-append out "/bin/" test-name)
 279                             (string-append tester "/bin/" test-name))
 280                (rename-file (string-append out "/share/" test-name)
 281                             (string-append tester "/share/" test-name)))))
 282          (delete 'check)
 283          (add-after 'install-tester 'check
 284            (lambda* (#:key inputs outputs tests? #:allow-other-keys)
 285              (when tests?
 286                (let* ((tester (assoc-ref outputs "tester"))
 287                       (belcard_tester (string-append tester
 288                                                      "/bin/belcard_tester")))
 289                  (invoke belcard_tester))))))))
 290     (inputs
 291      `(("bctoolbox" ,bctoolbox)
 292        ("belr" ,belr)))
 293     (synopsis "Belledonne Communications VCard Library")
 294     (description "Belcard is a C++ library to manipulate VCard standard
 295 format.")
 296     (home-page "https://gitlab.linphone.org/BC/public/belcard")
 297     (license license:gpl3+)))
 298
 299 (define-public bcmatroska2
 300   (package
 301     (name "bcmatroska2")
 302     (version "0.23")
 303     (source
 304      (origin
 305        (method git-fetch)
 306        (uri (git-reference
 307              (url "https://gitlab.linphone.org/BC/public/bcmatroska2.git")
 308              (commit version)))
 309        (file-name (git-file-name name version))
 310        (sha256
 311         (base32 "1avl9w18kh4dxm3g8j0bkw39bksd7bz3nfxvyibqqnz63ds8vfi2"))))
 312     (build-system cmake-build-system)
 313     (arguments
 314      `(#:tests? #f                                     ; No test target
 315        #:configure-flags (list "-DENABLE_STATIC=NO"))) ; Not required
 316     (synopsis "Belledonne Communications Media Container")
 317     (description "BcMatroska is a free and open standard multi-media container
 318 format.  It can hold an unlimited number of video, audio, picture, or subtitle
 319 tracks in one file.  This project provides a convenient distribution of the
 320 Matroska multimedia container format.")
 321     (home-page "https://gitlab.linphone.org/BC/public/bcmatroska2")
 322     (license (list license:gpl2+        ;for this package (build system files)
 323                    license:bsd-4        ;for Core C and LibEBML2
 324                    license:lgpl2.1+)))) ;for LibMatroska2
 325
 326 (define-public bcg729
 327   (package
 328     (name "bcg729")
 329     (version "1.1.1")
 330     (source
 331      (origin
 332        (method git-fetch)
 333        (uri (git-reference
 334              (url "git://git.linphone.org/bcg729")
 335              (commit version)))
 336        (file-name (git-file-name name version))
 337        (sha256
 338         (base32 "1hal6b3w6f8y5r1wa0xzj8sj2jjndypaxyw62q50p63garp2h739"))))
 339     (build-system cmake-build-system)
 340     (arguments
 341      `(#:configure-flags (list "-DENABLE_STATIC=NO"
 342                                "-DENABLE_TESTS=YES")
 343        #:phases
 344        (modify-phases %standard-phases
 345          (add-before 'check 'copy-inputs
 346            (lambda* (#:key inputs #:allow-other-keys)
 347              (let ((test-patterns (assoc-ref inputs "test-patterns"))
 348                    (dest (string-append "test/bcg729-patterns.zip")))
 349                (copy-recursively test-patterns dest))))
 350          (replace 'check
 351            (lambda _
 352              (with-directory-excursion "test"
 353                (invoke "unzip" "bcg729-patterns.zip")
 354                (for-each
 355                 (lambda (test-name)
 356                   (invoke "./testCampaign" "-s" test-name))
 357                 (list "fixedCodebookSearch"
 358                       "postProcessing"
 359                       "adaptativeCodebookSearch"
 360                       "computeLP"
 361                       "computeAdaptativeCodebookGain"
 362                       "postFilter"
 363                       "decoder"
 364                       "LPSynthesisFilter"
 365                       "decodeLSP"
 366                       ;; "encoder"
 367                       ;; "LSPQuantization"
 368                       "preProcessing"
 369                       "decodeFixedCodeVector"
 370                       "CNGdecoder"
 371                       ;; "LP2LSPConversion"
 372                       "gainQuantization"
 373                       "findOpenLoopPitchDelay"
 374                       "decodeGains"
 375                       "computeWeightedSpeech"
 376                       "interpolateqLSPAndConvert2LP"
 377                       "decodeAdaptativeCodeVector"))))))))
 378     (native-inputs
 379      `(("perl" ,perl)
 380        ("test-patterns"
 381         ,(origin
 382            (method url-fetch)
 383            (uri (string-append "http://www.belledonne-communications.com/"
 384                                "bc-downloads/bcg729-patterns.zip"))
 385            (sha256
 386             (base32 "1kivarhh3izrl9sg0szs6x6pbq2ap0y6xsraw0gbgspi4gnfihrh"))))
 387        ("unzip" ,unzip)))
 388     (synopsis "Belledonne Communications G729 Codec")
 389     (description "BcG729 is an implementation of both encoder and decoder of
 390 the ITU G729 speech codec.  The library written in C 99 is fully portable and
 391 can be executed on many platforms including both ARM and x86 processors.  It
 392 supports concurrent channels encoding and decoding for multi call application
 393 such as conferencing.")
 394     (home-page "https://linphone.org/technical-corner/bcg729")
 395     (license license:gpl3+)))
 396
 397 (define-public ortp
 398   (package
 399     (name "ortp")
 400     (version "1.0.2")
 401     (source
 402      (origin
 403        (method url-fetch)
 404        (uri
 405         (string-append "https://www.linphone.org/releases/sources/" name
 406                        "/" name "-" version ".tar.gz"))
 407        (sha256
 408         (base32 "016qg0lmdgmqh2kv19w9qhi4kkiyi5h1xp35g2s65b1j8ccm25d5"))))
 409     (build-system cmake-build-system)
 410     (arguments
 411      `(#:tests? #f                      ; No test target
 412        #:configure-flags
 413        (list "-DENABLE_STATIC=NO")))    ; Not required
 414     (native-inputs
 415      `(("dot" ,graphviz)
 416        ("doxygen" ,doxygen)))
 417     (inputs
 418      `(("bctoolbox" ,bctoolbox)))
 419     (synopsis "Belledonne Communications RTP Library")
 420     (description "oRTP is a C library implementing the RTP protocol.  It
 421 implements the RFC 3550 standard.")
 422     (home-page "https://gitlab.linphone.org/BC/public/ortp")
 423     (license license:gpl2+)))
 424
 425 (define-public bzrtp
 426   (package
 427     (name "bzrtp")
 428     (version "4.4.34")
 429     (source
 430      (origin
 431        (method git-fetch)
 432        (uri (git-reference
 433              (url "https://gitlab.linphone.org/BC/public/bzrtp")
 434              (commit version)))
 435        (file-name (git-file-name name version))
 436        (sha256
 437         (base32 "1yjmsbqmymzl4r7sba6w4a2yld8m6hzafr6jf7sj0syhwpnc3zv6"))))
 438     (build-system cmake-build-system)
 439     (arguments
 440      `(#:configure-flags
 441        (list
 442         "-DENABLE_STATIC=NO"
 443         "-DENABLE_TESTS=YES")))
 444     (inputs
 445      `(("bctoolbox" ,bctoolbox)
 446        ("sqlite3" ,sqlite)
 447        ("xml2" ,libxml2)))
 448     (synopsis "Belledonne Communications ZRTP Library")
 449     (description "BZRTP is an implementation of ZRTP keys exchange protocol,
 450 written in C.  It is fully portable and can be executed on many platforms
 451 including both ARM and x86.")
 452     (home-page "https://gitlab.linphone.org/BC/public/bzrtp")
 453     (license license:gpl3+)))
 454
 455 (define-public belle-sip
 456   (package
 457     (name "belle-sip")
 458     (version "1.6.3")
 459     (source
 460      (origin
 461        (method url-fetch)
 462        (uri
 463         (string-append "https://www.linphone.org/releases/sources/" name
 464                        "/" name "-" version ".tar.gz"))
 465        (sha256
 466         (base32 "0s55kggmgxap54dkw5856bgk4xg7yvbzialpxnjm0zhpic3hff1z"))))
 467     (build-system cmake-build-system)
 468     (arguments
 469      `(#:tests? #f                      ; Requires network access
 470        #:configure-flags
 471        (list "-DENABLE_STATIC=NO")      ; Not required
 472        #:phases
 473        (modify-phases %standard-phases
 474          (add-after 'unpack 'patch
 475            (lambda _
 476              (substitute* "src/CMakeLists.txt"
 477                ;; ANTLR would use multithreaded DFA generation otherwise,
 478                ;; which would not be reproducible.
 479                (("-Xmultithreaded ") ""))
 480              #t)))))
 481     (inputs
 482      `(("antlr3" ,antlr3-3.3)
 483        ("antlr3c" ,libantlr3c)
 484        ("bctoolbox" ,bctoolbox)
 485        ("java" ,icedtea)
 486        ("zlib" ,zlib)))
 487     (synopsis "Belledonne Communications SIP Library")
 488     (description "Belle-sip is a modern library implementing SIP transport,
 489 transaction and dialog layers.  It is written in C, with an object-oriented
 490 API.  It also comprises a simple HTTP/HTTPS client implementation.")
 491     (home-page "https://gitlab.linphone.org/BC/public/belle-sip")
 492     (license license:gpl2+)))
 493
 494 (define-public mediastreamer2
 495   (package
 496     (name "mediastreamer2")
 497     (version "2.16.1")
 498     (source
 499      (origin
 500        (method url-fetch)
 501        (uri
 502         (string-append "https://www.linphone.org/releases/sources/"
 503                        "mediastreamer/mediastreamer-" version ".tar.gz"))
 504        (sha256
 505         (base32 "0whpqr69wz0pnzvragkpfblxhd0rds8k06c3mw5a0ag216a1yd9k"))
 506        (patches (search-patches "mediastreamer2-srtp2.patch"))))
 507     (outputs '("out" "doc" "tester"))
 508     (build-system cmake-build-system)
 509     (arguments
 510      `(#:tests? #f                      ; No test target
 511        #:configure-flags
 512        (list "-DENABLE_STATIC=NO"      ; Not required
 513              "-DENABLE_STRICT=NO"      ; Would otherwise treat warnings as err
 514              "-DENABLE_BV16=NO"        ; Not available
 515              "-DCMAKE_C_FLAGS=-DMS2_GIT_VERSION=\\\"unknown\\\""
 516              "-DCMAKE_CXX_FLAGS=-DMS2_GIT_VERSION=\\\"unknown\\\"")
 517        #:phases
 518        (modify-phases %standard-phases
 519          (add-after 'install 'separate-outputs
 520            (lambda* (#:key outputs #:allow-other-keys)
 521              (let* ((out (assoc-ref outputs "out"))
 522                     (doc (assoc-ref outputs "doc"))
 523                     (tester (assoc-ref outputs "tester"))
 524                     (tester-name (string-append ,name "_tester")))
 525                ;; Copy the tester executable.
 526                (mkdir-p (string-append tester "/bin"))
 527                (rename-file (string-append out "/bin/" tester-name)
 528                             (string-append tester "/bin/" tester-name))
 529                ;; Copy the tester data files.
 530                (copy-recursively (string-append out "/share/" tester-name)
 531                                  (string-append tester "/share/" tester-name))
 532                (delete-file-recursively (string-append out "/share/"
 533                                                        tester-name))
 534                ;; Copy the HTML documentation.
 535                (copy-recursively (string-append out "/share/doc/"
 536                                                 ,name "-" ,version "/html")
 537                                  (string-append doc "/share/doc/"
 538                                                 ,name "-" ,version "/html"))
 539                (delete-file-recursively (string-append out "/share/doc/"
 540                                                        ,name "-" ,version
 541                                                        "/html"))
 542                #t))))))
 543     (native-inputs
 544      `(("dot" ,graphviz)
 545        ("doxygen" ,doxygen)
 546        ("python" ,python)))
 547     (inputs
 548      `(("alsa" ,alsa-lib)
 549        ("bcg729" ,bcg729)
 550        ("bcmatroska2" ,bcmatroska2)
 551        ("bctoolbox" ,bctoolbox)
 552        ("ffmpeg" ,ffmpeg)
 553        ("glew" ,glew)
 554        ("glu" ,glu)
 555        ("glx" ,mesa-utils)
 556        ("gsm" ,gsm)
 557        ("opengl" ,mesa)
 558        ("opus" ,opus)
 559        ("ortp" ,ortp)
 560        ("pcap" ,libpcap)
 561        ("portaudio" ,portaudio)
 562        ("pulseaudio" ,pulseaudio)
 563        ("spandsp" ,spandsp)
 564        ("speex" ,speex)
 565        ("speexdsp" ,speexdsp)
 566        ("srtp" ,libsrtp)
 567        ("theora" ,libtheora)
 568        ("turbojpeg" ,libjpeg-turbo)
 569        ("v4l" ,v4l-utils)
 570        ("vpx" ,libvpx)
 571        ("x11" ,libx11)
 572        ("xv" ,libxv)
 573        ("zrtp" ,bzrtp)))
 574     (synopsis "Belledonne Communications Streaming Engine")
 575     (description "Mediastreamer2 is a powerful and lightweight streaming engine
 576 for telephony applications.  This media processing and streaming toolkit is
 577 responsible for receiving and sending all multimedia streams in Linphone,
 578 including media capture, encoding and decoding, and rendering.")
 579     (home-page "https://gitlab.linphone.org/BC/public/mediastreamer2")
 580     (license license:gpl2+)))
 581
 582 (define-public liblinphone
 583   (package
 584     (name "liblinphone")
 585     (version "3.12.0")
 586     (source
 587      (origin
 588        (method url-fetch)
 589        (uri
 590         (string-append "https://www.linphone.org/releases/sources/linphone"
 591                        "/linphone-" version ".tar.gz"))
 592        (sha256
 593         (base32 "0phhkx55xdyg28d4wn8l8q4yvsmdgzmjiw584d4s190sq1azm91x"))))
 594     (outputs '("out" "doc" "tester"))
 595     (build-system cmake-build-system)
 596     (arguments
 597      `(#:tests? #f                      ; No test target
 598        #:configure-flags
 599        (list (string-append "-DGTK2_GDKCONFIG_INCLUDE_DIR="
 600                             (string-append (assoc-ref %build-inputs "gtk2")
 601                                            "/lib/gtk-2.0/include"))
 602              (string-append "-DGTK2_GLIBCONFIG_INCLUDE_DIR="
 603                             (string-append (assoc-ref %build-inputs "glib")
 604                                            "/lib/glib-2.0/include"))
 605              "-DENABLE_STATIC=NO"       ; Not required
 606              "-DENABLE_STRICT=NO"
 607              "-DENABLE_GTK_UI=YES")     ; for legacy UI
 608        #:imported-modules (,@%cmake-build-system-modules
 609                            (guix build glib-or-gtk-build-system))
 610        #:modules ((guix build cmake-build-system)
 611                   ((guix build glib-or-gtk-build-system) #:prefix glib-or-gtk:)
 612                   (guix build utils))
 613        #:phases
 614        (modify-phases %standard-phases
 615          (add-after 'unpack 'patch
 616            (lambda _
 617              (substitute* "gtk/main.c"
 618                (("#include \"liblinphone_gitversion.h\"")
 619                 ""))
 620              #t))
 621          (add-after 'install 'separate-outputs
 622            (lambda* (#:key outputs #:allow-other-keys)
 623              (let* ((out (assoc-ref outputs "out"))
 624                     (doc (assoc-ref outputs "doc"))
 625                     (tester (assoc-ref outputs "tester"))
 626                     (tester-name (string-append ,name "_tester")))
 627                ;; Copy the tester executable.
 628                (mkdir-p (string-append tester "/bin"))
 629                (rename-file (string-append out "/bin/" tester-name)
 630                             (string-append tester "/bin/" tester-name))
 631                ;; Copy the tester data files.
 632                (mkdir-p (string-append tester "/share/"))
 633                (rename-file (string-append out "/share/" tester-name)
 634                             (string-append tester "/share/" tester-name))
 635                ;; Copy the HTML and XML documentation.
 636                (copy-recursively
 637                 (string-append out "/share/doc/linphone-" ,version)
 638                 (string-append doc "/share/doc/" ,name "-" ,version))
 639                (delete-file-recursively
 640                 (string-append out "/share/doc/linphone-" ,version))
 641                #t)))
 642          (add-after 'install 'install-man-pages
 643            (lambda* (#:key outputs #:allow-other-keys)
 644              (let* ((out (assoc-ref outputs "out"))
 645                     (man (string-append out "/share/man/man1")))
 646                (for-each (lambda (file)
 647                            (install-file file man))
 648                          (find-files ".." ".*.1$"))
 649                #t)))
 650          (add-after 'separate-outputs 'glib-or-gtk-compile-schemas
 651            (assoc-ref glib-or-gtk:%standard-phases 'glib-or-gtk-compile-schemas))
 652          (add-after 'glib-or-gtk-compile-schemas 'glib-or-gtk-wrap
 653            (assoc-ref glib-or-gtk:%standard-phases 'glib-or-gtk-wrap)))))
 654     (native-inputs
 655      `(("gettext" ,gettext-minimal)
 656        ("udev" ,eudev)                  ;for libudev.h
 657        ;; For generating the C++ wrappers.
 658        ("dot" ,graphviz)
 659        ("doxygen" ,doxygen)
 660        ("python" ,python)
 661        ("pystache" ,python-pystache)
 662        ("six" ,python-six)))
 663     (inputs
 664      `(("bctoolbox" ,bctoolbox)
 665        ("belcard" ,belcard)
 666        ("bellesip" ,belle-sip)
 667        ("bzrtp" ,bzrtp)
 668        ("iconv" ,libiconv)
 669        ("glib" ,glib)
 670        ("gtk2" ,gtk+-2)
 671        ("mediastreamer2" ,mediastreamer2)
 672        ("notify" ,libnotify)
 673        ("ortp" ,ortp)
 674        ("sqlite" ,sqlite)
 675        ("xml2" ,libxml2)
 676        ("zlib" ,zlib)))
 677     (synopsis "Belledonne Communications Softphone Library")
 678     (description "Liblinphone is a high-level SIP library integrating
 679 all calling and instant messaging features into an unified
 680 easy-to-use API.  It is the cross-platform VoIP library on which the
 681 Linphone application is based on, and that anyone can use to add audio
 682 and video calls or instant messaging capabilities to an application.")
 683     (home-page "https://gitlab.linphone.org/BC/public/liblinphone")
 684     (license license:gpl2+)))
 685
 686 (define-public linphoneqt
 687   (package
 688     (name "linphoneqt")
 689     (version "4.1.1")
 690     (source
 691      (origin
 692        (method url-fetch)
 693        (uri
 694         (string-append "https://www.linphone.org/releases/sources/" name
 695                        "/" name "-" version ".tar.gz"))
 696        (sha256
 697         (base32 "1g2zrr9li0g1hgs6vys06vr98h5dx36z22hx7a6ry231536c002a"))
 698        (patches (search-patches "linphoneqt-tabbutton.patch"))))
 699     (build-system qt-build-system)
 700     (arguments
 701      `(#:tests? #f                      ; No test target
 702        #:phases
 703        (modify-phases %standard-phases
 704          (add-after 'unpack 'fix-cmake-error
 705            (lambda _
 706              ;; This is fixed in commit efed2fd8 of the master branch.
 707              (substitute* "CMakeLists.txt"
 708                (("js)\\$\"")
 709                 "js$\""))
 710              #t))
 711          (add-after 'unpack 'set-version-string
 712            (lambda _
 713              (substitute* "src/app/AppController.cpp"
 714                (("LINPHONE_QT_GIT_VERSION")
 715                 (format #f "~s" ,version)))
 716              #t))
 717          (add-after 'install 'extend-shared-resources
 718            ;; Not using the FHS exposes an issue where the client refers to
 719            ;; its own "share" directory, which lacks sound files installed by
 720            ;; liblinphone.
 721            (lambda* (#:key inputs outputs #:allow-other-keys)
 722              (let ((liblinphone (assoc-ref inputs "linphone"))
 723                     (out (assoc-ref outputs "out")))
 724                (symlink (string-append liblinphone "/share/sounds")
 725                         (string-append out "/share/sounds"))
 726                #t))))))
 727     (native-inputs
 728      `(("qttools" ,qttools)))
 729     (inputs
 730      `(("bctoolbox" ,bctoolbox)
 731        ("belcard" ,belcard)
 732        ("bellesip" ,belle-sip)
 733        ("linphone" ,liblinphone)
 734        ("mediastreamer2" ,mediastreamer2)
 735        ("qtbase" ,qtbase)
 736        ("qtdeclarative" ,qtdeclarative)
 737        ("qtgraphicaleffects" ,qtgraphicaleffects)
 738        ("qtquickcontrols" ,qtquickcontrols)
 739        ("qtquickcontrols2" ,qtquickcontrols2)
 740        ("qtsvg" ,qtsvg)))
 741     (synopsis "Desktop client for the Linphone SIP softphone")
 742     (description "Linphone is a SIP softphone for voice and video over IP calling
 743 (VoIP) and instant messaging.  Amongst its features are:
 744 @itemize
 745 @item High Definition (HD) audio and video calls
 746 @item Multiple call management (pause and resume)
 747 @item Call transfer
 748 @item Audio conferencing (merge calls into a conference call)
 749 @item Call recording and replay (audio only)
 750 @item Instant Messaging with message delivery status (IMDN)
 751 @item Picture and file sharing
 752 @item Echo cancellation
 753 @item Secure user authentication using TLS client certificates
 754 @item SRTP, zRTP and SRTP-DTLS voice and video encryption
 755 @item Telephone tone (DTMF) support using SIP INFO or RFC 4733
 756 @item Audio codecs: opus, speex, g711, g729, gsm, iLBC, g722, SILK, etc.
 757 @item Video codecs: VP8, H.264 and H.265 with resolutions up to 1080P, MPEG4
 758 @end itemize")
 759     (home-page "https://gitlab.linphone.org/BC/public/linphone-desktop")
 760     (license license:gpl2+)))
 761
 762 (define-public msopenh264
 763   (package
 764     (name "msopenh264")
 765     (version "1.2.1")
 766     (source
 767      (origin
 768        (method url-fetch)
 769        (uri
 770         (string-append "https://www.linphone.org/releases/sources/plugins/"
 771                        name "/" name "-" version ".tar.gz"))
 772        (sha256
 773         (base32 "0rdxgazm52560g52pp6mp3mwx6j1z3h2zyizzfycp8y8zi92fqm8"))
 774        (patches
 775         (list
 776          ;; For support for OpenH264 version >= 2.
 777          (origin
 778            (method url-fetch)
 779            (uri
 780             (string-append "https://gitlab.linphone.org/BC/public/msopenh264/"
 781                            "commit/493d147d28c9a0f788ba4e50b47a1ce7b18bf326"
 782                            ".diff"))
 783            (file-name "msopenh264-openh264.patch")
 784            (sha256
 785             (base32
 786              "0mmd7nz5n9ian4rcwn200nldmy5j0dpdrna7r32rqnaw82bx3kdb")))))))
 787     (build-system cmake-build-system)
 788     (arguments
 789      `(#:tests? #f                      ; No test target
 790        #:configure-flags
 791        (list "-DENABLE_STATIC=NO")))    ; Not required
 792     (inputs
 793      `(("mediastreamer2" ,mediastreamer2)
 794        ("openh264" ,openh264)
 795        ("ortp" ,ortp)))
 796     (synopsis "Media Streamer H.264 Codec")
 797     (description "MsOpenH264 is an  H.264 encoder/decoder plugin for
 798 mediastreamer2 based on the openh264 library.")
 799     (home-page "https://gitlab.linphone.org/BC/public/msopenh264")
 800     (license license:gpl2+)))
 801
 802 (define-public mssilk
 803   (package
 804     (name "mssilk")
 805     (version "1.1.1")
 806     (source
 807      (origin
 808        (method url-fetch)
 809        (uri
 810         (string-append "https://www.linphone.org/releases/sources/plugins/"
 811                        name "/" name "-" version ".tar.gz"))
 812        (sha256
 813         (base32 "07ip0vd29d1n98lnqs5wpimcsmpm65yl7g5vk4hbqghcbsjw94lj"))))
 814     (build-system cmake-build-system)
 815     (arguments
 816      `(#:tests? #f                      ; No test target
 817        #:configure-flags
 818        (list "-DENABLE_STATIC=NO")))    ; Not required
 819     (inputs
 820      `(("mediastreamer2" ,mediastreamer2)
 821        ("ortp" ,ortp)))
 822     (synopsis "Media Streamer SILK Codec")
 823     (description "MSSILK is a plugin of MediaStreamer, adding support for AMR
 824 codec.  It is based on the Skype's SILK implementation.")
 825     (home-page "https://gitlab.linphone.org/BC/public/mssilk")
 826     (license license:gpl2+)))
 827
 828 (define-public mswebrtc
 829   (package
 830     (name "mswebrtc")
 831     (version "1.1.1")
 832     (source
 833      (origin
 834        (method url-fetch)
 835        (uri
 836         (string-append "https://www.linphone.org/releases/sources/plugins/"
 837                        name "/" name "-" version ".tar.gz"))
 838        (sha256
 839         (base32 "1wj28hl9myhshqmn64xg0jf07aw75gmnilb5rff6rcbdxim87mqr"))))
 840     (build-system cmake-build-system)
 841     (arguments
 842      `(#:tests? #f                      ; No test target
 843        #:configure-flags
 844        (list
 845         "-DENABLE_STATIC=NO")))         ; Not required
 846     (inputs
 847      `(("bctoolbox" ,bctoolbox)
 848        ("mediastreamer2" ,mediastreamer2)
 849        ("ortp" ,ortp)))
 850     (synopsis "Media Streamer WebRTC Codec")
 851     (description "MSWebRTC is a plugin of MediaStreamer, adding support for
 852 WebRTC codec.  It includes features from WebRTC, such as, iSAC and AECM.")
 853     (home-page "https://gitlab.linphone.org/BC/public/mswebrtc")
 854     (license license:gpl2+)))
 855
 856 (define-public msamr
 857   (package
 858     (name "msamr")
 859     (version "1.1.3")
 860     (source
 861      (origin
 862        (method url-fetch)
 863        (uri
 864         (string-append "https://www.linphone.org/releases/sources/plugins/"
 865                        name "/" name "-" version ".tar.gz"))
 866        (sha256
 867         (base32 "16c9f3z4wnj73k7y8gb0fgpr4axsm7b5zrbjvy8vsgz9gyg3agm5"))))
 868     (build-system cmake-build-system)
 869     (arguments
 870      `(#:tests? #f                      ; No test target
 871        #:configure-flags
 872        (list "-DENABLE_STATIC=NO"       ; Not required
 873              "-DENABLE_WIDEBAND=YES")))
 874     (inputs
 875      `(("mediastreamer2" ,mediastreamer2)
 876        ("opencoreamr" ,opencore-amr)
 877        ("ortp" ,ortp)
 878        ("voamrwbenc" ,vo-amrwbenc)))
 879     (synopsis "Media Streamer AMR Codec")
 880     (description "MSAMR is a plugin of MediaStreamer, adding support for AMR
 881 codec.  It is based on the opencore-amr implementation.")
 882     (home-page "https://gitlab.linphone.org/BC/public/msamr")
 883     (license license:gpl3+)))