[jackhill/guix/guix.git] / tests / union.scm

;;; GNU Guix --- Functional package management for GNU
;;; Copyright © 2012, 2013, 2014, 2015, 2017, 2018, 2019 Ludovic Courtès <ludo@gnu.org>
;;; Copyright © 2018 Jan (janneke) Nieuwenhuizen <janneke@gnu.org>
;;;
;;; This file is part of GNU Guix.
;;;
;;; GNU Guix is free software; you can redistribute it and/or modify it
;;; under the terms of the GNU General Public License as published by
;;; the Free Software Foundation; either version 3 of the License, or (at
;;; your option) any later version.
;;;
;;; GNU Guix is distributed in the hope that it will be useful, but
;;; WITHOUT ANY WARRANTY; without even the implied warranty of
;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;;; GNU General Public License for more details.
;;;
;;; You should have received a copy of the GNU General Public License
;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.

(define-module (test-union)
  #:use-module (guix tests)
  #:use-module (guix store)
  #:use-module (guix utils)
  #:use-module (guix derivations)
  #:use-module (guix packages)
  #:use-module (guix build union)
  #:use-module ((guix build utils)
                #:select (with-directory-excursion directory-exists?))
  #:use-module (gnu packages bootstrap)
  #:use-module (srfi srfi-1)
  #:use-module (srfi srfi-64)
  #:use-module (rnrs io ports)
  #:use-module (ice-9 match))

;; Exercise the (guix build union) module.

(define %store
  (open-connection-for-tests))

\f
(test-begin "union")

(test-assert "union-build with symlink to directory"
  ;; http://bugs.gnu.org/17083
  ;; Here both ONE and TWO provide an element called 'foo', but in ONE it's a
  ;; directory whereas in TWO it's a symlink to a directory.
  (let* ((one     (build-expression->derivation
                   %store "one"
                   '(begin
                      (use-modules (guix build utils) (srfi srfi-26))
                      (let ((foo (string-append %output "/foo")))
                        (mkdir-p foo)
                        (call-with-output-file (string-append foo "/one")
                          (cut display "one" <>))))
                   #:modules '((guix build utils))))
         (two     (build-expression->derivation
                   %store "two"
                   '(begin
                      (use-modules (guix build utils) (srfi srfi-26))
                      (let ((foo (string-append %output "/foo"))
                            (bar (string-append %output "/bar")))
                        (mkdir-p bar)
                        (call-with-output-file (string-append bar "/two")
                          (cut display "two" <>))
                        (symlink "bar" foo)))
                   #:modules '((guix build utils))))
         (builder '(begin
                     (use-modules (guix build union))

                     (union-build (assoc-ref %outputs "out")
                                  (list (assoc-ref %build-inputs "one")
                                        (assoc-ref %build-inputs "two")))))
         (drv
          (build-expression->derivation %store "union-collision-symlink"
                                        builder
                                        #:inputs `(("one" ,one) ("two" ,two))
                                        #:modules '((guix build union)))))
    (and (build-derivations %store (list drv))
         (with-directory-excursion (pk (derivation->output-path drv))
           (and (string=? "one"
                          (call-with-input-file "foo/one" get-string-all))
                (string=? "two"
                          (call-with-input-file "foo/two" get-string-all))
                (string=? "two"
                          (call-with-input-file "bar/two" get-string-all))
                (not (file-exists? "bar/one")))))))

(test-skip (if (and %store (network-reachable?))
               0
               1))

(test-assert "union-build"
  (let* ((inputs  (map (match-lambda
                        ((name package)
                         `(,name ,(package-derivation %store package))))

                       ;; Purposefully leave duplicate entries.
                       (filter (compose package? cadr)
                               (append %bootstrap-inputs-for-tests
                                       (take %bootstrap-inputs-for-tests 3)))))
         (builder `(begin
                     (use-modules (guix build union))
                     (union-build (assoc-ref %outputs "out")
                                  (map cdr %build-inputs))))
         (drv
          (build-expression->derivation %store "union-test"
                                        builder
                                        #:inputs inputs
                                        #:modules '((guix build union)))))
    (and (build-derivations %store (list (pk 'drv drv)))
         (with-directory-excursion (derivation->output-path drv)
           (and (file-exists? "bin/touch")
                (file-exists? "bin/gcc")
                (file-exists? "bin/ld")
                (file-exists? "lib/libc.so")
                (directory-exists? "lib/gcc")
                (file-exists? "include/unistd.h")

                ;; The 'include/c++' sub-directory is only found in
                ;; gcc-bootstrap, so it should be unified in a
                ;; straightforward way, without traversing it.
                (eq? 'symlink (stat:type (lstat "include/c++")))

                ;; Conversely, several inputs have a 'bin' sub-directory, so
                ;; unifying it requires traversing them all, and creating a
                ;; new 'bin' sub-directory in the profile.
                (eq? 'directory (stat:type (lstat "bin"))))))))

(test-assert "union-build collision first & last"
  (let* ((guile   (package-derivation %store %bootstrap-guile))
         (fake    (build-expression->derivation
                   %store "fake-guile"
                   '(begin
                      (use-modules (guix build utils))
                      (let ((out (assoc-ref %outputs "out")))
                        (mkdir-p (string-append out "/bin"))
                        (call-with-output-file (string-append out "/bin/guile")
                          (const #t))))
                   #:modules '((guix build utils))))
         (builder (lambda (policy)
                    `(begin
                       (use-modules (guix build union)
                                    (srfi srfi-1))
                       (union-build (assoc-ref %outputs "out")
                                    (map cdr %build-inputs)
                                    #:resolve-collision ,policy))))
         (drv1
          (build-expression->derivation %store "union-first"
                                        (builder 'first)
                                        #:inputs `(("guile" ,guile)
                                                   ("fake" ,fake))
                                        #:modules '((guix build union))))
         (drv2
          (build-expression->derivation %store "union-last"
                                        (builder 'last)
                                        #:inputs `(("guile" ,guile)
                                                   ("fake" ,fake))
                                        #:modules '((guix build union)))))
    (and (build-derivations %store (list drv1 drv2))
         (with-directory-excursion (derivation->output-path drv1)
           (string=? (readlink "bin/guile")
                     (string-append (derivation->output-path guile)
                                    "/bin/guile")))
         (with-directory-excursion (derivation->output-path drv2)
           (string=? (readlink "bin/guile")
                     (string-append (derivation->output-path fake)
                                    "/bin/guile"))))))

(test-assert "union-build #:create-all-directories? #t"
  (let* ((build  `(begin
                    (use-modules (guix build union))
                    (union-build (assoc-ref %outputs "out")
                                 (map cdr %build-inputs)
                                 #:create-all-directories? #t)))
         (input  (package-derivation %store %bootstrap-guile))
         (drv    (build-expression->derivation %store "union-test-all-dirs"
                                               build
                                               #:modules '((guix build union))
                                               #:inputs `(("g" ,input)))))
    (and (build-derivations %store (list drv))
         (with-directory-excursion (derivation->output-path drv)
           ;; Even though there's only one input to the union,
           ;; #:create-all-directories? #t must have created bin/ rather than
           ;; making it a symlink to Guile's bin/.
           (and (file-exists? "bin/guile")
                (file-is-directory? "bin")
                (eq? 'symlink (stat:type (lstat "bin/guile"))))))))

(letrec-syntax ((test-relative-file-name
                 (syntax-rules (=>)
                   ((_ (reference file => expected) rest ...)
                    (begin
                      (test-equal (string-append "relative-file-name "
                                                 reference " " file)
                        expected
                        (relative-file-name reference file))
                      (test-relative-file-name rest ...)))
                   ((_)
                    #t))))
  (test-relative-file-name
   ("/a/b" "/a/c/d"     => "../c/d")
   ("/a/b" "/a/b"       => "")
   ("/a/b" "/a"         => "..")
   ("/a/b" "/a/b/c/d"   => "c/d")
   ("/a/b/c" "/a/d/e/f" => "../../d/e/f")))

(test-end)
Commit	Line	Data
233e7676	1	;;; GNU Guix --- Functional package management for GNU
03d76577	2	;;; Copyright © 2012, 2013, 2014, 2015, 2017, 2018, 2019 Ludovic Courtès <ludo@gnu.org>
c3629044	3	;;; Copyright © 2018 Jan (janneke) Nieuwenhuizen <janneke@gnu.org>
c8c88afa	4	;;;
233e7676	5	;;; This file is part of GNU Guix.
c8c88afa	6	;;;
233e7676	7	;;; GNU Guix is free software; you can redistribute it and/or modify it
c8c88afa LC	8	;;; under the terms of the GNU General Public License as published by
	9	;;; the Free Software Foundation; either version 3 of the License, or (at
	10	;;; your option) any later version.
	11	;;;
233e7676	12	;;; GNU Guix is distributed in the hope that it will be useful, but
c8c88afa LC	13	;;; WITHOUT ANY WARRANTY; without even the implied warranty of
	14	;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
	15	;;; GNU General Public License for more details.
	16	;;;
	17	;;; You should have received a copy of the GNU General Public License
233e7676	18	;;; along with GNU Guix. If not, see <http://www.gnu.org/licenses/>.
c8c88afa	19
c8c88afa	20	(define-module (test-union)
c1bc358f	21	#:use-module (guix tests)
c8c88afa LC	22	#:use-module (guix store)
	23	#:use-module (guix utils)
	24	#:use-module (guix derivations)
	25	#:use-module (guix packages)
	26	#:use-module (guix build union)
	27	#:use-module ((guix build utils)
	28	#:select (with-directory-excursion directory-exists?))
1ffa7090	29	#:use-module (gnu packages bootstrap)
97d3998e	30	#:use-module (srfi srfi-1)
c8c88afa	31	#:use-module (srfi srfi-64)
a53a9aed	32	#:use-module (rnrs io ports)
c8c88afa LC	33	#:use-module (ice-9 match))
	34
	35	;; Exercise the (guix build union) module.
	36
	37	(define %store
c1bc358f	38	(open-connection-for-tests))
c8c88afa LC	39
	40	\f
	41	(test-begin "union")
	42
a53a9aed LC	43	(test-assert "union-build with symlink to directory"
	44	;; http://bugs.gnu.org/17083
	45	;; Here both ONE and TWO provide an element called 'foo', but in ONE it's a
	46	;; directory whereas in TWO it's a symlink to a directory.
	47	(let* ((one (build-expression->derivation
	48	%store "one"
	49	'(begin
	50	(use-modules (guix build utils) (srfi srfi-26))
	51	(let ((foo (string-append %output "/foo")))
	52	(mkdir-p foo)
	53	(call-with-output-file (string-append foo "/one")
	54	(cut display "one" <>))))
	55	#:modules '((guix build utils))))
	56	(two (build-expression->derivation
	57	%store "two"
	58	'(begin
	59	(use-modules (guix build utils) (srfi srfi-26))
	60	(let ((foo (string-append %output "/foo"))
	61	(bar (string-append %output "/bar")))
	62	(mkdir-p bar)
	63	(call-with-output-file (string-append bar "/two")
	64	(cut display "two" <>))
	65	(symlink "bar" foo)))
	66	#:modules '((guix build utils))))
	67	(builder '(begin
	68	(use-modules (guix build union))
	69
	70	(union-build (assoc-ref %outputs "out")
	71	(list (assoc-ref %build-inputs "one")
	72	(assoc-ref %build-inputs "two")))))
	73	(drv
	74	(build-expression->derivation %store "union-collision-symlink"
	75	builder
	76	#:inputs `(("one" ,one) ("two" ,two))
	77	#:modules '((guix build union)))))
	78	(and (build-derivations %store (list drv))
	79	(with-directory-excursion (pk (derivation->output-path drv))
	80	(and (string=? "one"
	81	(call-with-input-file "foo/one" get-string-all))
	82	(string=? "two"
	83	(call-with-input-file "foo/two" get-string-all))
	84	(string=? "two"
	85	(call-with-input-file "bar/two" get-string-all))
	86	(not (file-exists? "bar/one")))))))
	87
12d720fd	88	(test-skip (if (and %store (network-reachable?))
ad1ebab3 LC	89	0
ad1ebab3 LC	90	1))
c8c88afa LC	91
	92	(test-assert "union-build"
	93	(let* ((inputs (map (match-lambda
	94	((name package)
	95	`(,name ,(package-derivation %store package))))
62112230 LC	96
62112230 LC	97	;; Purposefully leave duplicate entries.
a2b2070b	98	(filter (compose package? cadr)
03d76577 LC	99	(append %bootstrap-inputs-for-tests
03d76577 LC	100	(take %bootstrap-inputs-for-tests 3)))))
c8c88afa LC	101	(builder `(begin
	102	(use-modules (guix build union))
	103	(union-build (assoc-ref %outputs "out")
	104	(map cdr %build-inputs))))
	105	(drv
	106	(build-expression->derivation %store "union-test"
dd1a5a15 LC	107	builder
dd1a5a15 LC	108	#:inputs inputs
c8c88afa LC	109	#:modules '((guix build union)))))
c8c88afa LC	110	(and (build-derivations %store (list (pk 'drv drv)))
59688fc4	111	(with-directory-excursion (derivation->output-path drv)
c8c88afa LC	112	(and (file-exists? "bin/touch")
	113	(file-exists? "bin/gcc")
	114	(file-exists? "bin/ld")
	115	(file-exists? "lib/libc.so")
	116	(directory-exists? "lib/gcc")
43dd9202 LC	117	(file-exists? "include/unistd.h")
43dd9202 LC	118
127ed6a9 LC	119	;; The 'include/c++' sub-directory is only found in
127ed6a9 LC	120	;; gcc-bootstrap, so it should be unified in a
43dd9202	121	;; straightforward way, without traversing it.
127ed6a9	122	(eq? 'symlink (stat:type (lstat "include/c++")))
43dd9202 LC	123
	124	;; Conversely, several inputs have a 'bin' sub-directory, so
	125	;; unifying it requires traversing them all, and creating a
	126	;; new 'bin' sub-directory in the profile.
	127	(eq? 'directory (stat:type (lstat "bin"))))))))
c8c88afa	128
e40aa54e LC	129	(test-assert "union-build collision first & last"
	130	(let* ((guile (package-derivation %store %bootstrap-guile))
	131	(fake (build-expression->derivation
	132	%store "fake-guile"
	133	'(begin
	134	(use-modules (guix build utils))
	135	(let ((out (assoc-ref %outputs "out")))
	136	(mkdir-p (string-append out "/bin"))
	137	(call-with-output-file (string-append out "/bin/guile")
	138	(const #t))))
	139	#:modules '((guix build utils))))
	140	(builder (lambda (policy)
	141	`(begin
	142	(use-modules (guix build union)
	143	(srfi srfi-1))
	144	(union-build (assoc-ref %outputs "out")
	145	(map cdr %build-inputs)
	146	#:resolve-collision ,policy))))
	147	(drv1
	148	(build-expression->derivation %store "union-first"
	149	(builder 'first)
	150	#:inputs `(("guile" ,guile)
	151	("fake" ,fake))
	152	#:modules '((guix build union))))
	153	(drv2
	154	(build-expression->derivation %store "union-last"
	155	(builder 'last)
	156	#:inputs `(("guile" ,guile)
	157	("fake" ,fake))
	158	#:modules '((guix build union)))))
	159	(and (build-derivations %store (list drv1 drv2))
	160	(with-directory-excursion (derivation->output-path drv1)
	161	(string=? (readlink "bin/guile")
	162	(string-append (derivation->output-path guile)
	163	"/bin/guile")))
	164	(with-directory-excursion (derivation->output-path drv2)
	165	(string=? (readlink "bin/guile")
	166	(string-append (derivation->output-path fake)
	167	"/bin/guile"))))))
	168
addce19e HY	169	(test-assert "union-build #:create-all-directories? #t"
	170	(let* ((build `(begin
	171	(use-modules (guix build union))
	172	(union-build (assoc-ref %outputs "out")
	173	(map cdr %build-inputs)
	174	#:create-all-directories? #t)))
	175	(input (package-derivation %store %bootstrap-guile))
	176	(drv (build-expression->derivation %store "union-test-all-dirs"
	177	build
	178	#:modules '((guix build union))
	179	#:inputs `(("g" ,input)))))
	180	(and (build-derivations %store (list drv))
	181	(with-directory-excursion (derivation->output-path drv)
	182	;; Even though there's only one input to the union,
	183	;; #:create-all-directories? #t must have created bin/ rather than
	184	;; making it a symlink to Guile's bin/.
	185	(and (file-exists? "bin/guile")
	186	(file-is-directory? "bin")
	187	(eq? 'symlink (stat:type (lstat "bin/guile"))))))))
	188
dac1c97d LC	189	(letrec-syntax ((test-relative-file-name
	190	(syntax-rules (=>)
	191	((_ (reference file => expected) rest ...)
	192	(begin
	193	(test-equal (string-append "relative-file-name "
	194	reference " " file)
	195	expected
	196	(relative-file-name reference file))
	197	(test-relative-file-name rest ...)))
	198	((_)
	199	#t))))
	200	(test-relative-file-name
	201	("/a/b" "/a/c/d" => "../c/d")
	202	("/a/b" "/a/b" => "")
	203	("/a/b" "/a" => "..")
	204	("/a/b" "/a/b/c/d" => "c/d")
	205	("/a/b/c" "/a/d/e/f" => "../../d/e/f")))
	206
c8c88afa	207	(test-end)