[jackhill/guix/guix.git] / gnu / system / mapped-devices.scm

;;; GNU Guix --- Functional package management for GNU
;;; Copyright © 2014, 2015, 2016, 2017, 2018, 2019 Ludovic Courtès <ludo@gnu.org>
;;; Copyright © 2016 Andreas Enge <andreas@enge.fr>
;;; Copyright © 2017, 2018 Mark H Weaver <mhw@netris.org>
;;;
;;; This file is part of GNU Guix.
;;;
;;; GNU Guix is free software; you can redistribute it and/or modify it
;;; under the terms of the GNU General Public License as published by
;;; the Free Software Foundation; either version 3 of the License, or (at
;;; your option) any later version.
;;;
;;; GNU Guix is distributed in the hope that it will be useful, but
;;; WITHOUT ANY WARRANTY; without even the implied warranty of
;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;;; GNU General Public License for more details.
;;;
;;; You should have received a copy of the GNU General Public License
;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.

(define-module (gnu system mapped-devices)
  #:use-module (guix gexp)
  #:use-module (guix records)
  #:use-module ((guix modules) #:hide (file-name->module-name))
  #:use-module (guix i18n)
  #:use-module ((guix utils)
                #:select (source-properties->location
                          &fix-hint
                          &error-location))
  #:use-module (gnu services)
  #:use-module (gnu services shepherd)
  #:use-module (gnu system uuid)
  #:autoload   (gnu build file-systems) (find-partition-by-luks-uuid)
  #:autoload   (gnu build linux-modules)
                 (missing-modules)
  #:autoload   (gnu packages cryptsetup) (cryptsetup-static)
  #:autoload   (gnu packages linux) (mdadm-static)
  #:use-module (srfi srfi-1)
  #:use-module (srfi srfi-26)
  #:use-module (srfi srfi-34)
  #:use-module (srfi srfi-35)
  #:use-module (ice-9 match)
  #:export (mapped-device
            mapped-device?
            mapped-device-source
            mapped-device-target
            mapped-device-type
            mapped-device-location

            mapped-device-kind
            mapped-device-kind?
            mapped-device-kind-open
            mapped-device-kind-close
            mapped-device-kind-check

            device-mapping-service-type
            device-mapping-service

            check-device-initrd-modules           ;XXX: needs a better place

            luks-device-mapping
            raid-device-mapping))

;;; Commentary:
;;;
;;; This module supports "device mapping", a concept implemented by Linux's
;;; device-mapper.
;;;
;;; Code:

(define-record-type* <mapped-device> mapped-device
  make-mapped-device
  mapped-device?
  (source    mapped-device-source)                ;string | list of strings
  (target    mapped-device-target)                ;string
  (type      mapped-device-type)                  ;<mapped-device-kind>
  (location  mapped-device-location
             (default (current-source-location)) (innate)))

