src/cf/socket.m4

   1 AC_DEFUN([OPENAFS_SOCKET_CHECKS],[
   2 AC_CACHE_CHECK([if struct sockaddr has sa_len field],
   3     [ac_cv_sockaddr_len],
   4     [AC_COMPILE_IFELSE(
   5       [AC_LANG_PROGRAM(
   6         [[#include <sys/types.h>
   7           #include <sys/socket.h>]],
   8         [[struct sockaddr *a; a->sa_len=0;]])],
   9       [ac_cv_sockaddr_len=yes],
  10       [ac_cv_sockaddr_len=no])
  11 ])
  12 AS_IF([test "$ac_cv_sockaddr_len" = "yes"],
  13       [AC_DEFINE(STRUCT_SOCKADDR_HAS_SA_LEN, 1,
  14                  [define if you struct sockaddr sa_len])])
  15 ])
  16
  17 AC_DEFUN([OPENAFS_SOCKOPT_CHECK],[
  18 AC_CACHE_CHECK([for setsockopt(, SOL_IP, IP_RECVERR)],
  19     [ac_cv_setsockopt_iprecverr],
  20     [AC_COMPILE_IFELSE(
  21       [AC_LANG_PROGRAM(
  22         [[#include <sys/types.h>
  23           #include <sys/socket.h>
  24           #include <netinet/in.h>]],
  25         [[int on=1;
  26           setsockopt(0, SOL_IP, IP_RECVERR, &on, sizeof(on));]])],
  27       [ac_cv_setsockopt_iprecverr=yes],
  28       [ac_cv_setsockopt_iprecverr=no])])
  29
  30 AS_IF([test "$ac_cv_setsockopt_iprecverr" = "yes"],
  31       [AC_DEFINE([HAVE_SETSOCKOPT_IP_RECVERR], [1],
  32                  [define if we can receive socket errors via IP_RECVERR])])
  33 ])