Documentation
*************

GNU Emacs has convenient built-in help facilities, most of which derive their information from documentation strings associated with functions and variables.  This chapter describes how to access documentation strings in Lisp programs.

The contents of a documentation string should follow certain conventions.  In particular, its first line should be a complete sentence (or two complete sentences) that briefly describes what the function or variable does.  See Documentation Tips, for how to write good documentation strings.

Note that the documentation strings for Emacs are not the same thing as the Emacs manual.  Manuals have their own source files, written in the Texinfo language; documentation strings are specified in the definitions of the functions and variables they apply to.  A collection of documentation strings is not sufficient as a manual because a good manual is not organized in that fashion; it is organized in terms of topics of discussion.

For commands to display documentation strings, see Help (The GNU Emacs Manual).

Documentation Basics
====================

A documentation string is written using the Lisp syntax for strings, with double-quote characters surrounding the text.  It is, in fact, an actual Lisp string.  When the string appears in the proper place in a function or variable definition, it serves as the function's or variable's documentation.

In a function definition (a lambda or defun form), the documentation string is specified after the argument list, and is normally stored directly in the function object.  See Function Documentation.  You can also put function documentation in the function-documentation property of a function name (see Accessing Documentation).

In a variable definition (a defvar form), the documention string is specified after the initial value.  See Defining Variables.  The string is stored in the variable's variable-documentation property.

Sometimes, Emacs does not keep documentation strings in memory. There are two such circumstances.  Firstly, to save memory, the documentation for preloaded functions and variables (including primitives) is kept in a file named DOC, in the directory specified by doc-directory (see Accessing Documentation). Secondly, when a function or variable is loaded from a byte-compiled file, Emacs avoids loading its documentation string (see Docs and Compilation).  In both cases, Emacs looks up the documentation string from the file only when needed, such as when the user calls C-h f (describe-function) for a function.

Documentation strings can contain special key substitution sequences, referring to key bindings which are looked up only when the user views the documentation.  This allows the help commands to display the correct keys even if a user rearranges the default key bindings.  See Keys in Documentation.

In the documentation string of an autoloaded command (see Autoload), these key-substitution sequences have an additional special effect: they cause C-h f on the command to trigger autoloading.  (This is needed for correctly setting up the hyperlinks in the *Help* buffer.)