(define-record-type* <mapped-device-type> mapped-device-kind
  make-mapped-device-kind
  mapped-device-kind?
  (open      mapped-device-kind-open)             ;source target -> gexp
  (close     mapped-device-kind-close             ;source target -> gexp
             (default (const #~(const #f))))
  (check     mapped-device-kind-check             ;source -> Boolean
             (default (const #t))))

\f
;;;
;;; Device mapping as a Shepherd service.
;;;

(define device-mapping-service-type
  (shepherd-service-type
   'device-mapping
   (match-lambda
     (($ <mapped-device> source target
                         ($ <mapped-device-type> open close))
      (shepherd-service
       (provision (list (symbol-append 'device-mapping- (string->symbol target))))
       (requirement '(udev))
       (documentation "Map a device node using Linux's device mapper.")
       (start #~(lambda () #$(open source target)))
       (stop #~(lambda _ (not #$(close source target))))
       (respawn? #f))))))

(define (device-mapping-service mapped-device)
  "Return a service that sets up @var{mapped-device}."
  (service device-mapping-service-type mapped-device))

\f
;;;
;;; Static checks.
;;;

(define (check-device-initrd-modules device linux-modules location)
  "Raise an error if DEVICE needs modules beyond LINUX-MODULES to operate.
DEVICE must be a \"/dev\" file name."
  (define missing
    ;; Attempt to determine missing modules.
    (catch 'system-error
      (lambda ()
        (missing-modules device linux-modules))

      ;; If we can't do that (e.g., EPERM), skip the whole thing.
      (const '())))

  (unless (null? missing)
    ;; Note: What we suggest here is a list of module names (e.g.,
    ;; "usb_storage"), not file names (e.g., "usb-storage.ko").  This is
    ;; OK because we have machinery that accepts both the hyphen and the
    ;; underscore version.
    (raise (condition
            (&message
             (message (format #f (G_ "you may need these modules \
in the initrd for ~a:~{ ~a~}")
                              device missing)))
            (&fix-hint
             (hint (format #f (G_ "Try adding them to the
@code{initrd-modules} field of your @code{operating-system} declaration, along
these lines:

@example
 (operating-system
   ;; @dots{}
   (initrd-modules (append (list~{ ~s~})
                           %base-initrd-modules)))
@end example

If you think this diagnostic is inaccurate, use the @option{--skip-checks}
option of @command{guix system}.\n")
                           missing)))
            (&error-location
             (location (source-properties->location location)))))))

\f
;;;
;;; Common device mappings.
;;;

(define (open-luks-device source target)
  "Return a gexp that maps SOURCE to TARGET as a LUKS device, using
'cryptsetup'."
  (with-imported-modules (source-module-closure
                          '((gnu build file-systems)))
    #~(let ((source #$(if (uuid? source)
                          (uuid-bytevector source)
                          source)))
        ;; XXX: 'use-modules' should be at the top level.
        (use-modules (rnrs bytevectors)           ;bytevector?
                     ((gnu build file-systems)
                      #:select (find-partition-by-luks-uuid)))

        ;; Use 'cryptsetup-static', not 'cryptsetup', to avoid pulling the
        ;; whole world inside the initrd (for when we're in an initrd).
        (zero? (system* #$(file-append cryptsetup-static "/sbin/cryptsetup")
                        "open" "--type" "luks"

                        ;; Note: We cannot use the "UUID=source" syntax here
                        ;; because 'cryptsetup' implements it by searching the
                        ;; udev-populated /dev/disk/by-id directory but udev may
                        ;; be unavailable at the time we run this.
                        (if (bytevector? source)
                            (or (let loop ((tries-left 10))
                                  (and (positive? tries-left)
                                       (or (find-partition-by-luks-uuid source)
                                           ;; If the underlying partition is
                                           ;; not found, try again after
                                           ;; waiting a second, up to ten
                                           ;; times.  FIXME: This should be
                                           ;; dealt with in a more robust way.
                                           (begin (sleep 1)
                                                  (loop (- tries-left 1))))))
                                (error "LUKS partition not found" source))
                            source)

                        #$target)))))

(define (close-luks-device source target)
  "Return a gexp that closes TARGET, a LUKS device."
  #~(zero? (system* #$(file-append cryptsetup-static "/sbin/cryptsetup")
                    "close" #$target)))

(define* (check-luks-device md #:key
                            needed-for-boot?
                            (initrd-modules '())
                            #:allow-other-keys
                            #:rest rest)
  "Ensure the source of MD is valid."
  (let ((source   (mapped-device-source md))
        (location (mapped-device-location md)))
    (or (not (zero? (getuid)))
        (if (uuid? source)
            (match (find-partition-by-luks-uuid (uuid-bytevector source))
              (#f
               (raise (condition
                       (&message
                        (message (format #f (G_ "no LUKS partition with UUID '~a'")
                                         (uuid->string source))))
                       (&error-location
                        (location (source-properties->location
                                   (mapped-device-location md)))))))
              ((? string? device)
               (check-device-initrd-modules device initrd-modules location)))
            (check-device-initrd-modules source initrd-modules location)))))

(define luks-device-mapping
  ;; The type of LUKS mapped devices.
  (mapped-device-kind
   (open open-luks-device)
   (close close-luks-device)
   (check check-luks-device)))

(define (open-raid-device sources target)
  "Return a gexp that assembles SOURCES (a list of devices) to the RAID device
TARGET (e.g., \"/dev/md0\"), using 'mdadm'."
  #~(let ((sources '#$sources)

          ;; XXX: We're not at the top level here.  We could use a
          ;; non-top-level 'use-modules' form but that doesn't work when the
          ;; code is eval'd, like the Shepherd does.
          (every   (@ (srfi srfi-1) every))
          (format  (@ (ice-9 format) format)))
      (let loop ((attempts 0))
        (unless (every file-exists? sources)
          (when (> attempts 20)
            (error "RAID devices did not show up; bailing out"
                   sources))

          (format #t "waiting for RAID source devices~{ ~a~}...~%"
                  sources)
          (sleep 1)
          (loop (+ 1 attempts))))

      ;; Use 'mdadm-static' rather than 'mdadm' to avoid pulling its whole
      ;; closure (80 MiB) in the initrd when a RAID device is needed for boot.
      (zero? (apply system* #$(file-append mdadm-static "/sbin/mdadm")
                    "--assemble" #$target sources))))

(define (close-raid-device sources target)
  "Return a gexp that stops the RAID device TARGET."
  #~(zero? (system* #$(file-append mdadm-static "/sbin/mdadm")
                    "--stop" #$target)))

(define raid-device-mapping
  ;; The type of RAID mapped devices.
  (mapped-device-kind
   (open open-raid-device)
   (close close-raid-device)))

;;; mapped-devices.scm ends here
Commit	Line	Data
060d62a7	1	;;; GNU Guix --- Functional package management for GNU
59e80445	2	;;; Copyright © 2014, 2015, 2016, 2017, 2018, 2019 Ludovic Courtès <ludo@gnu.org>
97c8aef1	3	;;; Copyright © 2016 Andreas Enge <andreas@enge.fr>
3e5783e2	4	;;; Copyright © 2017, 2018 Mark H Weaver <mhw@netris.org>
060d62a7 LC	5	;;;
	6	;;; This file is part of GNU Guix.
	7	;;;
	8	;;; GNU Guix is free software; you can redistribute it and/or modify it
	9	;;; under the terms of the GNU General Public License as published by
	10	;;; the Free Software Foundation; either version 3 of the License, or (at
	11	;;; your option) any later version.
	12	;;;
	13	;;; GNU Guix is distributed in the hope that it will be useful, but
	14	;;; WITHOUT ANY WARRANTY; without even the implied warranty of
	15	;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
	16	;;; GNU General Public License for more details.
	17	;;;
	18	;;; You should have received a copy of the GNU General Public License
	19	;;; along with GNU Guix. If not, see <http://www.gnu.org/licenses/>.
	20
	21	(define-module (gnu system mapped-devices)
374f14c2	22	#:use-module (guix gexp)
060d62a7	23	#:use-module (guix records)
d2a1cf45	24	#:use-module ((guix modules) #:hide (file-name->module-name))
42ff7d3b LC	25	#:use-module (guix i18n)
	26	#:use-module ((guix utils)
	27	#:select (source-properties->location
8ab10c19	28	&fix-hint
42ff7d3b	29	&error-location))
1ea507bc LC	30	#:use-module (gnu services)
1ea507bc LC	31	#:use-module (gnu services shepherd)
9b336338	32	#:use-module (gnu system uuid)
42ff7d3b	33	#:autoload (gnu build file-systems) (find-partition-by-luks-uuid)
8ab10c19	34	#:autoload (gnu build linux-modules)
4cd386af	35	(missing-modules)
b7d408ec	36	#:autoload (gnu packages cryptsetup) (cryptsetup-static)
4ed2f515	37	#:autoload (gnu packages linux) (mdadm-static)
ffba7d49	38	#:use-module (srfi srfi-1)
424cea80	39	#:use-module (srfi srfi-26)
42ff7d3b LC	40	#:use-module (srfi srfi-34)
42ff7d3b LC	41	#:use-module (srfi srfi-35)
1ea507bc	42	#:use-module (ice-9 match)
060d62a7 LC	43	#:export (mapped-device
	44	mapped-device?
	45	mapped-device-source
	46	mapped-device-target
	47	mapped-device-type
4ca90ff5	48	mapped-device-location
060d62a7 LC	49
	50	mapped-device-kind
	51	mapped-device-kind?
	52	mapped-device-kind-open
374f14c2	53	mapped-device-kind-close
4ca90ff5	54	mapped-device-kind-check
374f14c2	55
1ea507bc LC	56	device-mapping-service-type
	57	device-mapping-service
	58
8ab10c19 LC	59	check-device-initrd-modules ;XXX: needs a better place
8ab10c19 LC	60
97c8aef1 AE	61	luks-device-mapping
97c8aef1 AE	62	raid-device-mapping))
060d62a7 LC	63
	64	;;; Commentary:
	65	;;;
	66	;;; This module supports "device mapping", a concept implemented by Linux's
	67	;;; device-mapper.
	68	;;;
	69	;;; Code:
	70
	71	(define-record-type* <mapped-device> mapped-device
	72	make-mapped-device
	73	mapped-device?
d6d1cea6	74	(source mapped-device-source) ;string \| list of strings
060d62a7	75	(target mapped-device-target) ;string
4ca90ff5 LC	76	(type mapped-device-type) ;<mapped-device-kind>
	77	(location mapped-device-location
	78	(default (current-source-location)) (innate)))
060d62a7 LC	79
	80	(define-record-type* <mapped-device-type> mapped-device-kind
	81	make-mapped-device-kind
	82	mapped-device-kind?
	83	(open mapped-device-kind-open) ;source target -> gexp
	84	(close mapped-device-kind-close ;source target -> gexp
4ca90ff5 LC	85	(default (const #~(const #f))))
	86	(check mapped-device-kind-check ;source -> Boolean
	87	(default (const #t))))
060d62a7	88
374f14c2	89	\f
1ea507bc LC	90	;;;
	91	;;; Device mapping as a Shepherd service.
	92	;;;
	93
	94	(define device-mapping-service-type
	95	(shepherd-service-type
	96	'device-mapping
	97	(match-lambda
4da8c19e LC	98	(($ <mapped-device> source target
4da8c19e LC	99	($ <mapped-device-type> open close))
1ea507bc LC	100	(shepherd-service
	101	(provision (list (symbol-append 'device-mapping- (string->symbol target))))
	102	(requirement '(udev))
	103	(documentation "Map a device node using Linux's device mapper.")
4da8c19e LC	104	(start #~(lambda () #$(open source target)))
4da8c19e LC	105	(stop #~(lambda _ (not #$(close source target))))
dfe06f6e	106	(respawn? #f))))))
1ea507bc	107
4da8c19e LC	108	(define (device-mapping-service mapped-device)
	109	"Return a service that sets up @var{mapped-device}."
	110	(service device-mapping-service-type mapped-device))
1ea507bc LC	111
1ea507bc LC	112	\f
8ab10c19 LC	113	;;;
	114	;;; Static checks.
	115	;;;
	116
	117	(define (check-device-initrd-modules device linux-modules location)
	118	"Raise an error if DEVICE needs modules beyond LINUX-MODULES to operate.
	119	DEVICE must be a \"/dev\" file name."
4cd386af LC	120	(define missing
4cd386af LC	121	;; Attempt to determine missing modules.
8ab10c19 LC	122	(catch 'system-error
8ab10c19 LC	123	(lambda ()
4cd386af LC	124	(missing-modules device linux-modules))
	125
	126	;; If we can't do that (e.g., EPERM), skip the whole thing.
	127	(const '())))
	128
	129	(unless (null? missing)
	130	;; Note: What we suggest here is a list of module names (e.g.,
	131	;; "usb_storage"), not file names (e.g., "usb-storage.ko"). This is
	132	;; OK because we have machinery that accepts both the hyphen and the
	133	;; underscore version.
	134	(raise (condition
	135	(&message
	136	(message (format #f (G_ "you may need these modules \
8ab10c19	137	in the initrd for ~a:~{ ~a~}")
4cd386af LC	138	device missing)))
	139	(&fix-hint
	140	(hint (format #f (G_ "Try adding them to the
8ab10c19 LC	141	@code{initrd-modules} field of your @code{operating-system} declaration, along
	142	these lines:
	143
	144	@example
	145	(operating-system
	146	;; @dots{}
	147	(initrd-modules (append (list~{ ~s~})
	148	%base-initrd-modules)))
88600acc LC	149	@end example
	150
	151	If you think this diagnostic is inaccurate, use the @option{--skip-checks}
	152	option of @command{guix system}.\n")
4cd386af LC	153	missing)))
	154	(&error-location
	155	(location (source-properties->location location)))))))
8ab10c19 LC	156
8ab10c19 LC	157	\f
374f14c2 LC	158	;;;
	159	;;; Common device mappings.
	160	;;;
	161
	162	(define (open-luks-device source target)
	163	"Return a gexp that maps SOURCE to TARGET as a LUKS device, using
	164	'cryptsetup'."
239c6e27 LC	165	(with-imported-modules (source-module-closure
239c6e27 LC	166	'((gnu build file-systems)))
9b336338 LC	167	#~(let ((source #$(if (uuid? source)
	168	(uuid-bytevector source)
	169	source)))
dfe06f6e LC	170	;; XXX: 'use-modules' should be at the top level.
	171	(use-modules (rnrs bytevectors) ;bytevector?
	172	((gnu build file-systems)
	173	#:select (find-partition-by-luks-uuid)))
	174
b7d408ec LC	175	;; Use 'cryptsetup-static', not 'cryptsetup', to avoid pulling the
	176	;; whole world inside the initrd (for when we're in an initrd).
	177	(zero? (system* #$(file-append cryptsetup-static "/sbin/cryptsetup")
a91c3fc7 LC	178	"open" "--type" "luks"
	179
	180	;; Note: We cannot use the "UUID=source" syntax here
	181	;; because 'cryptsetup' implements it by searching the
	182	;; udev-populated /dev/disk/by-id directory but udev may
	183	;; be unavailable at the time we run this.
	184	(if (bytevector? source)
f45878a8 MW	185	(or (let loop ((tries-left 10))
	186	(and (positive? tries-left)
	187	(or (find-partition-by-luks-uuid source)
	188	;; If the underlying partition is
	189	;; not found, try again after
	190	;; waiting a second, up to ten
	191	;; times. FIXME: This should be
	192	;; dealt with in a more robust way.
	193	(begin (sleep 1)
	194	(loop (- tries-left 1))))))
a91c3fc7 LC	195	(error "LUKS partition not found" source))
	196	source)
	197
	198	#$target)))))
374f14c2 LC	199
	200	(define (close-luks-device source target)
	201	"Return a gexp that closes TARGET, a LUKS device."
b7d408ec	202	#~(zero? (system* #$(file-append cryptsetup-static "/sbin/cryptsetup")
374f14c2 LC	203	"close" #$target)))
374f14c2 LC	204
424cea80 LC	205	(define* (check-luks-device md #:key
	206	needed-for-boot?
	207	(initrd-modules '())
	208	#:allow-other-keys
	209	#:rest rest)
42ff7d3b	210	"Ensure the source of MD is valid."
424cea80 LC	211	(let ((source (mapped-device-source md))
	212	(location (mapped-device-location md)))
	213	(or (not (zero? (getuid)))
	214	(if (uuid? source)
	215	(match (find-partition-by-luks-uuid (uuid-bytevector source))
	216	(#f
	217	(raise (condition
	218	(&message
	219	(message (format #f (G_ "no LUKS partition with UUID '~a'")
	220	(uuid->string source))))
	221	(&error-location
	222	(location (source-properties->location
	223	(mapped-device-location md)))))))
	224	((? string? device)
	225	(check-device-initrd-modules device initrd-modules location)))
	226	(check-device-initrd-modules source initrd-modules location)))))
42ff7d3b	227
374f14c2 LC	228	(define luks-device-mapping
	229	;; The type of LUKS mapped devices.
	230	(mapped-device-kind
	231	(open open-luks-device)
42ff7d3b LC	232	(close close-luks-device)
42ff7d3b LC	233	(check check-luks-device)))
374f14c2	234
7f8ad82b LC	235	(define (open-raid-device sources target)
	236	"Return a gexp that assembles SOURCES (a list of devices) to the RAID device
	237	TARGET (e.g., \"/dev/md0\"), using 'mdadm'."
10618627 LC	238	#~(let ((sources '#$sources)
	239
	240	;; XXX: We're not at the top level here. We could use a
	241	;; non-top-level 'use-modules' form but that doesn't work when the
	242	;; code is eval'd, like the Shepherd does.
	243	(every (@ (srfi srfi-1) every))
	244	(format (@ (ice-9 format) format)))
	245	(let loop ((attempts 0))
	246	(unless (every file-exists? sources)
	247	(when (> attempts 20)
	248	(error "RAID devices did not show up; bailing out"
	249	sources))
	250
	251	(format #t "waiting for RAID source devices~{ ~a~}...~%"
	252	sources)
	253	(sleep 1)
	254	(loop (+ 1 attempts))))
	255
4ed2f515 LC	256	;; Use 'mdadm-static' rather than 'mdadm' to avoid pulling its whole
	257	;; closure (80 MiB) in the initrd when a RAID device is needed for boot.
	258	(zero? (apply system* #$(file-append mdadm-static "/sbin/mdadm")
6e52376d	259	"--assemble" #$target sources))))
7f8ad82b LC	260
7f8ad82b LC	261	(define (close-raid-device sources target)
97c8aef1	262	"Return a gexp that stops the RAID device TARGET."
4ed2f515	263	#~(zero? (system* #$(file-append mdadm-static "/sbin/mdadm")
97c8aef1 AE	264	"--stop" #$target)))
	265
	266	(define raid-device-mapping
	267	;; The type of RAID mapped devices.
	268	(mapped-device-kind
	269	(open open-raid-device)
	270	(close close-raid-device)))
	271
060d62a7	272	;;; mapped-devices.scm ends here