First support for new Apache log scheme
[hcoop/domtool2.git] / src / plugins / apache.sml
1 (* HCoop Domtool (http://hcoop.sourceforge.net/)
2 * Copyright (c) 2006, Adam Chlipala
3 *
4 * This program is free software; you can redistribute it and/or
5 * modify it under the terms of the GNU General Public License
6 * as published by the Free Software Foundation; either version 2
7 * of the License, or (at your option) any later version.
8 *
9 * This program is distributed in the hope that it will be useful,
10 * but WITHOUT ANY WARRANTY; without even the implied warranty of
11 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
12 * GNU General Public License for more details.
13 *
14 * You should have received a copy of the GNU General Public License
15 * along with this program; if not, write to the Free Software
16 * Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301, USA.
17 *)
18
19 (* Apache HTTPD handling *)
20
21 structure Apache :> APACHE = struct
22
23 open Ast
24
25 val _ = Env.type_one "web_node"
26 Env.string
27 (fn node =>
28 List.exists (fn (x, _) => x = node) Config.Apache.webNodes_all
29 orelse (Domain.hasPriv "www"
30 andalso List.exists (fn (x, _) => x = node) Config.Apache.webNodes_admin))
31
32 val _ = Env.registerFunction ("web_node_to_node",
33 fn [e] => SOME e
34 | _ => NONE)
35
36 val _ = Env.type_one "proxy_port"
37 Env.int
38 (fn n => n > 1024)
39
40 val _ = Env.type_one "proxy_target"
41 Env.string
42 (fn s =>
43 let
44 fun default () = List.exists (fn s' => s = s') Config.Apache.proxyTargets
45 in
46 case String.fields (fn ch => ch = #":") s of
47 ["http", "//localhost", rest] =>
48 (case String.fields (fn ch => ch = #"/") rest of
49 port :: _ =>
50 (case Int.fromString port of
51 NONE => default ()
52 | SOME n => n > 1024 orelse default ())
53 | _ => default ())
54 | _ => default ()
55 end)
56
57 val _ = Env.type_one "rewrite_arg"
58 Env.string
59 (CharVector.all Char.isAlphaNum)
60
61 val _ = Env.type_one "suexec_flag"
62 Env.bool
63 (fn b => b orelse Domain.hasPriv "www")
64
65 fun validLocation s =
66 size s > 0 andalso size s < 1000 andalso CharVector.all
67 (fn ch => Char.isAlphaNum ch
68 orelse ch = #"-"
69 orelse ch = #"_"
70 orelse ch = #"."
71 orelse ch = #"/") s
72
73 val _ = Env.type_one "location"
74 Env.string
75 validLocation
76
77 fun validCert s = Acl.query {user = Domain.getUser (),
78 class = "cert",
79 value = s}
80
81 val _ = Env.type_one "ssl_cert_path"
82 Env.string
83 validCert
84
85 fun ssl e = case e of
86 (EVar "no_ssl", _) => SOME NONE
87 | (EApp ((EVar "use_cert", _), s), _) => Option.map SOME (Env.string s)
88 | _ => NONE
89
90 val dl = ErrorMsg.dummyLoc
91
92 val _ = Defaults.registerDefault ("WebNodes",
93 (TList (TBase "web_node", dl), dl),
94 (fn () => (EList (map (fn s => (EString s, dl)) Config.Apache.webNodes_default), dl)))
95
96 val _ = Defaults.registerDefault ("SSL",
97 (TBase "ssl", dl),
98 (fn () => (EVar "no_ssl", dl)))
99
100 val _ = Defaults.registerDefault ("User",
101 (TBase "your_user", dl),
102 (fn () => (EString (Domain.getUser ()), dl)))
103
104 val _ = Defaults.registerDefault ("Group",
105 (TBase "your_group", dl),
106 (fn () => (EString (Domain.getUser ()), dl)))
107
108 val _ = Defaults.registerDefault ("DocumentRoot",
109 (TBase "your_path", dl),
110 (fn () => (EString (Domain.homedir () ^ "/" ^ Config.Apache.public_html), dl)))
111
112 val _ = Defaults.registerDefault ("ServerAdmin",
113 (TBase "email", dl),
114 (fn () => (EString (Domain.getUser () ^ "@" ^ Config.defaultDomain), dl)))
115
116 val _ = Defaults.registerDefault ("SuExec",
117 (TBase "suexec_flag", dl),
118 (fn () => (EVar "true", dl)))
119
120 val redirect_code = fn (EVar "temp", _) => SOME "temp"
121 | (EVar "permanent", _) => SOME "permanent"
122 | (EVar "seeother", _) => SOME "seeother"
123 | (EVar "redir300", _) => SOME "300"
124 | (EVar "redir301", _) => SOME "301"
125 | (EVar "redir302", _) => SOME "302"
126 | (EVar "redir303", _) => SOME "303"
127 | (EVar "redir304", _) => SOME "304"
128 | (EVar "redir305", _) => SOME "305"
129 | (EVar "redir307", _) => SOME "307"
130 | _ => NONE
131
132 val flag = fn (EVar "redirect", _) => SOME "R"
133 | (EVar "forbidden", _) => SOME "F"
134 | (EVar "gone", _) => SOME "G"
135 | (EVar "last", _) => SOME "L"
136 | (EVar "chain", _) => SOME "C"
137 | (EVar "nosubreq", _) => SOME "NS"
138 | (EVar "nocase", _) => SOME "NC"
139 | (EVar "qsappend", _) => SOME "QSA"
140 | (EVar "noescape", _) => SOME "NE"
141 | (EVar "passthrough", _) => SOME "PT"
142 | (EApp ((EVar "mimeType", _), e), _) =>
143 Option.map (fn s => "T=" ^ s) (Env.string e)
144 | (EApp ((EVar "redirectWith", _), e), _) =>
145 Option.map (fn s => "R=" ^ s) (redirect_code e)
146 | (EApp ((EVar "skip", _), e), _) =>
147 Option.map (fn n => "S=" ^ Int.toString n) (Env.int e)
148 | (EApp ((EApp ((EVar "env", _), e1), _), e2), _) =>
149 (case Env.string e1 of
150 NONE => NONE
151 | SOME s1 => Option.map (fn s2 => "E=" ^ s1 ^ ":" ^ s2)
152 (Env.string e2))
153
154 | _ => NONE
155
156 val cond_flag = fn (EVar "cond_nocase", _) => SOME "NC"
157 | (EVar "ornext", _) => SOME "OR"
158 | _ => NONE
159
160 val apache_option = fn (EVar "execCGI", _) => SOME "ExecCGI"
161 | (EVar "includesNOEXEC", _) => SOME "IncludesNOEXEC"
162 | (EVar "indexes", _) => SOME "Indexes"
163 | _ => NONE
164
165 val autoindex_width = fn (EVar "autofit", _) => SOME "*"
166 | (EApp ((EVar "characters", _), n), _) =>
167 Option.map Int.toString (Env.int n)
168 | _ => NONE
169
170 val autoindex_option = fn (EApp ((EVar "descriptionWidth", _), w), _) =>
171 Option.map (fn w => ("DescriptionWidth", SOME w))
172 (autoindex_width w)
173 | (EVar "fancyIndexing", _) => SOME ("FancyIndexing", NONE)
174 | (EVar "foldersFirst", _) => SOME ("FoldersFirst", NONE)
175 | (EVar "htmlTable", _) => SOME ("HTMLTable", NONE)
176 | (EVar "iconsAreLinks", _) => SOME ("IconsAreLinks", NONE)
177 | (EApp ((EVar "iconHeight", _), n), _) =>
178 Option.map (fn w => ("IconHeight", SOME (Int.toString w)))
179 (Env.int n)
180 | (EApp ((EVar "iconWidth", _), n), _) =>
181 Option.map (fn w => ("IconWidth", SOME (Int.toString w)))
182 (Env.int n)
183 | (EVar "ignoreCase", _) => SOME ("IgnoreCase", NONE)
184 | (EVar "ignoreClient", _) => SOME ("IgnoreClient", NONE)
185 | (EApp ((EVar "nameWidth", _), w), _) =>
186 Option.map (fn w => ("NameWidth", SOME w))
187 (autoindex_width w)
188 | (EVar "scanHtmlTitles", _) => SOME ("ScanHTMLTitles", NONE)
189 | (EVar "suppressColumnSorting", _) => SOME ("SuppressColumnSorting", NONE)
190 | (EVar "suppressDescription", _) => SOME ("SuppressDescription", NONE)
191 | (EVar "suppressHtmlPreamble", _) => SOME ("SuppressHTMLPreamble", NONE)
192 | (EVar "suppressIcon", _) => SOME ("SuppressIcon", NONE)
193 | (EVar "suppressLastModified", _) => SOME ("SuppressLastModified", NONE)
194 | (EVar "suppressRules", _) => SOME ("SuppressRules", NONE)
195 | (EVar "suppressSize", _) => SOME ("SuppressSize", NONE)
196 | (EVar "trackModified", _) => SOME ("TrackModified", NONE)
197 | (EVar "versionSort", _) => SOME ("VersionSort", NONE)
198 | (EVar "xhtml", _) => SOME ("XHTML", NONE)
199
200 | _ => NONE
201
202 val vhostsChanged = ref false
203 val logDeleted = ref false
204
205 val () = Slave.registerPreHandler
206 (fn () => (vhostsChanged := false;
207 logDeleted := false))
208
209 fun findVhostUser fname =
210 let
211 val inf = TextIO.openIn fname
212
213 fun loop () =
214 case TextIO.inputLine inf of
215 NONE => NONE
216 | SOME line =>
217 if String.isPrefix "# Owner: " line then
218 case String.tokens Char.isSpace line of
219 [_, _, user] => SOME user
220 | _ => NONE
221 else
222 loop ()
223 in
224 loop ()
225 before TextIO.closeIn inf
226 end handle _ => NONE
227
228 val webNodes_full = Config.Apache.webNodes_all @ Config.Apache.webNodes_admin
229
230 fun isVersion1 node =
231 List.exists (fn (n, {version = ConfigTypes.APACHE_1_3, ...}) => n = node
232 | _ => false) webNodes_full
233
234 fun imVersion1 () = isVersion1 (Slave.hostname ())
235
236 fun isWaklog node =
237 List.exists (fn (n, {auth = ConfigTypes.MOD_WAKLOG, ...}) => n = node
238 | _ => false) webNodes_full
239
240 fun down () = if imVersion1 () then Config.Apache.down1 else Config.Apache.down
241 fun undown () = if imVersion1 () then Config.Apache.undown1 else Config.Apache.undown
242 fun reload () = if imVersion1 () then Config.Apache.reload1 else Config.Apache.reload
243
244 fun logDir {user, node, vhostId} =
245 String.concat [Config.Apache.logDirOf user,
246 "/",
247 node,
248 "/",
249 vhostId]
250
251 val () = Slave.registerFileHandler (fn fs =>
252 let
253 val spl = OS.Path.splitDirFile (#file fs)
254 in
255 if String.isSuffix ".vhost" (#file spl)
256 orelse String.isSuffix ".vhost_ssl" (#file spl) then let
257 val realVhostFile = OS.Path.joinDirFile
258 {dir = Config.Apache.confDir,
259 file = #file spl}
260
261 val user = findVhostUser (#file fs)
262 val oldUser = findVhostUser realVhostFile
263 in
264 if (oldUser = NONE andalso #action fs <> Slave.Add)
265 orelse (user = NONE andalso #action fs <> Slave.Delete) then
266 print ("Can't find user in " ^ #file fs ^ " or " ^ realVhostFile ^ "! Taking no action.\n")
267 else
268 let
269 val vhostId = if OS.Path.ext (#file spl) = SOME ".vhost_ssl" then
270 OS.Path.base (#file spl) ^ ".ssl"
271 else
272 OS.Path.base (#file spl)
273
274 fun realLogDir user =
275 logDir {user = valOf user,
276 node = Slave.hostname (),
277 vhostId = vhostId}
278 in
279 vhostsChanged := true;
280 case #action fs of
281 Slave.Delete =>
282 (if !logDeleted then
283 ()
284 else
285 (ignore (OS.Process.system (down ()));
286 logDeleted := true);
287 ignore (OS.Process.system (Config.rm
288 ^ " -rf "
289 ^ realVhostFile));
290 ignore (OS.Process.system (Config.rm
291 ^ " -rf "
292 ^ realLogDir oldUser)))
293 | Slave.Add =>
294 let
295 val rld = realLogDir user
296 in
297 ignore (OS.Process.system (Config.cp
298 ^ " "
299 ^ #file fs
300 ^ " "
301 ^ realVhostFile));
302 if Posix.FileSys.access (rld, []) then
303 ()
304 else
305 Slave.mkDirAll rld
306 end
307
308 | _ =>
309 (ignore (OS.Process.system (Config.cp
310 ^ " "
311 ^ #file fs
312 ^ " "
313 ^ realVhostFile));
314 if user <> oldUser then
315 let
316 val old = realLogDir oldUser
317 val rld = realLogDir user
318 in
319 if !logDeleted then
320 ()
321 else
322 (ignore (OS.Process.system (down ()));
323 logDeleted := true);
324 ignore (OS.Process.system (Config.rm
325 ^ " -rf "
326 ^ realLogDir oldUser));
327 if Posix.FileSys.access (rld, []) then
328 ()
329 else
330 Slave.mkDirAll rld
331 end
332 else
333 ())
334 end
335 end
336 else
337 ()
338 end)
339
340 val () = Slave.registerPostHandler
341 (fn () =>
342 (if !vhostsChanged then
343 Slave.shellF ([if !logDeleted then undown () else reload ()],
344 fn cl => "Error reloading Apache with " ^ cl)
345 else
346 ()))
347
348 val vhostFiles : (string * TextIO.outstream) list ref = ref []
349 fun write' s = app (fn (node, file) => TextIO.output (file, s node)) (!vhostFiles)
350 fun write s = app (fn (_, file) => TextIO.output (file, s)) (!vhostFiles)
351
352 val rewriteEnabled = ref false
353 val localRewriteEnabled = ref false
354 val currentVhost = ref ""
355 val currentVhostId = ref ""
356
357 val pre = ref (fn _ : {user : string, nodes : string list, id : string, hostname : string} => ())
358 fun registerPre f =
359 let
360 val old = !pre
361 in
362 pre := (fn x => (old x; f x))
363 end
364
365 val post = ref (fn () => ())
366 fun registerPost f =
367 let
368 val old = !post
369 in
370 post := (fn () => (old (); f ()))
371 end
372
373 val aliaser = ref (fn _ : string => ())
374 fun registerAliaser f =
375 let
376 val old = !aliaser
377 in
378 aliaser := (fn x => (old x; f x))
379 end
380
381 val () = Env.containerV_one "vhost"
382 ("host", Env.string)
383 (fn (env, host) =>
384 let
385 val nodes = Env.env (Env.list Env.string) (env, "WebNodes")
386
387 val ssl = Env.env ssl (env, "SSL")
388 val user = Env.env Env.string (env, "User")
389 val group = Env.env Env.string (env, "Group")
390 val docroot = Env.env Env.string (env, "DocumentRoot")
391 val sadmin = Env.env Env.string (env, "ServerAdmin")
392 val suexec = Env.env Env.bool (env, "SuExec")
393
394 val fullHost = host ^ "." ^ Domain.currentDomain ()
395 val vhostId = fullHost ^ (if Option.isSome ssl then ".ssl" else "")
396 val confFile = fullHost ^ (if Option.isSome ssl then ".vhost_ssl" else ".vhost")
397 in
398 currentVhost := fullHost;
399 currentVhostId := vhostId;
400
401 rewriteEnabled := false;
402 localRewriteEnabled := false;
403 vhostFiles := map (fn node =>
404 let
405 val file = Domain.domainFile {node = node,
406 name = confFile}
407 in
408 TextIO.output (file, "# Owner: ");
409 TextIO.output (file, user);
410 TextIO.output (file, "\n<VirtualHost ");
411 TextIO.output (file, Domain.nodeIp node);
412 TextIO.output (file, ":");
413 TextIO.output (file, case ssl of
414 SOME _ => "443"
415 | NONE => "80");
416 TextIO.output (file, ">\n");
417 TextIO.output (file, "\tErrorLog ");
418 TextIO.output (file, logDir {user = user, node = node, vhostId = vhostId});
419 TextIO.output (file, "/error.log\n\tCustomLog ");
420 TextIO.output (file, logDir {user = user, node = node, vhostId = vhostId});
421 TextIO.output (file, "/access.log combined\n");
422 TextIO.output (file, "\tServerName ");
423 TextIO.output (file, fullHost);
424 if suexec then
425 if isVersion1 node then
426 (TextIO.output (file, "\n\tUser ");
427 TextIO.output (file, user);
428 TextIO.output (file, "\n\tGroup ");
429 TextIO.output (file, group))
430 else
431 (TextIO.output (file, "\n\tSuexecUserGroup ");
432 TextIO.output (file, user);
433 TextIO.output (file, " ");
434 TextIO.output (file, group))
435 else
436 ();
437 if isWaklog node then
438 (TextIO.output (file, "\n\tWaklogProtected on\n\tWaklogPrincipal ");
439 TextIO.output (file, user);
440 TextIO.output (file, "/cgi@HCOOP.NET /etc/keytabs/cgi/");
441 TextIO.output (file, user))
442 else
443 ();
444 (logDir {user = user, node = node, vhostId = vhostId}, file)
445 end)
446 nodes;
447 write "\n\tDocumentRoot ";
448 write docroot;
449 write "\n\tServerAdmin ";
450 write sadmin;
451 case ssl of
452 SOME cert =>
453 (write "\n\tSSLEngine on\n\tSSLCertificateFile ";
454 write cert)
455 | NONE => ();
456 write "\n";
457 !pre {user = user, nodes = nodes, id = vhostId, hostname = fullHost}
458 end,
459 fn () => (!post ();
460 write "</VirtualHost>\n";
461 app (TextIO.closeOut o #2) (!vhostFiles)))
462
463 val inLocal = ref false
464
465 val () = Env.container_one "location"
466 ("prefix", Env.string)
467 (fn prefix =>
468 (write "\t<Location ";
469 write prefix;
470 write ">\n";
471 inLocal := true),
472 fn () => (write "\t</Location>\n";
473 inLocal := false;
474 localRewriteEnabled := false))
475
476 val () = Env.container_one "directory"
477 ("directory", Env.string)
478 (fn directory =>
479 (write "\t<Directory ";
480 write directory;
481 write ">\n";
482 inLocal := true),
483 fn () => (write "\t</Directory>\n";
484 inLocal := false;
485 localRewriteEnabled := false))
486
487 fun checkRewrite () =
488 if !inLocal then
489 if !rewriteEnabled orelse !localRewriteEnabled then
490 ()
491 else
492 (write "\tRewriteEngine on\n";
493 localRewriteEnabled := true)
494 else if !rewriteEnabled then
495 ()
496 else
497 (write "\tRewriteEngine on\n";
498 rewriteEnabled := true)
499
500 val () = Env.action_three "localProxyRewrite"
501 ("from", Env.string, "to", Env.string, "port", Env.int)
502 (fn (from, to, port) =>
503 (checkRewrite ();
504 write "\tRewriteRule\t";
505 write from;
506 write "\thttp://localhost:";
507 write (Int.toString port);
508 write "/";
509 write to;
510 write " [P]\n"))
511
512 val () = Env.action_two "proxyPass"
513 ("from", Env.string, "to", Env.string)
514 (fn (from, to) =>
515 (write "\tProxyPass\t";
516 write from;
517 write "\t";
518 write to;
519 write "\n"))
520
521 val () = Env.action_two "proxyPassReverse"
522 ("from", Env.string, "to", Env.string)
523 (fn (from, to) =>
524 (write "\tProxyPassReverse\t";
525 write from;
526 write "\t";
527 write to;
528 write "\n"))
529
530 val () = Env.action_three "rewriteRule"
531 ("from", Env.string, "to", Env.string, "flags", Env.list flag)
532 (fn (from, to, flags) =>
533 (checkRewrite ();
534 write "\tRewriteRule\t";
535 write from;
536 write "\t";
537 write to;
538 case flags of
539 [] => ()
540 | flag::rest => (write " [";
541 write flag;
542 app (fn flag => (write ",";
543 write flag)) rest;
544 write "]");
545 write "\n"))
546
547 val () = Env.action_three "rewriteCond"
548 ("test", Env.string, "pattern", Env.string, "flags", Env.list cond_flag)
549 (fn (from, to, flags) =>
550 (checkRewrite ();
551 write "\tRewriteCond\t";
552 write from;
553 write "\t";
554 write to;
555 case flags of
556 [] => ()
557 | flag::rest => (write " [";
558 write flag;
559 app (fn flag => (write ",";
560 write flag)) rest;
561 write "]");
562 write "\n"))
563
564 val () = Env.action_one "rewriteLogLevel"
565 ("level", Env.int)
566 (fn level =>
567 (checkRewrite ();
568 write "\tRewriteLog ";
569 write' (fn x => x);
570 write "/rewrite.log\n\tRewriteLogLevel ";
571 write (Int.toString level);
572 write "\n"))
573
574 val () = Env.action_two "alias"
575 ("from", Env.string, "to", Env.string)
576 (fn (from, to) =>
577 (write "\tAlias\t";
578 write from;
579 write " ";
580 write to;
581 write "\n"))
582
583 val () = Env.action_two "scriptAlias"
584 ("from", Env.string, "to", Env.string)
585 (fn (from, to) =>
586 (write "\tScriptAlias\t";
587 write from;
588 write " ";
589 write to;
590 write "\n"))
591
592 val () = Env.action_two "errorDocument"
593 ("code", Env.string, "handler", Env.string)
594 (fn (code, handler) =>
595 (write "\tErrorDocument\t";
596 write code;
597 write " ";
598 write handler;
599 write "\n"))
600
601 val () = Env.action_one "options"
602 ("options", Env.list apache_option)
603 (fn opts =>
604 case opts of
605 [] => ()
606 | _ => (write "\tOptions";
607 app (fn opt => (write " "; write opt)) opts;
608 write "\n"))
609
610 val () = Env.action_one "set_options"
611 ("options", Env.list apache_option)
612 (fn opts =>
613 case opts of
614 [] => ()
615 | _ => (write "\tOptions";
616 app (fn opt => (write " +"; write opt)) opts;
617 write "\n"))
618
619 val () = Env.action_one "unset_options"
620 ("options", Env.list apache_option)
621 (fn opts =>
622 case opts of
623 [] => ()
624 | _ => (write "\tOptions";
625 app (fn opt => (write " -"; write opt)) opts;
626 write "\n"))
627
628 val () = Env.action_one "directoryIndex"
629 ("filenames", Env.list Env.string)
630 (fn opts =>
631 (write "\tDirectoryIndex";
632 app (fn opt => (write " "; write opt)) opts;
633 write "\n"))
634
635 val () = Env.action_one "serverAlias"
636 ("host", Env.string)
637 (fn host =>
638 (write "\tServerAlias ";
639 write host;
640 write "\n";
641 !aliaser host))
642
643 val authType = fn (EVar "basic", _) => SOME "basic"
644 | (EVar "digest", _) => SOME "digest"
645 | _ => NONE
646
647 val () = Env.action_one "authType"
648 ("type", authType)
649 (fn ty =>
650 (write "\tAuthType ";
651 write ty;
652 write "\n"))
653
654 val () = Env.action_one "authName"
655 ("name", Env.string)
656 (fn name =>
657 (write "\tAuthName \"";
658 write name;
659 write "\"\n"))
660
661 val () = Env.action_one "authUserFile"
662 ("file", Env.string)
663 (fn name =>
664 (write "\tAuthUserFile ";
665 write name;
666 write "\n"))
667
668 val () = Env.action_none "requireValidUser"
669 (fn () => write "\tRequire valid-user\n")
670
671 val () = Env.action_one "requireUser"
672 ("users", Env.list Env.string)
673 (fn names =>
674 case names of
675 [] => ()
676 | _ => (write "\tRequire user";
677 app (fn name => (write " "; write name)) names;
678 write "\n"))
679
680 val () = Env.action_one "requireGroup"
681 ("groups", Env.list Env.string)
682 (fn names =>
683 case names of
684 [] => ()
685 | _ => (write "\tRequire group";
686 app (fn name => (write " "; write name)) names;
687 write "\n"))
688
689 val () = Env.action_none "orderAllowDeny"
690 (fn () => write "\tOrder allow,deny\n")
691
692 val () = Env.action_none "orderDenyAllow"
693 (fn () => write "\tOrder deny,allow\n")
694
695 val () = Env.action_none "allowFromAll"
696 (fn () => write "\tAllow from all\n")
697
698 val () = Env.action_one "allowFrom"
699 ("entries", Env.list Env.string)
700 (fn names =>
701 case names of
702 [] => ()
703 | _ => (write "\tAllow from";
704 app (fn name => (write " "; write name)) names;
705 write "\n"))
706
707 val () = Env.action_none "denyFromAll"
708 (fn () => write "\tDeny from all\n")
709
710 val () = Env.action_one "denyFrom"
711 ("entries", Env.list Env.string)
712 (fn names =>
713 case names of
714 [] => ()
715 | _ => (write "\tDeny from";
716 app (fn name => (write " "; write name)) names;
717 write "\n"))
718
719 val () = Env.action_none "satisfyAll"
720 (fn () => write "\tSatisfy all\n")
721
722 val () = Env.action_none "satisfyAny"
723 (fn () => write "\tSatisfy any\n")
724
725 val () = Env.action_one "forceType"
726 ("type", Env.string)
727 (fn ty => (write "\tForceType ";
728 write ty;
729 write "\n"))
730
731 val () = Env.action_none "forceTypeOff"
732 (fn () => write "\tForceType None\n")
733
734 val () = Env.action_two "action"
735 ("what", Env.string, "how", Env.string)
736 (fn (what, how) => (write "\tAction ";
737 write what;
738 write " ";
739 write how;
740 write "\n"))
741
742 val () = Env.action_one "addDefaultCharset"
743 ("charset", Env.string)
744 (fn ty => (write "\tAddDefaultCharset ";
745 write ty;
746 write "\n"))
747
748 (*val () = Env.action_one "davSvn"
749 ("path", Env.string)
750 (fn path => (write "\tDAV svn\n\tSVNPath ";
751 write path;
752 write "\n"))
753
754 val () = Env.action_one "authzSvnAccessFile"
755 ("path", Env.string)
756 (fn path => (write "\tAuthzSVNAccessFile ";
757 write path;
758 write "\n"))*)
759
760 val () = Env.action_two "addDescription"
761 ("description", Env.string, "patterns", Env.list Env.string)
762 (fn (desc, pats) =>
763 case pats of
764 [] => ()
765 | _ => (write "\tAddDescription \"";
766 write (String.toString desc);
767 write "\"";
768 app (fn pat => (write " "; write pat)) pats;
769 write "\n"))
770
771 val () = Env.action_one "indexOptions"
772 ("options", Env.list autoindex_option)
773 (fn opts =>
774 case opts of
775 [] => ()
776 | _ => (write "\tIndexOptions";
777 app (fn (opt, arg) =>
778 (write " ";
779 write opt;
780 Option.app (fn arg =>
781 (write "="; write arg)) arg)) opts;
782 write "\n"))
783
784 val () = Env.action_one "set_indexOptions"
785 ("options", Env.list autoindex_option)
786 (fn opts =>
787 case opts of
788 [] => ()
789 | _ => (write "\tIndexOptions";
790 app (fn (opt, arg) =>
791 (write " +";
792 write opt;
793 Option.app (fn arg =>
794 (write "="; write arg)) arg)) opts;
795 write "\n"))
796
797 val () = Env.action_one "unset_indexOptions"
798 ("options", Env.list autoindex_option)
799 (fn opts =>
800 case opts of
801 [] => ()
802 | _ => (write "\tIndexOptions";
803 app (fn (opt, _) =>
804 (write " -";
805 write opt)) opts;
806 write "\n"))
807
808 val () = Env.action_one "headerName"
809 ("name", Env.string)
810 (fn name => (write "\tHeaderName ";
811 write name;
812 write "\n"))
813
814 val () = Env.action_one "readmeName"
815 ("name", Env.string)
816 (fn name => (write "\tReadmeName ";
817 write name;
818 write "\n"))
819
820 val () = Domain.registerResetLocal (fn () =>
821 ignore (OS.Process.system (Config.rm ^ " -rf /var/domtool/vhosts/*")))
822
823 end