src/msg.sml

   1 (* HCoop Domtool (http://hcoop.sourceforge.net/)
   2  * Copyright (c) 2006, Adam Chlipala
   3  *
   4  * This program is free software; you can redistribute it and/or
   5  * modify it under the terms of the GNU General Public License
   6  * as published by the Free Software Foundation; either version 2
   7  * of the License, or (at your option) any later version.
   8  *
   9  * This program is distributed in the hope that it will be useful,
  10  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  11  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  12  * GNU General Public License for more details.
  13  *
  14  * You should have received a copy of the GNU General Public License
  15  * along with this program; if not, write to the Free Software
  16  * Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301, USA.
  17  *)
  18
  19 (* Network messages *)
  20
  21 structure Msg :> MSG = struct
  22
  23 open OpenSSL MsgTypes Slave
  24
  25 val a2i = fn Add => 0
  26            | Delete => 1
  27            | Modify => 2
  28
  29 val i2a = fn 0 => Add
  30            | 1 => Delete
  31            | 2 => Modify
  32            | _ => raise OpenSSL.OpenSSL "Bad action number to deserialize"
  33
  34 fun sendAcl (bio, {user, class, value}) =
  35     (OpenSSL.writeString (bio, user);
  36      OpenSSL.writeString (bio, class);
  37      OpenSSL.writeString (bio, value))
  38
  39 fun recvAcl bio =
  40     case (OpenSSL.readString bio, OpenSSL.readString bio, OpenSSL.readString bio) of
  41         (SOME user, SOME class, SOME value) => SOME {user = user, class = class, value = value}
  42       | _ => NONE
  43
  44 fun send (bio, m) =
  45     case m of
  46         MsgOk => OpenSSL.writeInt (bio, 1)
  47       | MsgError s => (OpenSSL.writeInt (bio, 2);
  48                        OpenSSL.writeString (bio, s))
  49       | MsgConfig s => (OpenSSL.writeInt (bio, 3);
  50                        OpenSSL.writeString (bio, s))
  51       | MsgFile {action, domain, dir, file} =>
  52         (OpenSSL.writeInt (bio, 4);
  53          OpenSSL.writeInt (bio, a2i action);
  54          OpenSSL.writeString (bio, domain);
  55          OpenSSL.writeString (bio, dir);
  56          OpenSSL.writeString (bio, file))
  57       | MsgDoFiles => OpenSSL.writeInt (bio, 5)
  58       | MsgGrant acl => (OpenSSL.writeInt (bio, 6);
  59                          sendAcl (bio, acl))
  60
  61 fun checkIt v =
  62     case v of
  63         NONE => raise OpenSSL.OpenSSL "Bad Msg format"
  64       | _ => v
  65
  66 fun recv bio =
  67     case OpenSSL.readInt bio of
  68         NONE => NONE
  69       | SOME n =>
  70         checkIt (case n of
  71                      1 => SOME MsgOk
  72                    | 2 => Option.map MsgError (OpenSSL.readString bio)
  73                    | 3 => Option.map MsgConfig (OpenSSL.readString bio)
  74                    | 4 => (case (OpenSSL.readInt bio,
  75                                  OpenSSL.readString bio,
  76                                  OpenSSL.readString bio,
  77                                  OpenSSL.readString bio) of
  78                                (SOME action, SOME domain, SOME dir, SOME file) =>
  79                                SOME (MsgFile {action = i2a action,
  80                                               domain = domain,
  81                                               dir = dir,
  82                                               file = file})
  83                              | _ => NONE)
  84                    | 5 => SOME MsgDoFiles
  85                    | 6 => (case recvAcl bio of
  86                                SOME acl => SOME (MsgGrant acl)
  87                              | _ => NONE)
  88                    | _ => NONE)
  89
  90 end