(* HCoop Domtool (http://hcoop.sourceforge.net/)
 * Copyright (c) 2006, Adam Chlipala
 *
 * This program is free software; you can redistribute it and/or
 * modify it under the terms of the GNU General Public License
 * as published by the Free Software Foundation; either version 2
 * of the License, or (at your option) any later version.
 *
 * This program is distributed in the hope that it will be useful,
 * but WITHOUT ANY WARRANTY; without even the implied warranty of
 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 * GNU General Public License for more details.
 *
 * You should have received a copy of the GNU General Public License
 * along with this program; if not, write to the Free Software
 * Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301, USA.
 *)

(* Main interface *)

structure Main :> MAIN = struct

open Ast Print

structure SM = StringMap

val dmy = ErrorMsg.dummyLoc

val defaultT : record ref = ref SM.empty
val defaultV : (unit -> exp) SM.map ref = ref SM.empty

fun registerDefault (name, t, v) =
    case SM.find (!defaultT, name) of
	NONE => (defaultT := SM.insert (!defaultT, name, t);
		 defaultV := SM.insert (!defaultV, name, v))
      | SOME _ => raise Fail "Duplicate default environment variable"

fun tInit () = (TAction ((CRoot, dmy),
			 !defaultT,
			 StringMap.empty),
		dmy)


	    
fun check' G fname =
    let
	(*val _ = print ("Check " ^ fname ^ "\n")*)
	val prog = Parse.parse fname
    in
	if !ErrorMsg.anyErrors then
	    G
	else
	    Tycheck.checkFile G (tInit ()) prog
    end

fun basis () =
    let
	val dir = Posix.FileSys.opendir Config.libRoot

	fun loop files =
	    case Posix.FileSys.readdir dir of
		NONE => (Posix.FileSys.closedir dir;
			 files)
	      | SOME fname =>
		if String.isSuffix ".dtl" fname then
		    loop (OS.Path.joinDirFile {dir = Config.libRoot,
					       file = fname}
			  :: files)
		else
		    loop files

	val files = loop []
	val files = Order.order files
    in
	if !ErrorMsg.anyErrors then
	    Env.empty
	else
	    foldl (fn (fname, G) => check' G fname) Env.empty files
    end

fun check fname =
    let
	val _ = ErrorMsg.reset ()
	val _ = Env.preTycheck ()

	val b = basis ()
    in
	if !ErrorMsg.anyErrors then
	    (b, NONE)
	else
	    let
		val _ = ErrorMsg.reset ()
		val prog = Parse.parse fname
	    in
		if !ErrorMsg.anyErrors then
		    (Env.empty, NONE)
		else
		    let
			val G' = Tycheck.checkFile b (tInit ()) prog
		    in
			(G', #3 prog)
		    end
	    end
    end

fun reduce fname =
    let
	val (G, body) = check fname
    in
	if !ErrorMsg.anyErrors then
	    NONE
	else
	    case body of
		SOME body =>
		let
		    val body' = Reduce.reduceExp G body
		in
		    (*printd (PD.hovBox (PD.PPS.Rel 0,
					 [PD.string "Result:",
					  PD.space 1,
					  p_exp body']))*)
		    SOME body'
		end
	      | _ => NONE
    end

fun eval fname =
    case reduce fname of
	(SOME body') =>
	if !ErrorMsg.anyErrors then
	    ()
	else
	    Eval.exec (SM.map (fn f => f ()) (!defaultV)) body'
      | NONE => ()

val dispatcher =
    Config.dispatcher ^ ":" ^ Int.toString Config.dispatcherPort

fun request fname =
    let
	val context = OpenSSL.context ("/home/adamc/fake/clientcert.pem",
				       "/home/adamc/fake/clientkey.pem",
				       Config.trustStore)

	val bio = OpenSSL.connect (context, dispatcher)

	val _ = print ("Subject: " ^ OpenSSL.peerCN bio ^ "\n")

	val inf = TextIO.openIn fname

	fun loop () =
	    case TextIO.inputLine inf of
		NONE => ()
	      | SOME line => (OpenSSL.writeAll (bio, line);
			      loop ())
    in
	loop ();
	TextIO.closeIn inf;
	OpenSSL.close bio
    end

fun service () =
    let
	val context = OpenSSL.context (Config.serverCert,
				       Config.serverKey,
				       Config.trustStore)

	val sock = OpenSSL.listen (context, Config.dispatcherPort)

	fun loop () =
	    case OpenSSL.accept sock of
		NONE => ()
	      | SOME bio =>
		let
		    (*val _ = print ("Subject: " ^ OpenSSL.peerCN bio ^ "\n")*)

		    fun loop' () =
			case OpenSSL.readOne bio of
			    NONE => ()
			  | SOME line => (print line;
					  loop' ())
		in
		    loop' ();
		    OpenSSL.close bio;
		    loop ()
		end
    in
	loop ();
	OpenSSL.shutdown sock
    end

end