src/domtool.grm

   1 (* HCoop Domtool (http://hcoop.sourceforge.net/)
   2  * Copyright (c) 2006, Adam Chlipala
   3  *
   4  * This program is free software; you can redistribute it and/or
   5  * modify it under the terms of the GNU General Public License
   6  * as published by the Free Software Foundation; either version 2
   7  * of the License, or (at your option) any later version.
   8  *
   9  * This program is distributed in the hope that it will be useful,
  10  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  11  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  12  * GNU General Public License for more details.
  13  *
  14  * You should have received a copy of the GNU General Public License
  15  * along with this program; if not, write to the Free Software
  16  * Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301, USA.
  17  *)
  18
  19 (* Parser for Domtool configuration files *)
  20
  21 open Ast
  22
  23 %%
  24 %header (functor DomtoolLrValsFn(structure Token : TOKEN))
  25
  26 %term
  27    EOF
  28  | SYMBOL of string | CSYMBOL of string
  29  | STRING of string | DOC of string
  30  | INT of int
  31  | ARROW | DARROW | LARROW
  32  | COLON | CARET | BANG | AND
  33  | LPAREN | RPAREN | LBRACK | RBRACK | LBRACE | RBRACE
  34  | EQ | COMMA | BSLASH | BSLASHBSLASH | SEMI | LET | IN | BEGIN | END
  35  | IF | THEN | ELSE
  36  | ROOT | SKIP
  37  | EXTERN | TYPE | VAL | WITH | WHERE | CONTEXT
  38
  39 %nonterm
  40    file of file
  41  | decls of decl list
  42  | decl of decl
  43  | decl' of decl'
  44  | docOpt of string option
  45  | expOpt of exp option
  46  | exp of exp
  47  | apps of exp
  48  | term of exp
  49  | sets of exp list
  50  | elist of exp list
  51  | elistNe of exp list
  52  | clist of exp list
  53  | typ of typ
  54  | ctxt of pred
  55  | recd of record
  56  | recdNe of record
  57  | SEMIopt of unit
  58
  59 %verbose                                (* print summary of errors *)
  60 %pos int                                (* positions *)
  61 %start file
  62 %pure
  63 %eop EOF
  64 %noshift EOF
  65
  66 %name Domtool
  67
  68 %nonassoc THEN ELSE
  69 %right SEMI
  70 %nonassoc COLON
  71 %nonassoc IN
  72 %right ARROW DARROW
  73 %right COMMA
  74 %nonassoc EQ
  75 %right WITH
  76 %right WHERE
  77 %right AND
  78 %nonassoc CARET BANG
  79
  80 %%
  81
  82 file   : docOpt decls expOpt               (docOpt, decls, expOpt)
  83
  84 decls  :                                   ([])
  85        | decl decls                        (decl :: decls)
  86
  87 decl   : decl' SEMI docOpt                 (decl', docOpt, (decl'left, docOptright))
  88
  89 decl'  : EXTERN TYPE SYMBOL                (DExternType SYMBOL)
  90        | EXTERN VAL SYMBOL COLON typ       (DExternVal (SYMBOL, typ))
  91        | VAL SYMBOL EQ exp                 (DVal (SYMBOL, NONE, exp))
  92        | VAL SYMBOL COLON typ EQ exp       (DVal (SYMBOL, SOME typ, exp))
  93        | CONTEXT CSYMBOL                   (DContext CSYMBOL)
  94
  95 docOpt :                                   (NONE)
  96        | DOC                               (SOME DOC)
  97
  98 expOpt :                                   (NONE)
  99        | exp                               (SOME exp)
 100
 101
 102 exp    : apps                              (apps)
 103        | apps WHERE sets END               (ELocal ((ESeq sets, (setsleft, setsright)), apps),
 104                                             (appsleft, ENDright))
 105        | apps WITH END                     (EWith (apps, (ESkip, (WITHleft, ENDright))),
 106                                             (appsleft, ENDright))
 107        | apps WITH exp END                 (EWith (apps, exp), (appsleft, ENDright))
 108        | apps WHERE sets WITH END          (ELocal ((ESeq sets, (setsleft, setsright)),
 109                                                     (EWith (apps, (ESkip, (WITHleft, ENDright))),
 110                                                      (appsleft, ENDright))),
 111                                             (appsleft, ENDright))
 112        | apps WHERE sets WITH exp END      (ELocal ((ESeq sets, (setsleft, setsright)),
 113                                                     (EWith (apps, exp), (appsleft, ENDright))),
 114                                             (appsleft, ENDright))
 115
 116        | BSLASH SYMBOL COLON LPAREN typ RPAREN ARROW exp (ELam (SYMBOL, SOME typ, exp),
 117                                                           (BSLASHleft, expright))
 118        | BSLASH SYMBOL ARROW exp           (ELam (SYMBOL, NONE, exp), (BSLASHleft, expright))
 119        | BSLASHBSLASH SYMBOL COLON ctxt ARROW exp (EALam (SYMBOL, ctxt, exp),
 120                                                           (BSLASHBSLASHleft, expright))
 121        | CSYMBOL EQ exp                    (ESet (CSYMBOL, exp), (CSYMBOLleft, expright))
 122        | exp SEMI exp                      (let
 123                                                 val ls = case #1 exp2 of
 124                                                              ESeq ls => exp :: ls
 125                                                            | _ => [exp1, exp2]
 126                                             in
 127                                                 (ESeq ls, (exp1left, exp2right))
 128                                             end)
 129        | exp SEMI                          (exp)
 130        | SYMBOL LARROW CSYMBOL SEMI exp    (EGet (SYMBOL, NONE, CSYMBOL, exp), (SYMBOLleft, expright))
 131        | SYMBOL COLON typ LARROW CSYMBOL SEMI exp (EGet (SYMBOL, SOME typ, CSYMBOL, exp), (SYMBOLleft, expright))
 132        | IF exp THEN exp ELSE exp END      (EIf (exp1, exp2, exp3), (IFleft, ENDright))
 133
 134 apps   : term                              (term)
 135        | apps term                         (EApp (apps, term), (appsleft, termright))
 136
 137 term   : LPAREN exp RPAREN                 (exp)
 138        | BEGIN exp END                     (exp)
 139        | INT                               (EInt INT, (INTleft, INTright))
 140        | STRING                            (EString STRING, (STRINGleft, STRINGright))
 141        | LBRACK elist RBRACK               (EList elist, (LBRACKleft, RBRACKright))
 142        | LET exp IN exp END                (ELocal (exp1, exp2), (LETleft, ENDright))
 143        | SYMBOL                            (EVar SYMBOL, (SYMBOLleft, SYMBOLright))
 144        | SKIP                              (ESkip, (SKIPleft, SKIPright))
 145
 146 sets   : CSYMBOL EQ apps SEMIopt           ([(ESet (CSYMBOL, apps), (CSYMBOLleft, appsright))])
 147        | CSYMBOL EQ apps SEMI sets         ((ESet (CSYMBOL, apps), (CSYMBOLleft, appsright))
 148                                             :: sets)
 149
 150 SEMIopt: SEMI                              ()
 151        |                                   ()
 152
 153 elist  :                                   ([])
 154        | elistNe                           (elistNe)
 155
 156 elistNe: exp                               ([exp])
 157        | exp COMMA elistNe                 (exp :: elistNe)
 158
 159 typ    : SYMBOL                            (TBase SYMBOL, (SYMBOLleft, SYMBOLright))
 160        | LBRACK typ RBRACK                 (TList typ, (LBRACKleft, RBRACKright))
 161        | typ ARROW typ                     (TArrow (typ1, typ2), (typleft, typright))
 162        | LBRACK ctxt RBRACK recd DARROW recd (TAction (ctxt, recd1, recd2), (LBRACKleft, recd2right))
 163        | LBRACK ctxt RBRACK recd           (TAction (ctxt, recd, StringMap.empty),
 164                                             (LBRACKleft, recdright))
 165        | LBRACK ctxt RBRACK                (TAction (ctxt, StringMap.empty, StringMap.empty),
 166                                             (LBRACKleft, ctxtright))
 167        | LPAREN typ RPAREN                 (typ)
 168        | ctxt DARROW typ                   (TNested (ctxt, typ), (ctxtleft, typright))
 169
 170 recd   : LBRACE RBRACE                     (StringMap.empty)
 171        | LBRACE recdNe RBRACE              (recdNe)
 172
 173 recdNe : CSYMBOL COLON typ                 (StringMap.insert (StringMap.empty, CSYMBOL, typ))
 174        | CSYMBOL COLON typ COMMA recdNe    (StringMap.insert (recdNe, CSYMBOL, typ))
 175
 176 ctxt   : ROOT                              (CRoot, (ROOTleft, ROOTright))
 177        | CSYMBOL                           (CConst CSYMBOL, (CSYMBOLleft, CSYMBOLright))
 178        | CARET ctxt                        (CPrefix ctxt, (CARETleft, ctxtright))
 179        | BANG ctxt                         (CNot ctxt, (BANGleft, ctxtright))
 180        | ctxt AND ctxt                     (CAnd (ctxt1, ctxt2), (ctxt1left, ctxt2right))
 181        | LPAREN ctxt RPAREN                (ctxt)