Parsing has never been this much fun

[hcoop/domtool2.git] / src / ast.sml

(* HCoop Domtool (http://hcoop.sourceforge.net/)
 * Copyright (c) 2006, Adam Chlipala
 *
 * This program is free software; you can redistribute it and/or
 * modify it under the terms of the GNU General Public License
 * as published by the Free Software Foundation; either version 2
 * of the License, or (at your option) any later version.
 *
 * This program is distributed in the hope that it will be useful,
 * but WITHOUT ANY WARRANTY; without even the implied warranty of
 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 * GNU General Public License for more details.
 *
 * You should have received a copy of the GNU General Public License
 * along with this program; if not, write to the Free Software
 * Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301, USA.
*)

(* Configuration language abstract syntax *)

structure Ast = struct

open DataStructures

(* A description of a predicate on configuration block stacks *)
datatype context' =
	 CRoot
       (* The stack is empty. *)
       | CConst of string
       (* The given context name is on top of the stack. *)
       | CPrefix of context
       (* Some prefix of the stack matches the context. *)
       | CNot of context
       (* The context does not match. *)
       | CAnd of context * context
       (* Both contexts match. *)
withtype context = context' * position

datatype typ' =
	 TBase of string
       (* Base type *)
       | TList of typ
       (* SML 'a list *)
       | TArrow of typ * typ
       (* SML -> *)
       | TAction of context * record * record
       (* An action that:
	*  - Is valid in the given context
	*  - Expects an environment compatible with the first record
	*  - Modifies it according to the second record *)
withtype typ = typ' * position
     and record = typ StringMap.map

datatype exp' =
	 EInt of int
       (* Constant integer *)
       | EString of string
       (* Constant string *)
       | EList of exp list
       (* Basic list constructor *)

       | ELam of string * typ * exp
       (* Function abstraction *)
       | EVar of string
       (* Variable bound by a function *)
       | EApp of exp * exp
       (* Function application *)

       | ESet of string * exp
       (* Set an environment variable *)
       | EEnv of string
       (* Get an environment variable *)
       | ESeq of exp list
       (* Monad sequencer; execute a number of commands in order *)
       | ELocal of exp
       (* Local execution; execute the action and then restore the previous
	* environment. *)
withtype exp = exp' * position


end