create files domtool needs to modify as domtool

[hcoop/domtool2.git] / lib / web_apps.dtl

{{Configuring common web applications}}

val addWordPress = \ loc : (location) ->
  location loc with
    rewriteRule "^(.*/)?\.svn/" "-" [forbidden, last];
    rewriteRule "^(.*/)?\.git/" "-" [forbidden, last];

    rewriteCond "%{REQUEST_FILENAME}" "!-f" [];
    rewriteCond "%{REQUEST_FILENAME}" "!-d" [];

    rewriteRule "." "/index.php" [last];
  end;
{{Add a standard WordPress blog set-up code to a virtual host.  The WordPress
  files should be rooted at the location you specify.}}

val wordPress = \ host : (host) -> \\ config : Vhost ->
  web host with
    addWordPress "/";
    diskCache "/wp-content";
    config
  end;
{{Create a WordPress blog with just the standard set-up code.  The WordPress blog should
  be rooted at the vhost's <tt>DocumentRoot</tt>.}}

val moin_default_htdocs : (location) = "/moin_static199";
{{Alias for static content used by the system-wide MoinMoin.}}

val addMoinMoin = begin
  htdocs <- Htdocs;
  prefix <- Prefix;
  script <- Script;

  alias htdocs "/afs/hcoop.net/common/app/moin/installed/moin19/lib/python2.7/site-packages/MoinMoin/web/static/htdocs";
  (*diskCache htdocs;*) (* disabled 2017-02-01 clinton : don't think this helps after all *)
  scriptAlias prefix (end_in_slash script);
end;
{{Add a MoinMoin wiki to a vhost.}}

val moinMoin = \ host : (host) -> \\ config : Vhost ->
  web host with
    addMoinMoin where
      Htdocs = moin_default_htdocs;
      Prefix = "/"
    end;
    config
  end;
{{Create a new vhost with just a MoinMoin wiki.}}

(* Legacy version of moin macros *)

val addMoinMoinOld = begin
  htdocs <- Htdocs;
  prefix <- Prefix;
  script <- Script;

  alias htdocs "/usr/share/moin/htdocs";
  scriptAlias prefix (end_in_slash script)
end;
{{Add a MoinMoin wiki to a vhost.}}