random128/configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl $Id: configure.in,v 1.14 2008/11/27 20:33:44 mrsam Exp $
   3 dnl
   4 dnl Copyright 1998 - 2002 Double Precision, Inc.  See COPYING for
   5 dnl distribution information.
   6
   7 AC_INIT(random128, 0.10, [courier-users@lists.sourceforge.net])
   8
   9 >confdefs.h  # Kill PACKAGE_ macros
  10
  11 AC_CONFIG_SRCDIR(random128.c)
  12 AM_INIT_AUTOMAKE([foreign no-define])
  13 LPATH="$PATH:/usr/local/bin"
  14
  15
  16 dnl Checks for programs.
  17 AM_CONFIG_HEADER(config.h)
  18 AC_USE_SYSTEM_EXTENSIONS
  19 AC_PROG_INSTALL
  20 AC_PROG_LN_S
  21 AC_PROG_CC
  22 AC_PATH_PROGS(PS, ps, ps, $LPATH)
  23 AC_PATH_PROGS(W, w, w, $LPATH)
  24 AC_PROG_LIBTOOL
  25
  26 if test "$PS" = "ps"
  27 then
  28         AC_MSG_ERROR(Cannot find pathname to ps)
  29 fi
  30
  31 if test x$GXX = xyes
  32 then
  33         CFLAGS="-Wall $CFLAGS"
  34 fi
  35
  36 CFLAGS="-I.. -I$srcdir/.. $CFLAGS"
  37
  38 dnl Checks for libraries.
  39
  40 dnl Checks for header files.
  41 AC_HEADER_SYS_WAIT
  42 AC_CHECK_HEADERS(unistd.h fcntl.h)
  43
  44 AC_TYPE_PID_T
  45
  46 AC_ARG_WITH(random, [ --with-random=/dev/urandom - location of the system random file generator
  47 --without-random            - there is no system random file generator ],
  48         random="$withval",
  49         random="y")
  50
  51 case "$random" in
  52 /*)
  53         ;;
  54 y*|1*)
  55         AC_CACHE_CHECK([for random source],random_cv_RANDOM,
  56
  57                 if test -c /dev/urandom
  58                 then
  59                         random_cv_RANDOM=/dev/urandom
  60                 else
  61                         if test -c /dev/random
  62                         then
  63                                 random_cv_RANDOM=/dev/random
  64                         else
  65                                 random_cv_RANDOM="none"
  66                         fi
  67                 fi
  68         )
  69         random="$random_cv_RANDOM"
  70         ;;
  71 *)
  72         random="none"
  73         ;;
  74 esac
  75
  76 if test "$random" != "none"
  77 then
  78         AC_DEFINE_UNQUOTED(RANDOM, "$random", [ Entropy source ])
  79 fi
  80
  81 AC_CACHE_CHECK([for some good options for ps],random_cv_PS_OPTIONS,
  82
  83         for opts in -Afl -Afw -Af -Al -afl -afw -af -al Afl Afw Af Al afl afw af al
  84         do
  85                 ps $opts >/dev/null 2>/dev/null || continue
  86                 break
  87         done
  88         random_cv_PS_OPTIONS="$opts"
  89 )
  90
  91 AC_DEFINE_UNQUOTED(PS_OPTIONS,"$random_cv_PS_OPTIONS",
  92         [ How to make ps(1) spit out lots of crap ])
  93 AC_DEFINE_UNQUOTED(PS,"$PS", [ The PS program ])
  94
  95 if test "$W" != "w"
  96 then
  97         AC_DEFINE_UNQUOTED(W, "$w", [ The W program ])
  98 fi
  99
 100 AC_OUTPUT(Makefile)