[jackhill/guix/guix.git] / tests / graph.scm

;;; GNU Guix --- Functional package management for GNU
;;; Copyright © 2015, 2016, 2017 Ludovic Courtès <ludo@gnu.org>
;;;
;;; This file is part of GNU Guix.
;;;
;;; GNU Guix is free software; you can redistribute it and/or modify it
;;; under the terms of the GNU General Public License as published by
;;; the Free Software Foundation; either version 3 of the License, or (at
;;; your option) any later version.
;;;
;;; GNU Guix is distributed in the hope that it will be useful, but
;;; WITHOUT ANY WARRANTY; without even the implied warranty of
;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;;; GNU General Public License for more details.
;;;
;;; You should have received a copy of the GNU General Public License
;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.

(define-module (test-graph)
  #:use-module (guix tests)
  #:use-module (guix graph)
  #:use-module (guix scripts graph)
  #:use-module (guix packages)
  #:use-module (guix derivations)
  #:use-module (guix store)
  #:use-module (guix monads)
  #:use-module (guix grafts)
  #:use-module (guix build-system gnu)
  #:use-module (guix build-system trivial)
  #:use-module (guix gexp)
  #:use-module (guix utils)
  #:use-module (gnu packages)
  #:use-module (gnu packages base)
  #:use-module (gnu packages guile)
  #:use-module (gnu packages libunistring)
  #:use-module (gnu packages bootstrap)
  #:use-module (ice-9 match)
  #:use-module (srfi srfi-1)
  #:use-module (srfi srfi-11)
  #:use-module (srfi srfi-26)
  #:use-module (srfi srfi-64))

(define %store
  (open-connection-for-tests))

;; Globally disable grafts because they can trigger early builds.
(%graft? #f)

(define (make-recording-backend)
  "Return a <graph-backend> and a thunk that returns the recorded nodes and
edges."
  (let ((nodes '())
        (edges '()))
    (define (record-node id label port)
      (set! nodes (cons (list id label) nodes)))
    (define (record-edge source target port)
      (set! edges (cons (list source target) edges)))
    (define (return)
      (values (reverse nodes) (reverse edges)))

    (values (graph-backend "test" "This is the test backend."
                           (const #t) (const #t)
                           record-node record-edge)
            return)))

(define (package->tuple package)
  "Return a tuple representing PACKAGE as produced by %PACKAGE-NODE-TYPE."
  (list (object-address package)
        (package-full-name package)))

(define (edge->tuple source target)
  "Likewise for an edge from SOURCE to TARGET."
  (list (object-address source)
        (object-address target)))

\f
(test-begin "graph")

(test-assert "package DAG"
  (let-values (((backend nodes+edges) (make-recording-backend)))
    (let* ((p1 (dummy-package "p1"))
           (p2 (dummy-package "p2" (inputs `(("p1" ,p1)))))
           (p3 (dummy-package "p3" (inputs `(("p2" ,p2) ("p1", p1))))))
      (run-with-store %store
        (export-graph (list p3) 'port
                      #:node-type %package-node-type
                      #:backend backend))
      ;; We should see nothing more than these 3 packages.
      (let-values (((nodes edges) (nodes+edges)))
        (and (equal? nodes (map package->tuple (list p3 p2 p1)))
             (equal? edges
                     (map edge->tuple
                          (list p3 p3 p2)
                          (list p2 p1 p1))))))))

(test-assert "reverse package DAG"
  (let-values (((backend nodes+edges) (make-recording-backend)))
    (run-with-store %store
      (export-graph (list libunistring) 'port
                    #:node-type %reverse-package-node-type
                    #:backend backend))
    ;; We should see nothing more than these 3 packages.
    (let-values (((nodes edges) (nodes+edges)))
      (and (member (package->tuple guile-2.0) nodes)
           (->bool (member (edge->tuple libunistring guile-2.0) edges))))))

(test-assert "bag-emerged DAG"
  (let-values (((backend nodes+edges) (make-recording-backend)))
    (let* ((o        (dummy-origin (method (lambda _
                                             (text-file "foo" "bar")))))
           (p        (dummy-package "p" (source o)))
           (implicit (map (match-lambda
                            ((label package) package))
                          (standard-packages))))
      (run-with-store %store
        (export-graph (list p) 'port
                      #:node-type %bag-emerged-node-type
                      #:backend backend))
      ;; We should see exactly P and IMPLICIT, with one edge from P to each
      ;; element of IMPLICIT.  O must not appear among NODES.
      (let-values (((nodes edges) (nodes+edges)))
        (and (equal? (match nodes
                       (((labels names) ...)
                        names))
                     (map package-full-name (cons p implicit)))
             (equal? (match edges
                       (((sources destinations) ...)
                        (zip (map store-path-package-name sources)
                             (map store-path-package-name destinations))))
                     (map (lambda (destination)
                            (list "p-0.drv"
                                  (string-append
                                   (package-full-name destination)
                                   ".drv")))
                          implicit)))))))

(test-assert "bag DAG"                            ;a big town in Iraq
  (let-values (((backend nodes+edges) (make-recording-backend)))
    (let ((p (dummy-package "p")))
      (run-with-store %store
        (export-graph (list p) 'port
                      #:node-type %bag-node-type
                      #:backend backend))
      ;; We should see P, its implicit inputs as well as the whole DAG, which
      ;; should include bootstrap binaries.
      (let-values (((nodes edges) (nodes+edges)))
        (every (lambda (name)
                 (find (cut string=? name <>)
                       (match nodes
                         (((labels names) ...)
                          names))))
               (match %bootstrap-inputs
                 (((labels packages) ...)
                  (map package-full-name packages))))))))

(test-assert "bag DAG, including origins"
  (let-values (((backend nodes+edges) (make-recording-backend)))
    (let* ((m (lambda* (uri hash-type hash name #:key system)
                (text-file "foo-1.2.3.tar.gz" "This is a fake!")))
           (o (origin (method m) (uri "the-uri") (sha256 #vu8(0 1 2))))
           (p (dummy-package "p" (source o))))
      (run-with-store %store
        (export-graph (list p) 'port
                      #:node-type %bag-with-origins-node-type
                      #:backend backend))
      ;; We should see O among the nodes, with an edge coming from P.
      (let-values (((nodes edges) (nodes+edges)))
        (run-with-store %store
          (mlet %store-monad ((o* (lower-object o))
                              (p* (lower-object p))
                              (g  (lower-object (default-guile))))
            (return
             (and (find (match-lambda
                          ((file "the-uri") #t)
                          (_                #f))
                        nodes)
                  (find (match-lambda
                          ((source target)
                           (and (string=? source (derivation-file-name p*))
                                (string=? target o*))))
                        edges)

                  ;; There must also be an edge from O to G.
                  (find (match-lambda
                          ((source target)
                           (and (string=? source o*)
                                (string=? target (derivation-file-name g)))))
                        edges)))))))))

(test-assert "derivation DAG"
  (let-values (((backend nodes+edges) (make-recording-backend)))
    (run-with-store %store
      (mlet* %store-monad ((txt   (text-file "text-file" "Hello!"))
                           (guile (package->derivation %bootstrap-guile))
                           (drv   (gexp->derivation "output"
                                                    #~(symlink #$txt #$output)
                                                    #:guile-for-build
                                                    guile)))
        ;; We should get at least these 3 nodes and corresponding edges.
        (mbegin %store-monad
          (export-graph (list drv) 'port
                        #:node-type %derivation-node-type
                        #:backend backend)
          (let-values (((nodes edges) (nodes+edges)))
            ;; XXX: For some reason we need to throw in some 'basename'.
            (return (and (match nodes
                           (((ids labels) ...)
                            (let ((ids (map basename ids)))
                              (every (lambda (item)
                                       (member (basename item) ids))
                                     (list txt
                                           (derivation-file-name drv)
                                           (derivation-file-name guile))))))
                         (every (cut member <>
                                     (map (lambda (edge)
                                            (map basename edge))
                                          edges))
                                (list (map (compose basename derivation-file-name)
                                           (list drv guile))
                                      (list (basename (derivation-file-name drv))
                                            (basename txt))))))))))))

(test-assert "reference DAG"
  (let-values (((backend nodes+edges) (make-recording-backend)))
    (run-with-store %store
      (mlet* %store-monad ((txt   (text-file "text-file" "Hello!"))
                           (guile (package->derivation %bootstrap-guile))
                           (drv   (gexp->derivation "output"
                                                    #~(symlink #$txt #$output)
                                                    #:guile-for-build
                                                    guile))
                           (out -> (derivation->output-path drv)))
        ;; We should see only OUT and TXT, with an edge from the former to the
        ;; latter.
        (mbegin %store-monad
          (built-derivations (list drv))
          (export-graph (list (derivation->output-path drv)) 'port
                        #:node-type %reference-node-type
                        #:backend backend)
          (let-values (((nodes edges) (nodes+edges)))
            (return
             (and (equal? (match nodes
                            (((ids labels) ...)
                             ids))
                          (list out txt))
                  (equal? edges `((,out ,txt)))))))))))

(test-assert "referrer DAG"
  (let-values (((backend nodes+edges) (make-recording-backend)))
    (run-with-store %store
      (mlet* %store-monad ((txt   (text-file "referrer-node" (random-text)))
                           (drv   (gexp->derivation "referrer"
                                                    #~(symlink #$txt #$output)))
                           (out -> (derivation->output-path drv)))
        ;; We should see only TXT and OUT, with an edge from the former to the
        ;; latter.
        (mbegin %store-monad
          (built-derivations (list drv))
          (export-graph (list txt) 'port
                        #:node-type %referrer-node-type
                        #:backend backend)
          (let-values (((nodes edges) (nodes+edges)))
            (return
             (and (equal? (match nodes
                            (((ids labels) ...)
                             ids))
                          (list txt out))
                  (equal? edges `((,txt ,out)))))))))))

(test-assert "node-edges"
  (run-with-store %store
    (let ((packages (fold-packages cons '())))
      (mlet %store-monad ((edges (node-edges %package-node-type packages)))
        (return (and (null? (edges sed))
                     (lset= eq?
                            (edges guile-2.0)
                            (match (package-direct-inputs guile-2.0)
                              (((labels packages _ ...) ...)
                               packages)))))))))

(test-assert "node-transitive-edges + node-back-edges"
  (run-with-store %store
    (let ((packages   (fold-packages cons '()))
          (bootstrap? (lambda (package)
                        (string-contains
                         (location-file (package-location package))
                         "bootstrap.scm")))
          (trivial?   (lambda (package)
                        (eq? (package-build-system package)
                             trivial-build-system))))
      (mlet %store-monad ((edges (node-back-edges %bag-node-type packages)))
        (let* ((glibc      (canonical-package glibc))
               (dependents (node-transitive-edges (list glibc) edges))
               (diff       (lset-difference eq? packages dependents)))
          ;; All the packages depend on libc, except bootstrap packages and
          ;; some that use TRIVIAL-BUILD-SYSTEM.
          (return (null? (remove (lambda (package)
                                   (or (trivial? package)
                                       (bootstrap? package)))
                                 diff))))))))

(test-assert "node-transitive-edges, no duplicates"
  (run-with-store %store
    (let* ((p0  (dummy-package "p0"))
           (p1a (dummy-package "p1a" (inputs `(("p0" ,p0)))))
           (p1b (dummy-package "p1b" (inputs `(("p0" ,p0)))))
           (p2  (dummy-package "p2" (inputs `(("p1a" ,p1a) ("p1b" ,p1b))))))
      (mlet %store-monad ((edges (node-edges %package-node-type
                                             (list p2 p1a p1b p0))))
        (return (lset= eq? (node-transitive-edges (list p2) edges)
                       (list p1a p1b p0)))))))

(test-equal "node-reachable-count"
  '(3 3)
  (run-with-store %store
    (let* ((p0  (dummy-package "p0"))
           (p1a (dummy-package "p1a" (inputs `(("p0" ,p0)))))
           (p1b (dummy-package "p1b" (inputs `(("p0" ,p0)))))
           (p2  (dummy-package "p2" (inputs `(("p1a" ,p1a) ("p1b" ,p1b))))))
      (mlet* %store-monad ((all -> (list p2 p1a p1b p0))
                           (edges  (node-edges %package-node-type all))
                           (back   (node-back-edges %package-node-type all)))
        (return (list (node-reachable-count (list p2) edges)
                      (node-reachable-count (list p0) back)))))))

(test-end "graph")
Commit	Line	Data
88856916	1	;;; GNU Guix --- Functional package management for GNU
b96a0640	2	;;; Copyright © 2015, 2016, 2017 Ludovic Courtès <ludo@gnu.org>
88856916 LC	3	;;;
	4	;;; This file is part of GNU Guix.
	5	;;;
	6	;;; GNU Guix is free software; you can redistribute it and/or modify it
	7	;;; under the terms of the GNU General Public License as published by
	8	;;; the Free Software Foundation; either version 3 of the License, or (at
	9	;;; your option) any later version.
	10	;;;
	11	;;; GNU Guix is distributed in the hope that it will be useful, but
	12	;;; WITHOUT ANY WARRANTY; without even the implied warranty of
	13	;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
	14	;;; GNU General Public License for more details.
	15	;;;
	16	;;; You should have received a copy of the GNU General Public License
	17	;;; along with GNU Guix. If not, see <http://www.gnu.org/licenses/>.
	18
	19	(define-module (test-graph)
	20	#:use-module (guix tests)
8fb58371	21	#:use-module (guix graph)
88856916 LC	22	#:use-module (guix scripts graph)
	23	#:use-module (guix packages)
	24	#:use-module (guix derivations)
	25	#:use-module (guix store)
	26	#:use-module (guix monads)
ef8de985	27	#:use-module (guix grafts)
88856916	28	#:use-module (guix build-system gnu)
923d846c	29	#:use-module (guix build-system trivial)
88856916	30	#:use-module (guix gexp)
923d846c	31	#:use-module (guix utils)
88856916	32	#:use-module (gnu packages)
923d846c LC	33	#:use-module (gnu packages base)
923d846c LC	34	#:use-module (gnu packages guile)
b96a0640	35	#:use-module (gnu packages libunistring)
88856916 LC	36	#:use-module (gnu packages bootstrap)
	37	#:use-module (ice-9 match)
	38	#:use-module (srfi srfi-1)
	39	#:use-module (srfi srfi-11)
	40	#:use-module (srfi srfi-26)
	41	#:use-module (srfi srfi-64))
	42
	43	(define %store
	44	(open-connection-for-tests))
	45
ef8de985 LC	46	;; Globally disable grafts because they can trigger early builds.
	47	(%graft? #f)
	48
88856916 LC	49	(define (make-recording-backend)
	50	"Return a <graph-backend> and a thunk that returns the recorded nodes and
	51	edges."
	52	(let ((nodes '())
	53	(edges '()))
	54	(define (record-node id label port)
	55	(set! nodes (cons (list id label) nodes)))
	56	(define (record-edge source target port)
	57	(set! edges (cons (list source target) edges)))
	58	(define (return)
	59	(values (reverse nodes) (reverse edges)))
	60
51377437 RW	61	(values (graph-backend "test" "This is the test backend."
51377437 RW	62	(const #t) (const #t)
88856916 LC	63	record-node record-edge)
	64	return)))
	65
	66	(define (package->tuple package)
	67	"Return a tuple representing PACKAGE as produced by %PACKAGE-NODE-TYPE."
	68	(list (object-address package)
	69	(package-full-name package)))
	70
	71	(define (edge->tuple source target)
	72	"Likewise for an edge from SOURCE to TARGET."
	73	(list (object-address source)
	74	(object-address target)))
	75
	76	\f
	77	(test-begin "graph")
	78
	79	(test-assert "package DAG"
	80	(let-values (((backend nodes+edges) (make-recording-backend)))
	81	(let* ((p1 (dummy-package "p1"))
	82	(p2 (dummy-package "p2" (inputs `(("p1" ,p1)))))
	83	(p3 (dummy-package "p3" (inputs `(("p2" ,p2) ("p1", p1))))))
	84	(run-with-store %store
	85	(export-graph (list p3) 'port
	86	#:node-type %package-node-type
	87	#:backend backend))
	88	;; We should see nothing more than these 3 packages.
	89	(let-values (((nodes edges) (nodes+edges)))
	90	(and (equal? nodes (map package->tuple (list p3 p2 p1)))
	91	(equal? edges
	92	(map edge->tuple
	93	(list p3 p3 p2)
	94	(list p2 p1 p1))))))))
	95
b96a0640 LC	96	(test-assert "reverse package DAG"
	97	(let-values (((backend nodes+edges) (make-recording-backend)))
	98	(run-with-store %store
	99	(export-graph (list libunistring) 'port
	100	#:node-type %reverse-package-node-type
	101	#:backend backend))
	102	;; We should see nothing more than these 3 packages.
	103	(let-values (((nodes edges) (nodes+edges)))
	104	(and (member (package->tuple guile-2.0) nodes)
	105	(->bool (member (edge->tuple libunistring guile-2.0) edges))))))
	106
88856916 LC	107	(test-assert "bag-emerged DAG"
88856916 LC	108	(let-values (((backend nodes+edges) (make-recording-backend)))
f88282af LC	109	(let* ((o (dummy-origin (method (lambda _
	110	(text-file "foo" "bar")))))
	111	(p (dummy-package "p" (source o)))
	112	(implicit (map (match-lambda
	113	((label package) package))
	114	(standard-packages))))
88856916 LC	115	(run-with-store %store
	116	(export-graph (list p) 'port
	117	#:node-type %bag-emerged-node-type
	118	#:backend backend))
	119	;; We should see exactly P and IMPLICIT, with one edge from P to each
f88282af	120	;; element of IMPLICIT. O must not appear among NODES.
88856916 LC	121	(let-values (((nodes edges) (nodes+edges)))
	122	(and (equal? (match nodes
	123	(((labels names) ...)
	124	names))
	125	(map package-full-name (cons p implicit)))
	126	(equal? (match edges
	127	(((sources destinations) ...)
	128	(zip (map store-path-package-name sources)
	129	(map store-path-package-name destinations))))
	130	(map (lambda (destination)
	131	(list "p-0.drv"
	132	(string-append
	133	(package-full-name destination)
	134	".drv")))
	135	implicit)))))))
	136
923d846c	137	(test-assert "bag DAG" ;a big town in Iraq
88856916 LC	138	(let-values (((backend nodes+edges) (make-recording-backend)))
	139	(let ((p (dummy-package "p")))
	140	(run-with-store %store
	141	(export-graph (list p) 'port
	142	#:node-type %bag-node-type
	143	#:backend backend))
	144	;; We should see P, its implicit inputs as well as the whole DAG, which
	145	;; should include bootstrap binaries.
	146	(let-values (((nodes edges) (nodes+edges)))
	147	(every (lambda (name)
	148	(find (cut string=? name <>)
	149	(match nodes
	150	(((labels names) ...)
	151	names))))
	152	(match %bootstrap-inputs
	153	(((labels packages) ...)
	154	(map package-full-name packages))))))))
	155
38b92daa LC	156	(test-assert "bag DAG, including origins"
	157	(let-values (((backend nodes+edges) (make-recording-backend)))
	158	(let* ((m (lambda* (uri hash-type hash name #:key system)
	159	(text-file "foo-1.2.3.tar.gz" "This is a fake!")))
	160	(o (origin (method m) (uri "the-uri") (sha256 #vu8(0 1 2))))
	161	(p (dummy-package "p" (source o))))
	162	(run-with-store %store
	163	(export-graph (list p) 'port
	164	#:node-type %bag-with-origins-node-type
	165	#:backend backend))
	166	;; We should see O among the nodes, with an edge coming from P.
	167	(let-values (((nodes edges) (nodes+edges)))
	168	(run-with-store %store
	169	(mlet %store-monad ((o* (lower-object o))
51385362 LC	170	(p* (lower-object p))
51385362 LC	171	(g (lower-object (default-guile))))
38b92daa LC	172	(return
	173	(and (find (match-lambda
	174	((file "the-uri") #t)
	175	(_ #f))
	176	nodes)
	177	(find (match-lambda
	178	((source target)
	179	(and (string=? source (derivation-file-name p*))
	180	(string=? target o*))))
51385362 LC	181	edges)
	182
	183	;; There must also be an edge from O to G.
	184	(find (match-lambda
	185	((source target)
	186	(and (string=? source o*)
	187	(string=? target (derivation-file-name g)))))
38b92daa LC	188	edges)))))))))
38b92daa LC	189
88856916 LC	190	(test-assert "derivation DAG"
	191	(let-values (((backend nodes+edges) (make-recording-backend)))
	192	(run-with-store %store
	193	(mlet* %store-monad ((txt (text-file "text-file" "Hello!"))
	194	(guile (package->derivation %bootstrap-guile))
	195	(drv (gexp->derivation "output"
	196	#~(symlink #$txt #$output)
	197	#:guile-for-build
	198	guile)))
	199	;; We should get at least these 3 nodes and corresponding edges.
	200	(mbegin %store-monad
	201	(export-graph (list drv) 'port
	202	#:node-type %derivation-node-type
	203	#:backend backend)
	204	(let-values (((nodes edges) (nodes+edges)))
	205	;; XXX: For some reason we need to throw in some 'basename'.
	206	(return (and (match nodes
	207	(((ids labels) ...)
	208	(let ((ids (map basename ids)))
	209	(every (lambda (item)
	210	(member (basename item) ids))
	211	(list txt
	212	(derivation-file-name drv)
	213	(derivation-file-name guile))))))
	214	(every (cut member <>
	215	(map (lambda (edge)
	216	(map basename edge))
	217	edges))
	218	(list (map (compose basename derivation-file-name)
	219	(list drv guile))
	220	(list (basename (derivation-file-name drv))
	221	(basename txt))))))))))))
	222
	223	(test-assert "reference DAG"
	224	(let-values (((backend nodes+edges) (make-recording-backend)))
	225	(run-with-store %store
	226	(mlet* %store-monad ((txt (text-file "text-file" "Hello!"))
	227	(guile (package->derivation %bootstrap-guile))
	228	(drv (gexp->derivation "output"
	229	#~(symlink #$txt #$output)
	230	#:guile-for-build
	231	guile))
	232	(out -> (derivation->output-path drv)))
	233	;; We should see only OUT and TXT, with an edge from the former to the
	234	;; latter.
	235	(mbegin %store-monad
	236	(built-derivations (list drv))
	237	(export-graph (list (derivation->output-path drv)) 'port
	238	#:node-type %reference-node-type
	239	#:backend backend)
	240	(let-values (((nodes edges) (nodes+edges)))
	241	(return
	242	(and (equal? (match nodes
	243	(((ids labels) ...)
	244	ids))
	245	(list out txt))
	246	(equal? edges `((,out ,txt)))))))))))
	247
7f8fec0f LC	248	(test-assert "referrer DAG"
	249	(let-values (((backend nodes+edges) (make-recording-backend)))
	250	(run-with-store %store
	251	(mlet* %store-monad ((txt (text-file "referrer-node" (random-text)))
	252	(drv (gexp->derivation "referrer"
	253	#~(symlink #$txt #$output)))
	254	(out -> (derivation->output-path drv)))
	255	;; We should see only TXT and OUT, with an edge from the former to the
	256	;; latter.
	257	(mbegin %store-monad
	258	(built-derivations (list drv))
	259	(export-graph (list txt) 'port
	260	#:node-type %referrer-node-type
	261	#:backend backend)
	262	(let-values (((nodes edges) (nodes+edges)))
	263	(return
	264	(and (equal? (match nodes
	265	(((ids labels) ...)
	266	ids))
	267	(list txt out))
	268	(equal? edges `((,txt ,out)))))))))))
	269
923d846c LC	270	(test-assert "node-edges"
	271	(run-with-store %store
	272	(let ((packages (fold-packages cons '())))
	273	(mlet %store-monad ((edges (node-edges %package-node-type packages)))
724eaef1	274	(return (and (null? (edges sed))
923d846c LC	275	(lset= eq?
	276	(edges guile-2.0)
	277	(match (package-direct-inputs guile-2.0)
	278	(((labels packages _ ...) ...)
	279	packages)))))))))
	280
	281	(test-assert "node-transitive-edges + node-back-edges"
	282	(run-with-store %store
	283	(let ((packages (fold-packages cons '()))
	284	(bootstrap? (lambda (package)
	285	(string-contains
	286	(location-file (package-location package))
	287	"bootstrap.scm")))
	288	(trivial? (lambda (package)
	289	(eq? (package-build-system package)
	290	trivial-build-system))))
	291	(mlet %store-monad ((edges (node-back-edges %bag-node-type packages)))
	292	(let* ((glibc (canonical-package glibc))
	293	(dependents (node-transitive-edges (list glibc) edges))
	294	(diff (lset-difference eq? packages dependents)))
	295	;; All the packages depend on libc, except bootstrap packages and
	296	;; some that use TRIVIAL-BUILD-SYSTEM.
	297	(return (null? (remove (lambda (package)
	298	(or (trivial? package)
	299	(bootstrap? package)))
	300	diff))))))))
	301
88d5858f LC	302	(test-assert "node-transitive-edges, no duplicates"
	303	(run-with-store %store
	304	(let* ((p0 (dummy-package "p0"))
	305	(p1a (dummy-package "p1a" (inputs `(("p0" ,p0)))))
	306	(p1b (dummy-package "p1b" (inputs `(("p0" ,p0)))))
	307	(p2 (dummy-package "p2" (inputs `(("p1a" ,p1a) ("p1b" ,p1b))))))
	308	(mlet %store-monad ((edges (node-edges %package-node-type
	309	(list p2 p1a p1b p0))))
	310	(return (lset= eq? (node-transitive-edges (list p2) edges)
	311	(list p1a p1b p0)))))))
	312
e144e342 LC	313	(test-equal "node-reachable-count"
	314	'(3 3)
	315	(run-with-store %store
	316	(let* ((p0 (dummy-package "p0"))
	317	(p1a (dummy-package "p1a" (inputs `(("p0" ,p0)))))
	318	(p1b (dummy-package "p1b" (inputs `(("p0" ,p0)))))
	319	(p2 (dummy-package "p2" (inputs `(("p1a" ,p1a) ("p1b" ,p1b))))))
	320	(mlet* %store-monad ((all -> (list p2 p1a p1b p0))
	321	(edges (node-edges %package-node-type all))
	322	(back (node-back-edges %package-node-type all)))
	323	(return (list (node-reachable-count (list p2) edges)
	324	(node-reachable-count (list p0) back)))))))
	325
88856916	326	(test-end "graph")