| 1 | ;;; GNU Guix --- Functional package management for GNU |
| 2 | ;;; Copyright © 2013, 2014, 2015, 2016, 2017 Ludovic Courtès <ludo@gnu.org> |
| 3 | ;;; Copyright © 2015 Mark H Weaver <mhw@netris.org> |
| 4 | ;;; Copyright © 2015, 2016 Alex Kost <alezost@gmail.com> |
| 5 | ;;; Copyright © 2016 Chris Marusich <cmmarusich@gmail.com> |
| 6 | ;;; |
| 7 | ;;; This file is part of GNU Guix. |
| 8 | ;;; |
| 9 | ;;; GNU Guix is free software; you can redistribute it and/or modify it |
| 10 | ;;; under the terms of the GNU General Public License as published by |
| 11 | ;;; the Free Software Foundation; either version 3 of the License, or (at |
| 12 | ;;; your option) any later version. |
| 13 | ;;; |
| 14 | ;;; GNU Guix is distributed in the hope that it will be useful, but |
| 15 | ;;; WITHOUT ANY WARRANTY; without even the implied warranty of |
| 16 | ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the |
| 17 | ;;; GNU General Public License for more details. |
| 18 | ;;; |
| 19 | ;;; You should have received a copy of the GNU General Public License |
| 20 | ;;; along with GNU Guix. If not, see <http://www.gnu.org/licenses/>. |
| 21 | |
| 22 | (define-module (gnu system) |
| 23 | #:use-module (guix store) |
| 24 | #:use-module (guix monads) |
| 25 | #:use-module (guix gexp) |
| 26 | #:use-module (guix records) |
| 27 | #:use-module (guix packages) |
| 28 | #:use-module (guix derivations) |
| 29 | #:use-module (guix profiles) |
| 30 | #:use-module (guix ui) |
| 31 | #:use-module (gnu packages base) |
| 32 | #:use-module (gnu packages bash) |
| 33 | #:use-module (gnu packages guile) |
| 34 | #:use-module (gnu packages admin) |
| 35 | #:use-module (gnu packages linux) |
| 36 | #:use-module (gnu packages pciutils) |
| 37 | #:use-module (gnu packages package-management) |
| 38 | #:use-module (gnu packages less) |
| 39 | #:use-module (gnu packages zile) |
| 40 | #:use-module (gnu packages nano) |
| 41 | #:use-module (gnu packages lsof) |
| 42 | #:use-module (gnu packages gawk) |
| 43 | #:use-module (gnu packages man) |
| 44 | #:use-module (gnu packages texinfo) |
| 45 | #:use-module (gnu packages compression) |
| 46 | #:use-module (gnu packages firmware) |
| 47 | #:use-module (gnu services) |
| 48 | #:use-module (gnu services shepherd) |
| 49 | #:use-module (gnu services base) |
| 50 | #:use-module (gnu system grub) |
| 51 | #:use-module (gnu system shadow) |
| 52 | #:use-module (gnu system nss) |
| 53 | #:use-module (gnu system locale) |
| 54 | #:use-module (gnu system pam) |
| 55 | #:use-module (gnu system linux-initrd) |
| 56 | #:use-module (gnu system file-systems) |
| 57 | #:use-module (gnu system mapped-devices) |
| 58 | #:use-module (ice-9 match) |
| 59 | #:use-module (srfi srfi-1) |
| 60 | #:use-module (srfi srfi-26) |
| 61 | #:use-module (srfi srfi-34) |
| 62 | #:use-module (srfi srfi-35) |
| 63 | #:use-module (rnrs bytevectors) |
| 64 | #:export (operating-system |
| 65 | operating-system? |
| 66 | |
| 67 | operating-system-bootloader |
| 68 | operating-system-services |
| 69 | operating-system-user-services |
| 70 | operating-system-packages |
| 71 | operating-system-host-name |
| 72 | operating-system-hosts-file |
| 73 | operating-system-kernel |
| 74 | operating-system-kernel-file |
| 75 | operating-system-kernel-arguments |
| 76 | operating-system-initrd |
| 77 | operating-system-users |
| 78 | operating-system-groups |
| 79 | operating-system-issue |
| 80 | operating-system-timezone |
| 81 | operating-system-locale |
| 82 | operating-system-locale-definitions |
| 83 | operating-system-locale-libcs |
| 84 | operating-system-mapped-devices |
| 85 | operating-system-file-systems |
| 86 | operating-system-store-file-system |
| 87 | operating-system-user-mapped-devices |
| 88 | operating-system-boot-mapped-devices |
| 89 | operating-system-activation-script |
| 90 | operating-system-user-accounts |
| 91 | operating-system-shepherd-service-names |
| 92 | |
| 93 | operating-system-derivation |
| 94 | operating-system-profile |
| 95 | operating-system-grub.cfg |
| 96 | operating-system-etc-directory |
| 97 | operating-system-locale-directory |
| 98 | operating-system-boot-script |
| 99 | |
| 100 | boot-parameters |
| 101 | boot-parameters? |
| 102 | boot-parameters-label |
| 103 | boot-parameters-root-device |
| 104 | boot-parameters-store-device |
| 105 | boot-parameters-store-mount-point |
| 106 | boot-parameters-kernel |
| 107 | boot-parameters-kernel-arguments |
| 108 | boot-parameters-initrd |
| 109 | read-boot-parameters |
| 110 | |
| 111 | local-host-aliases |
| 112 | %setuid-programs |
| 113 | %base-packages |
| 114 | %base-firmware)) |
| 115 | |
| 116 | ;;; Commentary: |
| 117 | ;;; |
| 118 | ;;; This module supports whole-system configuration. |
| 119 | ;;; |
| 120 | ;;; Code: |
| 121 | |
| 122 | ;; System-wide configuration. |
| 123 | ;; TODO: Add per-field docstrings/stexi. |
| 124 | (define-record-type* <operating-system> operating-system |
| 125 | make-operating-system |
| 126 | operating-system? |
| 127 | (kernel operating-system-kernel ; package |
| 128 | (default linux-libre)) |
| 129 | (kernel-arguments operating-system-kernel-arguments |
| 130 | (default '())) ; list of gexps/strings |
| 131 | (bootloader operating-system-bootloader) ; <grub-configuration> |
| 132 | |
| 133 | (initrd operating-system-initrd ; (list fs) -> M derivation |
| 134 | (default base-initrd)) |
| 135 | (firmware operating-system-firmware ; list of packages |
| 136 | (default %base-firmware)) |
| 137 | |
| 138 | (host-name operating-system-host-name) ; string |
| 139 | (hosts-file operating-system-hosts-file ; file-like | #f |
| 140 | (default #f)) |
| 141 | |
| 142 | (mapped-devices operating-system-mapped-devices ; list of <mapped-device> |
| 143 | (default '())) |
| 144 | (file-systems operating-system-file-systems) ; list of fs |
| 145 | (swap-devices operating-system-swap-devices ; list of strings |
| 146 | (default '())) |
| 147 | |
| 148 | (users operating-system-users ; list of user accounts |
| 149 | (default %base-user-accounts)) |
| 150 | (groups operating-system-groups ; list of user groups |
| 151 | (default %base-groups)) |
| 152 | |
| 153 | (skeletons operating-system-skeletons ; list of name/monadic value |
| 154 | (default (default-skeletons))) |
| 155 | (issue operating-system-issue ; string |
| 156 | (default %default-issue)) |
| 157 | |
| 158 | (packages operating-system-packages ; list of (PACKAGE OUTPUT...) |
| 159 | (default %base-packages)) ; or just PACKAGE |
| 160 | |
| 161 | (timezone operating-system-timezone) ; string |
| 162 | (locale operating-system-locale ; string |
| 163 | (default "en_US.utf8")) |
| 164 | (locale-definitions operating-system-locale-definitions ; list of <locale-definition> |
| 165 | (default %default-locale-definitions)) |
| 166 | (locale-libcs operating-system-locale-libcs ; list of <packages> |
| 167 | (default %default-locale-libcs)) |
| 168 | (name-service-switch operating-system-name-service-switch ; <name-service-switch> |
| 169 | (default %default-nss)) |
| 170 | |
| 171 | (services operating-system-user-services ; list of monadic services |
| 172 | (default %base-services)) |
| 173 | |
| 174 | (pam-services operating-system-pam-services ; list of PAM services |
| 175 | (default (base-pam-services))) |
| 176 | (setuid-programs operating-system-setuid-programs |
| 177 | (default %setuid-programs)) ; list of string-valued gexps |
| 178 | |
| 179 | (sudoers-file operating-system-sudoers-file ; file-like |
| 180 | (default %sudoers-specification))) |
| 181 | |
| 182 | \f |
| 183 | ;;; |
| 184 | ;;; Services. |
| 185 | ;;; |
| 186 | |
| 187 | (define (non-boot-file-system-service os) |
| 188 | "Return the file system service for the file systems of OS that are not |
| 189 | marked as 'needed-for-boot'." |
| 190 | (define file-systems |
| 191 | (remove file-system-needed-for-boot? |
| 192 | (operating-system-file-systems os))) |
| 193 | |
| 194 | (define (device-mappings fs) |
| 195 | (let ((device (file-system-device fs))) |
| 196 | (if (string? device) ;title is 'device |
| 197 | (filter (lambda (md) |
| 198 | (string=? (string-append "/dev/mapper/" |
| 199 | (mapped-device-target md)) |
| 200 | device)) |
| 201 | (operating-system-mapped-devices os)) |
| 202 | '()))) |
| 203 | |
| 204 | (define (add-dependencies fs) |
| 205 | ;; Add the dependencies due to device mappings to FS. |
| 206 | (file-system |
| 207 | (inherit fs) |
| 208 | (dependencies |
| 209 | (delete-duplicates (append (device-mappings fs) |
| 210 | (file-system-dependencies fs)) |
| 211 | eq?)))) |
| 212 | |
| 213 | (service file-system-service-type |
| 214 | (map add-dependencies file-systems))) |
| 215 | |
| 216 | (define (mapped-device-user device file-systems) |
| 217 | "Return a file system among FILE-SYSTEMS that uses DEVICE, or #f." |
| 218 | (let ((target (string-append "/dev/mapper/" (mapped-device-target device)))) |
| 219 | (find (lambda (fs) |
| 220 | (or (member device (file-system-dependencies fs)) |
| 221 | (and (eq? 'device (file-system-title fs)) |
| 222 | (string=? (file-system-device fs) target)))) |
| 223 | file-systems))) |
| 224 | |
| 225 | (define (operating-system-user-mapped-devices os) |
| 226 | "Return the subset of mapped devices that can be installed in |
| 227 | user-land--i.e., those not needed during boot." |
| 228 | (let ((devices (operating-system-mapped-devices os)) |
| 229 | (file-systems (operating-system-file-systems os))) |
| 230 | (filter (lambda (md) |
| 231 | (let ((user (mapped-device-user md file-systems))) |
| 232 | (or (not user) |
| 233 | (not (file-system-needed-for-boot? user))))) |
| 234 | devices))) |
| 235 | |
| 236 | (define (operating-system-boot-mapped-devices os) |
| 237 | "Return the subset of mapped devices that must be installed during boot, |
| 238 | from the initrd." |
| 239 | (let ((devices (operating-system-mapped-devices os)) |
| 240 | (file-systems (operating-system-file-systems os))) |
| 241 | (filter (lambda (md) |
| 242 | (let ((user (mapped-device-user md file-systems))) |
| 243 | (and user (file-system-needed-for-boot? user)))) |
| 244 | devices))) |
| 245 | |
| 246 | (define (device-mapping-services os) |
| 247 | "Return the list of device-mapping services for OS as a list." |
| 248 | (map device-mapping-service |
| 249 | (operating-system-user-mapped-devices os))) |
| 250 | |
| 251 | (define (swap-services os) |
| 252 | "Return the list of swap services for OS." |
| 253 | (map swap-service (operating-system-swap-devices os))) |
| 254 | |
| 255 | (define* (system-linux-image-file-name #:optional (system (%current-system))) |
| 256 | "Return the basename of the kernel image file for SYSTEM." |
| 257 | ;; FIXME: Evaluate the conditional based on the actual current system. |
| 258 | (if (string-prefix? "mips" (%current-system)) |
| 259 | "vmlinuz" |
| 260 | "bzImage")) |
| 261 | |
| 262 | (define (operating-system-kernel-file os) |
| 263 | "Return an object representing the absolute file name of the kernel image of |
| 264 | OS." |
| 265 | (file-append (operating-system-kernel os) |
| 266 | "/" (system-linux-image-file-name os))) |
| 267 | |
| 268 | (define* (operating-system-directory-base-entries os #:key container?) |
| 269 | "Return the basic entries of the 'system' directory of OS for use as the |
| 270 | value of the SYSTEM-SERVICE-TYPE service." |
| 271 | (mlet %store-monad ((locale (operating-system-locale-directory os))) |
| 272 | (if container? |
| 273 | (return `(("locale" ,locale))) |
| 274 | (mlet %store-monad |
| 275 | ((kernel -> (operating-system-kernel os)) |
| 276 | (initrd (operating-system-initrd-file os)) |
| 277 | (params (operating-system-parameters-file os))) |
| 278 | (return `(("kernel" ,kernel) |
| 279 | ("parameters" ,params) |
| 280 | ("initrd" ,initrd) |
| 281 | ("locale" ,locale))))))) ;used by libc |
| 282 | |
| 283 | (define* (essential-services os #:key container?) |
| 284 | "Return the list of essential services for OS. These are special services |
| 285 | that implement part of what's declared in OS are responsible for low-level |
| 286 | bookkeeping. CONTAINER? determines whether to return the list of services for |
| 287 | a container or that of a \"bare metal\" system." |
| 288 | (define known-fs |
| 289 | (map file-system-mount-point (operating-system-file-systems os))) |
| 290 | |
| 291 | (let* ((mappings (device-mapping-services os)) |
| 292 | (root-fs (root-file-system-service)) |
| 293 | (other-fs (non-boot-file-system-service os)) |
| 294 | (unmount (user-unmount-service known-fs)) |
| 295 | (swaps (swap-services os)) |
| 296 | (procs (user-processes-service)) |
| 297 | (host-name (host-name-service (operating-system-host-name os))) |
| 298 | (entries (operating-system-directory-base-entries |
| 299 | os #:container? container?))) |
| 300 | (cons* (service system-service-type entries) |
| 301 | %boot-service |
| 302 | |
| 303 | ;; %SHEPHERD-ROOT-SERVICE must come first so that the gexp that |
| 304 | ;; execs shepherd comes last in the boot script (XXX). Likewise, |
| 305 | ;; the cleanup service must come last so that its gexp runs before |
| 306 | ;; activation code. |
| 307 | %shepherd-root-service |
| 308 | %activation-service |
| 309 | (service cleanup-service-type #f) |
| 310 | |
| 311 | (pam-root-service (operating-system-pam-services os)) |
| 312 | (account-service (append (operating-system-accounts os) |
| 313 | (operating-system-groups os)) |
| 314 | (operating-system-skeletons os)) |
| 315 | (operating-system-etc-service os) |
| 316 | (service fstab-service-type '()) |
| 317 | (session-environment-service |
| 318 | (operating-system-environment-variables os)) |
| 319 | host-name procs root-fs unmount |
| 320 | (service setuid-program-service-type |
| 321 | (operating-system-setuid-programs os)) |
| 322 | (service profile-service-type |
| 323 | (operating-system-packages os)) |
| 324 | other-fs |
| 325 | (append mappings swaps |
| 326 | |
| 327 | ;; Add the firmware service, unless we are building for a |
| 328 | ;; container. |
| 329 | (if container? |
| 330 | '() |
| 331 | (list %linux-bare-metal-service |
| 332 | (service firmware-service-type |
| 333 | (operating-system-firmware os)))))))) |
| 334 | |
| 335 | (define* (operating-system-services os #:key container?) |
| 336 | "Return all the services of OS, including \"internal\" services that do not |
| 337 | explicitly appear in OS." |
| 338 | (append (operating-system-user-services os) |
| 339 | (essential-services os #:container? container?))) |
| 340 | |
| 341 | \f |
| 342 | ;;; |
| 343 | ;;; /etc. |
| 344 | ;;; |
| 345 | |
| 346 | (define %base-firmware |
| 347 | ;; Firmware usable by default. |
| 348 | (list ath9k-htc-firmware |
| 349 | openfwwf-firmware)) |
| 350 | |
| 351 | (define %base-packages |
| 352 | ;; Default set of packages globally visible. It should include anything |
| 353 | ;; required for basic administrator tasks. |
| 354 | (cons* procps psmisc which less zile nano |
| 355 | lsof ;for Guix's 'list-runtime-roots' |
| 356 | pciutils usbutils |
| 357 | util-linux inetutils isc-dhcp |
| 358 | |
| 359 | ;; wireless-tools is deprecated in favor of iw, but it's still what |
| 360 | ;; many people are familiar with, so keep it around. |
| 361 | iw wireless-tools rfkill |
| 362 | |
| 363 | iproute |
| 364 | net-tools ; XXX: remove when Inetutils suffices |
| 365 | man-db |
| 366 | info-reader ;the standalone Info reader (no Perl) |
| 367 | |
| 368 | ;; The 'sudo' command is already in %SETUID-PROGRAMS, but we also |
| 369 | ;; want the other commands and the man pages (notably because |
| 370 | ;; auto-completion in Emacs shell relies on man pages.) |
| 371 | sudo |
| 372 | |
| 373 | ;; Get 'insmod' & co. from kmod, not module-init-tools, since udev |
| 374 | ;; already depends on it anyway. |
| 375 | kmod eudev |
| 376 | |
| 377 | e2fsprogs kbd |
| 378 | |
| 379 | bash-completion |
| 380 | |
| 381 | ;; The packages below are also in %FINAL-INPUTS, so take them from |
| 382 | ;; there to avoid duplication. |
| 383 | (map canonical-package |
| 384 | (list guile-2.0 bash coreutils findutils grep sed |
| 385 | diffutils patch gawk tar gzip bzip2 xz lzip)))) |
| 386 | |
| 387 | (define %default-issue |
| 388 | ;; Default contents for /etc/issue. |
| 389 | " |
| 390 | This is the GNU system. Welcome.\n") |
| 391 | |
| 392 | (define (local-host-aliases host-name) |
| 393 | "Return aliases for HOST-NAME, to be used in /etc/hosts." |
| 394 | (string-append "127.0.0.1 localhost " host-name "\n" |
| 395 | "::1 localhost " host-name "\n")) |
| 396 | |
| 397 | (define (default-/etc/hosts host-name) |
| 398 | "Return the default /etc/hosts file." |
| 399 | (plain-file "hosts" (local-host-aliases host-name))) |
| 400 | |
| 401 | (define* (operating-system-etc-service os) |
| 402 | "Return a <service> that builds containing the static part of the /etc |
| 403 | directory." |
| 404 | (let ((login.defs (plain-file "login.defs" "# Empty for now.\n")) |
| 405 | |
| 406 | (issue (plain-file "issue" (operating-system-issue os))) |
| 407 | (nsswitch (plain-file "nsswitch.conf" |
| 408 | (name-service-switch->string |
| 409 | (operating-system-name-service-switch os)))) |
| 410 | |
| 411 | ;; Startup file for POSIX-compliant login shells, which set system-wide |
| 412 | ;; environment variables. |
| 413 | (profile (mixed-text-file "profile" "\ |
| 414 | # Crucial variables that could be missing in the profiles' 'etc/profile' |
| 415 | # because they would require combining both profiles. |
| 416 | # FIXME: See <http://bugs.gnu.org/20255>. |
| 417 | export MANPATH=$HOME/.guix-profile/share/man:/run/current-system/profile/share/man |
| 418 | export INFOPATH=$HOME/.guix-profile/share/info:/run/current-system/profile/share/info |
| 419 | export XDG_DATA_DIRS=$HOME/.guix-profile/share:/run/current-system/profile/share |
| 420 | export XDG_CONFIG_DIRS=$HOME/.guix-profile/etc/xdg:/run/current-system/profile/etc/xdg |
| 421 | |
| 422 | # Ignore the default value of 'PATH'. |
| 423 | unset PATH |
| 424 | |
| 425 | # Load the system profile's settings. |
| 426 | GUIX_PROFILE=/run/current-system/profile \\ |
| 427 | . /run/current-system/profile/etc/profile |
| 428 | |
| 429 | # Prepend setuid programs. |
| 430 | export PATH=/run/setuid-programs:$PATH |
| 431 | |
| 432 | # Since 'lshd' does not use pam_env, /etc/environment must be explicitly |
| 433 | # loaded when someone logs in via SSH. See <http://bugs.gnu.org/22175>. |
| 434 | # We need 'PATH' to be defined here, for 'cat' and 'cut'. Do this before |
| 435 | # reading the user's 'etc/profile' to allow variables to be overridden. |
| 436 | if [ -f /etc/environment -a -n \"$SSH_CLIENT\" \\ |
| 437 | -a -z \"$LINUX_MODULE_DIRECTORY\" ] |
| 438 | then |
| 439 | . /etc/environment |
| 440 | export `cat /etc/environment | cut -d= -f1` |
| 441 | fi |
| 442 | |
| 443 | if [ -f \"$HOME/.guix-profile/etc/profile\" ] |
| 444 | then |
| 445 | # Load the user profile's settings. |
| 446 | GUIX_PROFILE=\"$HOME/.guix-profile\" \\ |
| 447 | . \"$HOME/.guix-profile/etc/profile\" |
| 448 | else |
| 449 | # At least define this one so that basic things just work |
| 450 | # when the user installs their first package. |
| 451 | export PATH=\"$HOME/.guix-profile/bin:$PATH\" |
| 452 | fi |
| 453 | |
| 454 | # Set the umask, notably for users logging in via 'lsh'. |
| 455 | # See <http://bugs.gnu.org/22650>. |
| 456 | umask 022 |
| 457 | |
| 458 | # Allow GStreamer-based applications to find plugins. |
| 459 | export GST_PLUGIN_PATH=\"$HOME/.guix-profile/lib/gstreamer-1.0\" |
| 460 | |
| 461 | if [ -n \"$BASH_VERSION\" -a -f /etc/bashrc ] |
| 462 | then |
| 463 | # Load Bash-specific initialization code. |
| 464 | . /etc/bashrc |
| 465 | fi |
| 466 | ")) |
| 467 | |
| 468 | (bashrc (plain-file "bashrc" "\ |
| 469 | # Bash-specific initialization. |
| 470 | |
| 471 | # The 'bash-completion' package. |
| 472 | if [ -f /run/current-system/profile/etc/profile.d/bash_completion.sh ] |
| 473 | then |
| 474 | # Bash-completion sources ~/.bash_completion. It installs a dynamic |
| 475 | # completion loader that searches its own completion files as well |
| 476 | # as those in ~/.guix-profile and /run/current-system/profile. |
| 477 | source /run/current-system/profile/etc/profile.d/bash_completion.sh |
| 478 | fi\n"))) |
| 479 | (etc-service |
| 480 | `(("services" ,(file-append net-base "/etc/services")) |
| 481 | ("protocols" ,(file-append net-base "/etc/protocols")) |
| 482 | ("rpc" ,(file-append net-base "/etc/rpc")) |
| 483 | ("login.defs" ,#~#$login.defs) |
| 484 | ("issue" ,#~#$issue) |
| 485 | ("nsswitch.conf" ,#~#$nsswitch) |
| 486 | ("profile" ,#~#$profile) |
| 487 | ("bashrc" ,#~#$bashrc) |
| 488 | ("hosts" ,#~#$(or (operating-system-hosts-file os) |
| 489 | (default-/etc/hosts (operating-system-host-name os)))) |
| 490 | ("localtime" ,(file-append tzdata "/share/zoneinfo/" |
| 491 | (operating-system-timezone os))) |
| 492 | ("sudoers" ,(operating-system-sudoers-file os)))))) |
| 493 | |
| 494 | (define %root-account |
| 495 | ;; Default root account. |
| 496 | (user-account |
| 497 | (name "root") |
| 498 | (password "") |
| 499 | (uid 0) (group "root") |
| 500 | (comment "System administrator") |
| 501 | (home-directory "/root"))) |
| 502 | |
| 503 | (define (operating-system-accounts os) |
| 504 | "Return the user accounts for OS, including an obligatory 'root' account, |
| 505 | and excluding accounts requested by services." |
| 506 | ;; Make sure there's a root account. |
| 507 | (if (find (lambda (user) |
| 508 | (and=> (user-account-uid user) zero?)) |
| 509 | (operating-system-users os)) |
| 510 | (operating-system-users os) |
| 511 | (cons %root-account (operating-system-users os)))) |
| 512 | |
| 513 | (define (maybe-string->file file-name thing) |
| 514 | "If THING is a string, return a <plain-file> with THING as its content. |
| 515 | Otherwise just return THING. |
| 516 | |
| 517 | This is for backward-compatibility of fields that used to be strings and are |
| 518 | now file-like objects.." |
| 519 | (match thing |
| 520 | ((? string?) |
| 521 | (warning (_ "using a string for file '~a' is deprecated; \ |
| 522 | use 'plain-file' instead~%") |
| 523 | file-name) |
| 524 | (plain-file file-name thing)) |
| 525 | (x |
| 526 | x))) |
| 527 | |
| 528 | (define (maybe-file->monadic file-name thing) |
| 529 | "If THING is a value in %STORE-MONAD, return it as is; otherwise return |
| 530 | THING in the %STORE-MONAD. |
| 531 | |
| 532 | This is for backward-compatibility of fields that used to be monadic values |
| 533 | and are now file-like objects." |
| 534 | (with-monad %store-monad |
| 535 | (match thing |
| 536 | ((? procedure?) |
| 537 | (warning (_ "using a monadic value for '~a' is deprecated; \ |
| 538 | use 'plain-file' instead~%") |
| 539 | file-name) |
| 540 | thing) |
| 541 | (x |
| 542 | (return x))))) |
| 543 | |
| 544 | (define (operating-system-etc-directory os) |
| 545 | "Return that static part of the /etc directory of OS." |
| 546 | (etc-directory |
| 547 | (fold-services (operating-system-services os) |
| 548 | #:target-type etc-service-type))) |
| 549 | |
| 550 | (define (operating-system-environment-variables os) |
| 551 | "Return the environment variables of OS for |
| 552 | @var{session-environment-service-type}, to be used in @file{/etc/environment}." |
| 553 | `(("LANG" . ,(operating-system-locale os)) |
| 554 | ("TZ" . ,(operating-system-timezone os)) |
| 555 | ("TZDIR" . ,(file-append tzdata "/share/zoneinfo")) |
| 556 | ;; Tell 'modprobe' & co. where to look for modules. |
| 557 | ("LINUX_MODULE_DIRECTORY" . "/run/booted-system/kernel/lib/modules") |
| 558 | ;; These variables are honored by OpenSSL (libssl) and Git. |
| 559 | ("SSL_CERT_DIR" . "/etc/ssl/certs") |
| 560 | ("SSL_CERT_FILE" . "/etc/ssl/certs/ca-certificates.crt") |
| 561 | ("GIT_SSL_CAINFO" . "/etc/ssl/certs/ca-certificates.crt") |
| 562 | |
| 563 | ;; 'GTK_DATA_PREFIX' must name one directory where GTK+ themes are |
| 564 | ;; searched for. |
| 565 | ("GTK_DATA_PREFIX" . "/run/current-system/profile") |
| 566 | |
| 567 | ;; By default, applications that use D-Bus, such as Emacs, abort at startup |
| 568 | ;; when /etc/machine-id is missing. Make sure these warnings are non-fatal. |
| 569 | ("DBUS_FATAL_WARNINGS" . "0") |
| 570 | |
| 571 | ;; XXX: Normally we wouldn't need to do this, but our glibc@2.23 package |
| 572 | ;; used to look things up in 'PREFIX/lib/locale' instead of |
| 573 | ;; '/run/current-system/locale' as was intended. Keep this hack around so |
| 574 | ;; that people who still have glibc@2.23-using packages in their profiles |
| 575 | ;; can use them correctly. |
| 576 | ;; TODO: Remove when glibc@2.23 is long gone. |
| 577 | ("GUIX_LOCPATH" . "/run/current-system/locale"))) |
| 578 | |
| 579 | (define %setuid-programs |
| 580 | ;; Default set of setuid-root programs. |
| 581 | (let ((shadow (@ (gnu packages admin) shadow))) |
| 582 | (list (file-append shadow "/bin/passwd") |
| 583 | (file-append shadow "/bin/su") |
| 584 | (file-append inetutils "/bin/ping") |
| 585 | (file-append inetutils "/bin/ping6") |
| 586 | (file-append sudo "/bin/sudo") |
| 587 | (file-append fuse "/bin/fusermount")))) |
| 588 | |
| 589 | (define %sudoers-specification |
| 590 | ;; Default /etc/sudoers contents: 'root' and all members of the 'wheel' |
| 591 | ;; group can do anything. See |
| 592 | ;; <http://www.sudo.ws/sudo/man/1.8.10/sudoers.man.html>. |
| 593 | ;; TODO: Add a declarative API. |
| 594 | (plain-file "sudoers" "\ |
| 595 | root ALL=(ALL) ALL |
| 596 | %wheel ALL=(ALL) ALL\n")) |
| 597 | |
| 598 | (define* (operating-system-activation-script os #:key container?) |
| 599 | "Return the activation script for OS---i.e., the code that \"activates\" the |
| 600 | stateful part of OS, including user accounts and groups, special directories, |
| 601 | etc." |
| 602 | (let* ((services (operating-system-services os #:container? container?)) |
| 603 | (activation (fold-services services |
| 604 | #:target-type activation-service-type))) |
| 605 | (activation-service->script activation))) |
| 606 | |
| 607 | (define* (operating-system-boot-script os #:key container?) |
| 608 | "Return the boot script for OS---i.e., the code started by the initrd once |
| 609 | we're running in the final root. When CONTAINER? is true, skip all |
| 610 | hardware-related operations as necessary when booting a Linux container." |
| 611 | (let* ((services (operating-system-services os #:container? container?)) |
| 612 | (boot (fold-services services #:target-type boot-service-type))) |
| 613 | ;; BOOT is the script as a monadic value. |
| 614 | (service-parameters boot))) |
| 615 | |
| 616 | (define (operating-system-user-accounts os) |
| 617 | "Return the list of user accounts of OS." |
| 618 | (let* ((services (operating-system-services os)) |
| 619 | (account (fold-services services |
| 620 | #:target-type account-service-type))) |
| 621 | (filter user-account? |
| 622 | (service-parameters account)))) |
| 623 | |
| 624 | (define (operating-system-shepherd-service-names os) |
| 625 | "Return the list of Shepherd service names for OS." |
| 626 | (append-map shepherd-service-provision |
| 627 | (service-parameters |
| 628 | (fold-services (operating-system-services os) |
| 629 | #:target-type |
| 630 | shepherd-root-service-type)))) |
| 631 | |
| 632 | (define* (operating-system-derivation os #:key container?) |
| 633 | "Return a derivation that builds OS." |
| 634 | (let* ((services (operating-system-services os #:container? container?)) |
| 635 | (system (fold-services services))) |
| 636 | ;; SYSTEM contains the derivation as a monadic value. |
| 637 | (service-parameters system))) |
| 638 | |
| 639 | (define* (operating-system-profile os #:key container?) |
| 640 | "Return a derivation that builds the system profile of OS." |
| 641 | (mlet* %store-monad |
| 642 | ((services -> (operating-system-services os #:container? container?)) |
| 643 | (profile (fold-services services |
| 644 | #:target-type profile-service-type))) |
| 645 | (match profile |
| 646 | (("profile" profile) |
| 647 | (return profile))))) |
| 648 | |
| 649 | (define (operating-system-root-file-system os) |
| 650 | "Return the root file system of OS." |
| 651 | (find (match-lambda |
| 652 | (($ <file-system> _ _ "/") #t) |
| 653 | (_ #f)) |
| 654 | (operating-system-file-systems os))) |
| 655 | |
| 656 | (define (operating-system-initrd-file os) |
| 657 | "Return a gexp denoting the initrd file of OS." |
| 658 | (define boot-file-systems |
| 659 | (filter file-system-needed-for-boot? |
| 660 | (operating-system-file-systems os))) |
| 661 | |
| 662 | (define mapped-devices |
| 663 | (operating-system-boot-mapped-devices os)) |
| 664 | |
| 665 | (define make-initrd |
| 666 | (operating-system-initrd os)) |
| 667 | |
| 668 | (mlet %store-monad ((initrd (make-initrd boot-file-systems |
| 669 | #:linux (operating-system-kernel os) |
| 670 | #:mapped-devices mapped-devices))) |
| 671 | (return (file-append initrd "/initrd")))) |
| 672 | |
| 673 | (define (locale-name->definition* name) |
| 674 | "Variant of 'locale-name->definition' that raises an error upon failure." |
| 675 | (match (locale-name->definition name) |
| 676 | (#f |
| 677 | (raise (condition |
| 678 | (&message |
| 679 | (message (format #f (_ "~a: invalid locale name") name)))))) |
| 680 | (def def))) |
| 681 | |
| 682 | (define (operating-system-locale-directory os) |
| 683 | "Return the directory containing the locales compiled for the definitions |
| 684 | listed in OS. The C library expects to find it under |
| 685 | /run/current-system/locale." |
| 686 | (define name |
| 687 | (operating-system-locale os)) |
| 688 | |
| 689 | (define definitions |
| 690 | ;; While we're at it, check whether NAME is defined and add it if needed. |
| 691 | (if (member name (map locale-definition-name |
| 692 | (operating-system-locale-definitions os))) |
| 693 | (operating-system-locale-definitions os) |
| 694 | (cons (locale-name->definition* name) |
| 695 | (operating-system-locale-definitions os)))) |
| 696 | |
| 697 | (locale-directory definitions |
| 698 | #:libcs (operating-system-locale-libcs os))) |
| 699 | |
| 700 | (define (kernel->grub-label kernel) |
| 701 | "Return a label for the GRUB menu entry that boots KERNEL." |
| 702 | (string-append "GNU with " |
| 703 | (string-titlecase (package-name kernel)) " " |
| 704 | (package-version kernel) |
| 705 | " (beta)")) |
| 706 | |
| 707 | (define (store-file-system file-systems) |
| 708 | "Return the file system object among FILE-SYSTEMS that contains the store." |
| 709 | (match (filter (lambda (fs) |
| 710 | (and (file-system-mount? fs) |
| 711 | (not (memq 'bind-mount (file-system-flags fs))) |
| 712 | (string-prefix? (file-system-mount-point fs) |
| 713 | (%store-prefix)))) |
| 714 | file-systems) |
| 715 | ((and candidates (head . tail)) |
| 716 | (reduce (lambda (fs1 fs2) |
| 717 | (if (> (string-length (file-system-mount-point fs1)) |
| 718 | (string-length (file-system-mount-point fs2))) |
| 719 | fs1 |
| 720 | fs2)) |
| 721 | head |
| 722 | candidates)))) |
| 723 | |
| 724 | (define (operating-system-store-file-system os) |
| 725 | "Return the file system that contains the store of OS." |
| 726 | (store-file-system (operating-system-file-systems os))) |
| 727 | |
| 728 | (define* (operating-system-grub.cfg os #:optional (old-entries '())) |
| 729 | "Return the GRUB configuration file for OS. Use OLD-ENTRIES to populate the |
| 730 | \"old entries\" menu." |
| 731 | (mlet* %store-monad |
| 732 | ((system (operating-system-derivation os)) |
| 733 | (root-fs -> (operating-system-root-file-system os)) |
| 734 | (store-fs -> (operating-system-store-file-system os)) |
| 735 | (label -> (kernel->grub-label (operating-system-kernel os))) |
| 736 | (kernel -> (operating-system-kernel-file os)) |
| 737 | (initrd (operating-system-initrd-file os)) |
| 738 | (root-device -> (if (eq? 'uuid (file-system-title root-fs)) |
| 739 | (uuid->string (file-system-device root-fs)) |
| 740 | (file-system-device root-fs))) |
| 741 | (entries -> (list (menu-entry |
| 742 | (label label) |
| 743 | |
| 744 | ;; The device where the kernel and initrd live. |
| 745 | (device (grub-device store-fs)) |
| 746 | (device-mount-point |
| 747 | (file-system-mount-point store-fs)) |
| 748 | |
| 749 | (linux kernel) |
| 750 | (linux-arguments |
| 751 | (cons* (string-append "--root=" root-device) |
| 752 | #~(string-append "--system=" #$system) |
| 753 | #~(string-append "--load=" #$system |
| 754 | "/boot") |
| 755 | (operating-system-kernel-arguments os))) |
| 756 | (initrd initrd))))) |
| 757 | (grub-configuration-file (operating-system-bootloader os) entries |
| 758 | #:old-entries old-entries))) |
| 759 | |
| 760 | (define (grub-device fs) |
| 761 | "Given FS, a <file-system> object, return a value suitable for use as the |
| 762 | device in a <menu-entry>." |
| 763 | (case (file-system-title fs) |
| 764 | ((uuid) (file-system-device fs)) |
| 765 | ((label) (file-system-device fs)) |
| 766 | (else #f))) |
| 767 | |
| 768 | (define (operating-system-parameters-file os) |
| 769 | "Return a file that describes the boot parameters of OS. The primary use of |
| 770 | this file is the reconstruction of GRUB menu entries for old configurations." |
| 771 | (mlet %store-monad ((initrd (operating-system-initrd-file os)) |
| 772 | (root -> (operating-system-root-file-system os)) |
| 773 | (store -> (operating-system-store-file-system os)) |
| 774 | (label -> (kernel->grub-label |
| 775 | (operating-system-kernel os)))) |
| 776 | (gexp->file "parameters" |
| 777 | #~(boot-parameters |
| 778 | (version 0) |
| 779 | (label #$label) |
| 780 | (root-device #$(file-system-device root)) |
| 781 | (kernel #$(operating-system-kernel-file os)) |
| 782 | (kernel-arguments |
| 783 | #$(operating-system-kernel-arguments os)) |
| 784 | (initrd #$initrd) |
| 785 | (store |
| 786 | (device #$(grub-device store)) |
| 787 | (mount-point #$(file-system-mount-point store)))) |
| 788 | #:set-load-path? #f))) |
| 789 | |
| 790 | \f |
| 791 | ;;; |
| 792 | ;;; Boot parameters |
| 793 | ;;; |
| 794 | |
| 795 | (define-record-type* <boot-parameters> |
| 796 | boot-parameters make-boot-parameters boot-parameters? |
| 797 | (label boot-parameters-label) |
| 798 | ;; Because we will use the 'store-device' to create the GRUB search command, |
| 799 | ;; the 'store-device' has slightly different semantics than 'root-device'. |
| 800 | ;; The 'store-device' can be a file system uuid, a file system label, or #f, |
| 801 | ;; but it cannot be a device path such as "/dev/sda3", since GRUB would not |
| 802 | ;; understand that. The 'root-device', on the other hand, corresponds |
| 803 | ;; exactly to the device field of the <file-system> object representing the |
| 804 | ;; OS's root file system, so it might be a device path like "/dev/sda3". |
| 805 | (root-device boot-parameters-root-device) |
| 806 | (store-device boot-parameters-store-device) |
| 807 | (store-mount-point boot-parameters-store-mount-point) |
| 808 | (kernel boot-parameters-kernel) |
| 809 | (kernel-arguments boot-parameters-kernel-arguments) |
| 810 | (initrd boot-parameters-initrd)) |
| 811 | |
| 812 | (define (read-boot-parameters port) |
| 813 | "Read boot parameters from PORT and return the corresponding |
| 814 | <boot-parameters> object or #f if the format is unrecognized." |
| 815 | (match (read port) |
| 816 | (('boot-parameters ('version 0) |
| 817 | ('label label) ('root-device root) |
| 818 | ('kernel linux) |
| 819 | rest ...) |
| 820 | (boot-parameters |
| 821 | (label label) |
| 822 | (root-device root) |
| 823 | |
| 824 | ;; In the past, we would store the directory name of the kernel instead |
| 825 | ;; of the absolute file name of its image. Detect that and correct it. |
| 826 | (kernel (if (string=? linux (direct-store-path linux)) |
| 827 | (string-append linux "/" |
| 828 | (system-linux-image-file-name)) |
| 829 | linux)) |
| 830 | |
| 831 | (kernel-arguments |
| 832 | (match (assq 'kernel-arguments rest) |
| 833 | ((_ args) args) |
| 834 | (#f '()))) ;the old format |
| 835 | |
| 836 | (initrd |
| 837 | (match (assq 'initrd rest) |
| 838 | (('initrd ('string-append directory file)) ;the old format |
| 839 | (string-append directory file)) |
| 840 | (('initrd (? string? file)) |
| 841 | file))) |
| 842 | |
| 843 | (store-device |
| 844 | (match (assq 'store rest) |
| 845 | (('store ('device device) _ ...) |
| 846 | device) |
| 847 | (_ ;the old format |
| 848 | ;; Root might be a device path like "/dev/sda1", which is not a |
| 849 | ;; suitable GRUB device identifier. |
| 850 | (if (string-prefix? "/" root) |
| 851 | #f |
| 852 | root)))) |
| 853 | |
| 854 | (store-mount-point |
| 855 | (match (assq 'store rest) |
| 856 | (('store ('device _) ('mount-point mount-point) _ ...) |
| 857 | mount-point) |
| 858 | (_ ;the old format |
| 859 | "/"))))) |
| 860 | (x ;unsupported format |
| 861 | (warning (_ "unrecognized boot parameters for '~a'~%") |
| 862 | system) |
| 863 | #f))) |
| 864 | |
| 865 | ;;; system.scm ends here |