(* HCoop Domtool (http://hcoop.sourceforge.net/)
 * Copyright (c) 2006, Adam Chlipala
 *
 * This program is free software; you can redistribute it and/or
 * modify it under the terms of the GNU General Public License
 * as published by the Free Software Foundation; either version 2
 * of the License, or (at your option) any later version.
 *
 * This program is distributed in the hope that it will be useful,
 * but WITHOUT ANY WARRANTY; without even the implied warranty of
 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 * GNU General Public License for more details.
 *
 * You should have received a copy of the GNU General Public License
 * along with this program; if not, write to the Free Software
 * Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301, USA.
 *)

(* Apache HTTPD handling *)

structure Apache :> APACHE = struct

open Ast

val _ = Env.type_one "proxy_port"
	Env.int
	(fn n => n > 1024)

val _ = Env.type_one "proxy_target"
	Env.string
	(fn s =>
	    let
		fun default () = List.exists (fn s' => s = s') Config.Apache.proxyTargets
	    in
		case String.fields (fn ch => ch = #":") s of
		    ["http", "//localhost", rest] =>
		    (case String.fields (fn ch => ch = #"/") rest of
			 port :: _ =>
			 (case Int.fromString port of
			      NONE => default ()
			    | SOME n => n > 1024 orelse default ())
		       | _ => default ())
		  | _ => default ()
	    end)

val _ = Env.type_one "rewrite_arg"
	Env.string
	(CharVector.all Char.isAlphaNum)

fun validLocation s =
    size s > 0 andalso size s < 1000 andalso CharVector.all
						 (fn ch => Char.isAlphaNum ch
							   orelse ch = #"-"
							   orelse ch = #"_"
							   orelse ch = #"."
							   orelse ch = #"/") s

val _ = Env.type_one "location"
	Env.string
	validLocation

val dl = ErrorMsg.dummyLoc

val _ = Defaults.registerDefault ("WebNodes",
				  (TList (TBase "node", dl), dl),
				  (fn () => (EList (map (fn s => (EString s, dl)) Config.Apache.webNodes), dl)))

val _ = Defaults.registerDefault ("SSL",
				  (TBase "bool", dl),
				  (fn () => (EVar "false", dl)))

val _ = Defaults.registerDefault ("User",
				  (TBase "your_user", dl),
				  (fn () => (EString (Domain.getUser ()), dl)))

val _ = Defaults.registerDefault ("Group",
				  (TBase "your_group", dl),
				  (fn () => (EString (Domain.getUser ()), dl)))

val _ = Defaults.registerDefault ("DocumentRoot",
				  (TBase "your_path", dl),
				  (fn () => (EString (Config.homeBase ^ "/" ^ Domain.getUser () ^ "/" ^ Config.Apache.public_html), dl)))

val _ = Defaults.registerDefault ("ServerAdmin",
				  (TBase "email", dl),
				  (fn () => (EString (Domain.getUser () ^ "@" ^ Config.defaultDomain), dl)))


val redirect_code = fn (EVar "temp", _) => SOME "temp"
		     | (EVar "permanent", _) => SOME "permanent"
		     | (EVar "seeother", _) => SOME "seeother"
		     | (EVar "redir300", _) => SOME "300"
		     | (EVar "redir301", _) => SOME "301"
		     | (EVar "redir302", _) => SOME "302"
		     | (EVar "redir303", _) => SOME "303"
		     | (EVar "redir304", _) => SOME "304"
		     | (EVar "redir305", _) => SOME "305"
		     | (EVar "redir307", _) => SOME "307"
		     | _ => NONE

val flag = fn (EVar "redirect", _) => SOME "R"
	    | (EVar "forbidden", _) => SOME "F"
	    | (EVar "gone", _) => SOME "G"
	    | (EVar "last", _) => SOME "L"
	    | (EVar "chain", _) => SOME "C"
	    | (EVar "nosubreq", _) => SOME "NS"
	    | (EVar "nocase", _) => SOME "NC"
	    | (EVar "qsappend", _) => SOME "QSA"
	    | (EVar "noescape", _) => SOME "NE"
	    | (EVar "passthrough", _) => SOME "PT"
	    | (EApp ((EVar "mimeType", _), e), _) =>
	      Option.map (fn s => "T=" ^ s) (Env.string e)
	    | (EApp ((EVar "redirectWith", _), e), _) =>
	      Option.map (fn s => "R=" ^ s) (redirect_code e)
	    | (EApp ((EVar "skip", _), e), _) =>
	      Option.map (fn n => "S=" ^ Int.toString n) (Env.int e)
	    | (EApp ((EApp ((EVar "env", _), e1), _), e2), _) =>
	      (case Env.string e1 of
		   NONE => NONE
		 | SOME s1 => Option.map (fn s2 => "E=" ^ s1 ^ ":" ^ s2)
					 (Env.string e2))

	    | _ => NONE

val cond_flag = fn (EVar "cond_nocase", _) => SOME "NC"
	    | (EVar "ornext", _) => SOME "OR"
	    | _ => NONE

val apache_option = fn (EVar "execCGI", _) => SOME "ExecCGI"
		     | (EVar "includesNOEXEC", _) => SOME "IncludesNOEXEC"
		     | (EVar "indexes", _) => SOME "Indexes"
		     | _ => NONE

val autoindex_width = fn (EVar "autofit", _) => SOME "*"
		       | (EApp ((EVar "characters", _), n), _) =>
			 Option.map Int.toString (Env.int n)
		       | _ => NONE

val autoindex_option = fn (EApp ((EVar "descriptionWidth", _), w), _) =>
			  Option.map (fn w => ("DescriptionWidth", SOME w))
			  (autoindex_width w)
			| (EVar "fancyIndexing", _) => SOME ("FancyIndexing", NONE)
			| (EVar "foldersFirst", _) => SOME ("FoldersFirst", NONE)
			| (EVar "htmlTable", _) => SOME ("HTMLTable", NONE)
			| (EVar "iconsAreLinks", _) => SOME ("IconsAreLinks", NONE)
			| (EApp ((EVar "iconHeight", _), n), _) =>
			  Option.map (fn w => ("IconHeight", SOME (Int.toString w)))
				     (Env.int n)
			| (EApp ((EVar "iconWidth", _), n), _) =>
			  Option.map (fn w => ("IconWidth", SOME (Int.toString w)))
				     (Env.int n)
			| (EVar "ignoreCase", _) => SOME ("IgnoreCase", NONE)
			| (EVar "ignoreClient", _) => SOME ("IgnoreClient", NONE)
			| (EApp ((EVar "nameWidth", _), w), _) =>
			  Option.map (fn w => ("NameWidth", SOME w))
				     (autoindex_width w)
			| (EVar "scanHtmlTitles", _) => SOME ("ScanHTMLTitles", NONE)
			| (EVar "suppressColumnSorting", _) => SOME ("SuppressColumnSorting", NONE)
			| (EVar "suppressDescription", _) => SOME ("SuppressDescription", NONE)
			| (EVar "suppressHtmlPreamble", _) => SOME ("SuppressHTMLPreamble", NONE)
			| (EVar "suppressIcon", _) => SOME ("SuppressIcon", NONE)
			| (EVar "suppressLastModified", _) => SOME ("SuppressLastModified", NONE)
			| (EVar "suppressRules", _) => SOME ("SuppressRules", NONE)
			| (EVar "suppressSize", _) => SOME ("SuppressSize", NONE)
			| (EVar "trackModified", _) => SOME ("TrackModified", NONE)
			| (EVar "versionSort", _) => SOME ("VersionSort", NONE)
			| (EVar "xhtml", _) => SOME ("XHTML", NONE)

			| _ => NONE

val vhostsChanged = ref false

val () = Slave.registerPreHandler
	     (fn () => vhostsChanged := false)

fun findVhostUser fname =
    let
	val inf = TextIO.openIn fname

	fun loop () =
	    case TextIO.inputLine inf of
		NONE => NONE
	      | SOME line =>
		case String.tokens Char.isSpace line of
		    ["SuexecUserGroup", user, _] => SOME user
		  | _ => loop ()
    in
	loop ()
	before TextIO.closeIn inf
    end

val () = Slave.registerFileHandler (fn fs =>
				       let
					   val spl = OS.Path.splitDirFile (#file fs)
				       in
					   if String.isSuffix ".vhost" (#file spl)
					      orelse String.isSuffix ".vhost_ssl" (#file spl) then
					       case findVhostUser (#file fs) of
						   NONE => print ("Can't find user in " ^ #file fs ^ "!  Taking no action.\n")
						 | SOME user =>
						   let
						       val realVhostFile = OS.Path.joinDirFile
									       {dir = Config.Apache.confDir,
										file = #file spl}

						       val realLogDir = OS.Path.joinDirFile
									    {dir = Config.homeBase,
									     file = user}
						       val realLogDir = OS.Path.joinDirFile
									    {dir = realLogDir,
									     file = "apache"}
						       val realLogDir = OS.Path.joinDirFile
									    {dir = realLogDir,
									     file = "log"}
						       val realLogDir = OS.Path.joinDirFile
									    {dir = realLogDir,
									     file = Slave.hostname ()}
						       val {base, ...} = OS.Path.splitBaseExt (#file spl)
						       val realLogDir = OS.Path.joinDirFile
									    {dir = realLogDir,
									     file = base}
						   in
						       vhostsChanged := true;
						       case #action fs of
							   Slave.Delete =>
							   (ignore (OS.Process.system (Config.rm
										       ^ " -rf "
										       ^ realVhostFile));
							    ignore (OS.Process.system (Config.rm
										       ^ " -rf "
										       ^ realLogDir)))
							 | Slave.Add =>
							   (ignore (OS.Process.system (Config.cp
										       ^ " "
										       ^ #file fs
										       ^ " "
										       ^ realVhostFile));
							    OS.FileSys.mkDir realLogDir)
							   
							 | _ =>
							   ignore (OS.Process.system (Config.cp
										      ^ " "
										      ^ #file fs
										      ^ " "
										      ^ realVhostFile))
						   end
					   else
					       ()
				       end)

val () = Slave.registerPostHandler
	 (fn () =>
	     (if !vhostsChanged then
		  Slave.shellF ([Config.Apache.reload],
				fn cl => "Error reloading Apache with " ^ cl)
	      else
		  ()))

val vhostFiles : (string * TextIO.outstream) list ref = ref []
fun write' s = app (fn (node, file) => TextIO.output (file, s node)) (!vhostFiles)
fun write s = app (fn (_, file) => TextIO.output (file, s)) (!vhostFiles)

val rewriteEnabled = ref false
val currentVhost = ref ""
val currentVhostId = ref ""

val pre = ref (fn _ : {user : string, nodes : string list, id : string, hostname : string} => ())
fun registerPre f =
    let
	val old = !pre
    in
	pre := (fn x => (old x; f x))
    end

val post = ref (fn () => ())
fun registerPost f =
    let
	val old = !post
    in
	post := (fn () => (old (); f ()))
    end

val aliaser = ref (fn _ : string => ())
fun registerAliaser f =
    let
	val old = !aliaser
    in
	aliaser := (fn x => (old x; f x))
    end

val () = Env.containerV_one "vhost"
	 ("host", Env.string)
	 (fn (env, host) =>
	     let
		 val nodes = Env.env (Env.list Env.string) (env, "WebNodes")

		 val ssl = Env.env Env.bool (env, "SSL")
		 val user = Env.env Env.string (env, "User")
		 val group = Env.env Env.string (env, "Group")
		 val docroot = Env.env Env.string (env, "DocumentRoot")
		 val sadmin = Env.env Env.string (env, "ServerAdmin")

		 val fullHost = host ^ "." ^ Domain.currentDomain ()
		 val vhostId = fullHost ^ (if ssl then ".ssl" else "")
		 val confFile = fullHost ^ (if ssl then ".vhost_ssl" else ".vhost")
	     in
		 currentVhost := fullHost;
		 currentVhostId := vhostId;

		 rewriteEnabled := false;
		 vhostFiles := map (fn node =>
				       let
					   val file = Domain.domainFile {node = node,
									 name = confFile}
				       in
					   TextIO.output (file, "<VirtualHost ");
					   TextIO.output (file, Domain.nodeIp node);
					   TextIO.output (file, ":");
					   TextIO.output (file, if ssl then
								    "443"
								else
								    "80");
					   TextIO.output (file, ">\n");
					   TextIO.output (file, "\tErrorLog ");
					   TextIO.output (file, Config.homeBase);
					   TextIO.output (file, "/");
					   TextIO.output (file, user);
					   TextIO.output (file, "/apache/log/");
					   TextIO.output (file, node);
					   TextIO.output (file, "/");
					   TextIO.output (file, vhostId);
					   TextIO.output (file, "/error.log\n\tCustomLog ");
					   TextIO.output (file, Config.homeBase);
					   TextIO.output (file, "/");
					   TextIO.output (file, user);
					   TextIO.output (file, "/apache/log/");
					   TextIO.output (file, node);
					   TextIO.output (file, "/");
					   TextIO.output (file, vhostId);
					   TextIO.output (file, "/access.log combined\n");
					   (Config.homeBase ^ "/" ^ user ^ "/apache/log/"
					    ^ node ^ "/" ^ vhostId, file)
				       end)
				   nodes;
		 write "\tServerName ";
		 write fullHost;
		 write "\n\tSuexecUserGroup ";
		 write user;
		 write " ";
		 write group;
		 write "\n\tDocumentRoot ";
		 write docroot;
		 write "\n\tServerAdmin ";
		 write sadmin;
		 write "\n";
		 !pre {user = user, nodes = nodes, id = vhostId, hostname = fullHost}
	     end,
	  fn () => (!post ();
		    write "</VirtualHost>\n";
		    app (TextIO.closeOut o #2) (!vhostFiles)))

val () = Env.container_one "location"
	 ("prefix", Env.string)
	 (fn prefix =>
	     (write "\t<Location ";
	      write prefix;
	      write ">\n"),
	  fn () => write "\t</Location>\n")

val () = Env.container_one "directory"
	 ("directory", Env.string)
	 (fn directory =>
	     (write "\t<Directory ";
	      write directory;
	      write ">\n"),
	  fn () => write "\t</Directory>\n")

fun checkRewrite () =
    if !rewriteEnabled then
	()
    else
	(write "\tRewriteEngine on\n";
	 rewriteEnabled := true)

val () = Env.action_three "localProxyRewrite"
	 ("from", Env.string, "to", Env.string, "port", Env.int)
	 (fn (from, to, port) =>
	     (checkRewrite ();
	      write "\tRewriteRule\t";
	      write from;
	      write "\thttp://localhost:";
	      write (Int.toString port);
	      write "/";
	      write to;
	      write " [P]\n"))

val () = Env.action_two "proxyPass"
	 ("from", Env.string, "to", Env.string)
	 (fn (from, to) =>
		 (write "\tProxyPass\t";
		  write from;
		  write "\t";
		  write to;
		  write "\n"))

val () = Env.action_two "proxyPassReverse"
	 ("from", Env.string, "to", Env.string)
	 (fn (from, to) =>
		 (write "\tProxyPassReverse\t";
		  write from;
		  write "\t";
		  write to;
		  write "\n"))

val () = Env.action_three "rewriteRule"
	 ("from", Env.string, "to", Env.string, "flags", Env.list flag)
	 (fn (from, to, flags) =>
	     (checkRewrite ();
	      write "\tRewriteRule\t";
	      write from;
	      write "\t";
	      write to;
	      case flags of
		  [] => ()
		| flag::rest => (write " [";
				 write flag;
				 app (fn flag => (write ",";
						  write flag)) rest;
				 write "]");
	      write "\n"))

val () = Env.action_three "rewriteCond"
	 ("test", Env.string, "pattern", Env.string, "flags", Env.list cond_flag)
	 (fn (from, to, flags) =>
	     (checkRewrite ();
	      write "\tRewriteCond\t";
	      write from;
	      write "\t";
	      write to;
	      case flags of
		  [] => ()
		| flag::rest => (write " [";
				 write flag;
				 app (fn flag => (write ",";
						  write flag)) rest;
				 write "]");
	      write "\n"))

val () = Env.action_one "rewriteLogLevel"
	 ("level", Env.int)
	 (fn level =>
	     (checkRewrite ();
	      write "\tRewriteLog ";
	      write' (fn x => x);
	      write "/rewrite.log\n\tRewriteLogLevel ";
	      write (Int.toString level);
	      write "\n"))

val () = Env.action_two "alias"
	 ("from", Env.string, "to", Env.string)
	 (fn (from, to) =>
	     (write "\tAlias\t";
	      write from;
	      write " ";
	      write to;
	      write "\n"))

val () = Env.action_two "scriptAlias"
	 ("from", Env.string, "to", Env.string)
	 (fn (from, to) =>
	     (write "\tScriptAlias\t";
	      write from;
	      write " ";
	      write to;
	      write "\n"))

val () = Env.action_two "errorDocument"
	 ("code", Env.string, "handler", Env.string)
	 (fn (code, handler) =>
	     (write "\tErrorDocument\t";
	      write code;
	      write " ";
	      write handler;
	      write "\n"))

val () = Env.action_one "options"
	 ("options", Env.list apache_option)
	 (fn opts =>
	     case opts of
		 [] => ()
	       | _ => (write "\tOptions";
		       app (fn opt => (write " "; write opt)) opts;
		       write "\n"))

val () = Env.action_one "set_options"
	 ("options", Env.list apache_option)
	 (fn opts =>
	     case opts of
		 [] => ()
	       | _ => (write "\tOptions";
		       app (fn opt => (write " +"; write opt)) opts;
		       write "\n"))

val () = Env.action_one "unset_options"
	 ("options", Env.list apache_option)
	 (fn opts =>
	     case opts of
		 [] => ()
	       | _ => (write "\tOptions";
		       app (fn opt => (write " -"; write opt)) opts;
		       write "\n"))

val () = Env.action_one "directoryIndex"
	 ("filenames", Env.list Env.string)
	 (fn opts =>
	     (write "\tDirectoryIndex";
	      app (fn opt => (write " "; write opt)) opts;
	      write "\n"))

val () = Env.action_one "serverAlias"
	 ("host", Env.string)
	 (fn host =>
	     (write "\tServerAlias ";
	      write host;
	      write "\n";
	      !aliaser host))

val authType = fn (EVar "basic", _) => SOME "basic"
		| (EVar "digest", _) => SOME "digest"
		| _ => NONE

val () = Env.action_one "authType"
	 ("type", authType)
	 (fn ty =>
	     (write "\tAuthType ";
	      write ty;
	      write "\n"))

val () = Env.action_one "authName"
	 ("name", Env.string)
	 (fn name =>
	     (write "\tAuthName \"";
	      write name;
	      write "\"\n"))

val () = Env.action_one "authUserFile"
	 ("file", Env.string)
	 (fn name =>
	     (write "\tAuthUserFile ";
	      write name;
	      write "\n"))

val () = Env.action_none "requireValidUser"
	 (fn () => write "\tRequire valid-user\n")

val () = Env.action_one "requireUser"
	 ("users", Env.list Env.string)
	 (fn names =>
	     case names of
		 [] => ()
	       | _ => (write "\tRequire user";
		       app (fn name => (write " "; write name)) names;
		       write "\n"))

val () = Env.action_one "requireGroup"
	 ("groups", Env.list Env.string)
	 (fn names =>
	     case names of
		 [] => ()
	       | _ => (write "\tRequire group";
		       app (fn name => (write " "; write name)) names;
		       write "\n"))

val () = Env.action_none "orderAllowDeny"
	 (fn () => write "\tOrder allow,deny\n")

val () = Env.action_none "orderDenyAllow"
	 (fn () => write "\tOrder deny,allow\n")

val () = Env.action_none "allowFromAll"
	 (fn () => write "\tAllow from all\n")

val () = Env.action_one "allowFrom"
	 ("entries", Env.list Env.string)
	 (fn names =>
	     case names of
		 [] => ()
	       | _ => (write "\tAllow from";
		       app (fn name => (write " "; write name)) names;
		       write "\n"))

val () = Env.action_none "denyFromAll"
	 (fn () => write "\tDeny from all\n")

val () = Env.action_one "denyFrom"
	 ("entries", Env.list Env.string)
	 (fn names =>
	     case names of
		 [] => ()
	       | _ => (write "\tDeny from";
		       app (fn name => (write " "; write name)) names;
		       write "\n"))

val () = Env.action_none "satisfyAll"
	 (fn () => write "\tSatisfy all\n")

val () = Env.action_none "satisfyAny"
	 (fn () => write "\tSatisfy any\n")

val () = Env.action_one "forceType"
	 ("type", Env.string)
	 (fn ty => (write "\tForceType ";
		    write ty;
		    write "\n"))

val () = Env.action_none "forceTypeOff"
	 (fn () => write "\tForceType None\n")

val () = Env.action_two "action"
	 ("what", Env.string, "how", Env.string)
	 (fn (what, how) => (write "\tAction ";
			     write what;
			     write " ";
			     write how;
			     write "\n"))

val () = Env.action_one "addDefaultCharset"
	 ("charset", Env.string)
	 (fn ty => (write "\tAddDefaultCharset ";
		    write ty;
		    write "\n"))

val () = Env.action_one "davSvn"
	 ("path", Env.string)
	 (fn path => (write "\tDAV svn\n\tSVNPath ";
		      write path;
		      write "\n"))

val () = Env.action_one "authzSvnAccessFile"
	 ("path", Env.string)
	 (fn path => (write "\tAuthzSVNAccessFile ";
		      write path;
		      write "\n"))

val () = Env.action_two "addDescription"
	 ("description", Env.string, "patterns", Env.list Env.string)
	 (fn (desc, pats) =>
	     case pats of
		 [] => ()
	       | _ => (write "\tAddDescription \"";
		       write (String.toString desc);
		       write "\"";
		       app (fn pat => (write " "; write pat)) pats;
		       write "\n"))

val () = Env.action_one "indexOptions"
	 ("options", Env.list autoindex_option)
	 (fn opts =>
	     case opts of
		 [] => ()
	       | _ => (write "\tIndexOptions";
		       app (fn (opt, arg) =>
			       (write " ";
				write opt;
				Option.app (fn arg =>
					       (write "="; write arg)) arg)) opts;
		       write "\n"))

val () = Env.action_one "set_indexOptions"
	 ("options", Env.list autoindex_option)
	 (fn opts =>
	     case opts of
		 [] => ()
	       | _ => (write "\tIndexOptions";
		       app (fn (opt, arg) =>
			       (write " +";
				write opt;
				Option.app (fn arg =>
					       (write "="; write arg)) arg)) opts;
		       write "\n"))

val () = Env.action_one "unset_indexOptions"
	 ("options", Env.list autoindex_option)
	 (fn opts =>
	     case opts of
		 [] => ()
	       | _ => (write "\tIndexOptions";
		       app (fn (opt, _) =>
			       (write " -";
				write opt)) opts;
		       write "\n"))

val () = Env.action_one "headerName"
	 ("name", Env.string)
	 (fn name => (write "\tHeaderName ";
		      write name;
		      write "\n"))

val () = Env.action_one "readmeName"
	 ("name", Env.string)
	 (fn name => (write "\tReadmeName ";
		      write name;
		      write "\n"))

end