bdbobj/configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl $Id: configure.in,v 1.16 2008/11/27 20:33:44 mrsam Exp $
   3 dnl
   4 dnl Copyright 1998 - 1999 Double Precision, Inc.  See COPYING for
   5 dnl distribution information.
   6
   7 AC_INIT(bdbobj, 0.10, [courier-users@lists.sourceforge.net])
   8
   9 >confdefs.h  # Kill PACKAGE_ macros
  10
  11 AC_CONFIG_SRCDIR(bdbobj.h)
  12 AM_INIT_AUTOMAKE([foreign no-define])
  13 AM_CONFIG_HEADER(config.h)
  14
  15 dnl Checks for programs.
  16 AC_USE_SYSTEM_EXTENSIONS
  17 AC_PROG_CC
  18 AC_PROG_AWK
  19 AC_PROG_CXX
  20 AC_ISC_POSIX
  21 AC_PROG_LIBTOOL
  22
  23 dnl Checks for libraries.
  24
  25 saveLIBS="$LIBS"
  26 AC_CHECK_LIB(db, dbopen, [ LIBDB=-ldb ; LIBS="-ldb $LIBS" ],
  27         AC_CHECK_LIB(db, db_open, [ LIBDB=-ldb ; LIBS="-ldb $LIBS"],
  28         AC_CHECK_LIB(db, db_env_create, [ LIBDB=-ldb; LIBS="-ldb $LIBS"])
  29         ))
  30
  31 FOUND_DB=0
  32 AC_CHECK_FUNC(dbopen, FOUND_DB=1)
  33 AC_CHECK_FUNC(db_open, FOUND_DB=1)
  34 AC_CHECK_FUNC(db_env_create, FOUND_DB=1)
  35
  36 LIBS="$saveLIBS"
  37
  38 AC_SUBST(LIBDB)
  39
  40 AM_CONDITIONAL(FOUND_DB, test "$FOUND_DB" != 0)
  41
  42 dnl Checks for header files.
  43
  44 AC_CHECK_HEADERS(limits.h fcntl.h unistd.h)
  45
  46 dnl Checks for typedefs, structures, and compiler characteristics.
  47 AC_C_CONST
  48 AC_TYPE_SIZE_T
  49
  50 AC_LANG_CPLUSPLUS
  51 AC_CACHE_CHECK([if the C++ compiler needs -fhandle-exceptions],
  52         ac_cv_need_handlexceptions,
  53
  54 AC_TRY_COMPILE([],
  55 [
  56 throw;
  57 ], ac_cv_need_handlexceptions=no,
  58 ac_cv_need_handlexceptions=yes)
  59 )
  60
  61 if test "$ac_cv_need_handlexceptions" = "yes"
  62 then
  63         case "$CXXFLAGS" in
  64         *handle-exceptions*)
  65                 ;;
  66         *)
  67                 CXXFLAGS="-fhandle-exceptions $CXXFLAGS"
  68                 CXXFLAGS=`echo "$CXXFLAGS" | sed 's/-O2//'`
  69                 ;;
  70         esac
  71 fi
  72
  73 if test "$GCC" = "yes"
  74 then
  75         CFLAGS="-Wall $CFLAGS"
  76 fi
  77
  78 AC_OUTPUT(Makefile)