Access to Documentation Strings
===============================

 -- Function: documentation-property symbol property &optional verbatim
     This function returns the documentation string recorded in SYMBOL's property list under property PROPERTY.  It is most often used to look up the documentation strings of variables, for which PROPERTY is variable-documentation.  However, it can also be used to look up other kinds of documentation, such as for customization groups (but for function documentation, use the documentation function, below).

     If the property value refers to a documentation string stored in the DOC file or a byte-compiled file, this function looks up that string and returns it.

     If the property value isn't nil, isn't a string, and doesn't refer to text in a file, then it is evaluated as a Lisp expression to obtain a string.

     Finally, this function passes the string through substitute-command-keys to substitute key bindings (see Keys in Documentation).  It skips this step if VERBATIM is non-nil.

          (documentation-property 'command-line-processed
             'variable-documentation)
               => "Non-nil once command line has been processed"

          (symbol-plist 'command-line-processed)
               => (variable-documentation 188902)

          (documentation-property 'emacs 'group-documentation)
               => "Customization of the One True Editor."

 -- Function: documentation function &optional verbatim
     This function returns the documentation string of FUNCTION.  It handles macros, named keyboard macros, and special forms, as well as ordinary functions.

     If FUNCTION is a symbol, this function first looks for the function-documentation property of that symbol; if that has a non-nil value, the documentation comes from that value (if the value is not a string, it is evaluated).

     If FUNCTION is not a symbol, or if it has no function-documentation property, then documentation extracts the documentation string from the actual function definition, reading it from a file if called for.

     Finally, unless VERBATIM is non-nil, this function calls substitute-command-keys.  The result is the documentation string to return.

     The documentation function signals a void-function error if FUNCTION has no function definition.  However, it is OK if the function definition has no documentation string.  In that case, documentation returns nil.

 -- Function: face-documentation face
     This function returns the documentation string of FACE as a face.

Here is an example of using the two functions, documentation and documentation-property, to display the documentation strings for several symbols in a *Help* buffer.

     (defun describe-symbols (pattern)
       "Describe the Emacs Lisp symbols matching PATTERN.
     All symbols that have PATTERN in their name are described
     in the `*Help*' buffer."
       (interactive "sDescribe symbols matching: ")
       (let ((describe-func
              (function
               (lambda (s)

                 ;; Print description of symbol.
                 (if (fboundp s)             ; It is a function.
                     (princ
                      (format "%s\t%s\n%s\n\n" s
                        (if (commandp s)
                            (let ((keys (where-is-internal s)))
                              (if keys
                                  (concat
                                   "Keys: "
                                   (mapconcat 'key-description
                                              keys " "))
                                "Keys: none"))
                          "Function")

                        (or (documentation s)
                            "not documented"))))

                 (if (boundp s)              ; It is a variable.

                     (princ
                      (format "%s\t%s\n%s\n\n" s
                        (if (custom-variable-p s)
                            "Option " "Variable")

                        (or (documentation-property
                              s 'variable-documentation)
                            "not documented")))))))
             sym-list)

         ;; Build a list of symbols that match pattern.
         (mapatoms (function
                    (lambda (sym)
                      (if (string-match pattern (symbol-name sym))
                          (setq sym-list (cons sym sym-list))))))

         ;; Display the data.
         (help-setup-xref (list 'describe-symbols pattern) (interactive-p))
         (with-help-window (help-buffer)
           (mapcar describe-func (sort sym-list 'string<)))))

The describe-symbols function works like apropos, but provides more information.

     (describe-symbols "goal")

     ---------- Buffer: *Help* ----------
     goal-column     Option
     Semipermanent goal column for vertical motion, as set by ...

     set-goal-column Keys: C-x C-n
     Set the current horizontal position as a goal for C-n and C-p.

     Those commands will move to this position in the line moved to
     rather than trying to keep the same horizontal position.
     With a non-nil argument, clears out the goal column
     so that C-n and C-p resume vertical motion.
     The goal column is stored in the variable `goal-column'.

     temporary-goal-column   Variable
     Current goal column for vertical motion.
     It is the column where point was
     at the start of current run of vertical motion commands.
     When the `track-eol' feature is doing its job, the value is 9999.
     ---------- Buffer: *Help* ----------

 -- Function: Snarf-documentation filename
     This function is used when building Emacs, just before the runnable Emacs is dumped.  It finds the positions of the documentation strings stored in the file FILENAME, and records those positions into memory in the function definitions and variable property lists. See Building Emacs.

     Emacs reads the file FILENAME from the emacs/etc directory. When the dumped Emacs is later executed, the same file will be looked for in the directory doc-directory.  Usually FILENAME is "DOC".

 -- Variable: doc-directory
     This variable holds the name of the directory which should contain the file "DOC" that contains documentation strings for built-in and preloaded functions and variables.

     In most cases, this is the same as data-directory.  They may be different when you run Emacs from the directory where you built it, without actually installing it.  See Definition of data-directory.

Substituting Key Bindings in Documentation
==========================================

When documentation strings refer to key sequences, they should use the current, actual key bindings.  They can do so using certain special text sequences described below.  Accessing documentation strings in the usual way substitutes current key binding information for these special sequences.  This works by calling substitute-command-keys.  You can also call that function yourself.

Here is a list of the special sequences and what they mean:

\[COMMAND]
     stands for a key sequence that will invoke COMMAND, or M-x COMMAND if COMMAND has no key bindings.

\{MAPVAR}
     stands for a summary of the keymap which is the value of the variable MAPVAR.  The summary is made using describe-bindings.

\<MAPVAR>
     stands for no text itself.  It is used only for a side effect: it specifies MAPVAR's value as the keymap for any following \[COMMAND] sequences in this documentation string.

\=
     quotes the following character and is discarded; thus, \=\[ puts \[ into the output, and \=\= puts \= into the output.

Please note: Each \ must be doubled when written in a string in Emacs Lisp.

 -- Function: substitute-command-keys string
     This function scans STRING for the above special sequences and replaces them by what they stand for, returning the result as a string. This permits display of documentation that refers accurately to the user's own customized key bindings.

     If a command has multiple bindings, this function normally uses the first one it finds.  You can specify one particular key binding by assigning an :advertised-binding symbol property to the command, like this:

          (put 'undo :advertised-binding [?\C-/])

     The :advertised-binding property also affects the binding shown in menu items (see Menu Bar).  The property is ignored if it specifies a key binding that the command does not actually have.

Here are examples of the special sequences:

     (substitute-command-keys
        "To abort recursive edit, type: \\[abort-recursive-edit]")
     => "To abort recursive edit, type: C-]"

     (substitute-command-keys
        "The keys that are defined for the minibuffer here are:
       \\{minibuffer-local-must-match-map}")
     => "The keys that are defined for the minibuffer here are:

     ?               minibuffer-completion-help
     SPC             minibuffer-complete-word
     TAB             minibuffer-complete
     C-j             minibuffer-complete-and-exit
     RET             minibuffer-complete-and-exit
     C-g             abort-recursive-edit
     "

     (substitute-command-keys
        "To abort a recursive edit from the minibuffer, type\
     \\<minibuffer-local-must-match-map>\\[abort-recursive-edit].")
     => "To abort a recursive edit from the minibuffer, type C-g."

There are other special conventions for the text in documentation strings---for instance, you can refer to functions, variables, and sections of this manual.  See Documentation Tips, for details.

Describing Characters for Help Messages
=======================================

These functions convert events, key sequences, or characters to textual descriptions.  These descriptions are useful for including arbitrary text characters or key sequences in messages, because they convert non-printing and whitespace characters to sequences of printing characters.  The description of a non-whitespace printing character is the character itself.

 -- Function: key-description sequence &optional prefix
     This function returns a string containing the Emacs standard notation for the input events in SEQUENCE.  If PREFIX is non-nil, it is a sequence of input events leading up to SEQUENCE and is included in the return value.  Both arguments may be strings, vectors or lists.  See Input Events, for more information about valid events.

          (key-description [?\M-3 delete])
               => "M-3 <delete>"

          (key-description [delete] "\M-3")
               => "M-3 <delete>"

     See also the examples for single-key-description, below.

 -- Function: single-key-description event &optional no-angles
     This function returns a string describing EVENT in the standard Emacs notation for keyboard input.  A normal printing character appears as itself, but a control character turns into a string starting with C-, a meta character turns into a string starting with M-, and space, tab, etc., appear as SPC, TAB, etc.  A function key symbol appears inside angle brackets <...>.  An event that is a list appears as the name of the symbol in the CAR of the list, inside angle brackets.

     If the optional argument NO-ANGLES is non-nil, the angle brackets around function keys and event symbols are omitted; this is for compatibility with old versions of Emacs which didn't use the brackets.

          (single-key-description ?\C-x)
               => "C-x"

          (key-description "\C-x \M-y \n \t \r \f123")
               => "C-x SPC M-y SPC C-j SPC TAB SPC RET SPC C-l 1 2 3"

          (single-key-description 'delete)
               => "<delete>"

          (single-key-description 'C-mouse-1)
               => "<C-mouse-1>"

          (single-key-description 'C-mouse-1 t)
               => "C-mouse-1"

 -- Function: text-char-description character
     This function returns a string describing CHARACTER in the standard Emacs notation for characters that appear in text---like single-key-description, except that control characters are represented with a leading caret (which is how control characters in Emacs buffers are usually displayed).  Another difference is that text-char-description recognizes the 2**7 bit as the Meta character, whereas single-key-description uses the 2**27 bit for Meta.

          (text-char-description ?\C-c)
               => "^C"

          (text-char-description ?\M-m)
               => "\xed"

          (text-char-description ?\C-\M-m)
               => "\x8d"

          (text-char-description (+ 128 ?m))
               => "M-m"

          (text-char-description (+ 128 ?\C-m))
               => "M-^M"

 -- Command: read-kbd-macro string &optional need-vector
     This function is used mainly for operating on keyboard macros, but it can also be used as a rough inverse for key-description.  You call it with a string containing key descriptions, separated by spaces; it returns a string or vector containing the corresponding events. (This may or may not be a single valid key sequence, depending on what events you use; see Key Sequences.)  If NEED-VECTOR is non-nil, the return value is always a vector.

Help Functions
==============

Emacs provides a variety of on-line help functions, all accessible to the user as subcommands of the prefix C-h.  For more information about them, see Help (The GNU Emacs Manual).  Here we describe some program-level interfaces to the same information.

 -- Command: apropos pattern &optional do-all
     This function finds all ``meaningful'' symbols whose names contain a match for the apropos pattern PATTERN.  An apropos pattern is either a word to match, a space-separated list of words of which at least two must match, or a regular expression (if any special regular expression characters occur).  A symbol is ``meaningful'' if it has a definition as a function, variable, or face, or has properties.

     The function returns a list of elements that look like this:

          (SYMBOL SCORE FUNCTION-DOC VARIABLE-DOC
           PLIST-DOC WIDGET-DOC FACE-DOC GROUP-DOC)

     Here, SCORE is an integer measure of how important the symbol seems to be as a match.  Each of the remaining elements is a documentation string, or nil, for SYMBOL as a function, variable, etc.

     It also displays the symbols in a buffer named *Apropos*, each with a one-line description taken from the beginning of its documentation string.

     If DO-ALL is non-nil, or if the user option apropos-do-all is non-nil, then apropos also shows key bindings for the functions that are found; it also shows all interned symbols, not just meaningful ones (and it lists them in the return value as well).

 -- Variable: help-map
     The value of this variable is a local keymap for characters following the Help key, C-h.

 -- Prefix Command: help-command
     This symbol is not a function; its function definition cell holds the keymap known as help-map.  It is defined in help.el as follows:

          (define-key global-map (string help-char) 'help-command)
          (fset 'help-command help-map)

 -- User Option: help-char
     The value of this variable is the help character---the character that Emacs recognizes as meaning Help.  By default, its value is 8, which stands for C-h.  When Emacs reads this character, if help-form is a non-nil Lisp expression, it evaluates that expression, and displays the result in a window if it is a string.

     Usually the value of help-form is nil.  Then the help character has no special meaning at the level of command input, and it becomes part of a key sequence in the normal way.  The standard key binding of C-h is a prefix key for several general-purpose help features.

     The help character is special after prefix keys, too.  If it has no binding as a subcommand of the prefix key, it runs describe-prefix-bindings, which displays a list of all the subcommands of the prefix key.

 -- User Option: help-event-list
     The value of this variable is a list of event types that serve as alternative ``help characters''.  These events are handled just like the event specified by help-char.

 -- Variable: help-form
     If this variable is non-nil, its value is a form to evaluate whenever the character help-char is read.  If evaluating the form produces a string, that string is displayed.

     A command that calls read-event, read-char-choice, or read-char probably should bind help-form to a non-nil expression while it does input.  (The time when you should not do this is when C-h has some other meaning.) Evaluating this expression should result in a string that explains what the input is for and how to enter it properly.

     Entry to the minibuffer binds this variable to the value of minibuffer-help-form (see Definition of minibuffer-help-form).

 -- Variable: prefix-help-command
     This variable holds a function to print help for a prefix key.  The function is called when the user types a prefix key followed by the help character, and the help character has no binding after that prefix.  The variable's default value is describe-prefix-bindings.

 -- Command: describe-prefix-bindings
     This function calls describe-bindings to display a list of all the subcommands of the prefix key of the most recent key sequence.  The prefix described consists of all but the last event of that key sequence.  (The last event is, presumably, the help character.)

The following two functions are meant for modes that want to provide help without relinquishing control, such as the ``electric'' modes. Their names begin with Helper to distinguish them from the ordinary help functions.

 -- Command: Helper-describe-bindings
     This command pops up a window displaying a help buffer containing a listing of all of the key bindings from both the local and global keymaps. It works by calling describe-bindings.

 -- Command: Helper-help
     This command provides help for the current mode.  It prompts the user in the minibuffer with the message Help (Type ? for further options), and then provides assistance in finding out what the key bindings are, and what the mode is intended for.  It returns nil.

     This can be customized by changing the map Helper-help-map.

 -- Variable: data-directory
     This variable holds the name of the directory in which Emacs finds certain documentation and text files that come with Emacs.

 -- Function: help-buffer
     This function returns the name of the help buffer, which is normally *Help*; if such a buffer does not exist, it is first created.

 -- Macro: with-help-window buffer-name body...
     This macro evaluates the BODY forms, inserting any output they produce into a buffer named BUFFER-NAME like with-output-to-temp-buffer (see Temporary Displays). (Usually, BUFFER-NAME should be the value returned by the function help-buffer.)  It also puts the specified buffer into Help mode and displays a message telling the user how to quit and scroll the help window.

 -- Function: help-setup-xref item interactive-p
     This function updates the cross reference data in the *Help* buffer, which is used to regenerate the help information when the user clicks on the Back or Forward buttons.  Most commands that use the *Help* buffer should invoke this function before clearing the buffer.  The ITEM argument should have the form (FUNCTION . ARGS), where FUNCTION is a function to call, with argument list ARGS, to regenerate the help buffer. The INTERACTIVE-P argument is non-nil if the calling command was invoked interactively; in that case, the stack of items for the *Help* buffer's Back buttons is cleared.

See describe-symbols example, for an example of using help-buffer, with-help-window, and help-setup-xref.

 -- Macro: make-help-screen fname help-line help-text help-map
     This macro defines a help command named FNAME that acts like a prefix key that shows a list of the subcommands it offers.

     When invoked, FNAME displays HELP-TEXT in a window, then reads and executes a key sequence according to HELP-MAP.  The string HELP-TEXT should describe the bindings available in HELP-MAP.

     The command FNAME is defined to handle a few events itself, by scrolling the display of HELP-TEXT.  When FNAME reads one of those special events, it does the scrolling and then reads another event.  When it reads an event that is not one of those few, and which has a binding in HELP-MAP, it executes that key's binding and then returns.

     The argument HELP-LINE should be a single-line summary of the alternatives in HELP-MAP.  In the current version of Emacs, this argument is used only if you set the option three-step-help to t.

     This macro is used in the command help-for-help which is the binding of C-h C-h.

 -- User Option: three-step-help
     If this variable is non-nil, commands defined with make-help-screen display their HELP-LINE strings in the echo area at first, and display the longer HELP-TEXT strings only if the user types the help character again.