Emacs Display
*************

This chapter describes a number of features related to the display that Emacs presents to the user.

Refreshing the Screen
=====================

The function redraw-frame clears and redisplays the entire contents of a given frame (see Frames).  This is useful if the screen is corrupted.

 -- Function: redraw-frame frame
     This function clears and redisplays frame FRAME.

Even more powerful is redraw-display:

 -- Command: redraw-display
     This function clears and redisplays all visible frames.

This function calls for redisplay of certain windows, the next time redisplay is done, but does not clear them first.

 -- Function: force-window-update &optional object
     This function forces redisplay of some or all windows.  If OBJECT is a window, it forces redisplay of that window.  If OBJECT is a buffer or buffer name, it forces redisplay of all windows displaying that buffer.  If OBJECT is nil (or omitted), it forces redisplay of all windows.

Processing user input takes absolute priority over redisplay.  If you call these functions when input is available, they do nothing immediately, but a full redisplay does happen eventually---after all the input has been processed.

Normally, suspending and resuming Emacs also refreshes the screen. Some terminal emulators record separate contents for display-oriented programs such as Emacs and for ordinary sequential display.  If you are using such a terminal, you might want to inhibit the redisplay on resumption.

 -- Variable: no-redraw-on-reenter
     This variable controls whether Emacs redraws the entire screen after it has been suspended and resumed.  Non-nil means there is no need to redraw, nil means redrawing is needed.  The default is nil.

Forcing Redisplay
=================

Emacs redisplay normally stops if input arrives, and does not happen at all if input is available before it starts.  Most of the time, this is exactly what you want.  However, you can prevent preemption by binding redisplay-dont-pause to a non-nil value.

 -- Variable: redisplay-dont-pause
     If this variable is non-nil, pending input does not prevent or halt redisplay; redisplay occurs, and finishes, regardless of whether input is available.

You can request a display update, but only if no input is pending, with (sit-for 0).  To force a display update even when input is pending, do this:

     (let ((redisplay-dont-pause t))
       (sit-for 0))

Truncation
==========

When a line of text extends beyond the right edge of a window, the line can either be continued on the next screen line, or truncated to one screen line.  The additional screen lines used to display a long text line are called continuation lines.  Normally, a $ in the rightmost column of the window indicates truncation; a \ on the rightmost column indicates a line that ``wraps'' onto the next line, which is also called continuing the line.  (The display table can specify alternative indicators; see Display Tables.)

On a graphical display, the $ and \ indicators are replaced with arrow images displayed in the window fringes (see Fringes).

Note that continuation is different from filling; continuation happens on the screen only, not in the buffer contents, and it breaks a line precisely at the right margin, not at a word boundary.  See Filling.

 -- User Option: truncate-lines
     This buffer-local variable controls how Emacs displays lines that extend beyond the right edge of the window.  The default is nil, which specifies continuation.  If the value is non-nil, then these lines are truncated.

     If the variable truncate-partial-width-windows is non-nil, then truncation is always used for side-by-side windows (within one frame) regardless of the value of truncate-lines.

 -- User Option: default-truncate-lines
     This variable is the default value for truncate-lines, for buffers that do not have buffer-local values for it.

 -- User Option: truncate-partial-width-windows
     This variable controls display of lines that extend beyond the right edge of the window, in side-by-side windows (see Splitting Windows). If it is non-nil, these lines are truncated; otherwise, truncate-lines says what to do with them.

When horizontal scrolling (see Horizontal Scrolling) is in use in a window, that forces truncation.

If your buffer contains very long lines, and you use continuation to display them, just thinking about them can make Emacs redisplay slow.  The column computation and indentation functions also become slow.  Then you might find it advisable to set cache-long-line-scans to t.

 -- Variable: cache-long-line-scans
     If this variable is non-nil, various indentation and motion functions, and Emacs redisplay, cache the results of scanning the buffer, and consult the cache to avoid rescanning regions of the buffer unless they are modified.

     Turning on the cache slows down processing of short lines somewhat.

     This variable is automatically buffer-local in every buffer.

The Echo Area
=============

The echo area is used for displaying error messages (see Errors), for messages made with the message primitive, and for echoing keystrokes.  It is not the same as the minibuffer, despite the fact that the minibuffer appears (when active) in the same place on the screen as the echo area.  The GNU Emacs Manual specifies the rules for resolving conflicts between the echo area and the minibuffer for use of that screen space (see The Minibuffer (The GNU Emacs Manual)).

You can write output in the echo area by using the Lisp printing functions with t as the stream (see Output Functions), or explicitly.

Displaying Messages in the Echo Area
------------------------------------

This section describes the functions for explicitly producing echo area messages.  Many other Emacs features display messages there, too.

 -- Function: message format-string &rest arguments
     This function displays a message in the echo area.  The argument FORMAT-STRING is similar to a C language printf format string.  See format in Formatting Strings, for the details on the conversion specifications.  message returns the constructed string.

     In batch mode, message prints the message text on the standard error stream, followed by a newline.

     If FORMAT-STRING, or strings among the ARGUMENTS, have face text properties, these affect the way the message is displayed.

     If FORMAT-STRING is nil or the empty string, message clears the echo area; if the echo area has been expanded automatically, this brings it back to its normal size. If the minibuffer is active, this brings the minibuffer contents back onto the screen immediately.

          (message "Minibuffer depth is %d."
                   (minibuffer-depth))
           -| Minibuffer depth is 0.
          => "Minibuffer depth is 0."

          ---------- Echo Area ----------
          Minibuffer depth is 0.
          ---------- Echo Area ----------

     To automatically display a message in the echo area or in a pop-buffer, depending on its size, use display-message-or-buffer (see below).

 -- Macro: with-temp-message message &rest body
     This construct displays a message in the echo area temporarily, during the execution of BODY.  It displays MESSAGE, executes BODY, then returns the value of the last body form while restoring the previous echo area contents.

 -- Function: message-or-box format-string &rest arguments
     This function displays a message like message, but may display it in a dialog box instead of the echo area.  If this function is called in a command that was invoked using the mouse---more precisely, if last-nonmenu-event (see Command Loop Info) is either nil or a list---then it uses a dialog box or pop-up menu to display the message.  Otherwise, it uses the echo area.  (This is the same criterion that y-or-n-p uses to make a similar decision; see Yes-or-No Queries.)

     You can force use of the mouse or of the echo area by binding last-nonmenu-event to a suitable value around the call.

 -- Function: message-box format-string &rest arguments
     This function displays a message like message, but uses a dialog box (or a pop-up menu) whenever that is possible.  If it is impossible to use a dialog box or pop-up menu, because the terminal does not support them, then message-box uses the echo area, like message.

 -- Function: display-message-or-buffer message &optional buffer-name not-this-window frame
     This function displays the message MESSAGE, which may be either a string or a buffer.  If it is shorter than the maximum height of the echo area, as defined by max-mini-window-height, it is displayed in the echo area, using message.  Otherwise, display-buffer is used to show it in a pop-up buffer.

     Returns either the string shown in the echo area, or when a pop-up buffer is used, the window used to display it.

     If MESSAGE is a string, then the optional argument BUFFER-NAME is the name of the buffer used to display it when a pop-up buffer is used, defaulting to *Message*.  In the case where MESSAGE is a string and displayed in the echo area, it is not specified whether the contents are inserted into the buffer anyway.

     The optional arguments NOT-THIS-WINDOW and FRAME are as for display-buffer, and only used if a buffer is displayed.

 -- Function: current-message
     This function returns the message currently being displayed in the echo area, or nil if there is none.

Reporting Operation Progress
----------------------------

When an operation can take a while to finish, you should inform the user about the progress it makes.  This way the user can estimate remaining time and clearly see that Emacs is busy working, not hung.

Functions listed in this section provide simple and efficient way of reporting operation progress.  Here is a working example that does nothing useful:

     (let ((progress-reporter
            (make-progress-reporter "Collecting mana for Emacs..."
                                    0  500)))
       (dotimes (k 500)
         (sit-for 0.01)
         (progress-reporter-update progress-reporter k))
       (progress-reporter-done progress-reporter))

 -- Function: make-progress-reporter message min-value max-value &optional current-value min-change min-time
     This function creates and returns a progress reporter---an object you will use as an argument for all other functions listed here.  The idea is to precompute as much data as possible to make progress reporting very fast.

     When this progress reporter is subsequently used, it will display MESSAGE in the echo area, followed by progress percentage. MESSAGE is treated as a simple string.  If you need it to depend on a filename, for instance, use format before calling this function.

     MIN-VALUE and MAX-VALUE arguments stand for starting and final states of your operation.  For instance, if you scan a buffer, they should be the results of point-min and point-max correspondingly.  It is required that MAX-VALUE is greater than MIN-VALUE.  If you create progress reporter when some part of the operation has already been completed, then specify CURRENT-VALUE argument.  But normally you should omit it or set it to nil---it will default to MIN-VALUE then.

     Remaining arguments control the rate of echo area updates.  Progress reporter will wait for at least MIN-CHANGE more percents of the operation to be completed before printing next message. MIN-TIME specifies the minimum time in seconds to pass between successive prints.  It can be fractional.  Depending on Emacs and system capabilities, progress reporter may or may not respect this last argument or do it with varying precision.  Default value for MIN-CHANGE is 1 (one percent), for MIN-TIME---0.2 (seconds.)

     This function calls progress-reporter-update, so the first message is printed immediately.

 -- Function: progress-reporter-update reporter value
     This function does the main work of reporting progress of your operation.  It displays the message of REPORTER, followed by progress percentage determined by VALUE.  If percentage is zero, or close enough according to the MIN-CHANGE and MIN-TIME arguments, then it is omitted from the output.

     REPORTER must be the result of a call to make-progress-reporter.  VALUE specifies the current state of your operation and must be between MIN-VALUE and MAX-VALUE (inclusive) as passed to make-progress-reporter.  For instance, if you scan a buffer, then VALUE should be the result of a call to point.

     This function respects MIN-CHANGE and MIN-TIME as passed to make-progress-reporter and so does not output new messages on every invocation.  It is thus very fast and normally you should not try to reduce the number of calls to it: resulting overhead will most likely negate your effort.

 -- Function: progress-reporter-force-update reporter value &optional new-message
     This function is similar to progress-reporter-update except that it prints a message in the echo area unconditionally.

     The first two arguments have the same meaning as for progress-reporter-update.  Optional NEW-MESSAGE allows you to change the message of the REPORTER.  Since this functions always updates the echo area, such a change will be immediately presented to the user.

 -- Function: progress-reporter-done reporter
     This function should be called when the operation is finished.  It prints the message of REPORTER followed by word ``done'' in the echo area.

     You should always call this function and not hope for progress-reporter-update to print ``100%.''  Firstly, it may never print it, there are many good reasons for this not to happen. Secondly, ``done'' is more explicit.

 -- Macro: dotimes-with-progress-reporter (var count [result]) message body...
     This is a convenience macro that works the same way as dotimes does, but also reports loop progress using the functions described above.  It allows you to save some typing.

     You can rewrite the example in the beginning of this node using this macro this way:

          (dotimes-with-progress-reporter
              (k 500)
              "Collecting some mana for Emacs..."
            (sit-for 0.01))

Logging Messages in *Messages*
------------------------------

Almost all the messages displayed in the echo area are also recorded in the *Messages* buffer so that the user can refer back to them.  This includes all the messages that are output with message.

 -- User Option: message-log-max
     This variable specifies how many lines to keep in the *Messages* buffer.  The value t means there is no limit on how many lines to keep.  The value nil disables message logging entirely.  Here's how to display a message and prevent it from being logged:

          (let (message-log-max)
            (message ...))

To make *Messages* more convenient for the user, the logging facility combines successive identical messages.  It also combines successive related messages for the sake of two cases: question followed by answer, and a series of progress messages.

A ``question followed by an answer'' means two messages like the ones produced by y-or-n-p: the first is QUESTION, and the second is QUESTION...ANSWER.  The first message conveys no additional information beyond what's in the second, so logging the second message discards the first from the log.

A ``series of progress messages'' means successive messages like those produced by make-progress-reporter.  They have the form BASE...HOW-FAR, where BASE is the same each time, while HOW-FAR varies.  Logging each message in the series discards the previous one, provided they are consecutive.

The functions make-progress-reporter and y-or-n-p don't have to do anything special to activate the message log combination feature.  It operates whenever two consecutive messages are logged that share a common prefix ending in ....

Echo Area Customization
-----------------------

These variables control details of how the echo area works.

 -- Variable: cursor-in-echo-area
     This variable controls where the cursor appears when a message is displayed in the echo area.  If it is non-nil, then the cursor appears at the end of the message.  Otherwise, the cursor appears at point---not in the echo area at all.

     The value is normally nil; Lisp programs bind it to t for brief periods of time.

 -- Variable: echo-area-clear-hook
     This normal hook is run whenever the echo area is cleared---either by (message nil) or for any other reason.

 -- Variable: echo-keystrokes
     This variable determines how much time should elapse before command characters echo.  Its value must be an integer or floating point number, which specifies the number of seconds to wait before echoing.  If the user types a prefix key (such as C-x) and then delays this many seconds before continuing, the prefix key is echoed in the echo area.  (Once echoing begins in a key sequence, all subsequent characters in the same key sequence are echoed immediately.)

     If the value is zero, then command input is not echoed.

 -- Variable: message-truncate-lines
     Normally, displaying a long message resizes the echo area to display the entire message.  But if the variable message-truncate-lines is non-nil, the echo area does not resize, and the message is truncated to fit it, as in Emacs 20 and before.

