[jackhill/guix/guix.git] / tests / profiles.scm

;;; GNU Guix --- Functional package management for GNU
;;; Copyright © 2013, 2014, 2015, 2016, 2017, 2018 Ludovic Courtès <ludo@gnu.org>
;;; Copyright © 2014 Alex Kost <alezost@gmail.com>
;;;
;;; This file is part of GNU Guix.
;;;
;;; GNU Guix is free software; you can redistribute it and/or modify it
;;; under the terms of the GNU General Public License as published by
;;; the Free Software Foundation; either version 3 of the License, or (at
;;; your option) any later version.
;;;
;;; GNU Guix is distributed in the hope that it will be useful, but
;;; WITHOUT ANY WARRANTY; without even the implied warranty of
;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;;; GNU General Public License for more details.
;;;
;;; You should have received a copy of the GNU General Public License
;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.

(define-module (test-profiles)
  #:use-module (guix tests)
  #:use-module (guix profiles)
  #:use-module (guix store)
  #:use-module (guix monads)
  #:use-module (guix grafts)
  #:use-module (guix packages)
  #:use-module (guix derivations)
  #:use-module (guix build-system trivial)
  #:use-module (gnu packages bootstrap)
  #:use-module ((gnu packages base) #:prefix packages:)
  #:use-module ((gnu packages guile) #:prefix packages:)
  #:use-module (ice-9 match)
  #:use-module (ice-9 regex)
  #:use-module (ice-9 popen)
  #:use-module (rnrs io ports)
  #:use-module (srfi srfi-1)
  #:use-module (srfi srfi-11)
  #:use-module (srfi srfi-34)
  #:use-module (srfi srfi-64))

;; Test the (guix profiles) module.

(define %store
  (open-connection-for-tests))

;; Globally disable grafts because they can trigger early builds.
(%graft? #f)

(define-syntax-rule (test-assertm name exp)
  (test-assert name
    (run-with-store %store exp
                    #:guile-for-build (%guile-for-build))))

(define-syntax-rule (test-equalm name value exp)
  (test-equal name
    value
    (run-with-store %store exp
                    #:guile-for-build (%guile-for-build))))

;; Example manifest entries.

(define guile-1.8.8
  (manifest-entry
    (name "guile")
    (version "1.8.8")
    (item "/gnu/store/...")
    (output "out")))

(define guile-2.0.9
  (manifest-entry
    (name "guile")
    (version "2.0.9")
    (item "/gnu/store/...")
    (output "out")))

(define guile-2.0.9:debug
  (manifest-entry (inherit guile-2.0.9)
    (output "debug")))

(define glibc
  (manifest-entry
    (name "glibc")
    (version "2.19")
    (item "/gnu/store/...")
    (output "out")))

\f
(test-begin "profiles")

(test-assert "manifest-installed?"
  (let ((m (manifest (list guile-2.0.9 guile-2.0.9:debug))))
    (and (manifest-installed? m (manifest-pattern (name "guile")))
         (manifest-installed? m (manifest-pattern
                                  (name "guile") (output "debug")))
         (manifest-installed? m (manifest-pattern
                                  (name "guile") (output "out")
                                  (version "2.0.9")))
         (not (manifest-installed?
               m (manifest-pattern (name "guile") (version "1.8.8"))))
         (not (manifest-installed?
               m (manifest-pattern (name "guile") (output "foobar")))))))

(test-assert "manifest-matching-entries"
  (let* ((e (list guile-2.0.9 guile-2.0.9:debug))
         (m (manifest e)))
    (and (null? (manifest-matching-entries m
                                           (list (manifest-pattern
                                                   (name "python")))))
         (equal? e
                 (manifest-matching-entries m
                                            (list (manifest-pattern
                                                    (name "guile")
                                                    (output #f)))))
         (equal? (list guile-2.0.9)
                 (manifest-matching-entries m
                                            (list (manifest-pattern
                                                    (name "guile")
                                                    (version "2.0.9"))))))))

(test-assert "manifest-remove"
  (let* ((m0 (manifest (list guile-2.0.9 guile-2.0.9:debug)))
         (m1 (manifest-remove m0
                              (list (manifest-pattern (name "guile")))))
         (m2 (manifest-remove m1
                              (list (manifest-pattern (name "guile"))))) ; same
         (m3 (manifest-remove m2
                              (list (manifest-pattern
                                      (name "guile") (output "debug")))))
         (m4 (manifest-remove m3
                              (list (manifest-pattern (name "guile"))))))
    (match (manifest-entries m2)
      ((($ <manifest-entry> "guile" "2.0.9" "debug"))
       (and (equal? m1 m2)
            (null? (manifest-entries m3))
            (null? (manifest-entries m4)))))))

(test-assert "manifest-add"
  (let* ((m0 (manifest '()))
         (m1 (manifest-add m0 (list guile-1.8.8)))
         (m2 (manifest-add m1 (list guile-2.0.9)))
         (m3 (manifest-add m2 (list guile-2.0.9:debug)))
         (m4 (manifest-add m3 (list guile-2.0.9:debug))))
    (and (match (manifest-entries m1)
           ((($ <manifest-entry> "guile" "1.8.8" "out")) #t)
           (_ #f))
         (match (manifest-entries m2)
           ((($ <manifest-entry> "guile" "2.0.9" "out")) #t)
           (_ #f))
         (equal? m3 m4))))

(test-equal "manifest-add removes duplicates"    ;<https://bugs.gnu.org/30569>
  (list guile-2.0.9)
  (manifest-entries (manifest-add (manifest '())
                                  (list guile-2.0.9 guile-2.0.9))))

(test-assert "manifest-perform-transaction"
  (let* ((m0 (manifest (list guile-2.0.9 guile-2.0.9:debug)))
         (t1 (manifest-transaction
              (install (list guile-1.8.8))
              (remove (list (manifest-pattern (name "guile")
                                              (output "debug"))))))
         (t2 (manifest-transaction
              (remove (list (manifest-pattern (name "guile")
                                              (version "2.0.9")
                                              (output #f))))))
         (m1 (manifest-perform-transaction m0 t1))
         (m2 (manifest-perform-transaction m1 t2))
         (m3 (manifest-perform-transaction m0 t2)))
    (and (match (manifest-entries m1)
           ((($ <manifest-entry> "guile" "1.8.8" "out")) #t)
           (_ #f))
         (equal? m1 m2)
         (null? (manifest-entries m3)))))

(test-assert "manifest-transaction-effects"
  (let* ((m0 (manifest (list guile-1.8.8)))
         (t  (manifest-transaction
              (install (list guile-2.0.9 glibc))
              (remove (list (manifest-pattern (name "coreutils")))))))
    (let-values (((remove install upgrade downgrade)
                  (manifest-transaction-effects m0 t)))
      (and (null? remove) (null? downgrade)
           (equal? (list glibc) install)
           (equal? (list (cons guile-1.8.8 guile-2.0.9)) upgrade)))))

(test-assert "manifest-transaction-effects and downgrades"
  (let* ((m0 (manifest (list guile-2.0.9)))
         (t  (manifest-transaction (install (list guile-1.8.8)))))
    (let-values (((remove install upgrade downgrade)
                  (manifest-transaction-effects m0 t)))
      (and (null? remove) (null? install) (null? upgrade)
           (equal? (list (cons guile-2.0.9 guile-1.8.8)) downgrade)))))

(test-assert "manifest-transaction-effects and pseudo-upgrades"
  (let* ((m0 (manifest (list guile-2.0.9)))
         (t  (manifest-transaction (install (list guile-2.0.9)))))
    (let-values (((remove install upgrade downgrade)
                  (manifest-transaction-effects m0 t)))
      (and (null? remove) (null? install) (null? downgrade)
           (equal? (list (cons guile-2.0.9 guile-2.0.9)) upgrade)))))

(test-assert "manifest-transaction-null?"
  (manifest-transaction-null? (manifest-transaction)))

(test-assert "manifest-transaction-removal-candidate?"
  (let ((m (manifest (list guile-2.0.9)))
        (t (manifest-transaction
            (remove (list (manifest-pattern (name "guile")))))))
    (and (manifest-transaction-removal-candidate? guile-2.0.9 t)
         (not (manifest-transaction-removal-candidate? glibc t)))))

(test-assertm "profile-derivation"
  (mlet* %store-monad
      ((entry ->   (package->manifest-entry %bootstrap-guile))
       (guile      (package->derivation %bootstrap-guile))
       (drv        (profile-derivation (manifest (list entry))
                                       #:hooks '()
                                       #:locales? #f))
       (profile -> (derivation->output-path drv))
       (bindir ->  (string-append profile "/bin"))
       (_          (built-derivations (list drv))))
    (return (and (file-exists? (string-append bindir "/guile"))
                 (string=? (dirname (readlink bindir))
                           (derivation->output-path guile))))))

(test-assertm "profile-derivation, inputs"
  (mlet* %store-monad
      ((entry ->   (package->manifest-entry packages:glibc "debug"))
       (drv        (profile-derivation (manifest (list entry))
                                       #:hooks '()
                                       #:locales? #f)))
    (return (derivation-inputs drv))))

(test-assertm "profile-derivation, cross-compilation"
  (mlet* %store-monad
      ((manifest -> (packages->manifest (list packages:sed packages:grep)))
       (target ->   "arm-linux-gnueabihf")
       (grep        (package->cross-derivation packages:grep target))
       (sed         (package->cross-derivation packages:sed target))
       (locales     (package->derivation packages:glibc-utf8-locales))
       (drv         (profile-derivation manifest
                                        #:hooks '()
                                        #:locales? #t
                                        #:target target)))
    (define (find-input name)
      (let ((name (string-append name ".drv")))
        (any (lambda (input)
               (let ((input (derivation-input-path input)))
                 (and (string-suffix? name input) input)))
             (derivation-inputs drv))))

    ;; The inputs for grep and sed should be cross-build derivations, but that
    ;; for the glibc-utf8-locales should be a native build.
    (return (and (string=? (derivation-system drv) (%current-system))
                 (string=? (find-input (package-full-name packages:grep))
                           (derivation-file-name grep))
                 (string=? (find-input (package-full-name packages:sed))
                           (derivation-file-name sed))
                 (string=? (find-input
                            (package-full-name packages:glibc-utf8-locales))
                           (derivation-file-name locales))))))

(test-assert "package->manifest-entry defaults to \"out\""
  (let ((outputs (package-outputs packages:glibc)))
    (equal? (manifest-entry-output
             (package->manifest-entry (package
                                        (inherit packages:glibc)
                                        (outputs (reverse outputs)))))
            (manifest-entry-output
             (package->manifest-entry packages:glibc))
            "out")))

(test-assertm "profile-manifest, search-paths"
  (mlet* %store-monad
      ((guile ->   (package
                     (inherit %bootstrap-guile)
                     (native-search-paths
                      (package-native-search-paths packages:guile-2.0))))
       (entry ->   (package->manifest-entry guile))
       (drv        (profile-derivation (manifest (list entry))
                                       #:hooks '()
                                       #:locales? #f))
       (profile -> (derivation->output-path drv)))
    (mbegin %store-monad
      (built-derivations (list drv))

      ;; Read the manifest back and make sure search paths are preserved.
      (let ((manifest (profile-manifest profile)))
        (match (manifest-entries manifest)
          ((result)
           (return (equal? (manifest-entry-search-paths result)
                           (manifest-entry-search-paths entry)
                           (package-native-search-paths
                            packages:guile-2.0)))))))))

(test-assert "package->manifest-entry, search paths"
  ;; See <http://bugs.gnu.org/22073>.
  (let ((mpl (@ (gnu packages python) python2-matplotlib)))
    (lset= eq?
           (package-transitive-native-search-paths mpl)
           (manifest-entry-search-paths
            (package->manifest-entry mpl)))))

(test-equal "packages->manifest, propagated inputs"
  (map (match-lambda
         ((label package)
          (list (package-name package) (package-version package)
                package)))
       (package-propagated-inputs packages:guile-2.2))
  (map (lambda (entry)
         (list (manifest-entry-name entry)
               (manifest-entry-version entry)
               (manifest-entry-item entry)))
       (manifest-entry-dependencies
        (package->manifest-entry packages:guile-2.2))))

(test-assert "manifest-entry-parent"
  (let ((entry (package->manifest-entry packages:guile-2.2)))
    (match (manifest-entry-dependencies entry)
      ((dependencies ..1)
       (and (every (lambda (parent)
                     (eq? entry (force parent)))
                   (map manifest-entry-parent dependencies))
            (not (force (manifest-entry-parent entry))))))))

(test-assertm "read-manifest"
  (mlet* %store-monad ((manifest -> (packages->manifest
                                     (list (package
                                             (inherit %bootstrap-guile)
                                             (native-search-paths
                                              (package-native-search-paths
                                               packages:guile-2.0))))))
                       (drv (profile-derivation manifest
                                                #:hooks '()
                                                #:locales? #f))
                       (out -> (derivation->output-path drv)))
    (define (entry->sexp entry)
      (list (manifest-entry-name entry)
            (manifest-entry-version entry)
            (manifest-entry-search-paths entry)
            (manifest-entry-dependencies entry)
            (force (manifest-entry-parent entry))))

    (mbegin %store-monad
      (built-derivations (list drv))
      (let ((manifest2 (profile-manifest out)))
        (return (equal? (map entry->sexp (manifest-entries manifest))
                        (map entry->sexp (manifest-entries manifest2))))))))

(test-equal "collision"
  '(("guile-bootstrap" "2.0") ("guile-bootstrap" "42"))
  (guard (c ((profile-collision-error? c)
             (let ((entry1 (profile-collision-error-entry c))
                   (entry2 (profile-collision-error-conflict c)))
               (list (list (manifest-entry-name entry1)
                           (manifest-entry-version entry1))
                     (list (manifest-entry-name entry2)
                           (manifest-entry-version entry2))))))
    (run-with-store %store
      (mlet* %store-monad ((p0 -> (package
                                    (inherit %bootstrap-guile)
                                    (version "42")))
                           (p1 -> (dummy-package "p1"
                                    (propagated-inputs `(("p0" ,p0)))))
                           (manifest -> (packages->manifest
                                         (list %bootstrap-guile p1)))
                           (drv (profile-derivation manifest
                                                    #:hooks '()
                                                    #:locales? #f)))
        (return #f)))))

(test-equal "collision of propagated inputs"
  '(("guile-bootstrap" "2.0") ("guile-bootstrap" "42"))
  (guard (c ((profile-collision-error? c)
             (let ((entry1 (profile-collision-error-entry c))
                   (entry2 (profile-collision-error-conflict c)))
               (list (list (manifest-entry-name entry1)
                           (manifest-entry-version entry1))
                     (list (manifest-entry-name entry2)
                           (manifest-entry-version entry2))))))
    (run-with-store %store
      (mlet* %store-monad ((p0 -> (package
                                    (inherit %bootstrap-guile)
                                    (version "42")))
                           (p1 -> (dummy-package "p1"
                                    (propagated-inputs
                                     `(("guile" ,%bootstrap-guile)))))
                           (p2 -> (dummy-package "p2"
                                    (propagated-inputs
                                     `(("guile" ,p0)))))
                           (manifest -> (packages->manifest (list p1 p2)))
                           (drv (profile-derivation manifest
                                                    #:hooks '()
                                                    #:locales? #f)))
        (return #f)))))

(test-assertm "no collision"
  ;; Here we have an entry that is "lowered" (its 'item' field is a store file
  ;; name) and another entry (its 'item' field is a package) that is
  ;; equivalent.
  (mlet* %store-monad ((p -> (dummy-package "p"
                               (propagated-inputs
                                `(("guile" ,%bootstrap-guile)))))
                       (guile    (package->derivation %bootstrap-guile))
                       (entry -> (manifest-entry
                                   (inherit (package->manifest-entry
                                             %bootstrap-guile))
                                   (item (derivation->output-path guile))))
                       (manifest -> (manifest
                                     (list entry
                                           (package->manifest-entry p))))
                       (drv (profile-derivation manifest)))
    (return (->bool drv))))

(test-assertm "etc/profile"
  ;; Make sure we get an 'etc/profile' file that at least defines $PATH.
  (mlet* %store-monad
      ((guile ->   (package
                     (inherit %bootstrap-guile)
                     (native-search-paths
                      (package-native-search-paths packages:guile-2.0))))
       (entry ->   (package->manifest-entry guile))
       (drv        (profile-derivation (manifest (list entry))
                                       #:hooks '()
                                       #:locales? #f))
       (profile -> (derivation->output-path drv)))
    (mbegin %store-monad
      (built-derivations (list drv))
      (let* ((pipe (open-input-pipe
                    (string-append "unset GUIX_PROFILE; "
                                   ;; 'source' is a Bashism; use '.' (dot).
                                   ". " profile "/etc/profile; "
                                   ;; Don't try to parse set(1) output because
                                   ;; it differs among shells; just use echo.
                                   "echo $PATH")))
             (path (get-string-all pipe)))
        (return
         (and (zero? (close-pipe pipe))
              (string-contains path (string-append profile "/bin"))))))))

(test-assertm "etc/profile when etc/ already exists"
  ;; Here 'union-build' makes the profile's etc/ a symlink to the package's
  ;; etc/ directory, which makes it read-only.  Make sure the profile build
  ;; handles that.
  (mlet* %store-monad
      ((thing ->   (dummy-package "dummy"
                     (build-system trivial-build-system)
                     (arguments
                      `(#:guile ,%bootstrap-guile
                        #:builder
                        (let ((out (assoc-ref %outputs "out")))
                          (mkdir out)
                          (mkdir (string-append out "/etc"))
                          (call-with-output-file (string-append out "/etc/foo")
                            (lambda (port)
                              (display "foo!" port))))))))
       (entry ->   (package->manifest-entry thing))
       (drv        (profile-derivation (manifest (list entry))
                                       #:hooks '()
                                       #:locales? #f))
       (profile -> (derivation->output-path drv)))
    (mbegin %store-monad
      (built-derivations (list drv))
      (return (and (file-exists? (string-append profile "/etc/profile"))
                   (string=? (call-with-input-file
                                 (string-append profile "/etc/foo")
                               get-string-all)
                             "foo!"))))))

(test-assertm "etc/profile when etc/ is a symlink"
  ;; When etc/ is a symlink, the unsymlink code in 0.8.2 would fail
  ;; gracelessly because 'scandir' would return #f.
  (mlet* %store-monad
      ((thing ->   (dummy-package "dummy"
                     (build-system trivial-build-system)
                     (arguments
                      `(#:guile ,%bootstrap-guile
                        #:builder
                        (let ((out (assoc-ref %outputs "out")))
                          (mkdir out)
                          (mkdir (string-append out "/foo"))
                          (symlink "foo" (string-append out "/etc"))
                          (call-with-output-file (string-append out "/etc/bar")
                            (lambda (port)
                              (display "foo!" port))))))))
       (entry ->   (package->manifest-entry thing))
       (drv        (profile-derivation (manifest (list entry))
                                       #:hooks '()
                                       #:locales? #f))
       (profile -> (derivation->output-path drv)))
    (mbegin %store-monad
      (built-derivations (list drv))
      (return (and (file-exists? (string-append profile "/etc/profile"))
                   (string=? (call-with-input-file
                                 (string-append profile "/etc/bar")
                               get-string-all)
                             "foo!"))))))

(test-equalm "union vs. dangling symlink"        ;<https://bugs.gnu.org/26949>
  "does-not-exist"
  (mlet* %store-monad
      ((thing1 ->  (dummy-package "dummy"
                     (build-system trivial-build-system)
                     (arguments
                      `(#:guile ,%bootstrap-guile
                        #:builder
                        (let ((out (assoc-ref %outputs "out")))
                          (mkdir out)
                          (symlink "does-not-exist"
                                   (string-append out "/dangling"))
                          #t)))))
       (thing2 ->  (package (inherit thing1) (name "dummy2")))
       (drv        (profile-derivation (packages->manifest
                                        (list thing1 thing2))
                                       #:hooks '()
                                       #:locales? #f))
       (profile -> (derivation->output-path drv)))
    (mbegin %store-monad
      (built-derivations (list drv))
      (return (readlink (readlink (string-append profile "/dangling")))))))

(test-end "profiles")

;;; Local Variables:
;;; eval: (put 'dummy-package 'scheme-indent-function 1)
;;; End:
Commit	Line	Data
a2078770	1	;;; GNU Guix --- Functional package management for GNU
435603a1	2	;;; Copyright © 2013, 2014, 2015, 2016, 2017, 2018 Ludovic Courtès <ludo@gnu.org>
343745c8	3	;;; Copyright © 2014 Alex Kost <alezost@gmail.com>
a2078770 LC	4	;;;
	5	;;; This file is part of GNU Guix.
	6	;;;
	7	;;; GNU Guix is free software; you can redistribute it and/or modify it
	8	;;; under the terms of the GNU General Public License as published by
	9	;;; the Free Software Foundation; either version 3 of the License, or (at
	10	;;; your option) any later version.
	11	;;;
	12	;;; GNU Guix is distributed in the hope that it will be useful, but
	13	;;; WITHOUT ANY WARRANTY; without even the implied warranty of
	14	;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
	15	;;; GNU General Public License for more details.
	16	;;;
	17	;;; You should have received a copy of the GNU General Public License
	18	;;; along with GNU Guix. If not, see <http://www.gnu.org/licenses/>.
	19
	20	(define-module (test-profiles)
c1bc358f	21	#:use-module (guix tests)
a2078770	22	#:use-module (guix profiles)
462f5cca LC	23	#:use-module (guix store)
462f5cca LC	24	#:use-module (guix monads)
ef8de985	25	#:use-module (guix grafts)
462f5cca LC	26	#:use-module (guix packages)
462f5cca LC	27	#:use-module (guix derivations)
a0dac7a0	28	#:use-module (guix build-system trivial)
462f5cca	29	#:use-module (gnu packages bootstrap)
e39d1461	30	#:use-module ((gnu packages base) #:prefix packages:)
dedb17ad	31	#:use-module ((gnu packages guile) #:prefix packages:)
a2078770	32	#:use-module (ice-9 match)
ef8993e2	33	#:use-module (ice-9 regex)
d664f1b4 LC	34	#:use-module (ice-9 popen)
d664f1b4 LC	35	#:use-module (rnrs io ports)
ccda8f7d	36	#:use-module (srfi srfi-1)
79601521	37	#:use-module (srfi srfi-11)
a654dc4b	38	#:use-module (srfi srfi-34)
a2078770 LC	39	#:use-module (srfi srfi-64))
a2078770 LC	40
343745c8	41	;; Test the (guix profiles) module.
a2078770	42
462f5cca	43	(define %store
c1bc358f	44	(open-connection-for-tests))
a2078770	45
ef8de985 LC	46	;; Globally disable grafts because they can trigger early builds.
	47	(%graft? #f)
	48
ebf5ad46 LC	49	(define-syntax-rule (test-assertm name exp)
	50	(test-assert name
	51	(run-with-store %store exp
	52	#:guile-for-build (%guile-for-build))))
	53
22ef06b8 LC	54	(define-syntax-rule (test-equalm name value exp)
	55	(test-equal name
	56	value
	57	(run-with-store %store exp
	58	#:guile-for-build (%guile-for-build))))
	59
a2078770 LC	60	;; Example manifest entries.
a2078770 LC	61
f7554030 AK	62	(define guile-1.8.8
	63	(manifest-entry
	64	(name "guile")
	65	(version "1.8.8")
	66	(item "/gnu/store/...")
	67	(output "out")))
	68
a2078770 LC	69	(define guile-2.0.9
	70	(manifest-entry
	71	(name "guile")
	72	(version "2.0.9")
a54c94a4	73	(item "/gnu/store/...")
a2078770 LC	74	(output "out")))
	75
	76	(define guile-2.0.9:debug
	77	(manifest-entry (inherit guile-2.0.9)
	78	(output "debug")))
	79
79601521 LC	80	(define glibc
	81	(manifest-entry
	82	(name "glibc")
	83	(version "2.19")
	84	(item "/gnu/store/...")
	85	(output "out")))
	86
a2078770 LC	87	\f
	88	(test-begin "profiles")
	89
	90	(test-assert "manifest-installed?"
	91	(let ((m (manifest (list guile-2.0.9 guile-2.0.9:debug))))
	92	(and (manifest-installed? m (manifest-pattern (name "guile")))
	93	(manifest-installed? m (manifest-pattern
	94	(name "guile") (output "debug")))
	95	(manifest-installed? m (manifest-pattern
	96	(name "guile") (output "out")
	97	(version "2.0.9")))
	98	(not (manifest-installed?
	99	m (manifest-pattern (name "guile") (version "1.8.8"))))
	100	(not (manifest-installed?
	101	m (manifest-pattern (name "guile") (output "foobar")))))))
	102
	103	(test-assert "manifest-matching-entries"
	104	(let* ((e (list guile-2.0.9 guile-2.0.9:debug))
	105	(m (manifest e)))
	106	(and (null? (manifest-matching-entries m
	107	(list (manifest-pattern
	108	(name "python")))))
	109	(equal? e
	110	(manifest-matching-entries m
	111	(list (manifest-pattern
	112	(name "guile")
	113	(output #f)))))
	114	(equal? (list guile-2.0.9)
	115	(manifest-matching-entries m
	116	(list (manifest-pattern
	117	(name "guile")
	118	(version "2.0.9"))))))))
	119
	120	(test-assert "manifest-remove"
	121	(let* ((m0 (manifest (list guile-2.0.9 guile-2.0.9:debug)))
	122	(m1 (manifest-remove m0
	123	(list (manifest-pattern (name "guile")))))
	124	(m2 (manifest-remove m1
	125	(list (manifest-pattern (name "guile"))))) ; same
	126	(m3 (manifest-remove m2
	127	(list (manifest-pattern
	128	(name "guile") (output "debug")))))
	129	(m4 (manifest-remove m3
	130	(list (manifest-pattern (name "guile"))))))
	131	(match (manifest-entries m2)
	132	((($ <manifest-entry> "guile" "2.0.9" "debug"))
	133	(and (equal? m1 m2)
	134	(null? (manifest-entries m3))
	135	(null? (manifest-entries m4)))))))
	136
f7554030 AK	137	(test-assert "manifest-add"
	138	(let* ((m0 (manifest '()))
	139	(m1 (manifest-add m0 (list guile-1.8.8)))
	140	(m2 (manifest-add m1 (list guile-2.0.9)))
	141	(m3 (manifest-add m2 (list guile-2.0.9:debug)))
	142	(m4 (manifest-add m3 (list guile-2.0.9:debug))))
	143	(and (match (manifest-entries m1)
	144	((($ <manifest-entry> "guile" "1.8.8" "out")) #t)
	145	(_ #f))
	146	(match (manifest-entries m2)
	147	((($ <manifest-entry> "guile" "2.0.9" "out")) #t)
	148	(_ #f))
	149	(equal? m3 m4))))
	150
435603a1 LC	151	(test-equal "manifest-add removes duplicates" ;<https://bugs.gnu.org/30569>
	152	(list guile-2.0.9)
	153	(manifest-entries (manifest-add (manifest '())
	154	(list guile-2.0.9 guile-2.0.9))))
	155
343745c8 AK	156	(test-assert "manifest-perform-transaction"
	157	(let* ((m0 (manifest (list guile-2.0.9 guile-2.0.9:debug)))
	158	(t1 (manifest-transaction
	159	(install (list guile-1.8.8))
	160	(remove (list (manifest-pattern (name "guile")
	161	(output "debug"))))))
	162	(t2 (manifest-transaction
	163	(remove (list (manifest-pattern (name "guile")
	164	(version "2.0.9")
	165	(output #f))))))
	166	(m1 (manifest-perform-transaction m0 t1))
	167	(m2 (manifest-perform-transaction m1 t2))
	168	(m3 (manifest-perform-transaction m0 t2)))
	169	(and (match (manifest-entries m1)
	170	((($ <manifest-entry> "guile" "1.8.8" "out")) #t)
	171	(_ #f))
	172	(equal? m1 m2)
	173	(null? (manifest-entries m3)))))
	174
79601521 LC	175	(test-assert "manifest-transaction-effects"
	176	(let* ((m0 (manifest (list guile-1.8.8)))
	177	(t (manifest-transaction
	178	(install (list guile-2.0.9 glibc))
	179	(remove (list (manifest-pattern (name "coreutils")))))))
46b23e1a	180	(let-values (((remove install upgrade downgrade)
79601521	181	(manifest-transaction-effects m0 t)))
46b23e1a	182	(and (null? remove) (null? downgrade)
79601521	183	(equal? (list glibc) install)
ef8993e2 LC	184	(equal? (list (cons guile-1.8.8 guile-2.0.9)) upgrade)))))
ef8993e2 LC	185
46b23e1a LC	186	(test-assert "manifest-transaction-effects and downgrades"
	187	(let* ((m0 (manifest (list guile-2.0.9)))
	188	(t (manifest-transaction (install (list guile-1.8.8)))))
	189	(let-values (((remove install upgrade downgrade)
	190	(manifest-transaction-effects m0 t)))
	191	(and (null? remove) (null? install) (null? upgrade)
	192	(equal? (list (cons guile-2.0.9 guile-1.8.8)) downgrade)))))
	193
3bea13bb LC	194	(test-assert "manifest-transaction-effects and pseudo-upgrades"
	195	(let* ((m0 (manifest (list guile-2.0.9)))
	196	(t (manifest-transaction (install (list guile-2.0.9)))))
	197	(let-values (((remove install upgrade downgrade)
	198	(manifest-transaction-effects m0 t)))
	199	(and (null? remove) (null? install) (null? downgrade)
	200	(equal? (list (cons guile-2.0.9 guile-2.0.9)) upgrade)))))
	201
c8c25704 LC	202	(test-assert "manifest-transaction-null?"
	203	(manifest-transaction-null? (manifest-transaction)))
	204
6d382339 LC	205	(test-assert "manifest-transaction-removal-candidate?"
	206	(let ((m (manifest (list guile-2.0.9)))
	207	(t (manifest-transaction
	208	(remove (list (manifest-pattern (name "guile")))))))
	209	(and (manifest-transaction-removal-candidate? guile-2.0.9 t)
	210	(not (manifest-transaction-removal-candidate? glibc t)))))
	211
ebf5ad46 LC	212	(test-assertm "profile-derivation"
	213	(mlet* %store-monad
	214	((entry -> (package->manifest-entry %bootstrap-guile))
	215	(guile (package->derivation %bootstrap-guile))
	216	(drv (profile-derivation (manifest (list entry))
a6562c7e LC	217	#:hooks '()
a6562c7e LC	218	#:locales? #f))
ebf5ad46 LC	219	(profile -> (derivation->output-path drv))
	220	(bindir -> (string-append profile "/bin"))
	221	(_ (built-derivations (list drv))))
	222	(return (and (file-exists? (string-append bindir "/guile"))
	223	(string=? (dirname (readlink bindir))
	224	(derivation->output-path guile))))))
462f5cca	225
e39d1461 LC	226	(test-assertm "profile-derivation, inputs"
	227	(mlet* %store-monad
	228	((entry -> (package->manifest-entry packages:glibc "debug"))
	229	(drv (profile-derivation (manifest (list entry))
a6562c7e LC	230	#:hooks '()
a6562c7e LC	231	#:locales? #f)))
e39d1461 LC	232	(return (derivation-inputs drv))))
e39d1461 LC	233
176febe3 LC	234	(test-assertm "profile-derivation, cross-compilation"
	235	(mlet* %store-monad
	236	((manifest -> (packages->manifest (list packages:sed packages:grep)))
	237	(target -> "arm-linux-gnueabihf")
	238	(grep (package->cross-derivation packages:grep target))
	239	(sed (package->cross-derivation packages:sed target))
	240	(locales (package->derivation packages:glibc-utf8-locales))
	241	(drv (profile-derivation manifest
	242	#:hooks '()
	243	#:locales? #t
	244	#:target target)))
	245	(define (find-input name)
	246	(let ((name (string-append name ".drv")))
	247	(any (lambda (input)
	248	(let ((input (derivation-input-path input)))
	249	(and (string-suffix? name input) input)))
	250	(derivation-inputs drv))))
	251
	252	;; The inputs for grep and sed should be cross-build derivations, but that
	253	;; for the glibc-utf8-locales should be a native build.
	254	(return (and (string=? (derivation-system drv) (%current-system))
	255	(string=? (find-input (package-full-name packages:grep))
	256	(derivation-file-name grep))
	257	(string=? (find-input (package-full-name packages:sed))
	258	(derivation-file-name sed))
	259	(string=? (find-input
	260	(package-full-name packages:glibc-utf8-locales))
	261	(derivation-file-name locales))))))
	262
9e90fc77 LC	263	(test-assert "package->manifest-entry defaults to \"out\""
	264	(let ((outputs (package-outputs packages:glibc)))
	265	(equal? (manifest-entry-output
	266	(package->manifest-entry (package
	267	(inherit packages:glibc)
	268	(outputs (reverse outputs)))))
	269	(manifest-entry-output
	270	(package->manifest-entry packages:glibc))
	271	"out")))
	272
dedb17ad LC	273	(test-assertm "profile-manifest, search-paths"
	274	(mlet* %store-monad
	275	((guile -> (package
	276	(inherit %bootstrap-guile)
	277	(native-search-paths
	278	(package-native-search-paths packages:guile-2.0))))
	279	(entry -> (package->manifest-entry guile))
	280	(drv (profile-derivation (manifest (list entry))
a6562c7e LC	281	#:hooks '()
a6562c7e LC	282	#:locales? #f))
dedb17ad LC	283	(profile -> (derivation->output-path drv)))
	284	(mbegin %store-monad
	285	(built-derivations (list drv))
	286
	287	;; Read the manifest back and make sure search paths are preserved.
	288	(let ((manifest (profile-manifest profile)))
	289	(match (manifest-entries manifest)
	290	((result)
	291	(return (equal? (manifest-entry-search-paths result)
	292	(manifest-entry-search-paths entry)
	293	(package-native-search-paths
	294	packages:guile-2.0)))))))))
d664f1b4	295
ccda8f7d LC	296	(test-assert "package->manifest-entry, search paths"
	297	;; See <http://bugs.gnu.org/22073>.
	298	(let ((mpl (@ (gnu packages python) python2-matplotlib)))
	299	(lset= eq?
	300	(package-transitive-native-search-paths mpl)
	301	(manifest-entry-search-paths
	302	(package->manifest-entry mpl)))))
	303
55b4715f LC	304	(test-equal "packages->manifest, propagated inputs"
	305	(map (match-lambda
	306	((label package)
	307	(list (package-name package) (package-version package)
	308	package)))
	309	(package-propagated-inputs packages:guile-2.2))
	310	(map (lambda (entry)
	311	(list (manifest-entry-name entry)
	312	(manifest-entry-version entry)
	313	(manifest-entry-item entry)))
	314	(manifest-entry-dependencies
	315	(package->manifest-entry packages:guile-2.2))))
	316
b3a00885 LC	317	(test-assert "manifest-entry-parent"
	318	(let ((entry (package->manifest-entry packages:guile-2.2)))
	319	(match (manifest-entry-dependencies entry)
	320	((dependencies ..1)
	321	(and (every (lambda (parent)
	322	(eq? entry (force parent)))
	323	(map manifest-entry-parent dependencies))
	324	(not (force (manifest-entry-parent entry))))))))
	325
55b4715f LC	326	(test-assertm "read-manifest"
	327	(mlet* %store-monad ((manifest -> (packages->manifest
	328	(list (package
	329	(inherit %bootstrap-guile)
	330	(native-search-paths
	331	(package-native-search-paths
	332	packages:guile-2.0))))))
	333	(drv (profile-derivation manifest
	334	#:hooks '()
	335	#:locales? #f))
	336	(out -> (derivation->output-path drv)))
	337	(define (entry->sexp entry)
	338	(list (manifest-entry-name entry)
	339	(manifest-entry-version entry)
	340	(manifest-entry-search-paths entry)
b3a00885 LC	341	(manifest-entry-dependencies entry)
b3a00885 LC	342	(force (manifest-entry-parent entry))))
55b4715f LC	343
	344	(mbegin %store-monad
	345	(built-derivations (list drv))
	346	(let ((manifest2 (profile-manifest out)))
	347	(return (equal? (map entry->sexp (manifest-entries manifest))
	348	(map entry->sexp (manifest-entries manifest2))))))))
	349
a654dc4b LC	350	(test-equal "collision"
	351	'(("guile-bootstrap" "2.0") ("guile-bootstrap" "42"))
	352	(guard (c ((profile-collision-error? c)
	353	(let ((entry1 (profile-collision-error-entry c))
	354	(entry2 (profile-collision-error-conflict c)))
	355	(list (list (manifest-entry-name entry1)
	356	(manifest-entry-version entry1))
	357	(list (manifest-entry-name entry2)
	358	(manifest-entry-version entry2))))))
	359	(run-with-store %store
	360	(mlet* %store-monad ((p0 -> (package
	361	(inherit %bootstrap-guile)
	362	(version "42")))
	363	(p1 -> (dummy-package "p1"
	364	(propagated-inputs `(("p0" ,p0)))))
	365	(manifest -> (packages->manifest
	366	(list %bootstrap-guile p1)))
	367	(drv (profile-derivation manifest
	368	#:hooks '()
	369	#:locales? #f)))
	370	(return #f)))))
	371
	372	(test-equal "collision of propagated inputs"
	373	'(("guile-bootstrap" "2.0") ("guile-bootstrap" "42"))
	374	(guard (c ((profile-collision-error? c)
	375	(let ((entry1 (profile-collision-error-entry c))
	376	(entry2 (profile-collision-error-conflict c)))
	377	(list (list (manifest-entry-name entry1)
	378	(manifest-entry-version entry1))
	379	(list (manifest-entry-name entry2)
	380	(manifest-entry-version entry2))))))
	381	(run-with-store %store
	382	(mlet* %store-monad ((p0 -> (package
	383	(inherit %bootstrap-guile)
	384	(version "42")))
	385	(p1 -> (dummy-package "p1"
	386	(propagated-inputs
	387	`(("guile" ,%bootstrap-guile)))))
	388	(p2 -> (dummy-package "p2"
	389	(propagated-inputs
	390	`(("guile" ,p0)))))
	391	(manifest -> (packages->manifest (list p1 p2)))
	392	(drv (profile-derivation manifest
	393	#:hooks '()
	394	#:locales? #f)))
	395	(return #f)))))
	396
	397	(test-assertm "no collision"
	398	;; Here we have an entry that is "lowered" (its 'item' field is a store file
	399	;; name) and another entry (its 'item' field is a package) that is
	400	;; equivalent.
	401	(mlet* %store-monad ((p -> (dummy-package "p"
	402	(propagated-inputs
	403	`(("guile" ,%bootstrap-guile)))))
	404	(guile (package->derivation %bootstrap-guile))
	405	(entry -> (manifest-entry
	406	(inherit (package->manifest-entry
	407	%bootstrap-guile))
	408	(item (derivation->output-path guile))))
	409	(manifest -> (manifest
	410	(list entry
	411	(package->manifest-entry p))))
	412	(drv (profile-derivation manifest)))
	413	(return (->bool drv))))
414
d664f1b4 LC	415	(test-assertm "etc/profile"
	416	;; Make sure we get an 'etc/profile' file that at least defines $PATH.
	417	(mlet* %store-monad
	418	((guile -> (package
	419	(inherit %bootstrap-guile)
	420	(native-search-paths
	421	(package-native-search-paths packages:guile-2.0))))
	422	(entry -> (package->manifest-entry guile))
	423	(drv (profile-derivation (manifest (list entry))
a6562c7e LC	424	#:hooks '()
a6562c7e LC	425	#:locales? #f))
d664f1b4 LC	426	(profile -> (derivation->output-path drv)))
	427	(mbegin %store-monad
	428	(built-derivations (list drv))
	429	(let* ((pipe (open-input-pipe
9e006fb3 TUBK	430	(string-append "unset GUIX_PROFILE; "
	431	;; 'source' is a Bashism; use '.' (dot).
	432	". " profile "/etc/profile; "
	433	;; Don't try to parse set(1) output because
	434	;; it differs among shells; just use echo.
	435	"echo $PATH")))
	436	(path (get-string-all pipe)))
d664f1b4 LC	437	(return
d664f1b4 LC	438	(and (zero? (close-pipe pipe))
9e006fb3	439	(string-contains path (string-append profile "/bin"))))))))
d664f1b4	440
a0dac7a0 LC	441	(test-assertm "etc/profile when etc/ already exists"
	442	;; Here 'union-build' makes the profile's etc/ a symlink to the package's
	443	;; etc/ directory, which makes it read-only. Make sure the profile build
	444	;; handles that.
	445	(mlet* %store-monad
	446	((thing -> (dummy-package "dummy"
	447	(build-system trivial-build-system)
	448	(arguments
	449	`(#:guile ,%bootstrap-guile
	450	#:builder
	451	(let ((out (assoc-ref %outputs "out")))
	452	(mkdir out)
	453	(mkdir (string-append out "/etc"))
	454	(call-with-output-file (string-append out "/etc/foo")
	455	(lambda (port)
	456	(display "foo!" port))))))))
	457	(entry -> (package->manifest-entry thing))
	458	(drv (profile-derivation (manifest (list entry))
a6562c7e LC	459	#:hooks '()
a6562c7e LC	460	#:locales? #f))
a0dac7a0 LC	461	(profile -> (derivation->output-path drv)))
	462	(mbegin %store-monad
	463	(built-derivations (list drv))
	464	(return (and (file-exists? (string-append profile "/etc/profile"))
	465	(string=? (call-with-input-file
	466	(string-append profile "/etc/foo")
	467	get-string-all)
	468	"foo!"))))))
	469
113c17a0 LC	470	(test-assertm "etc/profile when etc/ is a symlink"
	471	;; When etc/ is a symlink, the unsymlink code in 0.8.2 would fail
	472	;; gracelessly because 'scandir' would return #f.
	473	(mlet* %store-monad
	474	((thing -> (dummy-package "dummy"
	475	(build-system trivial-build-system)
	476	(arguments
	477	`(#:guile ,%bootstrap-guile
	478	#:builder
	479	(let ((out (assoc-ref %outputs "out")))
	480	(mkdir out)
	481	(mkdir (string-append out "/foo"))
	482	(symlink "foo" (string-append out "/etc"))
	483	(call-with-output-file (string-append out "/etc/bar")
	484	(lambda (port)
	485	(display "foo!" port))))))))
	486	(entry -> (package->manifest-entry thing))
	487	(drv (profile-derivation (manifest (list entry))
a6562c7e LC	488	#:hooks '()
a6562c7e LC	489	#:locales? #f))
113c17a0 LC	490	(profile -> (derivation->output-path drv)))
	491	(mbegin %store-monad
	492	(built-derivations (list drv))
	493	(return (and (file-exists? (string-append profile "/etc/profile"))
	494	(string=? (call-with-input-file
	495	(string-append profile "/etc/bar")
	496	get-string-all)
	497	"foo!"))))))
	498
22ef06b8 LC	499	(test-equalm "union vs. dangling symlink" ;<https://bugs.gnu.org/26949>
	500	"does-not-exist"
	501	(mlet* %store-monad
	502	((thing1 -> (dummy-package "dummy"
	503	(build-system trivial-build-system)
	504	(arguments
	505	`(#:guile ,%bootstrap-guile
	506	#:builder
	507	(let ((out (assoc-ref %outputs "out")))
	508	(mkdir out)
	509	(symlink "does-not-exist"
	510	(string-append out "/dangling"))
	511	#t)))))
	512	(thing2 -> (package (inherit thing1) (name "dummy2")))
	513	(drv (profile-derivation (packages->manifest
	514	(list thing1 thing2))
	515	#:hooks '()
	516	#:locales? #f))
	517	(profile -> (derivation->output-path drv)))
	518	(mbegin %store-monad
	519	(built-derivations (list drv))
	520	(return (readlink (readlink (string-append profile "/dangling")))))))
	521
a2078770 LC	522	(test-end "profiles")
a2078770 LC	523
a2078770 LC	524	;;; Local Variables:
	525	;;; eval: (put 'dummy-package 'scheme-indent-function 1)
	526	;;; End: