gnu/packages/ghostscript.scm

   1 ;;; GNU Guix --- Functional package management for GNU
   2 ;;; Copyright © 2013 Andreas Enge <andreas@enge.fr>
   3 ;;; Copyright © 2014, 2015 Mark H Weaver <mhw@netris.org>
   4 ;;; Copyright © 2015 Ricardo Wurmus <rekado@elephly.net>
   5 ;;; Copyright © 2013, 2015 Ludovic Courtès <ludo@gnu.org>
   6 ;;;
   7 ;;; This file is part of GNU Guix.
   8 ;;;
   9 ;;; GNU Guix is free software; you can redistribute it and/or modify it
  10 ;;; under the terms of the GNU General Public License as published by
  11 ;;; the Free Software Foundation; either version 3 of the License, or (at
  12 ;;; your option) any later version.
  13 ;;;
  14 ;;; GNU Guix is distributed in the hope that it will be useful, but
  15 ;;; WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;;; GNU General Public License for more details.
  18 ;;;
  19 ;;; You should have received a copy of the GNU General Public License
  20 ;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.
  21
  22 (define-module (gnu packages ghostscript)
  23   #:use-module (gnu packages)
  24   #:use-module (gnu packages autotools)
  25   #:use-module (gnu packages compression)
  26   #:use-module (gnu packages fontutils)
  27   #:use-module (gnu packages image)
  28   #:use-module (gnu packages perl)
  29   #:use-module (gnu packages pkg-config)
  30   #:use-module (gnu packages python)
  31   #:use-module (gnu packages tcl)
  32   #:use-module (gnu packages xorg)
  33   #:use-module ((guix licenses) #:prefix license:)
  34   #:use-module (guix packages)
  35   #:use-module (guix download)
  36   #:use-module (guix build-system gnu))
  37
  38 (define-public lcms
  39   (package
  40    (name "lcms")
  41    (version "2.6")
  42    (source (origin
  43             (method url-fetch)
  44             (uri (string-append
  45                   "mirror://sourceforge/lcms/lcms2-" version ".tar.gz"))
  46             (sha256 (base32
  47                      "1c8lgq8gfs3nyplvbx9k8wzfj6r2bqi3f611vb1m8z3476454wji"))))
  48    (build-system gnu-build-system)
  49    (inputs `(("libjpeg-8" ,libjpeg-8)
  50              ("libtiff" ,libtiff)
  51              ("zlib" ,zlib)))
  52    (synopsis "Little CMS, a small-footprint colour management engine")
  53    (description
  54     "Little CMS is a small-footprint colour management engine, with special
  55 focus on accuracy and performance.  It uses the International Color
  56 Consortium standard (ICC), approved as ISO 15076-1.")
  57    (license license:x11)
  58    (home-page "http://www.littlecms.com/")))
  59
  60 (define-public libpaper
  61   (package
  62    (name "libpaper")
  63    (version "1.1.24")
  64    (source (origin
  65             (method url-fetch)
  66             (uri (string-append
  67                    ;; Debian moved their libpaper-1.1.24 to archive.debian.net
  68                    ;; but in the move the hash of their tarball changed.
  69                    "http://pkgs.fedoraproject.org/repo/pkgs/libpaper/libpaper_"
  70                    version ".tar.gz/5bc87d494ba470aba54f6d2d51471834/libpaper_"
  71                    version ".tar.gz"))
  72             (sha256 (base32
  73                      "0zhcx67afb6b5r936w5jmaydj3ks8zh83n9rm5sv3m3k8q8jib1q"))))
  74    (build-system gnu-build-system)
  75    (synopsis "Library for handling paper sizes")
  76    (description
  77     "The paper library and accompanying files are intended to provide a simple
  78 way for applications to take actions based on a system- or user-specified
  79 paper size.")
  80    (license license:gpl2)
  81    (home-page "https://packages.qa.debian.org/libp/libpaper.html")))
  82
  83 (define-public psutils
  84   (package
  85    (name "psutils")
  86    (version "17")
  87    (source (origin
  88             (method url-fetch)
  89             (uri "ftp://ftp.knackered.org/pub/psutils/psutils.tar.gz")
  90             (sha256 (base32
  91                      "1r4ab1fvgganm02kmm70b2r1azwzbav2am41gbigpa2bb1wynlrq"))))
  92    (build-system gnu-build-system)
  93    (inputs `(("perl" ,perl)))
  94    (arguments
  95     `(#:tests? #f ; none provided
  96       #:phases
  97       (alist-replace
  98        'configure
  99        (lambda* (#:key inputs outputs #:allow-other-keys #:rest args)
 100         (let ((perl (assoc-ref inputs "perl"))
 101               (out (assoc-ref outputs "out")))
 102          (copy-file "Makefile.unix" "Makefile")
 103          (substitute* "Makefile"
 104            (("/usr/local/bin/perl") (string-append perl "/bin/perl")))
 105          (substitute* "Makefile"
 106            (("/usr/local") out))
 107          ;; for the install phase
 108          (substitute* "Makefile"
 109            (("-mkdir") "mkdir -p"))
 110          ;; drop installation of non-free files
 111          (substitute* "Makefile"
 112            ((" install.include") ""))))
 113       %standard-phases)))
 114    (synopsis "Collection of utilities for manipulating PostScript documents")
 115    (description
 116     "PSUtils is a collection of utilities for manipulating PostScript
 117 documents.  Programs included are psnup, for placing out several logical pages
 118 on a single sheet of paper, psselect, for selecting pages from a document,
 119 pstops, for general imposition, psbook, for signature generation for booklet
 120 printing, and psresize, for adjusting page sizes.")
 121    (license (license:non-copyleft "file://LICENSE"
 122                                 "See LICENSE in the distribution."))
 123    (home-page "http://knackered.org/angus/psutils/")))
 124
 125 (define-public ghostscript
 126   (package
 127    (name "ghostscript")
 128    (version "9.14.0")
 129    (source (origin
 130             (method url-fetch)
 131             (uri (string-append "mirror://gnu/ghostscript/gnu-ghostscript-"
 132                                 version ".tar.xz"))
 133             (sha256
 134              (base32
 135               "0q4jj41p0qbr4mgcc9q78f5zs8cm1g57wgryhsm2yq4lfslm3ib1"))
 136             (patches (search-patches "ghostscript-CVE-2015-3228.patch"
 137                                      "ghostscript-runpath.patch"))
 138             (modules '((guix build utils)))
 139             (snippet
 140              ;; Honor --docdir.
 141              '(substitute* "Makefile.in"
 142                 (("^docdir=.*$") "docdir = @docdir@\n")
 143                 (("^exdir=.*$") "exdir = $(docdir)/examples\n")))))
 144    (build-system gnu-build-system)
 145    (outputs '("out" "doc"))                  ;16 MiB of HTML/PS doc + examples
 146    (inputs `(("freetype" ,freetype)
 147              ("lcms" ,lcms)
 148              ("libjpeg-8" ,libjpeg-8)
 149              ("libpng" ,libpng)
 150              ("libpaper" ,libpaper)
 151              ("libtiff" ,libtiff)
 152              ("zlib" ,zlib)))
 153    (native-inputs
 154       `(("perl" ,perl)
 155         ("pkg-config" ,pkg-config) ; needed to find libtiff
 156         ("python" ,python-wrapper)
 157         ("tcl" ,tcl)))
 158    (arguments
 159     `(#:phases
 160       (modify-phases %standard-phases
 161         (add-after 'configure 'patch-config-files
 162                    (lambda _
 163                      (substitute* "base/all-arch.mak"
 164                        (("/bin/sh") (which "bash")))
 165                      (substitute* "base/unixhead.mak"
 166                        (("/bin/sh") (which "bash")))))
 167         (add-after 'configure 'remove-doc-reference
 168                    (lambda _
 169                      ;; Don't retain a reference to the 'doc' output in 'gs'.
 170                      ;; The only use of this definition is in the output of
 171                      ;; 'gs --help', so this change is fine.
 172                      (substitute* "base/gscdef.c"
 173                        (("GS_DOCDIR")
 174                         "\"~/.guix-profile/share/doc/ghostscript\""))))
 175         (add-after 'build 'build-so
 176                    (lambda _
 177                      (zero? (system* "make" "so"))))
 178         (add-after 'install 'install-so
 179                    (lambda _
 180                      (zero? (system* "make" "install-so")))))))
 181    (synopsis "PostScript and PDF interpreter")
 182    (description
 183     "Ghostscript is an interpreter for the PostScript language and the PDF
 184 file format.  It also includes a C library that implements the graphics
 185 capabilities of the PostScript language.  It supports a wide variety of
 186 output file formats and printers.")
 187    (license license:agpl3+)
 188    (home-page "http://www.gnu.org/software/ghostscript/")))
 189
 190 (define-public ghostscript/x
 191   (package (inherit ghostscript)
 192     (name (string-append (package-name ghostscript) "-with-x"))
 193     (inputs `(("libxext" ,libxext)
 194               ("libxt" ,libxt)
 195               ,@(package-inputs ghostscript)))))
 196
 197 (define-public ijs
 198   (package
 199    (name "ijs")
 200    (version "9.14.0")
 201    (source (origin
 202             (method url-fetch)
 203             (uri (string-append "mirror://gnu/ghostscript/gnu-ghostscript-"
 204                                 version ".tar.xz"))
 205             (sha256 (base32
 206                      "0q4jj41p0qbr4mgcc9q78f5zs8cm1g57wgryhsm2yq4lfslm3ib1"))))
 207    (build-system gnu-build-system)
 208    (native-inputs
 209     `(("libtool"    ,libtool)
 210       ("automake"   ,automake)
 211       ("autoconf"   ,autoconf)))
 212    (arguments
 213     `(#:phases
 214       (alist-cons-after
 215        'unpack 'autogen
 216        (lambda _
 217          ;; need to regenerate macros
 218          (system* "autoreconf" "-if")
 219          ;; do not run configure
 220          (substitute* "autogen.sh"
 221            (("^.*\\$srcdir/configure.*") ""))
 222          (system* "bash" "autogen.sh")
 223
 224          ;; create configure script in ./ijs/
 225          (chdir "ijs")
 226          ;; do not run configure
 227          (substitute* "autogen.sh"
 228            (("^.*\\$srcdir/configure.*") "")
 229            (("^ + && echo Now type.*$")  ""))
 230          (zero? (system* "bash" "autogen.sh")))
 231        %standard-phases)))
 232    (synopsis "IJS driver framework for inkjet and other raster devices")
 233    (description
 234     "IJS is a protocol for transmission of raster page images.  This package
 235 provides the reference implementation of the raster printer driver
 236 architecture.")
 237    (license license:expat)
 238    (home-page "http://www.gnu.org/software/ghostscript/")))
 239
 240 (define-public gs-fonts
 241   (package
 242    (name "gs-fonts")
 243    (version "8.11")
 244    (source (origin
 245             (method url-fetch)
 246             (uri (string-append "mirror://sourceforge/gs-fonts/gs-fonts/"
 247                                 version
 248                                 "%20%28base%2035%2C%20GPL%29/ghostscript-fonts-std-"
 249                                 version
 250                                 ".tar.gz"))
 251             (sha256 (base32
 252                      "00f4l10xd826kak51wsmaz69szzm2wp8a41jasr4jblz25bg7dhf"))))
 253    (build-system gnu-build-system)
 254    (arguments
 255     `(#:tests? #f ; nothing to check, just files to copy
 256       #:modules ((guix build gnu-build-system)
 257                  (guix build utils)
 258                  (srfi srfi-1)) ; for alist-delete
 259       #:phases
 260        (alist-delete
 261         'configure
 262        (alist-delete
 263         'build
 264        (alist-replace
 265         'install
 266         (lambda* (#:key outputs #:allow-other-keys)
 267           (let* ((out (assoc-ref outputs "out"))
 268                  (dir (string-append out "/share/fonts/type1/ghostscript")))
 269             (mkdir-p dir)
 270             (for-each
 271               (lambda (file)
 272                 (copy-file file (string-append dir "/" file)))
 273               (find-files "." "pfb|afm"))))
 274        %standard-phases)))))
 275    (synopsis "Free replacements for the PostScript fonts")
 276    (description
 277     "Ghostscript fonts provides fonts and font metrics customarily distributed with
 278 Ghostscript.  It currently includes the 35 standard PostScript fonts.")
 279    (license license:gpl2)
 280    (home-page "http://sourceforge.net/projects/gs-fonts/")))
 281
 282 (define-public libspectre
 283   (package
 284    (name "libspectre")
 285    (version "0.2.7")
 286    (source (origin
 287             (method url-fetch)
 288             (uri (string-append "https://libspectre.freedesktop.org/releases/libspectre-"
 289                                 version ".tar.gz"))
 290             (sha256 (base32
 291                      "1v63lqc6bhhxwkpa43qmz8phqs8ci4dhzizyy16d3vkb20m846z8"))))
 292    (build-system gnu-build-system)
 293    (inputs `(("ghostscript" ,ghostscript)))
 294    (native-inputs `(("pkg-config" ,pkg-config)))
 295    (synopsis "Postscript rendering library")
 296    (description
 297     "libspectre is a small library for rendering Postscript documents.
 298 It provides a convenient easy to use API for handling and rendering
 299 Postscript documents.")
 300    (license license:gpl2+)
 301    (home-page "http://www.freedesktop.org/wiki/Software/libspectre")))