test-suite/tests/ports.test

   1 ;;;; ports.test --- Guile I/O ports.    -*- coding: utf-8; mode: scheme; -*-
   2 ;;;; Jim Blandy <jimb@red-bean.com> --- May 1999
   3 ;;;;
   4 ;;;;    Copyright (C) 1999, 2001, 2004, 2006, 2007, 2009, 2010,
   5 ;;;;      2011 Free Software Foundation, Inc.
   6 ;;;;
   7 ;;;; This library is free software; you can redistribute it and/or
   8 ;;;; modify it under the terms of the GNU Lesser General Public
   9 ;;;; License as published by the Free Software Foundation; either
  10 ;;;; version 3 of the License, or (at your option) any later version.
  11 ;;;;
  12 ;;;; This library is distributed in the hope that it will be useful,
  13 ;;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ;;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  15 ;;;; Lesser General Public License for more details.
  16 ;;;;
  17 ;;;; You should have received a copy of the GNU Lesser General Public
  18 ;;;; License along with this library; if not, write to the Free Software
  19 ;;;; Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA
  20
  21 (define-module (test-suite test-ports)
  22   #:use-module (test-suite lib)
  23   #:use-module (test-suite guile-test)
  24   #:use-module (ice-9 popen)
  25   #:use-module (ice-9 rdelim)
  26   #:use-module (rnrs bytevectors)
  27   #:use-module ((rnrs io ports) #:select (open-bytevector-input-port)))
  28
  29 (define (display-line . args)
  30   (for-each display args)
  31   (newline))
  32
  33 (define (test-file)
  34   (data-file-name "ports-test.tmp"))
  35
  36 \f
  37 ;;;; Some general utilities for testing ports.
  38
  39 ;; Make sure we are set up for 8-bit Latin-1 data.
  40 (fluid-set! %default-port-encoding "ISO-8859-1")
  41 (for-each (lambda (p)
  42             (set-port-encoding! p (fluid-ref %default-port-encoding)))
  43           (list (current-input-port) (current-output-port)
  44                 (current-error-port)))
  45
  46 ;;; Read from PORT until EOF, and return the result as a string.
  47 (define (read-all port)
  48   (let loop ((chars '()))
  49     (let ((char (read-char port)))
  50       (if (eof-object? char)
  51           (list->string (reverse! chars))
  52           (loop (cons char chars))))))
  53
  54 (define (read-file filename)
  55   (let* ((port (open-input-file filename))
  56          (string (read-all port)))
  57     (close-port port)
  58     string))
  59
  60 \f
  61 ;;;; Normal file ports.
  62
  63 ;;; Write out an s-expression, and read it back.
  64 (let ((string '("From fairest creatures we desire increase,"
  65                 "That thereby beauty's rose might never die,"))
  66       (filename (test-file)))
  67   (let ((port (open-output-file filename)))
  68     (write string port)
  69     (close-port port))
  70   (let ((port (open-input-file filename)))
  71     (let ((in-string (read port)))
  72       (pass-if "file: write and read back list of strings"
  73                (equal? string in-string)))
  74     (close-port port))
  75   (delete-file filename))
  76
  77 ;;; Write out a string, and read it back a character at a time.
  78 (let ((string "This is a test string\nwith no newline at the end")
  79       (filename (test-file)))
  80   (let ((port (open-output-file filename)))
  81     (display string port)
  82     (close-port port))
  83   (let ((in-string (read-file filename)))
  84     (pass-if "file: write and read back characters"
  85              (equal? string in-string)))
  86   (delete-file filename))
  87
  88 ;;; Buffered input/output port with seeking.
  89 (let* ((filename (test-file))
  90        (port (open-file filename "w+")))
  91   (display "J'Accuse" port)
  92   (seek port -1 SEEK_CUR)
  93   (pass-if "file: r/w 1"
  94            (char=? (read-char port) #\e))
  95   (pass-if "file: r/w 2"
  96            (eof-object? (read-char port)))
  97   (seek port -1 SEEK_CUR)
  98   (write-char #\x port)
  99   (seek port 7 SEEK_SET)
 100   (pass-if "file: r/w 3"
 101            (char=? (read-char port) #\x))
 102   (seek port -2 SEEK_END)
 103   (pass-if "file: r/w 4"
 104            (char=? (read-char port) #\s))
 105   (close-port port)
 106   (delete-file filename))
 107
 108 ;;; Unbuffered input/output port with seeking.
 109 (let* ((filename (test-file))
 110        (port (open-file filename "w+0")))
 111   (display "J'Accuse" port)
 112   (seek port -1 SEEK_CUR)
 113   (pass-if "file: ub r/w 1"
 114            (char=? (read-char port) #\e))
 115   (pass-if "file: ub r/w 2"
 116            (eof-object? (read-char port)))
 117   (seek port -1 SEEK_CUR)
 118   (write-char #\x port)
 119   (seek port 7 SEEK_SET)
 120   (pass-if "file: ub r/w 3"
 121            (char=? (read-char port) #\x))
 122   (seek port -2 SEEK_END)
 123   (pass-if "file: ub r/w 4"
 124            (char=? (read-char port) #\s))
 125   (close-port port)
 126   (delete-file filename))
 127
 128 ;;; Buffered output-only and input-only ports with seeking.
 129 (let* ((filename (test-file))
 130        (port (open-output-file filename)))
 131   (display "J'Accuse" port)
 132   (pass-if "file: out tell"
 133            (= (seek port 0 SEEK_CUR) 8))
 134   (seek port -1 SEEK_CUR)
 135   (write-char #\x port)
 136   (close-port port)
 137   (let ((iport (open-input-file filename)))
 138     (pass-if "file: in tell 0"
 139              (= (seek iport 0 SEEK_CUR) 0))
 140     (read-char iport)
 141     (pass-if "file: in tell 1"
 142              (= (seek iport 0 SEEK_CUR) 1))
 143     (unread-char #\z iport)
 144     (pass-if "file: in tell 0 after unread"
 145              (= (seek iport 0 SEEK_CUR) 0))
 146     (pass-if "file: unread char still there"
 147              (char=? (read-char iport) #\z))
 148     (seek iport 7 SEEK_SET)
 149     (pass-if "file: in last char"
 150              (char=? (read-char iport) #\x))
 151     (close-port iport))
 152   (delete-file filename))
 153
 154 ;;; unusual characters.
 155 (let* ((filename (test-file))
 156        (port (open-output-file filename)))
 157   (display (string #\nul (integer->char 255) (integer->char 128)
 158                    #\nul) port)
 159   (close-port port)
 160   (let* ((port (open-input-file filename))
 161          (line (read-line port)))
 162     (pass-if "file: read back NUL 1"
 163              (char=? (string-ref line 0) #\nul))
 164     (pass-if "file: read back 255"
 165              (char=? (string-ref line 1) (integer->char 255)))
 166     (pass-if "file: read back 128"
 167              (char=? (string-ref line 2) (integer->char 128)))
 168     (pass-if "file: read back NUL 2"
 169              (char=? (string-ref line 3) #\nul))
 170     (pass-if "file: EOF"
 171              (eof-object? (read-char port)))
 172     (close-port port))
 173   (delete-file filename))
 174
 175 ;;; line buffering mode.
 176 (let* ((filename (test-file))
 177        (port (open-file filename "wl"))
 178        (test-string "one line more or less"))
 179   (write-line test-string port)
 180   (let* ((in-port (open-input-file filename))
 181          (line (read-line in-port)))
 182     (close-port in-port)
 183     (close-port port)
 184     (pass-if "file: line buffering"
 185              (string=? line test-string)))
 186   (delete-file filename))
 187
 188 ;;; read-line should use the port encoding (not the locale encoding).
 189 (let ((str "ĉu bone?"))
 190   (with-locale "C"
 191                (let* ((filename (test-file))
 192                       (port (open-file filename "wl")))
 193                  (set-port-encoding! port "UTF-8")
 194                  (write-line str port)
 195                  (let ((in-port (open-input-file filename)))
 196                    (set-port-encoding! in-port "UTF-8")
 197                    (let ((line (read-line in-port)))
 198                      (close-port in-port)
 199                      (close-port port)
 200                      (pass-if "file: read-line honors port encoding"
 201                               (string=? line str))))
 202                  (delete-file filename))))
 203
 204 ;;; binary mode ignores port encoding
 205 (pass-if "file: binary mode ignores port encoding"
 206   (with-fluids ((%default-port-encoding "UTF-8"))
 207                (let* ((filename (test-file))
 208                       (port (open-file filename "w"))
 209                       (test-string "一二三")
 210                       (binary-test-string
 211                        (apply string
 212                               (map integer->char
 213                                    (uniform-vector->list
 214                                     (string->utf8 test-string))))))
 215                  (write-line test-string port)
 216                  (close-port port)
 217                  (let* ((in-port (open-file filename "rb"))
 218                         (line (read-line in-port)))
 219                    (close-port in-port)
 220                    (delete-file filename)
 221                    (string=? line binary-test-string)))))
 222
 223 ;;; binary mode ignores file coding declaration
 224 (pass-if "file: binary mode ignores file coding declaration"
 225   (with-fluids ((%default-port-encoding "UTF-8"))
 226                (let* ((filename (test-file))
 227                       (port (open-file filename "w"))
 228                       (test-string "一二三")
 229                       (binary-test-string
 230                        (apply string
 231                               (map integer->char
 232                                    (uniform-vector->list
 233                                     (string->utf8 test-string))))))
 234                  (write-line ";; coding: utf-8" port)
 235                  (write-line test-string port)
 236                  (close-port port)
 237                  (let* ((in-port (open-file filename "rb"))
 238                         (line1 (read-line in-port))
 239                         (line2 (read-line in-port)))
 240                    (close-port in-port)
 241                    (delete-file filename)
 242                    (string=? line2 binary-test-string)))))
 243
 244 ;; open-file honors file coding declarations
 245 (pass-if "file: open-file honors coding declarations"
 246   (with-fluids ((%default-port-encoding "UTF-8"))
 247                (let* ((filename (test-file))
 248                       (port (open-output-file filename))
 249                       (test-string "€100"))
 250                  (set-port-encoding! port "ISO-8859-15")
 251                  (write-line ";; coding: iso-8859-15" port)
 252                  (write-line test-string port)
 253                  (close-port port)
 254                  (let* ((in-port (open-input-file filename))
 255                         (line1 (read-line in-port))
 256                         (line2 (read-line in-port)))
 257                    (close-port in-port)
 258                    (delete-file filename)
 259                    (string=? line2 test-string)))))
 260
 261 ;;; ungetting characters and strings.
 262 (with-input-from-string "walk on the moon\nmoon"
 263                         (lambda ()
 264                           (read-char)
 265                           (unread-char #\a (current-input-port))
 266                           (pass-if "unread-char"
 267                                    (char=? (read-char) #\a))
 268                           (read-line)
 269                           (let ((replacenoid "chicken enchilada"))
 270                             (unread-char #\newline (current-input-port))
 271                             (unread-string replacenoid (current-input-port))
 272                             (pass-if "unread-string"
 273                                      (string=? (read-line) replacenoid)))
 274                           (pass-if "unread residue"
 275                                    (string=? (read-line) "moon"))))
 276
 277 ;;; non-blocking mode on a port.  create a pipe and set O_NONBLOCK on
 278 ;;; the reading end.  try to read a byte: should get EAGAIN or
 279 ;;; EWOULDBLOCK error.
 280 (let* ((p (pipe))
 281        (r (car p)))
 282   (fcntl r F_SETFL (logior (fcntl r F_GETFL) O_NONBLOCK))
 283   (pass-if "non-blocking-I/O"
 284            (catch 'system-error
 285                   (lambda () (read-char r) #f)
 286                   (lambda (key . args)
 287                     (and (eq? key 'system-error)
 288                          (let ((errno (car (list-ref args 3))))
 289                            (or (= errno EAGAIN)
 290                                (= errno EWOULDBLOCK))))))))
 291
 292 \f
 293 ;;;; Pipe (popen) ports.
 294
 295 ;;; Run a command, and read its output.
 296 (let* ((pipe (open-pipe "echo 'Howdy there, partner!'" "r"))
 297        (in-string (read-all pipe)))
 298   (close-pipe pipe)
 299   (pass-if "pipe: read"
 300            (equal? in-string "Howdy there, partner!\n")))
 301
 302 ;;; Run a command, send some output to it, and see if it worked.
 303 (let* ((filename (test-file))
 304        (pipe (open-pipe (string-append "grep Mommy > " filename) "w")))
 305   (display "Now Jimmy lives on a mushroom cloud\n" pipe)
 306   (display "Mommy, why does everybody have a bomb?\n" pipe)
 307   (close-pipe pipe)
 308   (let ((in-string (read-file filename)))
 309     (pass-if "pipe: write"
 310              (equal? in-string "Mommy, why does everybody have a bomb?\n")))
 311   (delete-file filename))
 312
 313 \f
 314 ;;;; Void ports.  These are so trivial we don't test them.
 315
 316 \f
 317 ;;;; String ports.
 318
 319 (with-test-prefix "string ports"
 320
 321   ;; Write text to a string port.
 322   (let* ((string "Howdy there, partner!")
 323          (in-string (call-with-output-string
 324                      (lambda (port)
 325                        (display string port)
 326                        (newline port)))))
 327     (pass-if "display text"
 328              (equal? in-string (string-append string "\n"))))
 329
 330   ;; Write an s-expression to a string port.
 331   (let* ((sexpr '("more utterly random text" 1729 #(a vector) 3.1415926))
 332          (in-sexpr
 333           (call-with-input-string (call-with-output-string
 334                                    (lambda (port)
 335                                      (write sexpr port)))
 336                                   read)))
 337     (pass-if "write/read sexpr"
 338              (equal? in-sexpr sexpr)))
 339
 340   ;; seeking and unreading from an input string.
 341   (let ((text "that text didn't look random to me"))
 342     (call-with-input-string text
 343                             (lambda (p)
 344                               (pass-if "input tell 0"
 345                                        (= (seek p 0 SEEK_CUR) 0))
 346                               (read-char p)
 347                               (pass-if "input tell 1"
 348                                        (= (seek p 0 SEEK_CUR) 1))
 349                               (unread-char #\x p)
 350                               (pass-if "input tell back to 0"
 351                                        (= (seek p 0 SEEK_CUR) 0))
 352                               (pass-if "input ungetted char"
 353                                        (char=? (read-char p) #\x))
 354                               (seek p 0 SEEK_END)
 355                               (pass-if "input seek to end"
 356                                        (= (seek p 0 SEEK_CUR)
 357                                           (string-length text)))
 358                               (unread-char #\x p)
 359                               (pass-if "input seek to beginning"
 360                                        (= (seek p 0 SEEK_SET) 0))
 361                               (pass-if "input reread first char"
 362                                        (char=? (read-char p)
 363                                                (string-ref text 0))))))
 364
 365   ;; seeking an output string.
 366   (let* ((text (string-copy "123456789"))
 367          (len (string-length text))
 368          (result (call-with-output-string
 369                   (lambda (p)
 370                     (pass-if "output tell 0"
 371                              (= (seek p 0 SEEK_CUR) 0))
 372                     (display text p)
 373                     (pass-if "output tell end"
 374                              (= (seek p 0 SEEK_CUR) len))
 375                     (pass-if "output seek to beginning"
 376                              (= (seek p 0 SEEK_SET) 0))
 377                     (write-char #\a p)
 378                     (seek p -1 SEEK_END)
 379                     (pass-if "output seek to last char"
 380                              (= (seek p 0 SEEK_CUR)
 381                                 (- len 1)))
 382                     (write-char #\b p)))))
 383     (string-set! text 0 #\a)
 384     (string-set! text (- len 1) #\b)
 385     (pass-if "output check"
 386              (string=? text result)))
 387
 388   (pass-if "%default-port-encoding is honored"
 389     (let ((encodings '("UTF-8" "UTF-16" "ISO-8859-1" "ISO-8859-3")))
 390       (equal? (map (lambda (e)
 391                      (with-fluids ((%default-port-encoding e))
 392                        (call-with-output-string
 393                          (lambda (p)
 394                            (and (string=? e (port-encoding p))
 395                                 (display (port-encoding p) p))))))
 396                    encodings)
 397               encodings)))
 398
 399   (pass-if "suitable encoding [latin-1]"
 400     (let ((str "hello, world"))
 401       (with-fluids ((%default-port-encoding "ISO-8859-1"))
 402         (equal? str
 403                 (with-output-to-string
 404                   (lambda ()
 405                     (display str)))))))
 406
 407   (pass-if "suitable encoding [latin-3]"
 408     (let ((str "ĉu bone?"))
 409       (with-fluids ((%default-port-encoding "ISO-8859-3"))
 410         (equal? str
 411                 (with-output-to-string
 412                   (lambda ()
 413                     (display str)))))))
 414
 415   (pass-if "wrong encoding"
 416     (let ((str "ĉu bone?"))
 417       (catch 'encoding-error
 418         (lambda ()
 419           ;; Latin-1 cannot represent ‘ĉ’.
 420           (with-fluids ((%default-port-encoding "ISO-8859-1"))
 421             (with-output-to-string
 422               (lambda ()
 423                 (display str)))))
 424         (lambda (key subr message errno port chr)
 425           (and (eq? chr #\ĉ)
 426                (string? (strerror errno)))))))
 427
 428   (pass-if "wrong encoding, substitute"
 429     (let ((str "ĉu bone?"))
 430       (with-fluids ((%default-port-encoding "ISO-8859-1"))
 431         (string=? (with-output-to-string
 432                     (lambda ()
 433                       (set-port-conversion-strategy! (current-output-port)
 434                                                      'substitute)
 435                       (display str)))
 436                   "?u bone?"))))
 437
 438   (pass-if "wrong encoding, escape"
 439     (let ((str "ĉu bone?"))
 440       (with-fluids ((%default-port-encoding "ISO-8859-1"))
 441         (string=? (with-output-to-string
 442                     (lambda ()
 443                       (set-port-conversion-strategy! (current-output-port)
 444                                                      'escape)
 445                       (display str)))
 446                   "\\u0109u bone?"))))
 447
 448   (pass-if "peek-char [latin-1]"
 449     (let ((p (with-fluids ((%default-port-encoding #f))
 450                (open-input-string "hello, world"))))
 451       (and (char=? (peek-char p) #\h)
 452            (char=? (peek-char p) #\h)
 453            (char=? (peek-char p) #\h)
 454            (= (port-line p) 0)
 455            (= (port-column p) 0))))
 456
 457   (pass-if "peek-char [utf-8]"
 458     (let ((p (with-fluids ((%default-port-encoding "UTF-8"))
 459                (open-input-string "안녕하세요"))))
 460       (and (char=? (peek-char p) #\안)
 461            (char=? (peek-char p) #\안)
 462            (char=? (peek-char p) #\안)
 463            (= (port-line p) 0)
 464            (= (port-column p) 0))))
 465
 466   (pass-if "peek-char [utf-16]"
 467     (let ((p (with-fluids ((%default-port-encoding "UTF-16BE"))
 468                (open-input-string "안녕하세요"))))
 469       (and (char=? (peek-char p) #\안)
 470            (char=? (peek-char p) #\안)
 471            (char=? (peek-char p) #\안)
 472            (= (port-line p) 0)
 473            (= (port-column p) 0))))
 474
 475   ;; Mini DSL to test decoding error handling.
 476   (letrec-syntax ((decoding-error?
 477                    (syntax-rules ()
 478                      ((_ port exp)
 479                       (catch 'decoding-error
 480                         (lambda ()
 481                           (pk 'exp exp)
 482                           #f)
 483                         (lambda (key subr message errno p)
 484                           (and (eq? p port)
 485                                (not (= 0 errno))))))))
 486                   (make-check
 487                    (syntax-rules (-> error eof)
 488                      ((_ port (proc -> error))
 489                       (if (eq? 'substitute
 490                                (port-conversion-strategy port))
 491                           (eq? (proc port) #\?)
 492                           (decoding-error? port (proc port))))
 493                      ((_ port (proc -> eof))
 494                       (eof-object? (proc port)))
 495                      ((_ port (proc -> char))
 496                       (eq? (proc port) char))))
 497                   (make-checks
 498                    (syntax-rules ()
 499                      ((_ port check ...)
 500                       (and (make-check port check) ...))))
 501                   (make-peek+read-checks
 502                    (syntax-rules ()
 503                      ((_ port (result ...) e1 expected ...)
 504                       (make-peek+read-checks port
 505                                              (result ...
 506                                                      (peek-char -> e1)
 507                                                      (read-char -> e1))
 508                                              expected ...))
 509                      ((_ port (result ...))
 510                       (make-checks port result ...))
 511                      ((_ port #f e1 expected ...)
 512                       (make-peek+read-checks port
 513                                              ((peek-char -> e1)
 514                                               (read-char -> e1))
 515                                              expected ...))))
 516
 517                   (test-decoding-error*
 518                       (syntax-rules ()
 519                         ((_ sequence encoding strategy (expected ...))
 520                          (begin
 521                           (pass-if (format #f "test-decoding-error: ~s ~s ~s"
 522                                            'sequence encoding strategy)
 523                             (let ((p (open-bytevector-input-port
 524                                       (u8-list->bytevector 'sequence))))
 525                               (set-port-encoding! p encoding)
 526                               (set-port-conversion-strategy! p strategy)
 527                               (make-checks p
 528                                            (read-char -> expected) ...)))
 529
 530                           ;; Generate the same test, but with one
 531                           ;; `peek-char' call before each `read-char'.
 532                           ;; Both should yield the same result.
 533                           (pass-if (format #f "test-decoding-error: ~s ~s ~s + peek-char"
 534                                            'sequence encoding strategy)
 535                             (let ((p (open-bytevector-input-port
 536                                       (u8-list->bytevector 'sequence))))
 537                               (set-port-encoding! p encoding)
 538                               (set-port-conversion-strategy! p strategy)
 539                               (make-peek+read-checks p #f expected
 540                                                      ...)))))))
 541                   (test-decoding-error
 542                       (syntax-rules ()
 543                         ((_ sequence encoding (expected ...))
 544                          (begin
 545                            (test-decoding-error* sequence encoding 'error
 546                              (expected ...))
 547
 548                            ;; `escape' should behave exactly like `error'.
 549                            (test-decoding-error* sequence encoding 'escape
 550                              (expected ...))
 551
 552                            (test-decoding-error* sequence encoding 'substitute
 553                              (expected ...)))))))
 554
 555     (test-decoding-error (255 65 66 67) "UTF-8"
 556       (error #\A #\B #\C eof))
 557
 558     (test-decoding-error (255 206 187 206 188) "UTF-8"
 559       (error #\λ #\μ eof))
 560
 561     (test-decoding-error (206 187 206) "UTF-8"
 562       ;; Unterminated sequence.
 563       (#\λ error eof))
 564
 565     ;; Check how ill-formed UTF-8 sequences are handled (see Table 3-7
 566     ;; of the "Conformance" chapter of Unicode 6.0.0.)
 567
 568     (test-decoding-error (#xc0 #x80 #x41) "UTF-8"
 569       (error                ;; C0: should be in the C2..DF range
 570        error                ;; 80: invalid
 571        #\A
 572        eof))
 573
 574     (test-decoding-error (#xc2 #x41 #x42) "UTF-8"
 575       ;; FIXME: This is the behavior of glibc/libiconv but it does not
 576       ;; conform to the Unicode 6.0.0 recommendation: according to it,
 577       ;; the #\A should not be swallowed (Section 3.9 reads:
 578       ;; "If the converter encounters an ill-formed UTF-8 code unit
 579       ;; sequence which starts with a valid first byte, but which does
 580       ;; not continue with valid successor bytes (see Table 3-7), it
 581       ;; must not consume the successor bytes".)
 582
 583       (error                ;; 41: should be in the 80..BF range
 584        #\B
 585        eof))
 586
 587     (test-decoding-error (#xe0 #x88 #x88) "UTF-8"
 588       (error                ;; 2nd byte should be in the A0..BF range
 589        eof))
 590
 591     (test-decoding-error (#xe0 #xa0 #x41 #x42) "UTF-8"
 592       (error                ;; 3rd byte should be in the 80..BF range
 593        #\B
 594        eof))
 595
 596     (test-decoding-error (#xf0 #x88 #x88 #x88) "UTF-8"
 597       (error                ;; 2nd byte should be in the 90..BF range
 598        eof))))
 599
 600 (with-test-prefix "call-with-output-string"
 601
 602   ;; In Guile 1.6.4, closing the port resulted in a segv, check that doesn't
 603   ;; occur.
 604   (pass-if-exception "proc closes port" exception:wrong-type-arg
 605     (call-with-output-string close-port)))
 606
 607
 608 \f
 609 ;;;; Soft ports.  No tests implemented yet.
 610
 611 \f
 612 ;;;; Generic operations across all port types.
 613
 614 (let ((port-loop-temp (test-file)))
 615
 616   ;; Return a list of input ports that all return the same text.
 617   ;; We map tests over this list.
 618   (define (input-port-list text)
 619
 620     ;; Create a text file some of the ports will use.
 621     (let ((out-port (open-output-file port-loop-temp)))
 622       (display text out-port)
 623       (close-port out-port))
 624
 625     (list (open-input-file port-loop-temp)
 626           (open-input-pipe (string-append "cat " port-loop-temp))
 627           (call-with-input-string text (lambda (x) x))
 628           ;; We don't test soft ports at the moment.
 629           ))
 630
 631   (define port-list-names '("file" "pipe" "string"))
 632
 633   ;; Test the line counter.
 634   (define (test-line-counter text second-line final-column)
 635     (with-test-prefix "line counter"
 636       (let ((ports (input-port-list text)))
 637         (for-each
 638          (lambda (port port-name)
 639            (with-test-prefix port-name
 640              (pass-if "at beginning of input"
 641                       (= (port-line port) 0))
 642              (pass-if "read first character"
 643                       (eqv? (read-char port) #\x))
 644              (pass-if "after reading one character"
 645                       (= (port-line port) 0))
 646              (pass-if "read first newline"
 647                       (eqv? (read-char port) #\newline))
 648              (pass-if "after reading first newline char"
 649                       (= (port-line port) 1))
 650              (pass-if "second line read correctly"
 651                       (equal? (read-line port) second-line))
 652              (pass-if "read-line increments line number"
 653                       (= (port-line port) 2))
 654              (pass-if "read-line returns EOF"
 655                       (let loop ((i 0))
 656                         (cond
 657                          ((eof-object? (read-line port)) #t)
 658                          ((> i 20) #f)
 659                          (else (loop (+ i 1))))))
 660              (pass-if "line count is 5 at EOF"
 661                       (= (port-line port) 5))
 662              (pass-if "column is correct at EOF"
 663                       (= (port-column port) final-column))))
 664          ports port-list-names)
 665         (for-each close-port ports)
 666         (delete-file port-loop-temp))))
 667
 668   (with-test-prefix "newline"
 669     (test-line-counter
 670      (string-append "x\n"
 671                     "He who receives an idea from me, receives instruction\n"
 672                     "himself without lessening mine; as he who lights his\n"
 673                     "taper at mine, receives light without darkening me.\n"
 674                     "  --- Thomas Jefferson\n")
 675      "He who receives an idea from me, receives instruction"
 676      0))
 677
 678   (with-test-prefix "no newline"
 679     (test-line-counter
 680      (string-append "x\n"
 681                     "He who receives an idea from me, receives instruction\n"
 682                     "himself without lessening mine; as he who lights his\n"
 683                     "taper at mine, receives light without darkening me.\n"
 684                     "  --- Thomas Jefferson\n"
 685                     "no newline here")
 686      "He who receives an idea from me, receives instruction"
 687      15)))
 688
 689 ;; Test port-line and port-column for output ports
 690
 691 (define (test-output-line-counter text final-column)
 692   (with-test-prefix "port-line and port-column for output ports"
 693     (let ((port (open-output-string)))
 694       (pass-if "at beginning of input"
 695                (and (= (port-line port) 0)
 696                     (= (port-column port) 0)))
 697       (write-char #\x port)
 698       (pass-if "after writing one character"
 699                (and (= (port-line port) 0)
 700                     (= (port-column port) 1)))
 701       (write-char #\newline port)
 702       (pass-if "after writing first newline char"
 703                (and (= (port-line port) 1)
 704                     (= (port-column port) 0)))
 705       (display text port)
 706       (pass-if "line count is 5 at end"
 707                (= (port-line port) 5))
 708       (pass-if "column is correct at end"
 709                (= (port-column port) final-column)))))
 710
 711 (test-output-line-counter
 712  (string-append "He who receives an idea from me, receives instruction\n"
 713                 "himself without lessening mine; as he who lights his\n"
 714                 "taper at mine, receives light without darkening me.\n"
 715                 "  --- Thomas Jefferson\n"
 716                 "no newline here")
 717  15)
 718
 719 (with-test-prefix "port-column"
 720
 721   (with-test-prefix "output"
 722
 723     (pass-if "x"
 724       (let ((port (open-output-string)))
 725         (display "x" port)
 726         (= 1 (port-column port))))
 727
 728     (pass-if "\\a"
 729       (let ((port (open-output-string)))
 730         (display "\a" port)
 731         (= 0 (port-column port))))
 732
 733     (pass-if "x\\a"
 734       (let ((port (open-output-string)))
 735         (display "x\a" port)
 736         (= 1 (port-column port))))
 737
 738     (pass-if "\\x08 backspace"
 739       (let ((port (open-output-string)))
 740         (display "\x08" port)
 741         (= 0 (port-column port))))
 742
 743     (pass-if "x\\x08 backspace"
 744       (let ((port (open-output-string)))
 745         (display "x\x08" port)
 746         (= 0 (port-column port))))
 747
 748     (pass-if "\\n"
 749       (let ((port (open-output-string)))
 750         (display "\n" port)
 751         (= 0 (port-column port))))
 752
 753     (pass-if "x\\n"
 754       (let ((port (open-output-string)))
 755         (display "x\n" port)
 756         (= 0 (port-column port))))
 757
 758     (pass-if "\\r"
 759       (let ((port (open-output-string)))
 760         (display "\r" port)
 761         (= 0 (port-column port))))
 762
 763     (pass-if "x\\r"
 764       (let ((port (open-output-string)))
 765         (display "x\r" port)
 766         (= 0 (port-column port))))
 767
 768     (pass-if "\\t"
 769       (let ((port (open-output-string)))
 770         (display "\t" port)
 771         (= 8 (port-column port))))
 772
 773     (pass-if "x\\t"
 774       (let ((port (open-output-string)))
 775         (display "x\t" port)
 776         (= 8 (port-column port)))))
 777
 778   (with-test-prefix "input"
 779
 780     (pass-if "x"
 781       (let ((port (open-input-string "x")))
 782         (while (not (eof-object? (read-char port))))
 783         (= 1 (port-column port))))
 784
 785     (pass-if "\\a"
 786       (let ((port (open-input-string "\a")))
 787         (while (not (eof-object? (read-char port))))
 788         (= 0 (port-column port))))
 789
 790     (pass-if "x\\a"
 791       (let ((port (open-input-string "x\a")))
 792         (while (not (eof-object? (read-char port))))
 793         (= 1 (port-column port))))
 794
 795     (pass-if "\\x08 backspace"
 796       (let ((port (open-input-string "\x08")))
 797         (while (not (eof-object? (read-char port))))
 798         (= 0 (port-column port))))
 799
 800     (pass-if "x\\x08 backspace"
 801       (let ((port (open-input-string "x\x08")))
 802         (while (not (eof-object? (read-char port))))
 803         (= 0 (port-column port))))
 804
 805     (pass-if "\\n"
 806       (let ((port (open-input-string "\n")))
 807         (while (not (eof-object? (read-char port))))
 808         (= 0 (port-column port))))
 809
 810     (pass-if "x\\n"
 811       (let ((port (open-input-string "x\n")))
 812         (while (not (eof-object? (read-char port))))
 813         (= 0 (port-column port))))
 814
 815     (pass-if "\\r"
 816       (let ((port (open-input-string "\r")))
 817         (while (not (eof-object? (read-char port))))
 818         (= 0 (port-column port))))
 819
 820     (pass-if "x\\r"
 821       (let ((port (open-input-string "x\r")))
 822         (while (not (eof-object? (read-char port))))
 823         (= 0 (port-column port))))
 824
 825     (pass-if "\\t"
 826       (let ((port (open-input-string "\t")))
 827         (while (not (eof-object? (read-char port))))
 828         (= 8 (port-column port))))
 829
 830     (pass-if "x\\t"
 831       (let ((port (open-input-string "x\t")))
 832         (while (not (eof-object? (read-char port))))
 833         (= 8 (port-column port))))))
 834
 835 (with-test-prefix "port-line"
 836
 837   ;; in guile 1.8.1 and earlier port-line was truncated to an int, whereas
 838   ;; scm_t_port actually holds a long; this restricted the range on 64-bit
 839   ;; systems
 840   (pass-if "set most-positive-fixnum/2"
 841     (let ((n    (quotient most-positive-fixnum 2))
 842           (port (open-output-string)))
 843       (set-port-line! port n)
 844       (eqv? n (port-line port)))))
 845
 846 (with-test-prefix "port-encoding"
 847
 848   (pass-if-exception "set-port-encoding!, wrong encoding"
 849     exception:miscellaneous-error
 850     (set-port-encoding! (open-input-string "") "does-not-exist"))
 851
 852   (pass-if-exception "%default-port-encoding, wrong encoding"
 853     exception:miscellaneous-error
 854     (read (with-fluids ((%default-port-encoding "does-not-exist"))
 855             (open-input-string "")))))
 856
 857 ;;;
 858 ;;; port-for-each
 859 ;;;
 860
 861 (with-test-prefix "port-for-each"
 862
 863   ;; In guile 1.8.0 through 1.8.2, port-for-each could pass a freed cell to
 864   ;; its iterator func if a port was inaccessible in the last gc mark but
 865   ;; the lazy sweeping has not yet reached it to remove it from the port
 866   ;; table (scm_i_port_table).  Provoking those gc conditions is a little
 867   ;; tricky, but the following code made it happen in 1.8.2.
 868   (pass-if "passing freed cell"
 869     (let ((lst '()))
 870       ;; clear out the heap
 871       (gc) (gc) (gc)
 872       ;; allocate cells so the opened ports aren't at the start of the heap
 873       (make-list 1000)
 874       (open-input-file "/dev/null")
 875       (make-list 1000)
 876       (open-input-file "/dev/null")
 877       ;; this gc leaves the above ports unmarked, ie. inaccessible
 878       (gc)
 879       ;; but they're still in the port table, so this sees them
 880       (port-for-each (lambda (port)
 881                        (set! lst (cons port lst))))
 882       ;; this forces completion of the sweeping
 883       (gc) (gc) (gc)
 884       ;; and (if the bug is present) the cells accumulated in LST are now
 885       ;; freed cells, which give #f from `port?'
 886       (not (memq #f (map port? lst))))))
 887
 888 (with-test-prefix
 889  "fdes->port"
 890  (pass-if "fdes->ports finds port"
 891           (let ((port (open-file (test-file) "w")))
 892
 893             (not (not (memq port (fdes->ports (port->fdes port))))))))
 894
 895 ;;;
 896 ;;; seek
 897 ;;;
 898
 899 (with-test-prefix "seek"
 900
 901   (with-test-prefix "file port"
 902
 903     (pass-if "SEEK_CUR"
 904       (call-with-output-file (test-file)
 905         (lambda (port)
 906           (display "abcde" port)))
 907       (let ((port (open-file (test-file) "r")))
 908         (read-char port)
 909         (seek port 2 SEEK_CUR)
 910         (eqv? #\d (read-char port))))
 911
 912     (pass-if "SEEK_SET"
 913       (call-with-output-file (test-file)
 914         (lambda (port)
 915           (display "abcde" port)))
 916       (let ((port (open-file (test-file) "r")))
 917         (read-char port)
 918         (seek port 3 SEEK_SET)
 919         (eqv? #\d (read-char port))))
 920
 921     (pass-if "SEEK_END"
 922       (call-with-output-file (test-file)
 923         (lambda (port)
 924           (display "abcde" port)))
 925       (let ((port (open-file (test-file) "r")))
 926         (read-char port)
 927         (seek port -2 SEEK_END)
 928         (eqv? #\d (read-char port))))))
 929
 930 ;;;
 931 ;;; truncate-file
 932 ;;;
 933
 934 (with-test-prefix "truncate-file"
 935
 936   (pass-if-exception "flonum file" exception:wrong-type-arg
 937     (truncate-file 1.0 123))
 938
 939   (pass-if-exception "frac file" exception:wrong-type-arg
 940     (truncate-file 7/3 123))
 941
 942   (with-test-prefix "filename"
 943
 944     (pass-if-exception "flonum length" exception:wrong-type-arg
 945       (call-with-output-file (test-file)
 946         (lambda (port)
 947           (display "hello" port)))
 948       (truncate-file (test-file) 1.0))
 949
 950     (pass-if "shorten"
 951       (call-with-output-file (test-file)
 952         (lambda (port)
 953           (display "hello" port)))
 954       (truncate-file (test-file) 1)
 955       (eqv? 1 (stat:size (stat (test-file)))))
 956
 957     (pass-if-exception "shorten to current pos" exception:miscellaneous-error
 958       (call-with-output-file (test-file)
 959         (lambda (port)
 960           (display "hello" port)))
 961       (truncate-file (test-file))))
 962
 963   (with-test-prefix "file descriptor"
 964
 965     (pass-if "shorten"
 966       (call-with-output-file (test-file)
 967         (lambda (port)
 968           (display "hello" port)))
 969       (let ((fd (open-fdes (test-file) O_RDWR)))
 970         (truncate-file fd 1)
 971         (close-fdes fd))
 972       (eqv? 1 (stat:size (stat (test-file)))))
 973
 974     (pass-if "shorten to current pos"
 975       (call-with-output-file (test-file)
 976         (lambda (port)
 977           (display "hello" port)))
 978       (let ((fd (open-fdes (test-file) O_RDWR)))
 979         (seek fd 1 SEEK_SET)
 980         (truncate-file fd)
 981         (close-fdes fd))
 982       (eqv? 1 (stat:size (stat (test-file))))))
 983
 984   (with-test-prefix "file port"
 985
 986     (pass-if "shorten"
 987       (call-with-output-file (test-file)
 988         (lambda (port)
 989           (display "hello" port)))
 990       (let ((port (open-file (test-file) "r+")))
 991         (truncate-file port 1))
 992       (eqv? 1 (stat:size (stat (test-file)))))
 993
 994     (pass-if "shorten to current pos"
 995       (call-with-output-file (test-file)
 996         (lambda (port)
 997           (display "hello" port)))
 998       (let ((port (open-file (test-file) "r+")))
 999         (read-char port)
1000         (truncate-file port))
1001       (eqv? 1 (stat:size (stat (test-file)))))))
1002
1003
1004 ;;;; testing read-delimited and friends
1005
1006 (with-test-prefix "read-delimited!"
1007   (let ((c (make-string 20 #\!)))
1008     (call-with-input-string
1009      "defdef\nghighi\n"
1010      (lambda (port)
1011
1012        (read-delimited! "\n" c port 'concat)
1013        (pass-if "read-delimited! reads a first line"
1014                 (string=? c "defdef\n!!!!!!!!!!!!!"))
1015
1016        (read-delimited! "\n" c port 'concat 3)
1017        (pass-if "read-delimited! reads a first line"
1018                 (string=? c "defghighi\n!!!!!!!!!!"))))))
1019
1020 \f
1021 ;;;; char-ready?
1022
1023 (call-with-input-string
1024  "howdy"
1025  (lambda (port)
1026    (pass-if "char-ready? returns true on string port"
1027             (char-ready? port))))
1028
1029 ;;; This segfaults on some versions of Guile.  We really should run
1030 ;;; the tests in a subprocess...
1031
1032 (call-with-input-string
1033  "howdy"
1034  (lambda (port)
1035    (with-input-from-port
1036        port
1037      (lambda ()
1038        (pass-if "char-ready? returns true on string port as default port"
1039                 (char-ready?))))))
1040
1041 \f
1042 ;;;; Close current-input-port, and make sure everyone can handle it.
1043
1044 (with-test-prefix "closing current-input-port"
1045   (for-each (lambda (procedure name)
1046               (with-input-from-port
1047                   (call-with-input-string "foo" (lambda (p) p))
1048                 (lambda ()
1049                   (close-port (current-input-port))
1050                   (pass-if-exception name
1051                     exception:wrong-type-arg
1052                     (procedure)))))
1053             (list read read-char read-line)
1054             '("read" "read-char" "read-line")))
1055
1056 (delete-file (test-file))
1057
1058 ;;; Local Variables:
1059 ;;; eval: (put 'test-decoding-error 'scheme-indent-function 3)
1060 ;;; End: