Server executing client's requested configuration with the right permissions

[hcoop/domtool2.git] / src / main.sml

(* HCoop Domtool (http://hcoop.sourceforge.net/)
 * Copyright (c) 2006, Adam Chlipala
 *
 * This program is free software; you can redistribute it and/or
 * modify it under the terms of the GNU General Public License
 * as published by the Free Software Foundation; either version 2
 * of the License, or (at your option) any later version.
 *
 * This program is distributed in the hope that it will be useful,
 * but WITHOUT ANY WARRANTY; without even the implied warranty of
 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 * GNU General Public License for more details.
 *
 * You should have received a copy of the GNU General Public License
 * along with this program; if not, write to the Free Software
 * Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301, USA.
 *)

(* Main interface *)

structure Main :> MAIN = struct

open Ast Print

structure SM = StringMap

fun init () = Acl.read Config.aclFile
	    
fun check' G fname =
    let
	val prog = Parse.parse fname
    in
	if !ErrorMsg.anyErrors then
	    G
	else
	    Tycheck.checkFile G (Defaults.tInit ()) prog
    end

fun basis () =
    let
	val dir = Posix.FileSys.opendir Config.libRoot

	fun loop files =
	    case Posix.FileSys.readdir dir of
		NONE => (Posix.FileSys.closedir dir;
			 files)
	      | SOME fname =>
		if String.isSuffix ".dtl" fname then
		    loop (OS.Path.joinDirFile {dir = Config.libRoot,
					       file = fname}
			  :: files)
		else
		    loop files

	val files = loop []
	val files = Order.order files
    in
	if !ErrorMsg.anyErrors then
	    Env.empty
	else
	    foldl (fn (fname, G) => check' G fname) Env.empty files
    end

fun check fname =
    let
	val _ = ErrorMsg.reset ()
	val _ = Env.preTycheck ()

	val b = basis ()
    in
	if !ErrorMsg.anyErrors then
	    (b, NONE)
	else
	    let
		val _ = ErrorMsg.reset ()
		val prog = Parse.parse fname
	    in
		if !ErrorMsg.anyErrors then
		    (Env.empty, NONE)
		else
		    let
			val G' = Tycheck.checkFile b (Defaults.tInit ()) prog
		    in
			(G', #3 prog)
		    end
	    end
    end

fun reduce fname =
    let
	val (G, body) = check fname
    in
	if !ErrorMsg.anyErrors then
	    NONE
	else
	    case body of
		SOME body =>
		let
		    val body' = Reduce.reduceExp G body
		in
		    (*printd (PD.hovBox (PD.PPS.Rel 0,
					 [PD.string "Result:",
					  PD.space 1,
					  p_exp body']))*)
		    SOME body'
		end
	      | _ => NONE
    end

fun eval fname =
    case reduce fname of
	(SOME body') =>
	if !ErrorMsg.anyErrors then
	    ()
	else
	    Eval.exec (Defaults.eInit ()) body'
      | NONE => ()

val dispatcher =
    Config.dispatcher ^ ":" ^ Int.toString Config.dispatcherPort

fun request fname =
    let
	val uid = Posix.ProcEnv.getuid ()
	val user = Posix.SysDB.Passwd.name (Posix.SysDB.getpwuid uid)

	val () = Acl.read Config.aclFile
	val () = Domain.setUser user
	val _ = check fname

	val context = OpenSSL.context (Config.certDir ^ "/" ^ user ^ ".pem",
				       Config.keyDir ^ "/" ^ user ^ ".pem",
				       Config.trustStore)

	val bio = OpenSSL.connect (context, dispatcher)

	val inf = TextIO.openIn fname

	fun loop () =
	    case TextIO.inputLine inf of
		NONE => ()
	      | SOME line => (OpenSSL.writeAll (bio, line);
			      loop ())
    in
	loop ();
	TextIO.closeIn inf;
	OpenSSL.close bio
    end
    handle ErrorMsg.Error => ()

fun service () =
    let
	val () = Acl.read Config.aclFile
	
	val context = OpenSSL.context (Config.serverCert,
				       Config.serverKey,
				       Config.trustStore)

	val sock = OpenSSL.listen (context, Config.dispatcherPort)

	fun loop () =
	    case OpenSSL.accept sock of
		NONE => ()
	      | SOME bio =>
		let
		    val user = OpenSSL.peerCN bio
		    val () = print ("\nConnection from " ^ user ^ "\n")
		    val () = Domain.setUser user

		    val outname = OS.FileSys.tmpName ()
		    val outf = TextIO.openOut outname

		    fun loop' () =
			case OpenSSL.readOne bio of
			    NONE => ()
			  | SOME line => (TextIO.output (outf, line);
					  loop' ())
		in
		    (loop' ();
		     TextIO.closeOut outf;
		     eval outname
		     handle ErrorMsg.Error => ();
		     OS.FileSys.remove outname;
		     OpenSSL.close bio)
		    handle OpenSSL.OpenSSL _ => ();
		    loop ()
		end
    in
	loop ();
	OpenSSL.shutdown sock
    end

end