temperaturecontrol: allow setting background tool without activating

[clinton/Smoothieware.git] / win_install.cmd

@echo off\r
rem Copyright 2013 Adam Green (http://mbed.org/users/AdamGreen/)\r
rem\r
rem Licensed under the Apache License, Version 2.0 (the "License");\r
rem you may not use this file except in compliance with the License.\r
rem You may obtain a copy of the License at\r
rem\r
rem     http://www.apache.org/licenses/LICENSE-2.0\r
rem\r
rem Unless required by applicable law or agreed to in writing, software\r
rem distributed under the License is distributed on an "AS IS" BASIS,\r
rem WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.\r
rem See the License for the specific language governing permissions and\r
rem limitations under the License.\r
\r
\r
rem Setup batch file specific environment variables.\r
setlocal\r
set ROOTDIR=%~dp0\r
set LOGFILE=%ROOTDIR%win_install.log\r
set ERRORFILE=%ROOTDIR%win_install.err\r
set GCC4ARM_VERSION=gcc-arm-none-eabi-4_8-2014q1\r
set GCC4ARM_FILENAME=gcc-arm-none-eabi-4_8-2014q1-20140314-win32.zip\r
set GCC4ARM_URL=https://launchpad.net/gcc-arm-embedded/4.8/4.8-2014-q1-update/+download/%GCC4ARM_FILENAME%\r
set GCC4ARM_TAR=%ROOTDIR%%GCC4ARM_FILENAME%\r
set GCC4ARM_MD5=09c19b3248863074f5498a88f31bee16\r
set GCC4ARM_MD5_FILENAME=%ROOTDIR%gcc-arm-none-eabi.md5\r
set GCC4ARM_DIR=%ROOTDIR%gcc-arm-none-eabi\r
set GCC4ARM_BINDIR=%GCC4ARM_DIR%\bin\r
set OUR_MAKE=%ROOTDIR%build\win32\make.exe\r
set BUILDENV_CMD=%GCC4ARM_BINDIR%\buildenv.cmd\r
set BUILDSHELL_CMD=%ROOTDIR%BuildShell.cmd\r
set BUILDSHELL_DEBUG_CMD=%ROOTDIR%BuildShellDebug.cmd\r
\r
\r
rem Make sure that we are running with current directory set to where this\r
rem batch file is located.\r
pushd %ROOTDIR%\r
\r
rem Initialize install log files.\r
echo Logging install results to %LOGFILE%\r
echo %DATE% %TIME%  Starting %0 %*>%LOGFILE%\r
\r
echo Downloading GNU Tools for ARM Embedded Processors...\r
echo %DATE% %TIME%  Executing build\win32\curl -kL0 %GCC4ARM_URL%>>%LOGFILE%\r
build\win32\curl -kL0 %GCC4ARM_URL% >%GCC4ARM_TAR%\r
if errorlevel 1 goto ExitOnError\r
\r
echo Validating md5 signature of GNU Tools for ARM Embedded Processors...\r
echo %GCC4ARM_MD5% *%GCC4ARM_FILENAME%>%GCC4ARM_MD5_FILENAME%\r
call :RunAndLog build\win32\md5sum --check %GCC4ARM_MD5_FILENAME%\r
if errorlevel 1 goto ExitOnError\r
del "%GCC4ARM_MD5_FILENAME%"\r
\r
echo Extracting GNU Tools for ARM Embedded Processors...\r
call :RunAndLog rd /s /q %GCC4ARM_DIR%\r
call :RunAndLog md %GCC4ARM_DIR%\r
if errorlevel 1 goto ExitOnError\r
call :RunAndLog cd %GCC4ARM_DIR%\r
call :RunAndLog ..\build\win32\bsdtar xf %GCC4ARM_TAR%\r
if errorlevel 1 goto ExitOnError\r
call :RunAndLog cd ..\r
\r
echo Creating helper scripts...\r
echo @echo off>%BUILDENV_CMD%\r
echo REM Uncomment next line and set destination drive to match mbed device>>%BUILDENV_CMD%\r
echo REM SET LPC_DEPLOY=copy PROJECT.bin f:\>>%BUILDENV_CMD%\r
echo.>>%BUILDENV_CMD%\r
echo SET PATH=%%~dp0;%%~dp0..\..\build\win32;%%PATH%%>>%BUILDENV_CMD%\r
rem\r
echo @cmd.exe /K %%~dp0\gcc-arm-none-eabi\bin\buildenv.cmd>%BUILDSHELL_CMD%\r
\r
rem Place GNU Tool for ARM Embedded Processors in the path before building gcc4mbed code.\r
set path=%GCC4ARM_BINDIR%;%ROOTDIR%build\win32;%PATH%\r
\r
echo Performing a clean build of the gcc4mbed samples...\r
call :RunAndLog %OUR_MAKE% clean\r
if errorlevel 1 goto ExitOnError\r
call :RunAndLog %OUR_MAKE%\r
if errorlevel 1 goto ExitOnError\r
\r
echo Cleaning up intermediate files...\r
call :RunAndLog del /f %GCC4ARM_TAR%\r
\r
echo **************************************************************************\r
echo To build gcc4mbed samples, you will first need to run the following batch\r
echo file so that your environment variables are set correctly:\r
echo  %BUILDSHELL_CMD%\r
echo You will want to run this each time you start a new Command Prompt.  You\r
echo can simply double-click on this batch file from Explorer to launch a\r
echo Command Prompt that has been properly initialized for building gcc4mbed\r
echo based code.\r
echo **************************************************************************\r
\r
rem Restore current directory and exit batch file on success.\r
echo %DATE% %TIME%  Finished successfully>>%LOGFILE%\r
echo Finished successfully\r
goto Exit\r
\r
\r
\r
rem Logs the command to be run and then executes the command while logging the results.\r
:RunAndLog\r
echo %DATE% %TIME%  Executing %*>>%LOGFILE%\r
%* 1>>%LOGFILE% 2>%ERRORFILE%\r
goto :EOF\r
\r
\r
\r
rem Exits the batch file due to error.\r
rem Make sure that any stderr text ends up in win_install.log and then restore\r
rem the current directory before forcing an early exit.\r
:ExitOnError\r
type %ERRORFILE% >>%LOGFILE%\r
echo %DATE% %TIME%  Failure forced early exit>>%LOGFILE%\r
type %LOGFILE%\r
\r
\r
:Exit\r
del %ERRORFILE%\r
popd\r
pause\r