Commit | Line | Data |
---|---|---|
2357f850 | 1 | dnl GNU Guix --- Functional package management for GNU |
14218251 | 2 | dnl Copyright © 2012, 2013, 2014, 2015, 2016, 2018 Ludovic Courtès <ludo@gnu.org> |
aa1e1947 | 3 | dnl Copyright © 2014 Mark H Weaver <mhw@netris.org> |
3b88f376 | 4 | dnl Copyright © 2017 Efraim Flashner <efraim@flashner.co.il> |
d388c2c4 | 5 | dnl |
2357f850 | 6 | dnl This file is part of GNU Guix. |
d388c2c4 | 7 | dnl |
2357f850 | 8 | dnl GNU Guix is free software; you can redistribute it and/or modify it |
d388c2c4 LC |
9 | dnl under the terms of the GNU General Public License as published by |
10 | dnl the Free Software Foundation; either version 3 of the License, or (at | |
11 | dnl your option) any later version. | |
12 | dnl | |
2357f850 | 13 | dnl GNU Guix is distributed in the hope that it will be useful, but |
d388c2c4 LC |
14 | dnl WITHOUT ANY WARRANTY; without even the implied warranty of |
15 | dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the | |
16 | dnl GNU General Public License for more details. | |
17 | dnl | |
18 | dnl You should have received a copy of the GNU General Public License | |
2357f850 | 19 | dnl along with GNU Guix. If not, see <http://www.gnu.org/licenses/>. |
d388c2c4 LC |
20 | |
21 | dnl GUIX_ASSERT_LIBGCRYPT_USABLE | |
22 | dnl | |
23 | dnl Assert that GNU libgcrypt is usable from Guile. | |
24 | AC_DEFUN([GUIX_ASSERT_LIBGCRYPT_USABLE], | |
25 | [AC_CACHE_CHECK([whether $LIBGCRYPT can be dynamically loaded], | |
26 | [guix_cv_libgcrypt_usable_p], | |
27 | [GUILE_CHECK([retval], | |
28 | [(dynamic-func \"gcry_md_hash_buffer\" (dynamic-link \"$LIBGCRYPT\"))]) | |
29 | if test "$retval" = 0; then | |
30 | guix_cv_libgcrypt_usable_p="yes" | |
31 | else | |
32 | guix_cv_libgcrypt_usable_p="no" | |
33 | fi]) | |
34 | ||
35 | if test "x$guix_cv_libgcrypt_usable_p" != "xyes"; then | |
36 | AC_MSG_ERROR([GNU libgcrypt does not appear to be usable; see `--with-libgcrypt-prefix' and `README'.]) | |
37 | fi]) | |
c2033df4 LC |
38 | |
39 | dnl GUIX_SYSTEM_TYPE | |
40 | dnl | |
41 | dnl Determine the Guix host system type, and store it in the | |
42 | dnl `guix_system' variable. | |
43 | AC_DEFUN([GUIX_SYSTEM_TYPE], [ | |
44 | AC_REQUIRE([AC_CANONICAL_HOST]) | |
eb25a30a LC |
45 | AC_PATH_PROG([SED], [sed]) |
46 | ||
c2033df4 LC |
47 | AC_ARG_WITH(system, AC_HELP_STRING([--with-system=SYSTEM], |
48 | [Platform identifier (e.g., `i686-linux').]), | |
49 | [guix_system="$withval"], | |
50 | [case "$host_cpu" in | |
51 | i*86) | |
52 | machine_name="i686";; | |
53 | amd64) | |
968ae903 | 54 | machine_name="x86_64";; |
dfdb15d9 | 55 | arm|armv[[7-9]]*) |
968ae903 LC |
56 | # Here we want to exclude CPUs such as "armv6l". On ARMv7 |
57 | # machines, we normally get "armv7l". However, in Guix, we | |
58 | # configure with --build=arm-unknown-linux-gnueabihf, leading | |
59 | # to just "arm", so we also have to allow it. | |
60 | # | |
aa1e1947 MW |
61 | # TODO: If not cross-compiling, add a sanity check to make |
62 | # sure this build machine has the needed features to | |
63 | # support executables compiled using our armhf gcc, | |
64 | # configured with: | |
65 | # --with-arch=armv7-a | |
66 | # --with-float=hard | |
67 | # --with-mode=thumb | |
68 | # --with-fpu=vfpv3-d16 | |
69 | machine_name="armhf";; | |
c2033df4 LC |
70 | *) |
71 | machine_name="$host_cpu";; | |
72 | esac | |
73 | ||
74 | case "$host_os" in | |
75 | linux-gnu*) | |
76 | # For backward compatibility, strip the `-gnu' part. | |
77 | guix_system="$machine_name-linux";; | |
4ed40a3e MR |
78 | gnu*) |
79 | # Always use i586 for GNU/Hurd. | |
80 | guix_system="i586-gnu";; | |
c2033df4 LC |
81 | *) |
82 | # Strip the version number from names such as `gnu0.3', | |
83 | # `darwin10.2.0', etc. | |
eb25a30a | 84 | guix_system="$machine_name-`echo $host_os | "$SED" -e's/[0-9.]*$//g'`";; |
c2033df4 | 85 | esac]) |
5fedc65b LC |
86 | |
87 | AC_MSG_CHECKING([for the Guix system type]) | |
88 | AC_MSG_RESULT([$guix_system]) | |
89 | ||
d8eea3d2 | 90 | AC_SUBST([guix_system]) |
c2033df4 | 91 | ]) |
9c7dd33a | 92 | |
b97556d7 LC |
93 | dnl GUIX_ASSERT_SUPPORTED_SYSTEM |
94 | dnl | |
95 | dnl Assert that this is a system to which the distro is ported. | |
96 | AC_DEFUN([GUIX_ASSERT_SUPPORTED_SYSTEM], [ | |
97 | AC_REQUIRE([GUIX_SYSTEM_TYPE]) | |
98 | ||
99 | AC_ARG_WITH([courage], [AC_HELP_STRING([--with-courage], | |
100 | [Assert that even if this platform is unsupported, you will be | |
101 | courageous and port the GNU System distribution to it (see | |
102 | "GNU Distribution" in the manual.)])], | |
103 | [guix_courageous="$withval"], | |
104 | [guix_courageous="no"]) | |
105 | ||
106 | # Currently only Linux-based systems are supported, and only on some | |
107 | # platforms. | |
108 | case "$guix_system" in | |
3b88f376 | 109 | x86_64-linux|i686-linux|armhf-linux|aarch64-linux|mips64el-linux) |
b97556d7 LC |
110 | ;; |
111 | *) | |
112 | if test "x$guix_courageous" = "xyes"; then | |
113 | AC_MSG_WARN([building Guix on `$guix_system', which is not supported]) | |
114 | else | |
115 | AC_MSG_ERROR([`$guix_system' is not a supported platform. | |
116 | See "GNU Distribution" in the manual, or try `--with-courage'.]) | |
117 | fi | |
118 | ;; | |
119 | esac | |
120 | ]) | |
121 | ||
9c7dd33a LC |
122 | dnl GUIX_ASSERT_GUILE_FEATURES FEATURES |
123 | dnl | |
124 | dnl Assert that FEATURES are provided by $GUILE. | |
125 | AC_DEFUN([GUIX_ASSERT_GUILE_FEATURES], [ | |
126 | for guix_guile_feature in $1 | |
127 | do | |
128 | AC_MSG_CHECKING([whether $GUILE provides feature '$guix_guile_feature']) | |
129 | if "$GUILE" -c "(exit (provided? '$guix_guile_feature))" | |
130 | then | |
131 | AC_MSG_RESULT([yes]) | |
132 | else | |
133 | AC_MSG_RESULT([no]) | |
134 | AC_MSG_ERROR([$GUILE does not support feature '$guix_guile_feature', which is required.]) | |
135 | fi | |
136 | done | |
137 | ]) | |
1959fb04 | 138 | |
14218251 LC |
139 | dnl GUIX_ASSERT_SYNTAX_OBJECT_EQUAL |
140 | dnl | |
141 | dnl Guile 2.2.1 was a brown-paper-bag release where 'equal?' wouldn't work | |
142 | dnl for syntax objects, which broke gexps. Unfortunately Fedora 25 provides it. | |
143 | dnl Reject it. | |
144 | AC_DEFUN([GUIX_ASSERT_SYNTAX_OBJECT_EQUAL], [ | |
145 | AC_CACHE_CHECK([whether 'equal?' works for syntax objects], | |
146 | [ac_cv_guix_syntax_object_equal], | |
147 | [if "$GUILE" -c '(exit (equal? (syntax x) (syntax x)))' | |
148 | then | |
149 | ac_cv_guix_syntax_object_equal=yes | |
150 | else | |
151 | ac_cv_guix_syntax_object_equal=no | |
152 | fi]) | |
153 | if test "x$ac_cv_guix_syntax_object_equal" != xyes; then | |
154 | # This bug was present in Guile 2.2.1 only. | |
155 | AC_MSG_ERROR(['equal?' does not work for syntax object; upgrade to Guile 2.2.2 or later.]) | |
156 | fi | |
157 | ]) | |
158 | ||
21531add LC |
159 | dnl GUIX_CHECK_GUILE_SSH |
160 | dnl | |
161 | dnl Check whether a recent-enough Guile-SSH is available. | |
162 | AC_DEFUN([GUIX_CHECK_GUILE_SSH], [ | |
163 | dnl Check whether 'channel-send-eof' (introduced in 0.10.2) is present. | |
164 | AC_CACHE_CHECK([whether Guile-SSH is available and recent enough], | |
165 | [guix_cv_have_recent_guile_ssh], | |
166 | [GUILE_CHECK([retval], | |
167 | [(and (@ (ssh channel) channel-send-eof) | |
168 | (@ (ssh popen) open-remote-pipe) | |
169 | (@ (ssh dist node) node-eval))]) | |
170 | if test "$retval" = 0; then | |
171 | guix_cv_have_recent_guile_ssh="yes" | |
172 | else | |
173 | guix_cv_have_recent_guile_ssh="no" | |
174 | fi]) | |
175 | ]) | |
176 | ||
2178ed66 LC |
177 | dnl GUIX_TEST_ROOT_DIRECTORY |
178 | AC_DEFUN([GUIX_TEST_ROOT_DIRECTORY], [ | |
179 | AC_CACHE_CHECK([for unit test root directory], | |
180 | [ac_cv_guix_test_root], | |
181 | [ac_cv_guix_test_root="`pwd`/test-tmp"]) | |
182 | ]) | |
183 | ||
93ce8a8e LC |
184 | dnl 'BINPRM_BUF_SIZE' constant in Linux (we leave room for the trailing zero.) |
185 | dnl The Hurd has a limit of about a page (see exec/hashexec.c.) | |
186 | m4_define([LINUX_HASH_BANG_LIMIT], 127) | |
2178ed66 LC |
187 | |
188 | dnl Hardcoded 'sun_path' length in <sys/un.h>. | |
189 | m4_define([SOCKET_FILE_NAME_LIMIT], 108) | |
190 | ||
191 | dnl GUIX_SOCKET_FILE_NAME_LENGTH | |
192 | AC_DEFUN([GUIX_SOCKET_FILE_NAME_LENGTH], [ | |
193 | AC_CACHE_CHECK([the length of the installed socket file name], | |
194 | [ac_cv_guix_socket_file_name_length], | |
195 | [ac_cv_guix_socket_file_name_length="`echo -n "$guix_localstatedir/guix/daemon-socket/socket" | wc -c`"]) | |
196 | ]) | |
197 | ||
198 | dnl GUIX_TEST_SOCKET_FILE_NAME_LENGTH | |
199 | AC_DEFUN([GUIX_TEST_SOCKET_FILE_NAME_LENGTH], [ | |
200 | AC_REQUIRE([GUIX_TEST_ROOT_DIRECTORY]) | |
201 | AC_CACHE_CHECK([the length of the socket file name used in tests], | |
202 | [ac_cv_guix_test_socket_file_name_length], | |
203 | [ac_cv_guix_test_socket_file_name_length="`echo -n "$ac_cv_guix_test_root/var/123456/daemon-socket/socket" | wc -c`"]) | |
204 | ]) | |
205 | ||
206 | dnl GUIX_HASH_BANG_LENGTH | |
207 | AC_DEFUN([GUIX_HASH_BANG_LENGTH], [ | |
208 | AC_CACHE_CHECK([the length of a typical hash bang line], | |
209 | [ac_cv_guix_hash_bang_length], | |
210 | [ac_cv_guix_hash_bang_length=`echo -n "$storedir/aaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaa-bootstrap-binaries-0/bin/bash" | wc -c`]) | |
211 | ]) | |
212 | ||
27ab3cee LC |
213 | dnl GUIX_TEST_HASH_BANG_LENGTH |
214 | AC_DEFUN([GUIX_TEST_HASH_BANG_LENGTH], [ | |
215 | AC_REQUIRE([GUIX_TEST_ROOT_DIRECTORY]) | |
216 | AC_CACHE_CHECK([the length of a hash bang line used in tests], | |
217 | [ac_cv_guix_test_hash_bang_length], | |
218 | [ac_cv_guix_test_hash_bang_length=`echo -n "$ac_cv_guix_test_root/store/aaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaa-bootstrap-binaries-0/bin/bash" | wc -c`]) | |
219 | ]) | |
220 | ||
2178ed66 LC |
221 | dnl GUIX_CHECK_FILE_NAME_LIMITS |
222 | dnl | |
223 | dnl GNU/Linux has a couple of silly limits that we can easily run into. | |
bb251307 LC |
224 | dnl Make sure everything is fine with the current settings. Set $1 to |
225 | dnl 'yes' if tests can run, 'no' otherwise. | |
2178ed66 LC |
226 | AC_DEFUN([GUIX_CHECK_FILE_NAME_LIMITS], [ |
227 | AC_REQUIRE([GUIX_SOCKET_FILE_NAME_LENGTH]) | |
228 | AC_REQUIRE([GUIX_TEST_SOCKET_FILE_NAME_LENGTH]) | |
229 | AC_REQUIRE([GUIX_HASH_BANG_LENGTH]) | |
27ab3cee | 230 | AC_REQUIRE([GUIX_TEST_HASH_BANG_LENGTH]) |
2178ed66 LC |
231 | |
232 | if test "$ac_cv_guix_socket_file_name_length" -ge ]SOCKET_FILE_NAME_LIMIT[; then | |
233 | AC_MSG_ERROR([socket file name would exceed the maxium allowed length]) | |
234 | fi | |
235 | if test "$ac_cv_guix_test_socket_file_name_length" -ge ]SOCKET_FILE_NAME_LIMIT[; then | |
236 | AC_MSG_WARN([socket file name limit may be exceeded when running tests]) | |
237 | fi | |
bb251307 LC |
238 | |
239 | $1=yes | |
2178ed66 | 240 | if test "$ac_cv_guix_hash_bang_length" -ge ]LINUX_HASH_BANG_LIMIT[; then |
bb251307 | 241 | $1=no |
2178ed66 LC |
242 | AC_MSG_ERROR([store directory '$storedir' would lead to overly long hash-bang lines]) |
243 | fi | |
27ab3cee | 244 | if test "$ac_cv_guix_test_hash_bang_length" -ge ]LINUX_HASH_BANG_LIMIT[; then |
bb251307 | 245 | $1=no |
27ab3cee LC |
246 | AC_MSG_WARN([test directory '$ac_cv_guix_test_root' may lead to overly long hash-bang lines]) |
247 | fi | |
2178ed66 | 248 | ]) |
368d08f7 LC |
249 | |
250 | dnl GUIX_CHECK_CXX11 | |
251 | dnl | |
252 | dnl Check whether the C++ compiler can compile a typical C++11 program. | |
253 | AC_DEFUN([GUIX_CHECK_CXX11], [ | |
254 | AC_REQUIRE([AC_PROG_CXX]) | |
255 | AC_CACHE_CHECK([whether $CXX supports C++11], | |
256 | [ac_cv_guix_cxx11_support], | |
257 | [save_CXXFLAGS="$CXXFLAGS" | |
258 | CXXFLAGS="-std=c++11 $CXXFLAGS" | |
259 | AC_COMPILE_IFELSE([ | |
260 | AC_LANG_SOURCE([ | |
261 | #include <functional> | |
262 | ||
263 | std::function<int(int)> | |
264 | return_plus_lambda (int x) | |
265 | { | |
266 | auto result = [[&]](int y) { | |
267 | return x + y; | |
268 | }; | |
269 | ||
270 | return result; | |
271 | } | |
272 | ])], | |
273 | [ac_cv_guix_cxx11_support=yes], | |
274 | [ac_cv_guix_cxx11_support=no]) | |
275 | CXXFLAGS="$save_CXXFLAGS" | |
276 | ]) | |
277 | ]) | |
278 | ||
279 | dnl GUIX_ASSERT_CXX11 | |
280 | dnl | |
281 | dnl Error out if the C++ compiler cannot compile C++11 code. | |
282 | AC_DEFUN([GUIX_ASSERT_CXX11], [ | |
283 | GUIX_CHECK_CXX11 | |
284 | if test "x$ac_cv_guix_cxx11_support" != "xyes"; then | |
285 | AC_MSG_ERROR([C++ compiler '$CXX' does not support the C++11 standard]) | |
286 | fi | |
287 | ]) | |
12e5b266 | 288 | |
dd01fecd LC |
289 | dnl GUIX_LIBGCRYPT_LIBDIR VAR |
290 | dnl | |
291 | dnl Attempt to determine libgcrypt's LIBDIR; store the result in VAR. | |
292 | AC_DEFUN([GUIX_LIBGCRYPT_LIBDIR], [ | |
293 | AC_PATH_PROG([LIBGCRYPT_CONFIG], [libgcrypt-config]) | |
294 | AC_CACHE_CHECK([libgcrypt's library directory], | |
295 | [guix_cv_libgcrypt_libdir], | |
296 | [if test "x$LIBGCRYPT_CONFIG" != "x"; then | |
ca34fc31 | 297 | guix_cv_libgcrypt_libdir=`$LIBGCRYPT_CONFIG --libs | grep -e -L | sed -e "s/.*-L\([[^ ]]\+\)[[[:blank:]]]\+-lgcrypt.*/\1/g"` |
dd01fecd LC |
298 | else |
299 | guix_cv_libgcrypt_libdir="" | |
300 | fi]) | |
301 | $1="$guix_cv_libgcrypt_libdir" | |
302 | ]) | |
ef5f5c86 | 303 | |
72153902 LC |
304 | dnl GUIX_LIBZ_LIBDIR VAR |
305 | dnl | |
306 | dnl Attempt to determine libz's LIBDIR; store the result in VAR. | |
307 | AC_DEFUN([GUIX_LIBZ_LIBDIR], [ | |
308 | AC_REQUIRE([PKG_PROG_PKG_CONFIG]) | |
309 | AC_CACHE_CHECK([zlib's library directory], | |
310 | [guix_cv_libz_libdir], | |
311 | [guix_cv_libz_libdir="`$PKG_CONFIG zlib --variable=libdir 2> /dev/null`"]) | |
312 | $1="$guix_cv_libz_libdir" | |
313 | ]) | |
314 | ||
ef5f5c86 LC |
315 | dnl GUIX_CURRENT_LOCALSTATEDIR |
316 | dnl | |
317 | dnl Determine the localstatedir of an existing Guix installation and set | |
318 | dnl 'guix_cv_current_localstatedir' accordingly. Set it to "none" if no | |
319 | dnl existing installation was found. | |
320 | AC_DEFUN([GUIX_CURRENT_LOCALSTATEDIR], [ | |
321 | AC_PATH_PROG([GUILE], [guile]) | |
322 | AC_CACHE_CHECK([the current installation's localstatedir], | |
323 | [guix_cv_current_localstatedir], | |
324 | [dnl Call 'dirname' because (guix config) appends "/guix" to LOCALSTATEDIR. | |
325 | guix_cv_current_localstatedir="`"$GUILE" \ | |
326 | -c '(use-modules (guix config)) | |
327 | (when (string=? %store-directory "'$storedir'") | |
328 | (display (dirname %state-directory)))' \ | |
329 | 2>/dev/null`" | |
330 | if test "x$guix_cv_current_localstatedir" = "x"; then | |
331 | guix_cv_current_localstatedir=none | |
332 | fi])]) | |
333 | ||
334 | dnl GUIX_CHECK_LOCALSTATEDIR | |
335 | dnl | |
336 | dnl Check that the LOCALSTATEDIR value is consistent with that of the existing | |
337 | dnl Guix installation, if any. Error out or warn if they do not match. | |
338 | AC_DEFUN([GUIX_CHECK_LOCALSTATEDIR], [ | |
339 | AC_REQUIRE([GUIX_CURRENT_LOCALSTATEDIR]) | |
340 | if test "x$guix_cv_current_localstatedir" != "xnone"; then | |
341 | if test "$guix_cv_current_localstatedir" != "$guix_localstatedir"; then | |
342 | case "$localstatedir" in | |
343 | NONE|\${prefix}*) | |
344 | # User kept the default value---i.e., did not pass '--localstatedir'. | |
345 | AC_MSG_ERROR([chosen localstatedir '$guix_localstatedir' does not match \ | |
346 | that of the existing installation '$guix_cv_current_localstatedir' | |
347 | Installing may corrupt $storedir! | |
348 | Use './configure --localstatedir=$guix_cv_current_localstatedir'.]) | |
349 | ;; | |
350 | *) | |
351 | # User passed an explicit '--localstatedir'. Assume they know what | |
352 | # they're doing. | |
353 | AC_MSG_WARN([chosen localstatedir '$guix_localstatedir' does not match \ | |
354 | that of the existing installation '$guix_cv_current_localstatedir']) | |
355 | AC_MSG_WARN([installing may corrupt $storedir!]) | |
356 | ;; | |
357 | esac | |
358 | fi | |
359 | fi]) |