src/cf/solaris-mapaddr.m4

   1 dnl This checks if the map_addr() function lacks the 'vacalign' argument. It
   2 dnl was removed some time around Solaris 11.4.
   3 dnl
   4 dnl Note that the map_addr() function has had arguments added in the past
   5 dnl (before Solaris 10). This check then only makes sense for newer Solaris;
   6 dnl don't rely on it for pre-10 Solaris releases.
   7 dnl
   8 AC_DEFUN([SOLARIS_MAPADDR_LACKS_VACALIGN],
   9  [AC_CACHE_CHECK([for a map_addr without vacalign],
  10    [ac_cv_solaris_mapaddr_lacks_vacalign],
  11    [AC_COMPILE_IFELSE(
  12      [AC_LANG_PROGRAM(
  13        [[#define _KERNEL
  14          #include <sys/vmsystm.h>]],
  15        [[caddr_t *addrp;
  16          size_t len;
  17          offset_t off;
  18          uint_t flags;
  19          map_addr(addrp, len, off, flags);]])],
  20      [ac_cv_solaris_mapaddr_lacks_vacalign=yes],
  21      [ac_cv_solaris_mapaddr_lacks_vacalign=no])])
  22
  23   AS_IF([test "x$ac_cv_solaris_mapaddr_lacks_vacalign" = "xyes"],
  24         [AC_DEFINE([MAPADDR_LACKS_VACALIGN], [1],
  25                    [define if the function map_addr lacks the vacalign argument])])])