Evaluating a test with automatic inclusion of basis

[hcoop/domtool2.git] / src / domain.sml

(* HCoop Domtool (http://hcoop.sourceforge.net/)
 * Copyright (c) 2006, Adam Chlipala
 *
 * This program is free software; you can redistribute it and/or
 * modify it under the terms of the GNU General Public License
 * as published by the Free Software Foundation; either version 2
 * of the License, or (at your option) any later version.
 *
 * This program is distributed in the hope that it will be useful,
 * but WITHOUT ANY WARRANTY; without even the implied warranty of
 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 * GNU General Public License for more details.
 *
 * You should have received a copy of the GNU General Public License
 * along with this program; if not, write to the Free Software
 * Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301, USA.
 *)

(* Domain-related primitive actions *)

structure Domain :> DOMAIN = struct

fun isIdent ch = Char.isLower ch orelse Char.isDigit ch

fun validHost s =
    size s > 0 andalso size s < 20
    andalso CharVector.all (fn ch => isIdent ch orelse ch = #"-") s

fun validDomain s =
    size s > 0 andalso size s < 100
    andalso List.all validHost (String.fields (fn ch => ch = #".") s)

val _ = Env.type_one "host"
	Env.string
	validHost

val _ = Env.type_one "domain"
	Env.string
	validDomain

open Ast

val befores = ref (fn (_ : string) => ())
val afters = ref (fn (_ : string) => ())

fun registerBefore f =
    let
	val old = !befores
    in
	befores := (fn x => (old x; f x))
    end

fun registerAfter f =
    let
	val old = !afters
    in
	afters := (fn x => (old x; f x))
    end

val current = ref ""
val currentPath = ref ""

fun currentDomain () = !current

fun domainFile name = TextIO.openOut (!currentPath ^ name)

fun getPath domain =
    let
	val toks = String.fields (fn ch => ch = #".") domain

	val elems = foldr (fn (piece, elems) =>
			      let
				  val elems = piece :: elems
				  val path = String.concatWith "/" (Config.resultRoot :: rev elems)
			      in
				  (if Posix.FileSys.ST.isDir
					  (Posix.FileSys.stat path) then
				       ()
				   else
				       (OS.FileSys.remove path;
					OS.FileSys.mkDir path))
				  handle OS.SysErr _ => OS.FileSys.mkDir path;
				  elems
			      end) [] toks
    in
	String.concatWith "/" (Config.resultRoot :: rev ("" :: elems))
    end

val _ = Env.container_one "domain"
			  ("domain", Env.string)
			  (fn dom => (current := dom;
				      currentPath := getPath dom;
				      !befores dom),
			   fn () => !afters (!current))

end