The variable max-mini-window-height, which specifies the maximum height for resizing minibuffer windows, also applies to the echo area (which is really a special use of the minibuffer window. See Minibuffer Misc.

Reporting Warnings
==================

Warnings are a facility for a program to inform the user of a possible problem, but continue running.

Warning Basics
--------------

Every warning has a textual message, which explains the problem for the user, and a severity level which is a symbol.  Here are the possible severity levels, in order of decreasing severity, and their meanings:

:emergency
     A problem that will seriously impair Emacs operation soon if you do not attend to it promptly.

:error
     A report of data or circumstances that are inherently wrong.

:warning
     A report of data or circumstances that are not inherently wrong, but raise suspicion of a possible problem.

:debug
     A report of information that may be useful if you are debugging.

When your program encounters invalid input data, it can either signal a Lisp error by calling error or signal or report a warning with severity :error.  Signaling a Lisp error is the easiest thing to do, but it means the program cannot continue processing.  If you want to take the trouble to implement a way to continue processing despite the bad data, then reporting a warning of severity :error is the right way to inform the user of the problem.  For instance, the Emacs Lisp byte compiler can report an error that way and continue compiling other functions.  (If the program signals a Lisp error and then handles it with condition-case, the user won't see the error message; it could show the message to the user by reporting it as a warning.)

Each warning has a warning type to classify it.  The type is a list of symbols.  The first symbol should be the custom group that you use for the program's user options.  For example, byte compiler warnings use the warning type (bytecomp).  You can also subcategorize the warnings, if you wish, by using more symbols in the list.

 -- Function: display-warning type message &optional level buffer-name
     This function reports a warning, using MESSAGE as the message and TYPE as the warning type.  LEVEL should be the severity level, with :warning being the default.

     BUFFER-NAME, if non-nil, specifies the name of the buffer for logging the warning.  By default, it is *Warnings*.

 -- Function: lwarn type level message &rest args
     This function reports a warning using the value of (format MESSAGE ARGS...) as the message.  In other respects it is equivalent to display-warning.

 -- Function: warn message &rest args
     This function reports a warning using the value of (format MESSAGE ARGS...) as the message, (emacs) as the type, and :warning as the severity level.  It exists for compatibility only; we recommend not using it, because you should specify a specific warning type.

Warning Variables
-----------------

Programs can customize how their warnings appear by binding the variables described in this section.

 -- Variable: warning-levels
     This list defines the meaning and severity order of the warning severity levels.  Each element defines one severity level, and they are arranged in order of decreasing severity.

     Each element has the form (LEVEL STRING FUNCTION), where LEVEL is the severity level it defines. STRING specifies the textual description of this level. STRING should use %s to specify where to put the warning type information, or it can omit the %s so as not to include that information.

     The optional FUNCTION, if non-nil, is a function to call with no arguments, to get the user's attention.

     Normally you should not change the value of this variable.

 -- Variable: warning-prefix-function
     If non-nil, the value is a function to generate prefix text for warnings.  Programs can bind the variable to a suitable function. display-warning calls this function with the warnings buffer current, and the function can insert text in it.  That text becomes the beginning of the warning message.

     The function is called with two arguments, the severity level and its entry in warning-levels.  It should return a list to use as the entry (this value need not be an actual member of warning-levels).  By constructing this value, the function can change the severity of the warning, or specify different handling for a given severity level.

     If the variable's value is nil then there is no function to call.

 -- Variable: warning-series
     Programs can bind this variable to t to say that the next warning should begin a series.  When several warnings form a series, that means to leave point on the first warning of the series, rather than keep moving it for each warning so that it appears on the last one. The series ends when the local binding is unbound and warning-series becomes nil again.

     The value can also be a symbol with a function definition.  That is equivalent to t, except that the next warning will also call the function with no arguments with the warnings buffer current.  The function can insert text which will serve as a header for the series of warnings.

     Once a series has begun, the value is a marker which points to the buffer position in the warnings buffer of the start of the series.

     The variable's normal value is nil, which means to handle each warning separately.

 -- Variable: warning-fill-prefix
     When this variable is non-nil, it specifies a fill prefix to use for filling each warning's text.

 -- Variable: warning-type-format
     This variable specifies the format for displaying the warning type in the warning message.  The result of formatting the type this way gets included in the message under the control of the string in the entry in warning-levels.  The default value is " (%s)". If you bind it to "" then the warning type won't appear at all.

Warning Options
---------------

These variables are used by users to control what happens when a Lisp program reports a warning.

 -- User Option: warning-minimum-level
     This user option specifies the minimum severity level that should be shown immediately to the user.  The default is :warning, which means to immediately display all warnings except :debug warnings.

 -- User Option: warning-minimum-log-level
     This user option specifies the minimum severity level that should be logged in the warnings buffer.  The default is :warning, which means to log all warnings except :debug warnings.

 -- User Option: warning-suppress-types
     This list specifies which warning types should not be displayed immediately for the user.  Each element of the list should be a list of symbols.  If its elements match the first elements in a warning type, then that warning is not displayed immediately.

 -- User Option: warning-suppress-log-types
     This list specifies which warning types should not be logged in the warnings buffer.  Each element of the list should be a list of symbols.  If it matches the first few elements in a warning type, then that warning is not logged.

Invisible Text
==============

You can make characters invisible, so that they do not appear on the screen, with the invisible property.  This can be either a text property (see Text Properties) or a property of an overlay (see Overlays).  Cursor motion also partly ignores these characters; if the command loop finds point within them, it moves point to the other side of them.

In the simplest case, any non-nil invisible property makes a character invisible.  This is the default case---if you don't alter the default value of buffer-invisibility-spec, this is how the invisible property works.  You should normally use t as the value of the invisible property if you don't plan to set buffer-invisibility-spec yourself.

More generally, you can use the variable buffer-invisibility-spec to control which values of the invisible property make text invisible.  This permits you to classify the text into different subsets in advance, by giving them different invisible values, and subsequently make various subsets visible or invisible by changing the value of buffer-invisibility-spec.

Controlling visibility with buffer-invisibility-spec is especially useful in a program to display the list of entries in a database.  It permits the implementation of convenient filtering commands to view just a part of the entries in the database.  Setting this variable is very fast, much faster than scanning all the text in the buffer looking for properties to change.

 -- Variable: buffer-invisibility-spec
     This variable specifies which kinds of invisible properties actually make a character invisible.  Setting this variable makes it buffer-local.

     t
          A character is invisible if its invisible property is non-nil.  This is the default.

     a list
          Each element of the list specifies a criterion for invisibility; if a character's invisible property fits any one of these criteria, the character is invisible.  The list can have two kinds of elements:

          ATOM
               A character is invisible if its invisible property value is ATOM or if it is a list with ATOM as a member.

          (ATOM . t)
               A character is invisible if its invisible property value is ATOM or if it is a list with ATOM as a member. Moreover, if this character is at the end of a line and is followed by a visible newline, it displays an ellipsis.

Two functions are specifically provided for adding elements to buffer-invisibility-spec and removing elements from it.

 -- Function: add-to-invisibility-spec element
     This function adds the element ELEMENT to buffer-invisibility-spec.  If buffer-invisibility-spec was t, it changes to a list, (t), so that text whose invisible property is t remains invisible.

 -- Function: remove-from-invisibility-spec element
     This removes the element ELEMENT from buffer-invisibility-spec.  This does nothing if ELEMENT is not in the list.

A convention for use of buffer-invisibility-spec is that a major mode should use the mode's own name as an element of buffer-invisibility-spec and as the value of the invisible property:

     ;; If you want to display an ellipsis:
     (add-to-invisibility-spec '(my-symbol . t))
     ;; If you don't want ellipsis:
     (add-to-invisibility-spec 'my-symbol)

     (overlay-put (make-overlay beginning end)
                  'invisible 'my-symbol)

     ;; When done with the overlays:
     (remove-from-invisibility-spec '(my-symbol . t))
     ;; Or respectively:
     (remove-from-invisibility-spec 'my-symbol)

Ordinarily, functions that operate on text or move point do not care whether the text is invisible.  The user-level line motion commands explicitly ignore invisible newlines if line-move-ignore-invisible is non-nil (the default), but only because they are explicitly programmed to do so.

However, if a command ends with point inside or immediately before invisible text, the main editing loop moves point further forward or further backward (in the same direction that the command already moved it) until that condition is no longer true.  Thus, if the command moved point back into an invisible range, Emacs moves point back to the beginning of that range, and then back one more character.  If the command moved point forward into an invisible range, Emacs moves point forward up to the first visible character that follows the invisible text.

Incremental search can make invisible overlays visible temporarily and/or permanently when a match includes invisible text.  To enable this, the overlay should have a non-nil isearch-open-invisible property.  The property value should be a function to be called with the overlay as an argument.  This function should make the overlay visible permanently; it is used when the match overlaps the overlay on exit from the search.

During the search, such overlays are made temporarily visible by temporarily modifying their invisible and intangible properties.  If you want this to be done differently for a certain overlay, give it an isearch-open-invisible-temporary property which is a function. The function is called with two arguments: the first is the overlay, and the second is nil to make the overlay visible, or t to make it invisible again.

Selective Display
=================

Selective display refers to a pair of related features for hiding certain lines on the screen.

The first variant, explicit selective display, is designed for use in a Lisp program: it controls which lines are hidden by altering the text.  This kind of hiding in some ways resembles the effect of the invisible property (see Invisible Text), but the two features are different and do not work the same way.

In the second variant, the choice of lines to hide is made automatically based on indentation.  This variant is designed to be a user-level feature.

The way you control explicit selective display is by replacing a newline (control-j) with a carriage return (control-m).  The text that was formerly a line following that newline is now hidden.  Strictly speaking, it is temporarily no longer a line at all, since only newlines can separate lines; it is now part of the previous line.

Selective display does not directly affect editing commands.  For example, C-f (forward-char) moves point unhesitatingly into hidden text.  However, the replacement of newline characters with carriage return characters affects some editing commands.  For example, next-line skips hidden lines, since it searches only for newlines.  Modes that use selective display can also define commands that take account of the newlines, or that control which parts of the text are hidden.

When you write a selectively displayed buffer into a file, all the control-m's are output as newlines.  This means that when you next read in the file, it looks OK, with nothing hidden.  The selective display effect is seen only within Emacs.

 -- Variable: selective-display
     This buffer-local variable enables selective display.  This means that lines, or portions of lines, may be made hidden.

       * If the value of selective-display is t, then the character control-m marks the start of hidden text; the control-m, and the rest of the line following it, are not displayed.  This is explicit selective display.

       * If the value of selective-display is a positive integer, then lines that start with more than that many columns of indentation are not displayed.

     When some portion of a buffer is hidden, the vertical movement commands operate as if that portion did not exist, allowing a single next-line command to skip any number of hidden lines. However, character movement commands (such as forward-char) do not skip the hidden portion, and it is possible (if tricky) to insert or delete text in an hidden portion.

     In the examples below, we show the display appearance of the buffer foo, which changes with the value of selective-display.  The contents of the buffer do not change.

          (setq selective-display nil)
               => nil

          ---------- Buffer: foo ----------
          1 on this column
           2on this column
            3n this column
            3n this column
           2on this column
          1 on this column
          ---------- Buffer: foo ----------

          (setq selective-display 2)
               => 2

          ---------- Buffer: foo ----------
          1 on this column
           2on this column
           2on this column
          1 on this column
          ---------- Buffer: foo ----------

 -- Variable: selective-display-ellipses
     If this buffer-local variable is non-nil, then Emacs displays ... at the end of a line that is followed by hidden text. This example is a continuation of the previous one.

          (setq selective-display-ellipses t)
               => t

          ---------- Buffer: foo ----------
          1 on this column
           2on this column ...
           2on this column
          1 on this column
          ---------- Buffer: foo ----------

     You can use a display table to substitute other text for the ellipsis (...).  See Display Tables.

Temporary Displays
==================

Temporary displays are used by Lisp programs to put output into a buffer and then present it to the user for perusal rather than for editing.  Many help commands use this feature.

 -- Special Form: with-output-to-temp-buffer buffer-name forms...
     This function executes FORMS while arranging to insert any output they print into the buffer named BUFFER-NAME, which is first created if necessary, and put into Help mode.  Finally, the buffer is displayed in some window, but not selected.

     If the FORMS do not change the major mode in the output buffer, so that it is still Help mode at the end of their execution, then with-output-to-temp-buffer makes this buffer read-only at the end, and also scans it for function and variable names to make them into clickable cross-references.  See Tips for Documentation Strings, in particular the item on hyperlinks in documentation strings, for more details.

     The string BUFFER-NAME specifies the temporary buffer, which need not already exist.  The argument must be a string, not a buffer. The buffer is erased initially (with no questions asked), and it is marked as unmodified after with-output-to-temp-buffer exits.

     with-output-to-temp-buffer binds standard-output to the temporary buffer, then it evaluates the forms in FORMS.  Output using the Lisp output functions within FORMS goes by default to that buffer (but screen display and messages in the echo area, although they are ``output'' in the general sense of the word, are not affected). See Output Functions.

     Several hooks are available for customizing the behavior of this construct; they are listed below.

     The value of the last form in FORMS is returned.

          ---------- Buffer: foo ----------
           This is the contents of foo.
          ---------- Buffer: foo ----------

          (with-output-to-temp-buffer "foo"
              (print 20)
              (print standard-output))
          => #<buffer foo>

          ---------- Buffer: foo ----------
          20

          #<buffer foo>

          ---------- Buffer: foo ----------

 -- Variable: temp-buffer-show-function
     If this variable is non-nil, with-output-to-temp-buffer calls it as a function to do the job of displaying a help buffer.  The function gets one argument, which is the buffer it should display.

     It is a good idea for this function to run temp-buffer-show-hook just as with-output-to-temp-buffer normally would, inside of save-selected-window and with the chosen window and buffer selected.

 -- Variable: temp-buffer-setup-hook
     This normal hook is run by with-output-to-temp-buffer before evaluating BODY.  When the hook runs, the temporary buffer is current.  This hook is normally set up with a function to put the buffer in Help mode.

 -- Variable: temp-buffer-show-hook
     This normal hook is run by with-output-to-temp-buffer after displaying the temporary buffer.  When the hook runs, the temporary buffer is current, and the window it was displayed in is selected.  This hook is normally set up with a function to make the buffer read only, and find function names and variable names in it, provided the major mode is Help mode.

 -- Function: momentary-string-display string position &optional char message
     This function momentarily displays STRING in the current buffer at POSITION.  It has no effect on the undo list or on the buffer's modification status.

     The momentary display remains until the next input event.  If the next input event is CHAR, momentary-string-display ignores it and returns.  Otherwise, that event remains buffered for subsequent use as input.  Thus, typing CHAR will simply remove the string from the display, while typing (say) C-f will remove the string from the display and later (presumably) move point forward.  The argument CHAR is a space by default.

     The return value of momentary-string-display is not meaningful.

     If the string STRING does not contain control characters, you can do the same job in a more general way by creating (and then subsequently deleting) an overlay with a before-string property. See Overlay Properties.

     If MESSAGE is non-nil, it is displayed in the echo area while STRING is displayed in the buffer.  If it is nil, a default message says to type CHAR to continue.

     In this example, point is initially located at the beginning of the second line:

          ---------- Buffer: foo ----------
          This is the contents of foo.
          -!-Second line.
          ---------- Buffer: foo ----------

          (momentary-string-display
            "**** Important Message! ****"
            (point) ?\r
            "Type RET when done reading")
          => t

          ---------- Buffer: foo ----------
          This is the contents of foo.
          **** Important Message! ****Second line.
          ---------- Buffer: foo ----------

          ---------- Echo Area ----------
          Type RET when done reading
          ---------- Echo Area ----------

Overlays
========

You can use overlays to alter the appearance of a buffer's text on the screen, for the sake of presentation features.  An overlay is an object that belongs to a particular buffer, and has a specified beginning and end.  It also has properties that you can examine and set; these affect the display of the text within the overlay.

An overlay uses markers to record its beginning and end; thus, editing the text of the buffer adjusts the beginning and end of each overlay so that it stays with the text.  When you create the overlay, you can specify whether text inserted at the beginning should be inside the overlay or outside, and likewise for the end of the overlay.

Managing Overlays
-----------------

This section describes the functions to create, delete and move overlays, and to examine their contents.  Overlay changes are not recorded in the buffer's undo list, since the overlays are not part of the buffer's contents.

 -- Function: overlayp object
     This function returns t if OBJECT is an overlay.

 -- Function: make-overlay start end &optional buffer front-advance rear-advance
     This function creates and returns an overlay that belongs to BUFFER and ranges from START to END.  Both START and END must specify buffer positions; they may be integers or markers.  If BUFFER is omitted, the overlay is created in the current buffer.

     The arguments FRONT-ADVANCE and REAR-ADVANCE specify the marker insertion type for the start of the overlay and for the end of the overlay, respectively.  See Marker Insertion Types.  If they are both nil, the default, then the overlay extends to include any text inserted at the beginning, but not text inserted at the end. If FRONT-ADVANCE is non-nil, text inserted at the beginning of the overlay is excluded from the overlay.  If REAR-ADVANCE is non-nil, text inserted at the end of the overlay is included in the overlay.

 -- Function: overlay-start overlay
     This function returns the position at which OVERLAY starts, as an integer.

 -- Function: overlay-end overlay
     This function returns the position at which OVERLAY ends, as an integer.

 -- Function: overlay-buffer overlay
     This function returns the buffer that OVERLAY belongs to.  It returns nil if OVERLAY has been deleted.

 -- Function: delete-overlay overlay
     This function deletes OVERLAY.  The overlay continues to exist as a Lisp object, and its property list is unchanged, but it ceases to be attached to the buffer it belonged to, and ceases to have any effect on display.

     A deleted overlay is not permanently disconnected.  You can give it a position in a buffer again by calling move-overlay.

 -- Function: move-overlay overlay start end &optional buffer
     This function moves OVERLAY to BUFFER, and places its bounds at START and END.  Both arguments START and END must specify buffer positions; they may be integers or markers.

     If BUFFER is omitted, OVERLAY stays in the same buffer it was already associated with; if OVERLAY was deleted, it goes into the current buffer.

     The return value is OVERLAY.

     This is the only valid way to change the endpoints of an overlay.  Do not try modifying the markers in the overlay by hand, as that fails to update other vital data structures and can cause some overlays to be ``lost''.

 -- Function: remove-overlays &optional start end name value
     This function removes all the overlays between START and END whose property NAME has the value VALUE.  It can move the endpoints of the overlays in the region, or split them.

     If NAME is omitted or nil, it means to delete all overlays in the specified region.  If START and/or END are omitted or nil, that means the beginning and end of the buffer respectively. Therefore, (remove-overlays) removes all the overlays in the current buffer.

Here are some examples:

     ;; Create an overlay.
     (setq foo (make-overlay 1 10))
          => #<overlay from 1 to 10 in display.texi>
     (overlay-start foo)
          => 1
     (overlay-end foo)
          => 10
     (overlay-buffer foo)
          => #<buffer display.texi>
     ;; Give it a property we can check later.
     (overlay-put foo 'happy t)
          => t
     ;; Verify the property is present.
     (overlay-get foo 'happy)
          => t
     ;; Move the overlay.
     (move-overlay foo 5 20)
          => #<overlay from 5 to 20 in display.texi>
     (overlay-start foo)
          => 5
     (overlay-end foo)
          => 20
     ;; Delete the overlay.
     (delete-overlay foo)
          => nil
     ;; Verify it is deleted.
     foo
          => #<overlay in no buffer>
     ;; A deleted overlay has no position.
     (overlay-start foo)
          => nil
     (overlay-end foo)
          => nil
     (overlay-buffer foo)
          => nil
     ;; Undelete the overlay.
     (move-overlay foo 1 20)
          => #<overlay from 1 to 20 in display.texi>
     ;; Verify the results.
     (overlay-start foo)
          => 1
     (overlay-end foo)
          => 20
     (overlay-buffer foo)
          => #<buffer display.texi>
     ;; Moving and deleting the overlay does not change its properties.
     (overlay-get foo 'happy)
          => t

Overlay Properties
------------------

Overlay properties are like text properties in that the properties that alter how a character is displayed can come from either source.  But in most respects they are different.  See Text Properties, for comparison.

Text properties are considered a part of the text; overlays and their properties are specifically considered not to be part of the text.  Thus, copying text between various buffers and strings preserves text properties, but does not try to preserve overlays. Changing a buffer's text properties marks the buffer as modified, while moving an overlay or changing its properties does not.  Unlike text property changes, overlay property changes are not recorded in the buffer's undo list.

These functions read and set the properties of an overlay:

 -- Function: overlay-get overlay prop
     This function returns the value of property PROP recorded in OVERLAY, if any.  If OVERLAY does not record any value for that property, but it does have a category property which is a symbol, that symbol's PROP property is used.  Otherwise, the value is nil.

 -- Function: overlay-put overlay prop value
     This function sets the value of property PROP recorded in OVERLAY to VALUE.  It returns VALUE.

 -- Function: overlay-properties overlay
     This returns a copy of the property list of OVERLAY.

See also the function get-char-property which checks both overlay properties and text properties for a given character. See Examining Properties.

Many overlay properties have special meanings; here is a table of them:

priority
     This property's value (which should be a nonnegative integer number) determines the priority of the overlay.  The priority matters when two or more overlays cover the same character and both specify the same property; the one whose priority value is larger takes priority over the other.  For the face property, the higher priority value does not completely replace the other; instead, its face attributes override the face attributes of the lower priority face property.

     Currently, all overlays take priority over text properties.  Please avoid using negative priority values, as we have not yet decided just what they should mean.

window
     If the window property is non-nil, then the overlay applies only on that window.

category
     If an overlay has a category property, we call it the category of the overlay.  It should be a symbol.  The properties of the symbol serve as defaults for the properties of the overlay.

face
     This property controls the way text is displayed---for example, which font and which colors.  See Faces, for more information.

     In the simplest case, the value is a face name.  It can also be a list; then each element can be any of these possibilities:

       * A face name (a symbol or string).

       * A property list of face attributes.  This has the form (KEYWORD VALUE ...), where each KEYWORD is a face attribute name and VALUE is a meaningful value for that attribute.  With this feature, you do not need to create a face each time you want to specify a particular attribute for certain text.  See Face Attributes.

       * A cons cell of the form (foreground-color . COLOR-NAME) or (background-color . COLOR-NAME).  These elements specify just the foreground color or just the background color.

          (foreground-color . COLOR-NAME) has the same effect as (:foreground COLOR-NAME); likewise for the background.

mouse-face
     This property is used instead of face when the mouse is within the range of the overlay.

display
     This property activates various features that change the way text is displayed.  For example, it can make text appear taller or shorter, higher or lower, wider or narrower, or replaced with an image. See Display Property.

help-echo
     If an overlay has a help-echo property, then when you move the mouse onto the text in the overlay, Emacs displays a help string in the echo area, or in the tooltip window.  For details see Text help-echo.

modification-hooks
     This property's value is a list of functions to be called if any character within the overlay is changed or if text is inserted strictly within the overlay.

     The hook functions are called both before and after each change. If the functions save the information they receive, and compare notes between calls, they can determine exactly what change has been made in the buffer text.

     When called before a change, each function receives four arguments: the overlay, nil, and the beginning and end of the text range to be modified.

     When called after a change, each function receives five arguments: the overlay, t, the beginning and end of the text range just modified, and the length of the pre-change text replaced by that range. (For an insertion, the pre-change length is zero; for a deletion, that length is the number of characters deleted, and the post-change beginning and end are equal.)

     If these functions modify the buffer, they should bind inhibit-modification-hooks to t around doing so, to avoid confusing the internal mechanism that calls these hooks.

insert-in-front-hooks
     This property's value is a list of functions to be called before and after inserting text right at the beginning of the overlay.  The calling conventions are the same as for the modification-hooks functions.

insert-behind-hooks
     This property's value is a list of functions to be called before and after inserting text right at the end of the overlay.  The calling conventions are the same as for the modification-hooks functions.

invisible
     The invisible property can make the text in the overlay invisible, which means that it does not appear on the screen. See Invisible Text, for details.

intangible
     The intangible property on an overlay works just like the intangible text property.  See Special Properties, for details.

isearch-open-invisible
     This property tells incremental search how to make an invisible overlay visible, permanently, if the final match overlaps it.  See Invisible Text.

isearch-open-invisible-temporary
     This property tells incremental search how to make an invisible overlay visible, temporarily, during the search.  See Invisible Text.

before-string
     This property's value is a string to add to the display at the beginning of the overlay.  The string does not appear in the buffer in any sense---only on the screen.

after-string
     This property's value is a string to add to the display at the end of the overlay.  The string does not appear in the buffer in any sense---only on the screen.

evaporate
     If this property is non-nil, the overlay is deleted automatically if it becomes empty (i.e., if its length becomes zero).  If you give an empty overlay a non-nil evaporate property, that deletes it immediately.

local-map
     If this property is non-nil, it specifies a keymap for a portion of the text.  The property's value replaces the buffer's local map, when the character after point is within the overlay.  See Active Keymaps.

keymap
     The keymap property is similar to local-map but overrides the buffer's local map (and the map specified by the local-map property) rather than replacing it.

Searching for Overlays
----------------------

 -- Function: overlays-at pos
     This function returns a list of all the overlays that cover the character at position POS in the current buffer.  The list is in no particular order.  An overlay contains position POS if it begins at or before POS, and ends after POS.

     To illustrate usage, here is a Lisp function that returns a list of the overlays that specify property PROP for the character at point:

          (defun find-overlays-specifying (prop)
            (let ((overlays (overlays-at (point)))
                  found)
              (while overlays
                (let ((overlay (car overlays)))
                  (if (overlay-get overlay prop)
                      (setq found (cons overlay found))))
                (setq overlays (cdr overlays)))
              found))

 -- Function: overlays-in beg end
     This function returns a list of the overlays that overlap the region BEG through END.  ``Overlap'' means that at least one character is contained within the overlay and also contained within the specified region; however, empty overlays are included in the result if they are located at BEG, or strictly between BEG and END.

 -- Function: next-overlay-change pos
     This function returns the buffer position of the next beginning or end of an overlay, after POS.  If there is none, it returns (point-max).

 -- Function: previous-overlay-change pos
     This function returns the buffer position of the previous beginning or end of an overlay, before POS.  If there is none, it returns (point-min).

Here's a function which uses next-overlay-change to search for the next character which gets a given property prop from either its overlays or its text properties (see Property Search):

     (defun find-overlay-prop (prop)
       (save-excursion
         (while (and (not (eobp))
                     (not (get-char-property (point) prop)))
           (goto-char (min (next-overlay-change (point))
                           (next-single-property-change (point) prop))))
         (point)))

Now you can search for a happy property like this:

     (find-overlay-prop 'happy)

Width
=====

Since not all characters have the same width, these functions let you check the width of a character.  See Primitive Indent, and Screen Lines, for related functions.

 -- Function: char-width char
     This function returns the width in columns of the character CHAR, if it were displayed in the current buffer and the selected window.

 -- Function: string-width string
     This function returns the width in columns of the string STRING, if it were displayed in the current buffer and the selected window.

 -- Function: truncate-string-to-width string width &optional start-column padding ellipsis
     This function returns the part of STRING that fits within WIDTH columns, as a new string.

     If STRING does not reach WIDTH, then the result ends where STRING ends.  If one multi-column character in STRING extends across the column WIDTH, that character is not included in the result.  Thus, the result can fall short of WIDTH but cannot go beyond it.

     The optional argument START-COLUMN specifies the starting column. If this is non-nil, then the first START-COLUMN columns of the string are omitted from the value.  If one multi-column character in STRING extends across the column START-COLUMN, that character is not included.

     The optional argument PADDING, if non-nil, is a padding character added at the beginning and end of the result string, to extend it to exactly WIDTH columns.  The padding character is used at the end of the result if it falls short of WIDTH.  It is also used at the beginning of the result if one multi-column character in STRING extends across the column START-COLUMN.

     If ELLIPSIS is non-nil, it should be a string which will replace the end of STR (including any padding) if it extends beyond END-COLUMN, unless the display width of STR is equal to or less than the display width of ELLIPSIS.  If ELLIPSIS is non-nil and not a string, it stands for "...".

          (truncate-string-to-width "\tab\t" 12 4)
               => "ab"
          (truncate-string-to-width "\tab\t" 12 4 ?\s)
               => "    ab  "

Line Height
===========

The total height of each display line consists of the height of the contents of the line, and additional vertical line spacing below the display row.

The height of the line contents is normally determined from the maximum height of any character or image on that display line, including the final newline if there is one.  (A line that is continued doesn't include a final newline.)  In the most common case, the line height equals the height of the default frame font.

There are several ways to explicitly control or change the line height, either by specifying an absolute height for the display line, or by adding additional vertical space below one or all lines.

A newline can have a line-height text or overlay property that controls the total height of the display line ending in that newline.

If the property value is a list (HEIGHT TOTAL), then HEIGHT is used as the actual property value for the line-height, and TOTAL specifies the total displayed height of the line, so the line spacing added below the line equals the TOTAL height minus the actual line height.  In this case, the other ways to specify the line spacing are ignored.

If the property value is t, the displayed height of the line is exactly what its contents demand; no line-spacing is added. This case is useful for tiling small images or image slices without adding blank areas between the images.

If the property value is not t, it is a height spec.  A height spec stands for a numeric height value; this height spec specifies the actual line height, LINE-HEIGHT.  There are several ways to write a height spec; here's how each of them translates into a numeric height:

INTEGER
     If the height spec is a positive integer, the height value is that integer.

FLOAT
     If the height spec is a float, FLOAT, the numeric height value is FLOAT times the frame's default line height.

(FACE . RATIO)
     If the height spec is a cons of the format shown, the numeric height is RATIO times the height of face FACE.  RATIO can be any type of number, or nil which means a ratio of 1. If FACE is t, it refers to the current face.

(nil . RATIO)
     If the height spec is a cons of the format shown, the numeric height is RATIO times the height of the contents of the line.

Thus, any valid non-t property value specifies a height in pixels, LINE-HEIGHT, one way or another.  If the line contents' height is less than LINE-HEIGHT, Emacs adds extra vertical space above the line to achieve the total height LINE-HEIGHT.  Otherwise, LINE-HEIGHT has no effect.

If you don't specify the line-height property, the line's height consists of the contents' height plus the line spacing. There are several ways to specify the line spacing for different parts of Emacs text.

You can specify the line spacing for all lines in a frame with the line-spacing frame parameter (see Layout Parameters). However, if the variable default-line-spacing is non-nil, it overrides the frame's line-spacing parameter.  An integer value specifies the number of pixels put below lines on graphical displays.  A floating point number specifies the spacing relative to the frame's default line height.

You can specify the line spacing for all lines in a buffer via the buffer-local line-spacing variable.  An integer value specifies the number of pixels put below lines on graphical displays.  A floating point number specifies the spacing relative to the default frame line height.  This overrides line spacings specified for the frame.

Finally, a newline can have a line-spacing text or overlay property that controls the height of the display line ending with that newline.  The property value overrides the default frame line spacing and the buffer local line-spacing variable.

One way or another, these mechanisms specify a Lisp value for the spacing of each line.  The value is a height spec, and it translates into a Lisp value as described above.  However, in this case the numeric height value specifies the line spacing, rather than the line height.

Faces
=====

A face is a named collection of graphical attributes: font family, foreground color, background color, optional underlining, and many others.  Faces are used in Emacs to control the style of display of particular parts of the text or the frame.  See Standard Faces (The GNU Emacs Manual), for the list of faces Emacs normally comes with.

Each face has its own face number, which distinguishes faces at low levels within Emacs.  However, for most purposes, you refer to faces in Lisp programs by the symbols that name them.

 -- Function: facep object
     This function returns t if OBJECT is a face name string or symbol (or if it is a vector of the kind used internally to record face data).  It returns nil otherwise.

Each face name is meaningful for all frames, and by default it has the same meaning in all frames.  But you can arrange to give a particular face name a special meaning in one frame if you wish.

Defining Faces
--------------

The way to define a new face is with defface.  This creates a kind of customization item (see Customization) which the user can customize using the Customization buffer (see Easy Customization (The GNU Emacs Manual)).

 -- Macro: defface face spec doc [keyword value]...
     This declares FACE as a customizable face that defaults according to SPEC.  You should not quote the symbol FACE, and it should not end in -face (that would be redundant).  The argument DOC specifies the face documentation.  The keywords you can use in defface are the same as in defgroup and defcustom (see Common Keywords).

     When defface executes, it defines the face according to SPEC, then uses any customizations that were read from the init file (see Init File) to override that specification.

     The purpose of SPEC is to specify how the face should appear on different kinds of terminals.  It should be an alist whose elements have the form (DISPLAY ATTS).  Each element's CAR, DISPLAY, specifies a class of terminals.  (The first element, if its CAR is default, is special---it specifies defaults for the remaining elements).  The element's CADR, ATTS, is a list of face attributes and their values; it specifies what the face should look like on that kind of terminal. The possible attributes are defined in the value of custom-face-attributes.

     The DISPLAY part of an element of SPEC determines which frames the element matches.  If more than one element of SPEC matches a given frame, the first element that matches is the one used for that frame.  There are three possibilities for DISPLAY:

     default
          This element of SPEC doesn't match any frames; instead, it specifies defaults that apply to all frames.  This kind of element, if used, must be the first element of SPEC.  Each of the following elements can override any or all of these defaults.

     t
          This element of SPEC matches all frames.  Therefore, any subsequent elements of SPEC are never used.  Normally t is used in the last (or only) element of SPEC.

     a list
          If DISPLAY is a list, each element should have the form (CHARACTERISTIC VALUE...).  Here CHARACTERISTIC specifies a way of classifying frames, and the VALUEs are possible classifications which DISPLAY should apply to.  Here are the possible values of CHARACTERISTIC:

          type
               The kind of window system the frame uses---either graphic (any graphics-capable display), x, pc (for the MS-DOS console), w32 (for MS Windows 9X/NT), or tty (a non-graphics-capable display).

          class
               What kinds of colors the frame supports---either color, grayscale, or mono.

          background
               The kind of background---either light or dark.

          min-colors
               An integer that represents the minimum number of colors the frame should support.  This matches a frame if its display-color-cells value is at least the specified integer.

          supports
               Whether or not the frame can display the face attributes given in VALUE... (see Face Attributes).  See the documentation for the function display-supports-face-attributes-p for more information on exactly how this testing is done.  See Display Face Attribute Testing.

          If an element of DISPLAY specifies more than one VALUE for a given CHARACTERISTIC, any of those values is acceptable.  If DISPLAY has more than one element, each element should specify a different CHARACTERISTIC; then each characteristic of the frame must match one of the VALUEs specified for it in DISPLAY.

Here's how the standard face region is defined:

       '((((class color) (min-colors 88) (background dark))
          :background "blue3")

         (((class color) (min-colors 88) (background light))
          :background "lightgoldenrod2")
         (((class color) (min-colors 16) (background dark))
          :background "blue3")
         (((class color) (min-colors 16) (background light))
          :background "lightgoldenrod2")
         (((class color) (min-colors 8))
          :background "blue" :foreground "white")
         (((type tty) (class mono))
          :inverse-video t)
         (t :background "gray"))

       "Basic face for highlighting the region."
       :group 'basic-faces)

Internally, defface uses the symbol property face-defface-spec to record the face attributes specified in defface, saved-face for the attributes saved by the user with the customization buffer, customized-face for the attributes customized by the user for the current session, but not saved, and face-documentation for the documentation string.

 -- User Option: frame-background-mode
     This option, if non-nil, specifies the background type to use for interpreting face definitions.  If it is dark, then Emacs treats all frames as if they had a dark background, regardless of their actual background colors.  If it is light, then Emacs treats all frames as if they had a light background.

Face Attributes
---------------

The effect of using a face is determined by a fixed set of face attributes.  This table lists all the face attributes, and what they mean.  Note that in general, more than one face can be specified for a given piece of text; when that happens, the attributes of all the faces are merged to specify how to display the text.  See Displaying Faces.

Any attribute in a face can have the value unspecified.  This means the face doesn't specify that attribute.  In face merging, when the first face fails to specify a particular attribute, that means the next face gets a chance.  However, the default face must specify all attributes.

Some of these font attributes are meaningful only on certain kinds of displays---if your display cannot handle a certain attribute, the attribute is ignored.  (The attributes :family, :width, :height, :weight, and :slant correspond to parts of an X Logical Font Descriptor.)

:family
     Font family name, or fontset name (see Fontsets).  If you specify a font family name, the wild-card characters * and ? are allowed.

:width
     Relative proportionate width, also known as the character set width or set width.  This should be one of the symbols ultra-condensed, extra-condensed, condensed, semi-condensed, normal, semi-expanded, expanded, extra-expanded, or ultra-expanded.

:height
     Either the font height, an integer in units of 1/10 point, a floating point number specifying the amount by which to scale the height of any underlying face, or a function, which is called with the old height (from the underlying face), and should return the new height.

:weight
     Font weight---a symbol from this series (from most dense to most faint): ultra-bold, extra-bold, bold, semi-bold, normal, semi-light, light, extra-light, or ultra-light.

     On a text-only terminal, any weight greater than normal is displayed as extra bright, and any weight less than normal is displayed as half-bright (provided the terminal supports the feature).

:slant
     Font slant---one of the symbols italic, oblique, normal, reverse-italic, or reverse-oblique.

     On a text-only terminal, slanted text is displayed as half-bright, if the terminal supports the feature.

:foreground
     Foreground color, a string.  The value can be a system-defined color name, or a hexadecimal color specification of the form #RRGGBB.  (#000000 is black, #ff0000 is red, #00ff00 is green, #0000ff is blue, and #ffffff is white.)

:background
     Background color, a string, like the foreground color.

:inverse-video
     Whether or not characters should be displayed in inverse video.  The value should be t (yes) or nil (no).

:stipple
     The background stipple, a bitmap.

     The value can be a string; that should be the name of a file containing external-format X bitmap data.  The file is found in the directories listed in the variable x-bitmap-file-path.

     Alternatively, the value can specify the bitmap directly, with a list of the form (WIDTH HEIGHT DATA).  Here, WIDTH and HEIGHT specify the size in pixels, and DATA is a string containing the raw bits of the bitmap, row by row.  Each row occupies (WIDTH + 7) / 8 consecutive bytes in the string (which should be a unibyte string for best results). This means that each row always occupies at least one whole byte.

     If the value is nil, that means use no stipple pattern.

     Normally you do not need to set the stipple attribute, because it is used automatically to handle certain shades of gray.

:underline
     Whether or not characters should be underlined, and in what color.  If the value is t, underlining uses the foreground color of the face.  If the value is a string, underlining uses that color.  The value nil means do not underline.

:overline
     Whether or not characters should be overlined, and in what color. The value is used like that of :underline.

:strike-through
     Whether or not characters should be strike-through, and in what color.  The value is used like that of :underline.

:inherit
     The name of a face from which to inherit attributes, or a list of face names.  Attributes from inherited faces are merged into the face like an underlying face would be, with higher priority than underlying faces. If a list of faces is used, attributes from faces earlier in the list override those from later faces.

:box
     Whether or not a box should be drawn around characters, its color, the width of the box lines, and 3D appearance.

Here are the possible values of the :box attribute, and what they mean:

nil
     Don't draw a box.

t
     Draw a box with lines of width 1, in the foreground color.

COLOR
     Draw a box with lines of width 1, in color COLOR.

(:line-width WIDTH :color COLOR :style STYLE)
     This way you can explicitly specify all aspects of the box.  The value WIDTH specifies the width of the lines to draw; it defaults to 1.

     The value COLOR specifies the color to draw with.  The default is the foreground color of the face for simple boxes, and the background color of the face for 3D boxes.

     The value STYLE specifies whether to draw a 3D box.  If it is released-button, the box looks like a 3D button that is not being pressed.  If it is pressed-button, the box looks like a 3D button that is being pressed.  If it is nil or omitted, a plain 2D box is used.

In older versions of Emacs, before :family, :height, :width, :weight, and :slant existed, these attributes were used to specify the type face.  They are now semi-obsolete, but they still work:

:font
     This attribute specifies the font name.

:bold
     A non-nil value specifies a bold font.

:italic
     A non-nil value specifies an italic font.

For compatibility, you can still set these ``attributes'', even though they are not real face attributes.  Here is what that does:

:font
     You can specify an X font name as the ``value'' of this ``attribute''; that sets the :family, :width, :height, :weight, and :slant attributes according to the font name.

     If the value is a pattern with wildcards, the first font that matches the pattern is used to set these attributes.

:bold
     A non-nil makes the face bold; nil makes it normal. This actually works by setting the :weight attribute.

:italic
     A non-nil makes the face italic; nil makes it normal. This actually works by setting the :slant attribute.

 -- Variable: x-bitmap-file-path
     This variable specifies a list of directories for searching for bitmap files, for the :stipple attribute.

 -- Function: bitmap-spec-p object
     This returns t if OBJECT is a valid bitmap specification, suitable for use with :stipple (see above).  It returns nil otherwise.

Face Attribute Functions
------------------------

You can modify the attributes of an existing face with the following functions.  If you specify FRAME, they affect just that frame; otherwise, they affect all frames as well as the defaults that apply to new frames.

 -- Function: set-face-attribute face frame &rest arguments
     This function sets one or more attributes of face FACE for frame FRAME.  If FRAME is nil, it sets the attribute for all frames, and the defaults for new frames.

     The extra arguments ARGUMENTS specify the attributes to set, and the values for them.  They should consist of alternating attribute names (such as :family or :underline) and corresponding values. Thus,

          (set-face-attribute 'foo nil
                              :width 'extended
                              :weight 'bold
                              :underline "red")

     sets the attributes :width, :weight and :underline to the corresponding values.

 -- Function: face-attribute face attribute &optional frame inherit
     This returns the value of the ATTRIBUTE attribute of face FACE on FRAME.  If FRAME is nil, that means the selected frame (see Input Focus).

     If FRAME is t, the value is the default for FACE for new frames.

     If INHERIT is nil, only attributes directly defined by FACE are considered, so the return value may be unspecified, or a relative value.  If INHERIT is non-nil, FACE's definition of ATTRIBUTE is merged with the faces specified by its :inherit attribute; however the return value may still be unspecified or relative.  If INHERIT is a face or a list of faces, then the result is further merged with that face (or faces), until it becomes specified and absolute.

     To ensure that the return value is always specified and absolute, use a value of default for INHERIT; this will resolve any unspecified or relative values by merging with the default face (which is always completely specified).

     For example,

          (face-attribute 'bold :weight)
               => bold

The functions above did not exist before Emacs 21.  For compatibility with older Emacs versions, you can use the following functions to set and examine the face attributes which existed in those versions.

 -- Function: face-attribute-relative-p attribute value
     This function returns non-nil if VALUE, when used as the value of the face attribute ATTRIBUTE, is relative (that is, if it modifies an underlying or inherited value of ATTRIBUTE).

 -- Function: merge-face-attribute attribute value1 value2
     If VALUE1 is a relative value for the face attribute ATTRIBUTE, returns it merged with the underlying value VALUE2; otherwise, if VALUE1 is an absolute value for the face attribute ATTRIBUTE, returns VALUE1 unchanged.

 -- Function: set-face-foreground face color &optional frame
 -- Function: set-face-background face color &optional frame
     These functions set the foreground (or background, respectively) color of face FACE to COLOR.  The argument COLOR should be a string, the name of a color.

     Certain shades of gray are implemented by stipple patterns on black-and-white screens.

 -- Function: set-face-stipple face pattern &optional frame
     This function sets the background stipple pattern of face FACE to PATTERN.  The argument PATTERN should be the name of a stipple pattern defined by the X server, or actual bitmap data (see Face Attributes), or nil meaning don't use stipple.

     Normally there is no need to pay attention to stipple patterns, because they are used automatically to handle certain shades of gray.

 -- Function: set-face-font face font &optional frame
     This function sets the font of face FACE.  This actually sets the attributes :family, :width, :height, :weight, and :slant according to the font name FONT.

 -- Function: set-face-bold-p face bold-p &optional frame
     This function specifies whether FACE should be bold.  If BOLD-P is non-nil, that means yes; nil means no. This actually sets the :weight attribute.

 -- Function: set-face-italic-p face italic-p &optional frame
     This function specifies whether FACE should be italic.  If ITALIC-P is non-nil, that means yes; nil means no. This actually sets the :slant attribute.

 -- Function: set-face-underline-p face underline-p &optional frame
     This function sets the underline attribute of face FACE. Non-nil means do underline; nil means don't.

 -- Function: set-face-inverse-video-p face inverse-video-p &optional frame
     This function sets the :inverse-video attribute of face FACE.

 -- Function: invert-face face &optional frame
     This function swaps the foreground and background colors of face FACE.

These functions examine the attributes of a face.  If you don't specify FRAME, they refer to the default data for new frames. They return the symbol unspecified if the face doesn't define any value for that attribute.

 -- Function: face-foreground face &optional frame inherit
 -- Function: face-background face &optional frame inherit
     These functions return the foreground color (or background color, respectively) of face FACE, as a string.

     If INHERIT is nil, only a color directly defined by the face is returned.  If INHERIT is non-nil, any faces specified by its :inherit attribute are considered as well, and if INHERIT is a face or a list of faces, then they are also considered, until a specified color is found.  To ensure that the return value is always specified, use a value of default for INHERIT.

 -- Function: face-stipple face &optional frame inherit
     This function returns the name of the background stipple pattern of face FACE, or nil if it doesn't have one.

     If INHERIT is nil, only a stipple directly defined by the face is returned.  If INHERIT is non-nil, any faces specified by its :inherit attribute are considered as well, and if INHERIT is a face or a list of faces, then they are also considered, until a specified stipple is found.  To ensure that the return value is always specified, use a value of default for INHERIT.

 -- Function: face-font face &optional frame
     This function returns the name of the font of face FACE.

 -- Function: face-bold-p face &optional frame
     This function returns t if FACE is bold---that is, if it is bolder than normal.  It returns nil otherwise.

 -- Function: face-italic-p face &optional frame
     This function returns t if FACE is italic or oblique, nil otherwise.

 -- Function: face-underline-p face &optional frame
     This function returns the :underline attribute of face FACE.

 -- Function: face-inverse-video-p face &optional frame
     This function returns the :inverse-video attribute of face FACE.

Displaying Faces
----------------

Here are the ways to specify which faces to use for display of text:

  * With defaults.  The default face is used as the ultimate default for all text.  (In Emacs 19 and 20, the default face is used only when no other face is specified.)

  * For a mode line or header line, the face mode-line or mode-line-inactive, or header-line, is merged in just before default.

  * With text properties.  A character can have a face property; if so, the faces and face attributes specified there apply.  See Special Properties.

     If the character has a mouse-face property, that is used instead of the face property when the mouse is ``near enough'' to the character.

  * With overlays.  An overlay can have face and mouse-face properties too; they apply to all the text covered by the overlay.

  * With a region that is active.  In Transient Mark mode, the region is highlighted with the face region (see Standard Faces (The GNU Emacs Manual)).

  * With special glyphs.  Each glyph can specify a particular face number.  See Glyphs.

If these various sources together specify more than one face for a particular character, Emacs merges the attributes of the various faces specified.  For each attribute, Emacs tries first the face of any special glyph; then the face for region highlighting, if appropriate; then the faces specified by overlays, followed by those specified by text properties, then the mode-line or mode-line-inactive or header-line face (if in a mode line or a header line), and last the default face.

When multiple overlays cover one character, an overlay with higher priority overrides those with lower priority.  See Overlays.

Font Selection
--------------

Selecting a font means mapping the specified face attributes for a character to a font that is available on a particular display.  The face attributes, as determined by face merging, specify most of the font choice, but not all.  Part of the choice depends on what character it is.

If the face specifies a fontset name, that fontset determines a pattern for fonts of the given charset.  If the face specifies a font family, a font pattern is constructed.

Emacs tries to find an available font for the given face attributes and character's registry and encoding.  If there is a font that matches exactly, it is used, of course.  The hard case is when no available font exactly fits the specification.  Then Emacs looks for one that is ``close''---one attribute at a time.  You can specify the order to consider the attributes.  In the case where a specified font family is not available, you can specify a set of mappings for alternatives to try.

 -- Variable: face-font-selection-order
     This variable specifies the order of importance of the face attributes :width, :height, :weight, and :slant.  The value should be a list containing those four symbols, in order of decreasing importance.

     Font selection first finds the best available matches for the first attribute listed; then, among the fonts which are best in that way, it searches for the best matches in the second attribute, and so on.

     The attributes :weight and :width have symbolic values in a range centered around normal.  Matches that are more extreme (farther from normal) are somewhat preferred to matches that are less extreme (closer to normal); this is designed to ensure that non-normal faces contrast with normal ones, whenever possible.

     The default is (:width :height :weight :slant), which means first find the fonts closest to the specified :width, then---among the fonts with that width---find a best match for the specified font height, and so on.

     One example of a case where this variable makes a difference is when the default font has no italic equivalent.  With the default ordering, the italic face will use a non-italic font that is similar to the default one.  But if you put :slant before :height, the italic face will use an italic font, even if its height is not quite right.

 -- Variable: face-font-family-alternatives
     This variable lets you specify alternative font families to try, if a given family is specified and doesn't exist.  Each element should have this form:

          (FAMILY ALTERNATE-FAMILIES...)

     If FAMILY is specified but not available, Emacs will try the other families given in ALTERNATE-FAMILIES, one by one, until it finds a family that does exist.

 -- Variable: face-font-registry-alternatives
     This variable lets you specify alternative font registries to try, if a given registry is specified and doesn't exist.  Each element should have this form:

          (REGISTRY ALTERNATE-REGISTRIES...)

     If REGISTRY is specified but not available, Emacs will try the other registries given in ALTERNATE-REGISTRIES, one by one, until it finds a registry that does exist.

Emacs can make use of scalable fonts, but by default it does not use them, since the use of too many or too big scalable fonts can crash XFree86 servers.

 -- Variable: scalable-fonts-allowed
     This variable controls which scalable fonts to use.  A value of nil, the default, means do not use scalable fonts.  t means to use any scalable font that seems appropriate for the text.

     Otherwise, the value must be a list of regular expressions.  Then a scalable font is enabled for use if its name matches any regular expression in the list.  For example,

          (setq scalable-fonts-allowed '("muleindian-2$"))

     allows the use of scalable fonts with registry muleindian-2.

 -- Function: clear-face-cache &optional unload-p
     This function clears the face cache for all frames. If UNLOAD-P is non-nil, that means to unload all unused fonts as well.

 -- Variable: face-font-rescale-alist
     This variable specifies scaling for certain faces.  Its value should be a list of elements of the form

          (FONTNAME-REGEXP . SCALE-FACTOR)

     If FONTNAME-REGEXP matches the font name that is about to be used, this says to choose a larger similar font according to the factor SCALE-FACTOR.  You would use this feature to normalize the font size if certain fonts are bigger or smaller than their nominal heights and widths would suggest.

Functions for Working with Faces
--------------------------------

Here are additional functions for creating and working with faces.

 -- Function: make-face name
     This function defines a new face named NAME, initially with all attributes nil.  It does nothing if there is already a face named NAME.

 -- Function: face-list
     This function returns a list of all defined face names.

 -- Function: copy-face old-face new-name &optional frame new-frame
     This function defines a face named NEW-NAME as a copy of the existing face named OLD-FACE.  It creates the face NEW-NAME if that doesn't already exist.

     If the optional argument FRAME is given, this function applies only to that frame.  Otherwise it applies to each frame individually, copying attributes from OLD-FACE in each frame to NEW-FACE in the same frame.

     If the optional argument NEW-FRAME is given, then copy-face copies the attributes of OLD-FACE in FRAME to NEW-NAME in NEW-FRAME.

 -- Function: face-id face
     This function returns the face number of face FACE.

 -- Function: face-documentation face
     This function returns the documentation string of face FACE, or nil if none was specified for it.

 -- Function: face-equal face1 face2 &optional frame
     This returns t if the faces FACE1 and FACE2 have the same attributes for display.

 -- Function: face-differs-from-default-p face &optional frame
     This returns non-nil if the face FACE displays differently from the default face.

A face alias provides an equivalent name for a face.  You can define a face alias by giving the alias symbol the face-alias property, with a value of the target face name.  The following example makes modeline an alias for the mode-line face.

     (put 'modeline 'face-alias 'mode-line)

Automatic Face Assignment
-------------------------

This hook is used for automatically assigning faces to text in the buffer.  It is part of the implementation of Font-Lock mode.

 -- Variable: fontification-functions
     This variable holds a list of functions that are called by Emacs redisplay as needed to assign faces automatically to text in the buffer.

     The functions are called in the order listed, with one argument, a buffer position POS.  Each function should attempt to assign faces to the text in the current buffer starting at POS.

     Each function should record the faces they assign by setting the face property.  It should also add a non-nil fontified property for all the text it has assigned faces to. That property tells redisplay that faces have been assigned to that text already.

     It is probably a good idea for each function to do nothing if the character after POS already has a non-nil fontified property, but this is not required.  If one function overrides the assignments made by a previous one, the properties as they are after the last function finishes are the ones that really matter.

     For efficiency, we recommend writing these functions so that they usually assign faces to around 400 to 600 characters at each call.

Looking Up Fonts
----------------

 -- Function: x-list-fonts pattern &optional face frame maximum
     This function returns a list of available font names that match PATTERN.  If the optional arguments FACE and FRAME are specified, then the list is limited to fonts that are the same size as FACE currently is on FRAME.

     The argument PATTERN should be a string, perhaps with wildcard characters: the * character matches any substring, and the ? character matches any single character.  Pattern matching of font names ignores case.

     If you specify FACE and FRAME, FACE should be a face name (a symbol) and FRAME should be a frame.

     The optional argument MAXIMUM sets a limit on how many fonts to return.  If this is non-nil, then the return value is truncated after the first MAXIMUM matching fonts.  Specifying a small value for MAXIMUM can make this function much faster, in cases where many fonts match the pattern.

 -- Function: x-family-fonts &optional family frame
     This function returns a list describing the available fonts for family FAMILY on FRAME.  If FAMILY is omitted or nil, this list applies to all families, and therefore, it contains all available fonts.  Otherwise, FAMILY must be a string; it may contain the wildcards ? and *.

     The list describes the display that FRAME is on; if FRAME is omitted or nil, it applies to the selected frame's display (see Input Focus).

     The list contains a vector of the following form for each font:

          [FAMILY WIDTH POINT-SIZE WEIGHT SLANT
           FIXED-P FULL REGISTRY-AND-ENCODING]

     The first five elements correspond to face attributes; if you specify these attributes for a face, it will use this font.

     The last three elements give additional information about the font. FIXED-P is non-nil if the font is fixed-pitch. FULL is the full name of the font, and REGISTRY-AND-ENCODING is a string giving the registry and encoding of the font.

     The result list is sorted according to the current face font sort order.

 -- Function: x-font-family-list &optional frame
     This function returns a list of the font families available for FRAME's display.  If FRAME is omitted or nil, it describes the selected frame's display (see Input Focus).

     The value is a list of elements of this form:

          (FAMILY . FIXED-P)

     Here FAMILY is a font family, and FIXED-P is non-nil if fonts of that family are fixed-pitch.

 -- Variable: font-list-limit
     This variable specifies maximum number of fonts to consider in font matching.  The function x-family-fonts will not return more than that many fonts, and font selection will consider only that many fonts when searching a matching font for face attributes.  The default is currently 100.

Fontsets
--------

A fontset is a list of fonts, each assigned to a range of character codes.  An individual font cannot display the whole range of characters that Emacs supports, but a fontset can.  Fontsets have names, just as fonts do, and you can use a fontset name in place of a font name when you specify the ``font'' for a frame or a face.  Here is information about defining a fontset under Lisp program control.

 -- Function: create-fontset-from-fontset-spec fontset-spec &optional style-variant-p noerror
     This function defines a new fontset according to the specification string FONTSET-SPEC.  The string should have this format:

          FONTPATTERN, [CHARSETNAME:FONTNAME]...

     Whitespace characters before and after the commas are ignored.

     The first part of the string, FONTPATTERN, should have the form of a standard X font name, except that the last two fields should be fontset-ALIAS.

     The new fontset has two names, one long and one short.  The long name is FONTPATTERN in its entirety.  The short name is fontset-ALIAS.  You can refer to the fontset by either name.  If a fontset with the same name already exists, an error is signaled, unless NOERROR is non-nil, in which case this function does nothing.

     If optional argument STYLE-VARIANT-P is non-nil, that says to create bold, italic and bold-italic variants of the fontset as well. These variant fontsets do not have a short name, only a long one, which is made by altering FONTPATTERN to indicate the bold or italic status.

     The specification string also says which fonts to use in the fontset. See below for the details.

The construct CHARSET:FONT specifies which font to use (in this fontset) for one particular character set.  Here, CHARSET is the name of a character set, and FONT is the font to use for that character set.  You can use this construct any number of times in the specification string.

For the remaining character sets, those that you don't specify explicitly, Emacs chooses a font based on FONTPATTERN: it replaces fontset-ALIAS with a value that names one character set. For the ASCII character set, fontset-ALIAS is replaced with ISO8859-1.

In addition, when several consecutive fields are wildcards, Emacs collapses them into a single wildcard.  This is to prevent use of auto-scaled fonts.  Fonts made by scaling larger fonts are not usable for editing, and scaling a smaller font is not useful because it is better to use the smaller font in its own size, which Emacs does.

Thus if FONTPATTERN is this,

     -*-fixed-medium-r-normal-*-24-*-*-*-*-*-fontset-24

the font specification for ASCII characters would be this:

     -*-fixed-medium-r-normal-*-24-*-ISO8859-1

and the font specification for Chinese GB2312 characters would be this:

     -*-fixed-medium-r-normal-*-24-*-gb2312*-*

You may not have any Chinese font matching the above font specification.  Most X distributions include only Chinese fonts that have song ti or fangsong ti in the FAMILY field.  In such a case, Fontset-N can be specified as below:

     Emacs.Fontset-0: -*-fixed-medium-r-normal-*-24-*-*-*-*-*-fontset-24,\
             chinese-gb2312:-*-*-medium-r-normal-*-24-*-gb2312*-*

Then, the font specifications for all but Chinese GB2312 characters have fixed in the FAMILY field, and the font specification for Chinese GB2312 characters has a wild card * in the FAMILY field.

 -- Function: set-fontset-font name character fontname &optional frame
     This function modifies the existing fontset NAME to use the font name FONTNAME for the character CHARACTER.

     If NAME is nil, this function modifies the default fontset, whose short name is fontset-default.

     CHARACTER may be a cons; (FROM . TO), where FROM and TO are non-generic characters.  In that case, use FONTNAME for all characters in the range FROM and TO (inclusive).

     CHARACTER may be a charset.  In that case, use FONTNAME for all character in the charsets.

     FONTNAME may be a cons; (FAMILY . REGISTRY), where FAMILY is a family name of a font (possibly including a foundry name at the head), REGISTRY is a registry name of a font (possibly including an encoding name at the tail).

     For instance, this changes the default fontset to use a font of which registry name is JISX0208.1983 for all characters belonging to the charset japanese-jisx0208.

          (set-fontset-font nil 'japanese-jisx0208 '(nil . "JISX0208.1983"))

 -- Function: char-displayable-p char
     This function returns t if Emacs ought to be able to display CHAR.  More precisely, if the selected frame's fontset has a font to display the character set that CHAR belongs to.

     Fontsets can specify a font on a per-character basis; when the fontset does that, this function's value may not be accurate.

Fringes
=======

The fringes of a window are thin vertical strips down the sides that are used for displaying bitmaps that indicate truncation, continuation, horizontal scrolling, and the overlay arrow.

Fringe Size and Position
------------------------

The following buffer-local variables control the position and width of the window fringes.

 -- Variable: fringes-outside-margins
     The fringes normally appear between the display margins and the window text.  If the value is non-nil, they appear outside the display margins.  See Display Margins.

 -- Variable: left-fringe-width
     This variable, if non-nil, specifies the width of the left fringe in pixels.  A value of nil means to use the left fringe width from the window's frame.

 -- Variable: right-fringe-width
     This variable, if non-nil, specifies the width of the right fringe in pixels.  A value of nil means to use the right fringe width from the window's frame.

The values of these variables take effect when you display the buffer in a window.  If you change them while the buffer is visible, you can call set-window-buffer to display it once again in the same window, to make the changes take effect.

 -- Function: set-window-fringes window left &optional right outside-margins
     This function sets the fringe widths of window WINDOW. If WINDOW is nil, the selected window is used.

     The argument LEFT specifies the width in pixels of the left fringe, and likewise RIGHT for the right fringe.  A value of nil for either one stands for the default width.  If OUTSIDE-MARGINS is non-nil, that specifies that fringes should appear outside of the display margins.

 -- Function: window-fringes &optional window
     This function returns information about the fringes of a window WINDOW.  If WINDOW is omitted or nil, the selected window is used.  The value has the form (LEFT-WIDTH RIGHT-WIDTH OUTSIDE-MARGINS).

Fringe Indicators
-----------------

The fringe indicators are tiny icons Emacs displays in the window fringe (on a graphic display) to indicate truncated or continued lines, buffer boundaries, overlay arrow, etc.

 -- User Option: indicate-empty-lines
     When this is non-nil, Emacs displays a special glyph in the fringe of each empty line at the end of the buffer, on graphical displays.  See Fringes.  This variable is automatically buffer-local in every buffer.

 -- Variable: indicate-buffer-boundaries
     This buffer-local variable controls how the buffer boundaries and window scrolling are indicated in the window fringes.

     Emacs can indicate the buffer boundaries---that is, the first and last line in the buffer---with angle icons when they appear on the screen. In addition, Emacs can display an up-arrow in the fringe to show that there is text above the screen, and a down-arrow to show there is text below the screen.

     There are four kinds of basic values:

     nil
          Don't display the icons.

     left
          Display them in the left fringe.

     right
          Display them in the right fringe.

     ANYTHING-ELSE
          Display the icon at the top of the window top in the left fringe, and other in the right fringe.

     If value is a cons (ANGLES . ARROWS), ANGLES controls the angle icons, and ARROWS controls the arrows.  Both ANGLES and ARROWS work according to the table above. Thus, (t .  right) places the top angle icon in the left fringe, the bottom angle icon in the right fringe, and both arrows in the right fringe.

 -- Variable: default-indicate-buffer-boundaries
     The value of this variable is the default value for indicate-buffer-boundaries in buffers that do not override it.

 -- Variable: fringe-indicator-alist
     This buffer-local variable specifies the mapping from logical fringe indicators to the actual bitmaps displayed in the window fringes.

     These symbols identify the logical fringe indicators:

     Truncation and continuation line indicators:
          truncation, continuation.

     Buffer position indicators:
          up, down, top, bottom, top-bottom.

     Empty line indicator:
          empty-line.

     Overlay arrow indicator:
          overlay-arrow.

     Unknown bitmap indicator:
          unknown.

     The value is an alist where each element (INDICATOR . BITMAPS) specifies the fringe bitmaps used to display a specific logical fringe indicator.

     Here, INDICATOR specifies the logical indicator type, and BITMAPS is list of symbols (LEFT RIGHT [LEFT1 RIGHT1]) which specifies the actual bitmap shown in the left or right fringe for the logical indicator.

     The LEFT and RIGHT symbols specify the bitmaps shown in the left and/or right fringe for the specific indicator.  The LEFT1 or RIGHT1 bitmaps are used only for the `bottom' and `top-bottom indicators when the last (only) line in has no final newline.  Alternatively, BITMAPS may be a single symbol which is used in both left and right fringes.

     When fringe-indicator-alist has a buffer-local value, and there is no bitmap defined for a logical indicator, or the bitmap is t, the corresponding value from the (non-local) default-fringes-indicator-alist is used.

     To completely hide a specific indicator, set the bitmap to nil.

 -- Variable: default-fringes-indicator-alist
     The value of this variable is the default value for fringe-indicator-alist in buffers that do not override it.

Standard fringe bitmaps for indicators:
     left-arrow, right-arrow, up-arrow, down-arrow, left-curly-arrow, right-curly-arrow, left-triangle, right-triangle, top-left-angle,  top-right-angle, bottom-left-angle, bottom-right-angle, left-bracket, right-bracket, filled-rectangle, hollow-rectangle, filled-square, hollow-square, vertical-bar, horizontal-bar, empty-line, question-mark.

Fringe Cursors
--------------

When a line is exactly as wide as the window, Emacs displays the cursor in the right fringe instead of using two lines.  Different bitmaps are used to represent the cursor in the fringe depending on the current buffer's cursor type.

Logical cursor types:
     box , hollow, bar, hbar, hollow-small.

The hollow-small type is used instead of hollow when the normal hollow-rectangle bitmap is too tall to fit on a specific display line.

 -- Variable: overflow-newline-into-fringe
     If this is non-nil, lines exactly as wide as the window (not counting the final newline character) are not continued.  Instead, when point is at the end of the line, the cursor appears in the right fringe.

 -- Variable: fringe-cursor-alist
     This variable specifies the mapping from logical cursor type to the actual fringe bitmaps displayed in the right fringe.  The value is an alist where each element (CURSOR. BITMAP) specifies the fringe bitmaps used to display a specific logical cursor type in the fringe.  Here, CURSOR specifies the logical cursor type and BITMAP is a symbol specifying the fringe bitmap to be displayed for that logical cursor type.

     When fringe-cursor-alist has a buffer-local value, and there is no bitmap defined for a cursor type, the corresponding value from the (non-local) default-fringes-indicator-alist is used.

 -- Variable: default-fringes-cursor-alist
     The value of this variable is the default value for fringe-cursor-alist in buffers that do not override it.

Standard bitmaps for displaying the cursor in right fringe:
     filled-rectangle, hollow-rectangle, filled-square, hollow-square, vertical-bar, horizontal-bar.

Fringe Bitmaps
--------------

The fringe bitmaps are the actual bitmaps which represent the logical fringe indicators for truncated or continued lines, buffer boundaries, overlay arrow, etc.  Fringe bitmap symbols have their own name space.  The fringe bitmaps are shared by all frames and windows. You can redefine the built-in fringe bitmaps, and you can define new fringe bitmaps.

The way to display a bitmap in the left or right fringes for a given line in a window is by specifying the display property for one of the characters that appears in it.  Use a display specification of the form (left-fringe BITMAP [FACE]) or (right-fringe BITMAP [FACE]) (see Display Property).  Here, BITMAP is a symbol identifying the bitmap you want, and FACE (which is optional) is the name of the face whose colors should be used for displaying the bitmap, instead of the default fringe face.  FACE is automatically merged with the fringe face, so normally FACE need only specify the foreground color for the bitmap.

 -- Function: fringe-bitmaps-at-pos &optional pos window
     This function returns the fringe bitmaps of the display line containing position POS in window WINDOW.  The return value has the form (LEFT RIGHT OV), where LEFT is the symbol for the fringe bitmap in the left fringe (or nil if no bitmap), RIGHT is similar for the right fringe, and OV is non-nil if there is an overlay arrow in the left fringe.

     The value is nil if POS is not visible in WINDOW. If WINDOW is nil, that stands for the selected window. If POS is nil, that stands for the value of point in WINDOW.

Customizing Fringe Bitmaps
--------------------------

 -- Function: define-fringe-bitmap bitmap bits &optional height width align
     This function defines the symbol BITMAP as a new fringe bitmap, or replaces an existing bitmap with that name.

     The argument BITS specifies the image to use.  It should be either a string or a vector of integers, where each element (an integer) corresponds to one row of the bitmap.  Each bit of an integer corresponds to one pixel of the bitmap, where the low bit corresponds to the rightmost pixel of the bitmap.

     The height is normally the length of BITS.  However, you can specify a different height with non-nil HEIGHT.  The width is normally 8, but you can specify a different width with non-nil WIDTH.  The width must be an integer between 1 and 16.

     The argument ALIGN specifies the positioning of the bitmap relative to the range of rows where it is used; the default is to center the bitmap.  The allowed values are top, center, or bottom.

     The ALIGN argument may also be a list (ALIGN PERIODIC) where ALIGN is interpreted as described above. If PERIODIC is non-nil, it specifies that the rows in bits should be repeated enough times to reach the specified height.

     The return value on success is an integer identifying the new bitmap. You should save that integer in a variable so it can be used to select this bitmap.

     This function signals an error if there are no more free bitmap slots.

 -- Function: destroy-fringe-bitmap bitmap
     This function destroy the fringe bitmap identified by BITMAP. If BITMAP identifies a standard fringe bitmap, it actually restores the standard definition of that bitmap, instead of eliminating it entirely.

 -- Function: set-fringe-bitmap-face bitmap &optional face
     This sets the face for the fringe bitmap BITMAP to FACE. If FACE is nil, it selects the fringe face.  The bitmap's face controls the color to draw it in.

     FACE is merged with the fringe face, so normally FACE should specify only the foreground color.

The Overlay Arrow
-----------------

The overlay arrow is useful for directing the user's attention to a particular line in a buffer.  For example, in the modes used for interface to debuggers, the overlay arrow indicates the line of code about to be executed.  This feature has nothing to do with overlays (see Overlays).

 -- Variable: overlay-arrow-string
     This variable holds the string to display to call attention to a particular line, or nil if the arrow feature is not in use. On a graphical display the contents of the string are ignored; instead a glyph is displayed in the fringe area to the left of the display area.

 -- Variable: overlay-arrow-position
     This variable holds a marker that indicates where to display the overlay arrow.  It should point at the beginning of a line.  On a non-graphical display the arrow text appears at the beginning of that line, overlaying any text that would otherwise appear.  Since the arrow is usually short, and the line usually begins with indentation, normally nothing significant is overwritten.

     The overlay-arrow string is displayed in any given buffer if the value of overlay-arrow-position in that buffer points into that buffer.  Thus, it works to can display multiple overlay arrow strings by creating buffer-local bindings of overlay-arrow-position. However, it is usually cleaner to use overlay-arrow-variable-list to achieve this result.

You can do a similar job by creating an overlay with a before-string property.  See Overlay Properties.

You can define multiple overlay arrows via the variable overlay-arrow-variable-list.

 -- Variable: overlay-arrow-variable-list
     This variable's value is a list of variables, each of which specifies the position of an overlay arrow.  The variable overlay-arrow-position has its normal meaning because it is on this list.

Each variable on this list can have properties overlay-arrow-string and overlay-arrow-bitmap that specify an overlay arrow string (for text-only terminals) or fringe bitmap (for graphical terminals) to display at the corresponding overlay arrow position.  If either property is not set, the default (overlay-arrow-string or overlay-arrow-fringe-bitmap) is used.

Scroll Bars
===========

Normally the frame parameter vertical-scroll-bars controls whether the windows in the frame have vertical scroll bars, and whether they are on the left or right.  The frame parameter scroll-bar-width specifies how wide they are (nil meaning the default).  See Layout Parameters.

 -- Function: frame-current-scroll-bars &optional frame
     This function reports the scroll bar type settings for frame FRAME.  The value is a cons cell (VERTICAL-TYPE . HORIZONTAL-TYPE), where VERTICAL-TYPE is either left, right, or nil (which means no scroll bar.)  HORIZONTAL-TYPE is meant to specify the horizontal scroll bar type, but since they are not implemented, it is always nil.

You can enable or disable scroll bars for a particular buffer, by setting the variable vertical-scroll-bar.  This variable automatically becomes buffer-local when set.  The possible values are left, right, t, which means to use the frame's default, and nil for no scroll bar.

You can also control this for individual windows.  Call the function set-window-scroll-bars to specify what to do for a specific window:

 -- Function: set-window-scroll-bars window width &optional vertical-type horizontal-type
     This function sets the width and type of scroll bars for window WINDOW.

     WIDTH specifies the scroll bar width in pixels (nil means use the width specified for the frame).  VERTICAL-TYPE specifies whether to have a vertical scroll bar and, if so, where.  The possible values are left, right and nil, just like the values of the vertical-scroll-bars frame parameter.

     The argument HORIZONTAL-TYPE is meant to specify whether and where to have horizontal scroll bars, but since they are not implemented, it has no effect.  If WINDOW is nil, the selected window is used.

 -- Function: window-scroll-bars &optional window
     Report the width and type of scroll bars specified for WINDOW. If WINDOW is omitted or nil, the selected window is used. The value is a list of the form (WIDTH COLS VERTICAL-TYPE HORIZONTAL-TYPE).  The value WIDTH is the value that was specified for the width (which may be nil); COLS is the number of columns that the scroll bar actually occupies.

     HORIZONTAL-TYPE is not actually meaningful.

If you don't specify these values for a window with set-window-scroll-bars, the buffer-local variables scroll-bar-mode and scroll-bar-width in the buffer being displayed control the window's vertical scroll bars.  The function set-window-buffer examines these variables.  If you change them in a buffer that is already visible in a window, you can make the window take note of the new values by calling set-window-buffer specifying the same buffer that is already displayed.

 -- Variable: scroll-bar-mode
     This variable, always local in all buffers, controls whether and where to put scroll bars in windows displaying the buffer.  The possible values are nil for no scroll bar, left to put a scroll bar on the left, and right to put a scroll bar on the right.

 -- Function: window-current-scroll-bars &optional window
     This function reports the scroll bar type for window WINDOW. If WINDOW is omitted or nil, the selected window is used. The value is a cons cell (VERTICAL-TYPE . HORIZONTAL-TYPE).  Unlike window-scroll-bars, this reports the scroll bar type actually used, once frame defaults and scroll-bar-mode are taken into account.

 -- Variable: scroll-bar-width
     This variable, always local in all buffers, specifies the width of the buffer's scroll bars, measured in pixels.  A value of nil means to use the value specified by the frame.

Pointer Shape
=============

Normally, the mouse pointer has the text shape over text and the arrow shape over window areas which do not correspond to any buffer text.  You can specify the mouse pointer shape over text or images via the pointer text property, and for images with the :pointer and :map image properties.

The available pointer shapes are: text (or nil), arrow, hand, vdrag, hdrag, modeline, and hourglass.

 -- Variable: void-text-area-pointer
     This variable specifies the mouse pointer shape in void text areas, i.e. the areas after the end of a line or below the last line in the buffer.  The default is to use the arrow (non-text) pointer.

The display Property
====================

The display text property (or overlay property) is used to insert images into text, and also control other aspects of how text displays.  The value of the display property should be a display specification, or a list or vector containing several display specifications.

Some kinds of display properties specify something to display instead of the text that has the property.  In this case, ``the text'' means all the consecutive characters that have the same Lisp object as their display property; these characters are replaced as a single unit.  By contrast, characters that have similar but distinct Lisp objects as their display properties are handled separately.  Here's a function that illustrates this point:

     (defun foo ()
       (goto-char (point-min))
       (dotimes (i 5)
         (let ((string (concat "A")))
           (put-text-property (point) (1+ (point)) 'display string)
           (forward-char 1)
           (put-text-property (point) (1+ (point)) 'display string)
           (forward-char 1))))

It gives each of the first ten characters in the buffer string "A" as the display property, but they don't all get the same string.  The first two characters get the same string, so they together are replaced with one A.  The next two characters get a second string, so they together are replaced with one A. Likewise for each following pair of characters.  Thus, the ten characters appear as five A's.  This function would have the same results:

     (defun foo ()
       (goto-char (point-min))
       (dotimes (i 5)
         (let ((string (concat "A")))
           (put-text-property (point) (2+ (point)) 'display string)
           (put-text-property (point) (1+ (point)) 'display string)
           (forward-char 2))))

This illustrates that what matters is the property value for each character.  If two consecutive characters have the same object as the display property value, it's irrelevant whether they got this property from a single call to put-text-property or from two different calls.

The rest of this section describes several kinds of display specifications and what they mean.

Specified Spaces
----------------

To display a space of specified width and/or height, use a display specification of the form (space . PROPS), where PROPS is a property list (a list of alternating properties and values).  You can put this property on one or more consecutive characters; a space of the specified height and width is displayed in place of all of those characters.  These are the properties you can use in PROPS to specify the weight of the space:

:width WIDTH
     If WIDTH is an integer or floating point number, it specifies that the space width should be WIDTH times the normal character width.  WIDTH can also be a pixel width specification (see Pixel Specification).

:relative-width FACTOR
     Specifies that the width of the stretch should be computed from the first character in the group of consecutive characters that have the same display property.  The space width is the width of that character, multiplied by FACTOR.

:align-to HPOS
     Specifies that the space should be wide enough to reach HPOS. If HPOS is a number, it is measured in units of the normal character width.  HPOS can also be a pixel width specification (see Pixel Specification).

You should use one and only one of the above properties.  You can also specify the height of the space, with these properties:

:height HEIGHT
     Specifies the height of the space. If HEIGHT is an integer or floating point number, it specifies that the space height should be HEIGHT times the normal character height.  The HEIGHT may also be a pixel height specification (see Pixel Specification).

:relative-height FACTOR
     Specifies the height of the space, multiplying the ordinary height of the text having this display specification by FACTOR.

:ascent ASCENT
     If the value of ASCENT is a non-negative number no greater than 100, it specifies that ASCENT percent of the height of the space should be considered as the ascent of the space---that is, the part above the baseline.  The ascent may also be specified in pixel units with a pixel ascent specification (see Pixel Specification).

Don't use both :height and :relative-height together.

The :width and :align-to properties are supported on non-graphic terminals, but the other space properties in this section are not.

Pixel Specification for Spaces
------------------------------

The value of the :width, :align-to, :height, and :ascent properties can be a special kind of expression that is evaluated during redisplay.  The result of the evaluation is used as an absolute number of pixels.

The following expressions are supported:

       EXPR ::= NUM | (NUM) | UNIT | ELEM | POS | IMAGE | FORM
       NUM  ::= INTEGER | FLOAT | SYMBOL
       UNIT ::= in | mm | cm | width | height

       ELEM ::= left-fringe | right-fringe | left-margin | right-margin
             |  scroll-bar | text
       POS  ::= left | center | right
       FORM ::= (NUM . EXPR) | (OP EXPR ...)
       OP   ::= + | -

The form NUM specifies a fraction of the default frame font height or width.  The form (NUM) specifies an absolute number of pixels.  If NUM is a symbol, SYMBOL, its buffer-local variable binding is used.

The in, mm, and cm units specify the number of pixels per inch, millimeter, and centimeter, respectively.  The width and height units correspond to the default width and height of the current face.  An image specification image corresponds to the width or height of the image.

The left-fringe, right-fringe, left-margin, right-margin, scroll-bar, and text elements specify to the width of the corresponding area of the window.

The left, center, and right positions can be used with :align-to to specify a position relative to the left edge, center, or right edge of the text area.

Any of the above window elements (except text) can also be used with :align-to to specify that the position is relative to the left edge of the given area.  Once the base offset for a relative position has been set (by the first occurrence of one of these symbols), further occurrences of these symbols are interpreted as the width of the specified area.  For example, to align to the center of the left-margin, use

     :align-to (+ left-margin (0.5 . left-margin))

If no specific base offset is set for alignment, it is always relative to the left edge of the text area.  For example, :align-to 0 in a header-line aligns with the first text column in the text area.

A value of the form (NUM . EXPR) stands for the product of the values of NUM and EXPR.  For example, (2 . in) specifies a width of 2 inches, while (0.5 . IMAGE) specifies half the width (or height) of the specified image.

The form (+ EXPR ...) adds up the value of the expressions.  The form (- EXPR ...) negates or subtracts the value of the expressions.

Other Display Specifications
----------------------------

Here are the other sorts of display specifications that you can use in the display text property.

STRING
     Display STRING instead of the text that has this property.

     Recursive display specifications are not supported---STRING's display properties, if any, are not used.

(image . IMAGE-PROPS)
     This kind of display specification is an image descriptor (see Images). When used as a display specification, it means to display the image instead of the text that has the display specification.

(slice X Y WIDTH HEIGHT)
     This specification together with image specifies a slice (a partial area) of the image to display.  The elements Y and X specify the top left corner of the slice, within the image; WIDTH and HEIGHT specify the width and height of the slice.  Integer values are numbers of pixels.  A floating point number in the range 0.0--1.0 stands for that fraction of the width or height of the entire image.

((margin nil) STRING)
     A display specification of this form means to display STRING instead of the text that has the display specification, at the same position as that text.  It is equivalent to using just STRING, but it is done as a special case of marginal display (see Display Margins).

(space-width FACTOR)
     This display specification affects all the space characters within the text that has the specification.  It displays all of these spaces FACTOR times as wide as normal.  The element FACTOR should be an integer or float.  Characters other than spaces are not affected at all; in particular, this has no effect on tab characters.

(height HEIGHT)
     This display specification makes the text taller or shorter. Here are the possibilities for HEIGHT:

     (+ N)
          This means to use a font that is N steps larger.  A ``step'' is defined by the set of available fonts---specifically, those that match what was otherwise specified for this text, in all attributes except height.  Each size for which a suitable font is available counts as another step.  N should be an integer.

     (- N)
          This means to use a font that is N steps smaller.

     a number, FACTOR
          A number, FACTOR, means to use a font that is FACTOR times as tall as the default font.

     a symbol, FUNCTION
          A symbol is a function to compute the height.  It is called with the current height as argument, and should return the new height to use.

     anything else, FORM
          If the HEIGHT value doesn't fit the previous possibilities, it is a form.  Emacs evaluates it to get the new height, with the symbol height bound to the current specified font height.

(raise FACTOR)
     This kind of display specification raises or lowers the text it applies to, relative to the baseline of the line.

     FACTOR must be a number, which is interpreted as a multiple of the height of the affected text.  If it is positive, that means to display the characters raised.  If it is negative, that means to display them lower down.

     If the text also has a height display specification, that does not affect the amount of raising or lowering, which is based on the faces used for the text.

You can make any display specification conditional.  To do that, package it in another list of the form (when CONDITION . SPEC).  Then the specification SPEC applies only when CONDITION evaluates to a non-nil value.  During the evaluation, object is bound to the string or buffer having the conditional display property.  position and buffer-position are bound to the position within object and the buffer position where the display property was found, respectively.  Both positions can be different when object is a string.

Displaying in the Margins
-------------------------

A buffer can have blank areas called display margins on the left and on the right.  Ordinary text never appears in these areas, but you can put things into the display margins using the display property.

To put text in the left or right display margin of the window, use a display specification of the form (margin right-margin) or (margin left-margin) on it.  To put an image in a display margin, use that display specification along with the display specification for the image.  Unfortunately, there is currently no way to make text or images in the margin mouse-sensitive.

If you put such a display specification directly on text in the buffer, the specified margin display appears instead of that buffer text itself.  To put something in the margin in association with certain buffer text without preventing or altering the display of that text, put a before-string property on the text and put the display specification on the contents of the before-string.

Before the display margins can display anything, you must give them a nonzero width.  The usual way to do that is to set these variables:

 -- Variable: left-margin-width
     This variable specifies the width of the left margin. It is buffer-local in all buffers.

 -- Variable: right-margin-width
     This variable specifies the width of the right margin. It is buffer-local in all buffers.

Setting these variables does not immediately affect the window.  These variables are checked when a new buffer is displayed in the window. Thus, you can make changes take effect by calling set-window-buffer.

You can also set the margin widths immediately.

 -- Function: set-window-margins window left &optional right
     This function specifies the margin widths for window WINDOW. The argument LEFT controls the left margin and RIGHT controls the right margin (default 0).

 -- Function: window-margins &optional window
     This function returns the left and right margins of WINDOW as a cons cell of the form (LEFT . RIGHT). If WINDOW is nil, the selected window is used.

Images
======

To display an image in an Emacs buffer, you must first create an image descriptor, then use it as a display specifier in the display property of text that is displayed (see Display Property).

Emacs can display a number of different image formats; some of them are supported only if particular support libraries are installed on your machine.  In some environments, Emacs can load image libraries on demand; if so, the variable image-library-alist can be used to modify the set of known names for these dynamic libraries (though it is not possible to add new image formats).

The supported image formats include XBM, XPM (this requires the libraries libXpm version 3.4k and libz), GIF (requiring libungif 4.1.0), Postscript, PBM, JPEG (requiring the libjpeg library version v6a), TIFF (requiring libtiff v3.4), and PNG (requiring libpng 1.0.2).

You specify one of these formats with an image type symbol.  The image type symbols are xbm, xpm, gif, postscript, pbm, jpeg, tiff, and png.

 -- Variable: image-types
     This variable contains a list of those image type symbols that are potentially supported in the current configuration. Potentially here means that Emacs knows about the image types, not necessarily that they can be loaded (they could depend on unavailable dynamic libraries, for example).

     To know which image types are really available, use image-type-available-p.

 -- Variable: image-library-alist
     This in an alist of image types vs external libraries needed to display them.

     Each element is a list (IMAGE-TYPE LIBRARY...), where the car is a supported image format from image-types, and the rest are strings giving alternate filenames for the corresponding external libraries to load.

     Emacs tries to load the libraries in the order they appear on the list; if none is loaded, the running session of Emacs won't support the image type.  pbm and xbm don't need to be listed; they're always supported.

     This variable is ignored if the image libraries are statically linked into Emacs.

 -- Function: image-type-available-p type

     This function returns non-nil if image type TYPE is available, i.e., if images of this type can be loaded and displayed in Emacs.  TYPE should be one of the types contained in image-types.

     For image types whose support libraries are statically linked, this function always returns t; for other image types, it returns t if the dynamic library could be loaded, nil otherwise.

Image Descriptors
-----------------

An image description is a list of the form (image . PROPS), where PROPS is a property list containing alternating keyword symbols (symbols whose names start with a colon) and their values. You can use any Lisp object as a property, but the only properties that have any special meaning are certain symbols, all of them keywords.

Every image descriptor must contain the property :type TYPE to specify the format of the image.  The value of TYPE should be an image type symbol; for example, xpm for an image in XPM format.

Here is a list of other properties that are meaningful for all image types:

:file FILE
     The :file property says to load the image from file FILE.  If FILE is not an absolute file name, it is expanded in data-directory.

:data DATA
     The :data property says the actual contents of the image. Each image must use either :data or :file, but not both. For most image types, the value of the :data property should be a string containing the image data; we recommend using a unibyte string.

     Before using :data, look for further information in the section below describing the specific image format.  For some image types, :data may not be supported; for some, it allows other data types; for some, :data alone is not enough, so you need to use other image properties along with :data.

:margin MARGIN
     The :margin property specifies how many pixels to add as an extra margin around the image.  The value, MARGIN, must be a non-negative number, or a pair (X . Y) of such numbers.  If it is a pair, X specifies how many pixels to add horizontally, and Y specifies how many pixels to add vertically. If :margin is not specified, the default is zero.

:ascent ASCENT
     The :ascent property specifies the amount of the image's height to use for its ascent---that is, the part above the baseline. The value, ASCENT, must be a number in the range 0 to 100, or the symbol center.

     If ASCENT is a number, that percentage of the image's height is used for its ascent.

     If ASCENT is center, the image is vertically centered around a centerline which would be the vertical centerline of text drawn at the position of the image, in the manner specified by the text properties and overlays that apply to the image.

     If this property is omitted, it defaults to 50.

:relief RELIEF
     The :relief property, if non-nil, adds a shadow rectangle around the image.  The value, RELIEF, specifies the width of the shadow lines, in pixels.  If RELIEF is negative, shadows are drawn so that the image appears as a pressed button; otherwise, it appears as an unpressed button.

:conversion ALGORITHM
     The :conversion property, if non-nil, specifies a conversion algorithm that should be applied to the image before it is displayed; the value, ALGORITHM, specifies which algorithm.

     laplace
     emboss
          Specifies the Laplace edge detection algorithm, which blurs out small differences in color while highlighting larger differences.  People sometimes consider this useful for displaying the image for a ``disabled'' button.

     (edge-detection :matrix MATRIX :color-adjust ADJUST)
          Specifies a general edge-detection algorithm.  MATRIX must be either a nine-element list or a nine-element vector of numbers.  A pixel at position x/y in the transformed image is computed from original pixels around that position.  MATRIX specifies, for each pixel in the neighborhood of x/y, a factor with which that pixel will influence the transformed pixel; element 0 specifies the factor for the pixel at x-1/y-1, element 1 the factor for the pixel at x/y-1 etc., as shown below:

                 (x-1/y-1  x/y-1  x+1/y-1
                  x-1/y    x/y    x+1/y
                  x-1/y+1  x/y+1  x+1/y+1)

          The resulting pixel is computed from the color intensity of the color resulting from summing up the RGB values of surrounding pixels, multiplied by the specified factors, and dividing that sum by the sum of the factors' absolute values.

          Laplace edge-detection currently uses a matrix of

                 (1  0  0
                  0  0  0
                  9  9 -1)

          Emboss edge-detection uses a matrix of

                 ( 2 -1  0
                  -1  0  1
                   0  1 -2)

     disabled
          Specifies transforming the image so that it looks ``disabled''.

:mask MASK
     If MASK is heuristic or (heuristic BG), build a clipping mask for the image, so that the background of a frame is visible behind the image.  If BG is not specified, or if BG is t, determine the background color of the image by looking at the four corners of the image, assuming the most frequently occurring color from the corners is the background color of the image.  Otherwise, BG must be a list (RED GREEN BLUE) specifying the color to assume for the background of the image.

     If MASK is nil, remove a mask from the image, if it has one.  Images in some formats include a mask which can be removed by specifying :mask nil.

:pointer SHAPE
     This specifies the pointer shape when the mouse pointer is over this image.  See Pointer Shape, for available pointer shapes.

:map MAP
     This associates an image map of hot spots with this image.

     An image map is an alist where each element has the format (AREA ID PLIST).  An AREA is specified as either a rectangle, a circle, or a polygon.

     A rectangle is a cons (rect . ((X0 . Y0) . (X1 . Y1))) which specifies the pixel coordinates of the upper left and bottom right corners of the rectangle area.

     A circle is a cons (circle . ((X0 . Y0) . R)) which specifies the center and the radius of the circle; R may be a float or integer.

     A polygon is a cons (poly . [X0 Y0 X1 Y1 ...]) where each pair in the vector describes one corner in the polygon.

     When the mouse pointer is above a hot-spot area of an image, the PLIST of that hot-spot is consulted; if it contains a help-echo property it defines a tool-tip for the hot-spot, and if it contains a pointer property, it defines the shape of the mouse cursor when it is over the hot-spot. See Pointer Shape, for available pointer shapes.

     When you click the mouse when the mouse pointer is over a hot-spot, an event is composed by combining the ID of the hot-spot with the mouse event; for instance, [area4 mouse-1] if the hot-spot's ID is area4.

 -- Function: image-mask-p spec &optional frame
     This function returns t if image SPEC has a mask bitmap. FRAME is the frame on which the image will be displayed. FRAME nil or omitted means to use the selected frame (see Input Focus).

XBM Images
----------

To use XBM format, specify xbm as the image type.  This image format doesn't require an external library, so images of this type are always supported.

Additional image properties supported for the xbm image type are:

:foreground FOREGROUND
     The value, FOREGROUND, should be a string specifying the image foreground color, or nil for the default color.  This color is used for each pixel in the XBM that is 1.  The default is the frame's foreground color.

:background BACKGROUND
     The value, BACKGROUND, should be a string specifying the image background color, or nil for the default color.  This color is used for each pixel in the XBM that is 0.  The default is the frame's background color.

If you specify an XBM image using data within Emacs instead of an external file, use the following three properties:

:data DATA
     The value, DATA, specifies the contents of the image. There are three formats you can use for DATA:

       * A vector of strings or bool-vectors, each specifying one line of the image.  Do specify :height and :width.

       * A string containing the same byte sequence as an XBM file would contain. You must not specify :height and :width in this case, because omitting them is what indicates the data has the format of an XBM file.  The file contents specify the height and width of the image.

       * A string or a bool-vector containing the bits of the image (plus perhaps some extra bits at the end that will not be used).  It should contain at least WIDTH * height bits.  In this case, you must specify :height and :width, both to indicate that the string contains just the bits rather than a whole XBM file, and to specify the size of the image.

:width WIDTH
     The value, WIDTH, specifies the width of the image, in pixels.

:height HEIGHT
     The value, HEIGHT, specifies the height of the image, in pixels.

XPM Images
----------

To use XPM format, specify xpm as the image type.  The additional image property :color-symbols is also meaningful with the xpm image type:

:color-symbols SYMBOLS
     The value, SYMBOLS, should be an alist whose elements have the form (NAME . COLOR).  In each element, NAME is the name of a color as it appears in the image file, and COLOR specifies the actual color to use for displaying that name.

GIF Images
----------

For GIF images, specify image type gif.

:index INDEX
     You can use :index to specify one image from a GIF file that contains more than one image.  This property specifies use of image number INDEX from the file.  If the GIF file doesn't contain an image with index INDEX, the image displays as a hollow box.

Postscript Images
-----------------

To use Postscript for an image, specify image type postscript. This works only if you have Ghostscript installed.  You must always use these three properties:

:pt-width WIDTH
     The value, WIDTH, specifies the width of the image measured in points (1/72 inch).  WIDTH must be an integer.

:pt-height HEIGHT
     The value, HEIGHT, specifies the height of the image in points (1/72 inch).  HEIGHT must be an integer.

:bounding-box BOX
     The value, BOX, must be a list or vector of four integers, which specifying the bounding box of the Postscript image, analogous to the BoundingBox comment found in Postscript files.

          %%BoundingBox: 22 171 567 738

Displaying Postscript images from Lisp data is not currently implemented, but it may be implemented by the time you read this. See the etc/NEWS file to make sure.

Other Image Types
-----------------

For PBM images, specify image type pbm.  Color, gray-scale and monochromatic images are supported.   For mono PBM images, two additional image properties are supported.

:foreground FOREGROUND
     The value, FOREGROUND, should be a string specifying the image foreground color, or nil for the default color.  This color is used for each pixel in the XBM that is 1.  The default is the frame's foreground color.

:background BACKGROUND
     The value, BACKGROUND, should be a string specifying the image background color, or nil for the default color.  This color is used for each pixel in the XBM that is 0.  The default is the frame's background color.

For JPEG images, specify image type jpeg.

For TIFF images, specify image type tiff.

For PNG images, specify image type png.

Defining Images
---------------

The functions create-image, defimage and find-image provide convenient ways to create image descriptors.

 -- Function: create-image file-or-data &optional type data-p &rest props
     This function creates and returns an image descriptor which uses the data in FILE-OR-DATA.  FILE-OR-DATA can be a file name or a string containing the image data; DATA-P should be nil for the former case, non-nil for the latter case.

     The optional argument TYPE is a symbol specifying the image type. If TYPE is omitted or nil, create-image tries to determine the image type from the file's first few bytes, or else from the file's name.

     The remaining arguments, PROPS, specify additional image properties---for example,

          (create-image "foo.xpm" 'xpm nil :heuristic-mask t)

     The function returns nil if images of this type are not supported.  Otherwise it returns an image descriptor.

 -- Macro: defimage symbol specs &optional doc
     This macro defines SYMBOL as an image name.  The arguments SPECS is a list which specifies how to display the image. The third argument, DOC, is an optional documentation string.

     Each argument in SPECS has the form of a property list, and each one should specify at least the :type property and either the :file or the :data property.  The value of :type should be a symbol specifying the image type, the value of :file is the file to load the image from, and the value of :data is a string containing the actual image data.  Here is an example:

          (defimage test-image
            ((:type xpm :file "~/test1.xpm")
             (:type xbm :file "~/test1.xbm")))

     defimage tests each argument, one by one, to see if it is usable---that is, if the type is supported and the file exists.  The first usable argument is used to make an image descriptor which is stored in SYMBOL.

     If none of the alternatives will work, then SYMBOL is defined as nil.

 -- Function: find-image specs
     This function provides a convenient way to find an image satisfying one of a list of image specifications SPECS.

     Each specification in SPECS is a property list with contents depending on image type.  All specifications must at least contain the properties :type TYPE and either :file FILE or :data DATA, where TYPE is a symbol specifying the image type, e.g. xbm, FILE is the file to load the image from, and DATA is a string containing the actual image data. The first specification in the list whose TYPE is supported, and FILE exists, is used to construct the image specification to be returned.  If no specification is satisfied, nil is returned.

     The image is looked for in image-load-path.

 -- Variable: image-load-path
     This variable's value is a list of locations in which to search for image files.  If an element is a string or a variable symbol whose value is a string, the string is taken to be the name of a directory to search.  If an element is a variable symbol whose value is a list, that is taken to be a list of directory names to search.

     The default is to search in the images subdirectory of the directory specified by data-directory, then the directory specified by data-directory, and finally in the directories in load-path.  Subdirectories are not automatically included in the search, so if you put an image file in a subdirectory, you have to supply the subdirectory name explicitly.  For example, to find the image images/foo/bar.xpm within data-directory, you should specify the image as follows:

          (defimage foo-image '((:type xpm :file "foo/bar.xpm")))

 -- Function: image-load-path-for-library library image &optional path no-error
     This function returns a suitable search path for images relative to LIBRARY.

     First it searches for IMAGE in a path suitable for LIBRARY, which includes ../../etc/images and ../etc/images relative to the library file itself, followed by image-load-path and load-path.

     Then this function returns a list of directories which contains first the directory in which IMAGE was found, followed by the value of load-path.  If PATH is given, it is used instead of load-path.

     If NO-ERROR is non-nil and a suitable path can't be found, don't signal an error.  Instead, return a list of directories as before, except that nil appears in place of the image directory.

     Here is an example that uses a common idiom to provide compatibility with versions of Emacs that lack the variable image-load-path:

          ;; Shush compiler.
          (defvar image-load-path)

          (let* ((load-path (image-load-path-for-library "mh-e" "mh-logo.xpm"))
                 (image-load-path (cons (car load-path)
                                        (when (boundp 'image-load-path)
                                          image-load-path))))
            (mh-tool-bar-folder-buttons-init))

Showing Images
--------------

You can use an image descriptor by setting up the display property yourself, but it is easier to use the functions in this section.

 -- Function: insert-image image &optional string area slice
     This function inserts IMAGE in the current buffer at point.  The value IMAGE should be an image descriptor; it could be a value returned by create-image, or the value of a symbol defined with defimage.  The argument STRING specifies the text to put in the buffer to hold the image.  If it is omitted or nil, insert-image uses " " by default.

     The argument AREA specifies whether to put the image in a margin. If it is left-margin, the image appears in the left margin; right-margin specifies the right margin.  If AREA is nil or omitted, the image is displayed at point within the buffer's text.

     The argument SLICE specifies a slice of the image to insert.  If SLICE is nil or omitted the whole image is inserted. Otherwise, SLICE is a list (X Y WIDTH HEIGHT) which specifies the X and Y positions and WIDTH and HEIGHT of the image area to insert.  Integer values are in units of pixels.  A floating point number in the range 0.0--1.0 stands for that fraction of the width or height of the entire image.

     Internally, this function inserts STRING in the buffer, and gives it a display property which specifies IMAGE.  See Display Property.

 -- Function: insert-sliced-image image &optional string area rows cols
     This function inserts IMAGE in the current buffer at point, like insert-image, but splits the image into ROWSxCOLS equally sized slices.

 -- Function: put-image image pos &optional string area
     This function puts image IMAGE in front of POS in the current buffer.  The argument POS should be an integer or a marker.  It specifies the buffer position where the image should appear. The argument STRING specifies the text that should hold the image as an alternative to the default.

     The argument IMAGE must be an image descriptor, perhaps returned by create-image or stored by defimage.

     The argument AREA specifies whether to put the image in a margin. If it is left-margin, the image appears in the left margin; right-margin specifies the right margin.  If AREA is nil or omitted, the image is displayed at point within the buffer's text.

     Internally, this function creates an overlay, and gives it a before-string property containing text that has a display property whose value is the image.  (Whew!)

 -- Function: remove-images start end &optional buffer
     This function removes images in BUFFER between positions START and END.  If BUFFER is omitted or nil, images are removed from the current buffer.

     This removes only images that were put into BUFFER the way put-image does it, not images that were inserted with insert-image or in other ways.

 -- Function: image-size spec &optional pixels frame
     This function returns the size of an image as a pair (WIDTH . HEIGHT).  SPEC is an image specification.  PIXELS non-nil means return sizes measured in pixels, otherwise return sizes measured in canonical character units (fractions of the width/height of the frame's default font).  FRAME is the frame on which the image will be displayed. FRAME null or omitted means use the selected frame (see Input Focus).

 -- Variable: max-image-size
     This variable is used to define the maximum size of image that Emacs will load.  Emacs will refuse to load (and display) any image that is larger than this limit.

     If the value is an integer, it directly specifies the maximum image height and width, measured in pixels.  If it is a floating point number, it specifies the maximum image height and width as a ratio to the frame height and width.  If the value is non-numeric, there is no explicit limit on the size of images.

     The purpose of this variable is to prevent unreasonably large images from accidentally being loaded into Emacs.  It only takes effect the first time an image is loaded.  Once an image is placed in the image cache, it can always be displayed, even if the value of MAX-IMAGE-SIZE is subsequently changed (see Image Cache).

Image Cache
-----------

Emacs stores images in an image cache when it displays them, so it can display them again more efficiently.  It removes an image from the cache when it hasn't been displayed for a specified period of time.

When an image is looked up in the cache, its specification is compared with cached image specifications using equal.  This means that all images with equal specifications share the same image in the cache.

 -- Variable: image-cache-eviction-delay
     This variable specifies the number of seconds an image can remain in the cache without being displayed.  When an image is not displayed for this length of time, Emacs removes it from the image cache.

     If the value is nil, Emacs does not remove images from the cache except when you explicitly clear it.  This mode can be useful for debugging.

 -- Function: clear-image-cache &optional frame
     This function clears the image cache.  If FRAME is non-nil, only the cache for that frame is cleared.  Otherwise all frames' caches are cleared.

Buttons
=======

The button package defines functions for inserting and manipulating clickable (with the mouse, or via keyboard commands) buttons in Emacs buffers, such as might be used for help hyper-links, etc.  Emacs uses buttons for the hyper-links in help text and the like.

A button is essentially a set of properties attached (via text properties or overlays) to a region of text in an Emacs buffer.  These properties are called button properties.

One of the these properties (action) is a function, which will be called when the user invokes it using the keyboard or the mouse. The invoked function may then examine the button and use its other properties as desired.

In some ways the Emacs button package duplicates functionality offered by the widget package (see Introduction (The Emacs Widget Library)), but the button package has the advantage that it is much faster, much smaller, and much simpler to use (for elisp programmers---for users, the result is about the same).  The extra speed and space savings are useful mainly if you need to create many buttons in a buffer (for instance an *Apropos* buffer uses buttons to make entries clickable, and may contain many thousands of entries).

Button Properties
-----------------

Buttons have an associated list of properties defining their appearance and behavior, and other arbitrary properties may be used for application specific purposes.  Some properties that have special meaning to the button package include:

action
     The function to call when the user invokes the button, which is passed the single argument BUTTON.  By default this is ignore, which does nothing.

mouse-action
     This is similar to action, and when present, will be used instead of action for button invocations resulting from mouse-clicks (instead of the user hitting RET).  If not present, mouse-clicks use action instead.

face
     This is an Emacs face controlling how buttons of this type are displayed; by default this is the button face.

mouse-face
     This is an additional face which controls appearance during mouse-overs (merged with the usual button face); by default this is the usual Emacs highlight face.

keymap
     The button's keymap, defining bindings active within the button region.  By default this is the usual button region keymap, stored in the variable button-map, which defines RET and mouse-2 to invoke the button.

type
     The button-type of the button.  When creating a button, this is usually specified using the :type keyword argument. See Button Types.

help-echo
     A string displayed by the Emacs tool-tip help system; by default, "mouse-2, RET: Push this button".

follow-link
     The follow-link property, defining how a Mouse-1 click behaves on this button, see Links and Mouse-1.

button
     All buttons have a non-nil button property, which may be useful in finding regions of text that comprise buttons (which is what the standard button functions do).

There are other properties defined for the regions of text in a button, but these are not generally interesting for typical uses.

Button Types
------------

Every button has a button type, which defines default values for the button's properties.  Button types are arranged in a hierarchy, with specialized types inheriting from more general types, so that it's easy to define special-purpose types of buttons for specific tasks.

 -- Function: define-button-type name &rest properties
     Define a `button type' called NAME.  The remaining arguments form a sequence of PROPERTY VALUE pairs, specifying default property values for buttons with this type (a button's type may be set by giving it a type property when creating the button, using the :type keyword argument).

     In addition, the keyword argument :supertype may be used to specify a button-type from which NAME inherits its default property values.  Note that this inheritance happens only when NAME is defined; subsequent changes to a supertype are not reflected in its subtypes.

Using define-button-type to define default properties for buttons is not necessary---buttons without any specified type use the built-in button-type button---but it is encouraged, since doing so usually makes the resulting code clearer and more efficient.

Making Buttons
--------------

Buttons are associated with a region of text, using an overlay or text properties to hold button-specific information, all of which are initialized from the button's type (which defaults to the built-in button type button).  Like all Emacs text, the appearance of the button is governed by the face property; by default (via the face property inherited from the button button-type) this is a simple underline, like a typical web-page link.

For convenience, there are two sorts of button-creation functions, those that add button properties to an existing region of a buffer, called make-...button, and those that also insert the button text, called insert-...button.

The button-creation functions all take the &rest argument PROPERTIES, which should be a sequence of PROPERTY VALUE pairs, specifying properties to add to the button; see Button Properties.  In addition, the keyword argument :type may be used to specify a button-type from which to inherit other properties; see Button Types.  Any properties not explicitly specified during creation will be inherited from the button's type (if the type defines such a property).

The following functions add a button using an overlay (see Overlays) to hold the button properties:

 -- Function: make-button beg end &rest properties
     This makes a button from BEG to END in the current buffer, and returns it.

 -- Function: insert-button label &rest properties
     This insert a button with the label LABEL at point, and returns it.

The following functions are similar, but use Emacs text properties (see Text Properties) to hold the button properties, making the button actually part of the text instead of being a property of the buffer.  Buttons using text properties do not create markers into the buffer, which is important for speed when you use extremely large numbers of buttons.  Both functions return the position of the start of the new button:

 -- Function: make-text-button beg end &rest properties
     This makes a button from BEG to END in the current buffer, using text properties.

 -- Function: insert-text-button label &rest properties
     This inserts a button with the label LABEL at point, using text properties.

Manipulating Buttons
--------------------

These are functions for getting and setting properties of buttons. Often these are used by a button's invocation function to determine what to do.

Where a BUTTON parameter is specified, it means an object referring to a specific button, either an overlay (for overlay buttons), or a buffer-position or marker (for text property buttons). Such an object is passed as the first argument to a button's invocation function when it is invoked.

 -- Function: button-start button
     Return the position at which BUTTON starts.

 -- Function: button-end button
     Return the position at which BUTTON ends.

 -- Function: button-get button prop
     Get the property of button BUTTON named PROP.

 -- Function: button-put button prop val
     Set BUTTON's PROP property to VAL.

 -- Function: button-activate button &optional use-mouse-action
     Call BUTTON's action property (i.e., invoke it).  If USE-MOUSE-ACTION is non-nil, try to invoke the button's mouse-action property instead of action; if the button has no mouse-action property, use action as normal.

 -- Function: button-label button
     Return BUTTON's text label.

 -- Function: button-type button
     Return BUTTON's button-type.

 -- Function: button-has-type-p button type
     Return t if BUTTON has button-type TYPE, or one of TYPE's subtypes.

 -- Function: button-at pos
     Return the button at position POS in the current buffer, or nil.

 -- Function: button-type-put type prop val
     Set the button-type TYPE's PROP property to VAL.

 -- Function: button-type-get type prop
     Get the property of button-type TYPE named PROP.

 -- Function: button-type-subtype-p type supertype
     Return t if button-type TYPE is a subtype of SUPERTYPE.

Button Buffer Commands
----------------------

These are commands and functions for locating and operating on buttons in an Emacs buffer.

push-button is the command that a user uses to actually `push' a button, and is bound by default in the button itself to RET and to mouse-2 using a region-specific keymap.  Commands that are useful outside the buttons itself, such as forward-button and backward-button are additionally available in the keymap stored in button-buffer-map; a mode which uses buttons may want to use button-buffer-map as a parent keymap for its keymap.

If the button has a non-nil follow-link property, and MOUSE-1-CLICK-FOLLOWS-LINK is set, a quick Mouse-1 click will also activate the push-button command. See Links and Mouse-1.

 -- Command: push-button &optional pos use-mouse-action
     Perform the action specified by a button at location POS. POS may be either a buffer position or a mouse-event.  If USE-MOUSE-ACTION is non-nil, or POS is a mouse-event (see Mouse Events), try to invoke the button's mouse-action property instead of action; if the button has no mouse-action property, use action as normal. POS defaults to point, except when push-button is invoked interactively as the result of a mouse-event, in which case, the mouse event's position is used.  If there's no button at POS, do nothing and return nil, otherwise return t.

 -- Command: forward-button n &optional wrap display-message
     Move to the Nth next button, or Nth previous button if N is negative.  If N is zero, move to the start of any button at point.  If WRAP is non-nil, moving past either end of the buffer continues from the other end.  If DISPLAY-MESSAGE is non-nil, the button's help-echo string is displayed.  Any button with a non-nil skip property is skipped over.  Returns the button found.

 -- Command: backward-button n &optional wrap display-message
     Move to the Nth previous button, or Nth next button if N is negative.  If N is zero, move to the start of any button at point.  If WRAP is non-nil, moving past either end of the buffer continues from the other end.  If DISPLAY-MESSAGE is non-nil, the button's help-echo string is displayed.  Any button with a non-nil skip property is skipped over.  Returns the button found.

 -- Function: next-button pos &optional count-current
     Return the next button after position POS in the current buffer. If COUNT-CURRENT is non-nil, count any button at POS in the search, instead of starting at the next button.

 -- Function: previous-button pos &optional count-current
     Return the Nth button before position POS in the current buffer.  If COUNT-CURRENT is non-nil, count any button at POS in the search, instead of starting at the next button.

Blinking Parentheses
====================

This section describes the mechanism by which Emacs shows a matching open parenthesis when the user inserts a close parenthesis.

 -- Variable: blink-paren-function
     The value of this variable should be a function (of no arguments) to be called whenever a character with close parenthesis syntax is inserted. The value of blink-paren-function may be nil, in which case nothing is done.

 -- User Option: blink-matching-paren
     If this variable is nil, then blink-matching-open does nothing.

 -- User Option: blink-matching-paren-distance
     This variable specifies the maximum distance to scan for a matching parenthesis before giving up.

 -- User Option: blink-matching-delay
     This variable specifies the number of seconds for the cursor to remain at the matching parenthesis.  A fraction of a second often gives good results, but the default is 1, which works on all systems.

 -- Command: blink-matching-open
     This function is the default value of blink-paren-function.  It assumes that point follows a character with close parenthesis syntax and moves the cursor momentarily to the matching opening character.  If that character is not already on the screen, it displays the character's context in the echo area.  To avoid long delays, this function does not search farther than blink-matching-paren-distance characters.

     Here is an example of calling this function explicitly.

          (defun interactive-blink-matching-open ()
            "Indicate momentarily the start of sexp before point."
            (interactive)

            (let ((blink-matching-paren-distance
                   (buffer-size))
                  (blink-matching-paren t))
              (blink-matching-open)))

Usual Display Conventions
=========================

The usual display conventions define how to display each character code.  You can override these conventions by setting up a display table (see Display Tables).  Here are the usual display conventions:

  * Character codes 32 through 126 map to glyph codes 32 through 126. Normally this means they display as themselves.

  * Character code 9 is a horizontal tab.  It displays as whitespace up to a position determined by tab-width.

  * Character code 10 is a newline.

  * All other codes in the range 0 through 31, and code 127, display in one of two ways according to the value of ctl-arrow.  If it is non-nil, these codes map to sequences of two glyphs, where the first glyph is the ASCII code for ^.  (A display table can specify a glyph to use instead of ^.)  Otherwise, these codes map just like the codes in the range 128 to 255.

     On MS-DOS terminals, Emacs arranges by default for the character code 127 to be mapped to the glyph code 127, which normally displays as an empty polygon.  This glyph is used to display non-ASCII characters that the MS-DOS terminal doesn't support.  See MS-DOS and MULE (The GNU Emacs Manual).

  * Character codes 128 through 255 map to sequences of four glyphs, where the first glyph is the ASCII code for \, and the others are digit characters representing the character code in octal.  (A display table can specify a glyph to use instead of \.)

  * Multibyte character codes above 256 are displayed as themselves, or as a question mark or empty box if the terminal cannot display that character.

The usual display conventions apply even when there is a display table, for any character whose entry in the active display table is nil.  Thus, when you set up a display table, you need only specify the characters for which you want special behavior.

These display rules apply to carriage return (character code 13), when it appears in the buffer.  But that character may not appear in the buffer where you expect it, if it was eliminated as part of end-of-line conversion (see Coding System Basics).

These variables affect the way certain characters are displayed on the screen.  Since they change the number of columns the characters occupy, they also affect the indentation functions.  These variables also affect how the mode line is displayed; if you want to force redisplay of the mode line using the new values, call the function force-mode-line-update (see Mode Line Format).

 -- User Option: ctl-arrow
     This buffer-local variable controls how control characters are displayed.  If it is non-nil, they are displayed as a caret followed by the character: ^A.  If it is nil, they are displayed as a backslash followed by three octal digits: \001.

 -- Variable: default-ctl-arrow
     The value of this variable is the default value for ctl-arrow in buffers that do not override it.  See Default Value.

 -- User Option: tab-width
     The value of this buffer-local variable is the spacing between tab stops used for displaying tab characters in Emacs buffers.  The value is in units of columns, and the default is 8.  Note that this feature is completely independent of the user-settable tab stops used by the command tab-to-tab-stop.  See Indent Tabs.

Display Tables
==============

You can use the display table feature to control how all possible character codes display on the screen.  This is useful for displaying European languages that have letters not in the ASCII character set.

The display table maps each character code into a sequence of glyphs, each glyph being a graphic that takes up one character position on the screen.  You can also define how to display each glyph on your terminal, using the glyph table.

Display tables affect how the mode line is displayed; if you want to force redisplay of the mode line using a new display table, call force-mode-line-update (see Mode Line Format).

Display Table Format
--------------------

A display table is actually a char-table (see Char-Tables) with display-table as its subtype.

 -- Function: make-display-table
     This creates and returns a display table.  The table initially has nil in all elements.

The ordinary elements of the display table are indexed by character codes; the element at index C says how to display the character code C.  The value should be nil or a vector of glyph values (see Glyphs).  If an element is nil, it says to display that character according to the usual display conventions (see Usual Display).

If you use the display table to change the display of newline characters, the whole buffer will be displayed as one long ``line.''

The display table also has six ``extra slots'' which serve special purposes.  Here is a table of their meanings; nil in any slot means to use the default for that slot, as stated below.

0
     The glyph for the end of a truncated screen line (the default for this is $).  See Glyphs.  On graphical terminals, Emacs uses arrows in the fringes to indicate truncation, so the display table has no effect.

1
     The glyph for the end of a continued line (the default is \). On graphical terminals, Emacs uses curved arrows in the fringes to indicate continuation, so the display table has no effect.

2
     The glyph for indicating a character displayed as an octal character code (the default is \).

3
     The glyph for indicating a control character (the default is ^).

4
     A vector of glyphs for indicating the presence of invisible lines (the default is ...).  See Selective Display.

5
     The glyph used to draw the border between side-by-side windows (the default is |).  See Splitting Windows.  This takes effect only when there are no scroll bars; if scroll bars are supported and in use, a scroll bar separates the two windows.

For example, here is how to construct a display table that mimics the effect of setting ctl-arrow to a non-nil value:

     (setq disptab (make-display-table))
     (let ((i 0))
       (while (< i 32)
         (or (= i ?\t) (= i ?\n)
             (aset disptab i (vector ?^ (+ i 64))))
         (setq i (1+ i)))
       (aset disptab 127 (vector ?^ ??)))

 -- Function: display-table-slot display-table slot
     This function returns the value of the extra slot SLOT of DISPLAY-TABLE.  The argument SLOT may be a number from 0 to 5 inclusive, or a slot name (symbol).  Valid symbols are truncation, wrap, escape, control, selective-display, and vertical-border.

 -- Function: set-display-table-slot display-table slot value
     This function stores VALUE in the extra slot SLOT of DISPLAY-TABLE.  The argument SLOT may be a number from 0 to 5 inclusive, or a slot name (symbol).  Valid symbols are truncation, wrap, escape, control, selective-display, and vertical-border.

 -- Function: describe-display-table display-table
     This function displays a description of the display table DISPLAY-TABLE in a help buffer.

 -- Command: describe-current-display-table
     This command displays a description of the current display table in a help buffer.

Active Display Table
--------------------

Each window can specify a display table, and so can each buffer.  When a buffer B is displayed in window W, display uses the display table for window W if it has one; otherwise, the display table for buffer B if it has one; otherwise, the standard display table if any.  The display table chosen is called the active display table.

 -- Function: window-display-table &optional window
     This function returns WINDOW's display table, or nil if WINDOW does not have an assigned display table.  The default for WINDOW is the selected window.

 -- Function: set-window-display-table window table
     This function sets the display table of WINDOW to TABLE. The argument TABLE should be either a display table or nil.

 -- Variable: buffer-display-table
     This variable is automatically buffer-local in all buffers; its value in a particular buffer specifies the display table for that buffer.  If it is nil, that means the buffer does not have an assigned display table.

 -- Variable: standard-display-table
     This variable's value is the default display table, used whenever a window has no display table and neither does the buffer displayed in that window.  This variable is nil by default.

If there is no display table to use for a particular window---that is, if the window specifies none, its buffer specifies none, and standard-display-table is nil---then Emacs uses the usual display conventions for all character codes in that window.  See Usual Display.

A number of functions for changing the standard display table are defined in the library disp-table.

Glyphs
------

A glyph is a generalization of a character; it stands for an image that takes up a single character position on the screen.  Glyphs are represented in Lisp as integers, just as characters are.  Normally Emacs finds glyphs in the display table (see Display Tables).

A glyph can be simple or it can be defined by the glyph table.  A simple glyph is just a way of specifying a character and a face to output it in.  The glyph code for a simple glyph, mod 524288, is the character to output, and the glyph code divided by 524288 specifies the face number (see Face Functions) to use while outputting it.  (524288 is 2**19.) See Faces.

On character terminals, you can set up a glyph table to define the meaning of glyph codes.  The glyph codes is the value of the variable glyph-table.

 -- Variable: glyph-table
     The value of this variable is the current glyph table.  It should be a vector; the Gth element defines glyph code G.

     If a glyph code is greater than or equal to the length of the glyph table, that code is automatically simple.  If the value of glyph-table is nil instead of a vector, then all glyphs are simple.  The glyph table is not used on graphical displays, only on character terminals.  On graphical displays, all glyphs are simple.

Here are the possible types of elements in the glyph table:

STRING
     Send the characters in STRING to the terminal to output this glyph.  This alternative is available on character terminals, but not on graphical displays.

INTEGER
     Define this glyph code as an alias for glyph code INTEGER.  You can use an alias to specify a face code for the glyph and use a small number as its code.

nil
     This glyph is simple.

 -- Function: create-glyph string
     This function returns a newly-allocated glyph code which is set up to display by sending STRING to the terminal.

Beeping
=======

This section describes how to make Emacs ring the bell (or blink the screen) to attract the user's attention.  Be conservative about how often you do this; frequent bells can become irritating.  Also be careful not to use just beeping when signaling an error is more appropriate.  (see Errors.)

 -- Function: ding &optional do-not-terminate
     This function beeps, or flashes the screen (see visible-bell below). It also terminates any keyboard macro currently executing unless DO-NOT-TERMINATE is non-nil.

 -- Function: beep &optional do-not-terminate
     This is a synonym for ding.

 -- User Option: visible-bell
     This variable determines whether Emacs should flash the screen to represent a bell.  Non-nil means yes, nil means no.  This is effective on graphical displays, and on text-only terminals provided the terminal's Termcap entry defines the visible bell capability (vb).

 -- Variable: ring-bell-function
     If this is non-nil, it specifies how Emacs should ``ring the bell.''  Its value should be a function of no arguments.  If this is non-nil, it takes precedence over the visible-bell variable.

Window Systems
==============

Emacs works with several window systems, most notably the X Window System.  Both Emacs and X use the term ``window'', but use it differently.  An Emacs frame is a single window as far as X is concerned; the individual Emacs windows are not known to X at all.

 -- Variable: window-system
     This variable tells Lisp programs what window system Emacs is running under.  The possible values are

     x
          Emacs is displaying using X.

     pc
          Emacs is displaying using MS-DOS.

     w32
          Emacs is displaying using Windows.

     mac
          Emacs is displaying using a Macintosh.

     nil
          Emacs is using a character-based terminal.

 -- Variable: window-setup-hook
     This variable is a normal hook which Emacs runs after handling the initialization files.  Emacs runs this hook after it has completed loading your init file, the default initialization file (if any), and the terminal-specific Lisp code, and running the hook term-setup-hook.

     This hook is used for internal purposes: setting up communication with the window system, and creating the initial window.  Users should not interfere with it.