lisp/faces.el

   1 ;;; faces.el --- Lisp interface to the c "face" structure
   2
   3 ;; Copyright (C) 1992, 1993 Free Software Foundation, Inc.
   4
   5 ;; This file is part of GNU Emacs.
   6
   7 ;; GNU Emacs is free software; you can redistribute it and/or modify
   8 ;; it under the terms of the GNU General Public License as published by
   9 ;; the Free Software Foundation; either version 2, or (at your option)
  10 ;; any later version.
  11
  12 ;; GNU Emacs is distributed in the hope that it will be useful,
  13 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ;; GNU General Public License for more details.
  16
  17 ;; You should have received a copy of the GNU General Public License
  18 ;; along with GNU Emacs; see the file COPYING.  If not, write to
  19 ;; the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.
  20
  21 ;;; Commentary:
  22
  23 ;; Mostly derived from Lucid.
  24
  25 ;;; Code:
  26
  27 \f
  28 ;;;; Functions for manipulating face vectors.
  29
  30 ;;; A face vector is a vector of the form:
  31 ;;;    [face ID FONT FOREGROUND BACKGROUND BACKGROUND-PIXMAP UNDERLINE]
  32
  33 ;;; Type checkers.
  34 (defsubst internal-facep (x)
  35   (and (vectorp x) (= (length x) 8) (eq (aref x 0) 'face)))
  36
  37 (defmacro internal-check-face (face)
  38   (` (while (not (internal-facep (, face)))
  39        (setq (, face) (signal 'wrong-type-argument (list 'internal-facep (, face)))))))
  40
  41 ;;; Accessors.
  42 (defsubst face-name (face)
  43   "Return the name of face FACE."
  44   (aref (internal-get-face face) 1))
  45
  46 (defsubst face-id (face)
  47   "Return the internal ID number of face FACE."
  48   (aref (internal-get-face face) 2))
  49
  50 (defsubst face-font (face &optional frame)
  51   "Return the font name of face FACE, or nil if it is unspecified.
  52 If the optional argument FRAME is given, report on face FACE in that frame.
  53 Otherwise report on the defaults for face FACE (for new frames)."
  54   (aref (internal-get-face face frame) 3))
  55
  56 (defsubst face-foreground (face &optional frame)
  57   "Return the foreground color name of face FACE, or nil if unspecified.
  58 If the optional argument FRAME is given, report on face FACE in that frame.
  59 Otherwise report on the defaults for face FACE (for new frames)."
  60   (aref (internal-get-face face frame) 4))
  61
  62 (defsubst face-background (face &optional frame)
  63   "Return the background color name of face FACE, or nil if unspecified.
  64 If the optional argument FRAME is given, report on face FACE in that frame.
  65 Otherwise report on the defaults for face FACE (for new frames)."
  66   (aref (internal-get-face face frame) 5))
  67
  68 (defsubst face-background-pixmap (face &optional frame)
  69  "Return the background pixmap name of face FACE, or nil if unspecified.
  70 If the optional argument FRAME is given, report on face FACE in that frame.
  71 Otherwise report on the defaults for face FACE (for new frames)."
  72  (aref (internal-get-face face frame) 6))
  73
  74 (defsubst face-underline-p (face &optional frame)
  75  "Return t if face FACE is underlined.
  76 If the optional argument FRAME is given, report on face FACE in that frame.
  77 Otherwise report on the defaults for face FACE (for new frames)."
  78  (aref (internal-get-face face frame) 7))
  79
  80 \f
  81 ;;; Mutators.
  82
  83 (defsubst set-face-font (face font &optional frame)
  84   "Change the font of face FACE to FONT (a string).
  85 If the optional FRAME argument is provided, change only
  86 in that frame; otherwise change each frame."
  87   (interactive (internal-face-interactive "font"))
  88   (if (stringp font) (setq font (x-resolve-font-name font face frame)))
  89   (internal-set-face-1 face 'font font 3 frame))
  90
  91 (defsubst set-face-foreground (face color &optional frame)
  92   "Change the foreground color of face FACE to COLOR (a string).
  93 If the optional FRAME argument is provided, change only
  94 in that frame; otherwise change each frame."
  95   (interactive (internal-face-interactive "foreground"))
  96   (internal-set-face-1 face 'foreground color 4 frame))
  97
  98 (defsubst set-face-background (face color &optional frame)
  99   "Change the background color of face FACE to COLOR (a string).
 100 If the optional FRAME argument is provided, change only
 101 in that frame; otherwise change each frame."
 102   (interactive (internal-face-interactive "background"))
 103   (internal-set-face-1 face 'background color 5 frame))
 104
 105 (defsubst set-face-background-pixmap (face name &optional frame)
 106   "Change the background pixmap of face FACE to PIXMAP.
 107 PIXMAP should be a string, the name of a file of pixmap data.
 108 The directories listed in the `x-bitmap-file-path' variable are searched.
 109
 110 Alternatively, PIXMAP may be a list of the form (WIDTH HEIGHT DATA)
 111 where WIDTH and HEIGHT are the size in pixels,
 112 and DATA is a string, containing the raw bits of the bitmap.
 113
 114 If the optional FRAME argument is provided, change only
 115 in that frame; otherwise change each frame."
 116   (interactive (internal-face-interactive "background-pixmap"))
 117   (internal-set-face-1 face 'background-pixmap name 6 frame))
 118
 119 (defsubst set-face-underline-p (face underline-p &optional frame)
 120   "Specify whether face FACE is underlined.  (Yes if UNDERLINE-P is non-nil.)
 121 If the optional FRAME argument is provided, change only
 122 in that frame; otherwise change each frame."
 123   (interactive (internal-face-interactive "underline-p" "underlined"))
 124   (internal-set-face-1 face 'underline underline-p 7 frame))
 125
 126 \f
 127 ;;;; Associating face names (symbols) with their face vectors.
 128
 129 (defvar global-face-data nil "do not use this")
 130
 131 (defun face-list ()
 132   "Returns a list of all defined face names."
 133   (mapcar 'car global-face-data))
 134
 135 (defun internal-find-face (name &optional frame)
 136   "Retrieve the face named NAME.  Return nil if there is no such face.
 137 If the optional argument FRAME is given, this gets the face NAME for
 138 that frame; otherwise, it uses the selected frame.
 139 If FRAME is the symbol t, then the global, non-frame face is returned.
 140 If NAME is already a face, it is simply returned."
 141   (if (and (eq frame t) (not (symbolp name)))
 142       (setq name (face-name name)))
 143   (if (symbolp name)
 144       (cdr (assq name
 145                  (if (eq frame t)
 146                      global-face-data
 147                    (frame-face-alist (or frame (selected-frame))))))
 148     (internal-check-face name)
 149     name))
 150
 151 (defun internal-get-face (name &optional frame)
 152   "Retrieve the face named NAME; error if there is none.
 153 If the optional argument FRAME is given, this gets the face NAME for
 154 that frame; otherwise, it uses the selected frame.
 155 If FRAME is the symbol t, then the global, non-frame face is returned.
 156 If NAME is already a face, it is simply returned."
 157   (or (internal-find-face name frame)
 158       (internal-check-face name)))
 159
 160
 161 (defun internal-set-face-1 (face name value index frame)
 162   (let ((inhibit-quit t))
 163     (if (null frame)
 164         (let ((frames (frame-list)))
 165           (while frames
 166             (internal-set-face-1 (face-name face) name value index (car frames))
 167             (setq frames (cdr frames)))
 168           (aset (internal-get-face (if (symbolp face) face (face-name face)) t)
 169                 index value)
 170           value)
 171       (or (eq frame t)
 172           (set-face-attribute-internal (face-id face) name value frame))
 173       (aset (internal-get-face face frame) index value))))
 174
 175
 176 (defun read-face-name (prompt)
 177   (let (face)
 178     (while (= (length face) 0)
 179       (setq face (completing-read prompt
 180                                   (mapcar '(lambda (x) (list (symbol-name x)))
 181                                           (face-list))
 182                                   nil t)))
 183     (intern face)))
 184
 185 (defun internal-face-interactive (what &optional bool)
 186   (let* ((fn (intern (concat "face-" what)))
 187          (prompt (concat "Set " what " of face"))
 188          (face (read-face-name (concat prompt ": ")))
 189          (default (if (fboundp fn)
 190                       (or (funcall fn face (selected-frame))
 191                           (funcall fn 'default (selected-frame)))))
 192          (value (if bool
 193                     (y-or-n-p (concat "Should face " (symbol-name face)
 194                                       " be " bool "? "))
 195                   (read-string (concat prompt " " (symbol-name face) " to: ")
 196                                default))))
 197     (list face (if (equal value "") nil value))))
 198
 199
 200
 201 (defun make-face (name)
 202   "Define a new FACE on all frames.
 203 You can modify the font, color, etc of this face with the set-face- functions.
 204 If the face already exists, it is unmodified."
 205   (interactive "SMake face: ")
 206   (or (internal-find-face name)
 207       (let ((face (make-vector 8 nil)))
 208         (aset face 0 'face)
 209         (aset face 1 name)
 210         (let* ((frames (frame-list))
 211                (inhibit-quit t)
 212                (id (internal-next-face-id)))
 213           (make-face-internal id)
 214           (aset face 2 id)
 215           (while frames
 216             (set-frame-face-alist (car frames)
 217                                   (cons (cons name (copy-sequence face))
 218                                         (frame-face-alist (car frames))))
 219             (setq frames (cdr frames)))
 220           (setq global-face-data (cons (cons name face) global-face-data)))
 221         ;; when making a face after frames already exist
 222         (if (eq window-system 'x)
 223             (make-face-x-resource-internal face))
 224         face)))
 225
 226 ;; Fill in a face by default based on X resources, for all existing frames.
 227 ;; This has to be done when a new face is made.
 228 (defun make-face-x-resource-internal (face &optional frame set-anyway)
 229   (cond ((null frame)
 230          (let ((frames (frame-list)))
 231            (while frames
 232              (make-face-x-resource-internal (face-name face)
 233                                             (car frames) set-anyway)
 234              (setq frames (cdr frames)))))
 235         (t
 236          (setq face (internal-get-face (face-name face) frame))
 237          ;;
 238          ;; These are things like "attributeForeground" instead of simply
 239          ;; "foreground" because people tend to do things like "*foreground",
 240          ;; which would cause all faces to be fully qualified, making faces
 241          ;; inherit attributes in a non-useful way.  So we've made them slightly
 242          ;; less obvious to specify in order to make them work correctly in
 243          ;; more random environments.
 244          ;;
 245          ;; I think these should be called "face.faceForeground" instead of
 246          ;; "face.attributeForeground", but they're the way they are for
 247          ;; hysterical reasons.
 248          ;;
 249          (let* ((name (symbol-name (face-name face)))
 250                 (fn  (or (x-get-resource (concat name ".attributeFont")
 251                                          "Face.AttributeFont")
 252                          (and set-anyway (face-font face))))
 253                 (fg  (or (x-get-resource (concat name ".attributeForeground")
 254                                          "Face.AttributeForeground")
 255                          (and set-anyway (face-foreground face))))
 256                 (bg  (or (x-get-resource (concat name ".attributeBackground")
 257                                          "Face.AttributeBackground")
 258                          (and set-anyway (face-background face))))
 259 ;;              (bgp (or (x-get-resource (concat name ".attributeBackgroundPixmap")
 260 ;;                                       "Face.AttributeBackgroundPixmap")
 261 ;;                       (and set-anyway (face-background-pixmap face))))
 262                 (ulp (or (x-get-resource (concat name ".attributeUnderline")
 263                                          "Face.AttributeUnderline")
 264                          (and set-anyway (face-underline-p face))))
 265                 )
 266            (if fn
 267                (condition-case ()
 268                    (set-face-font face fn frame)
 269                  (error (message "font `%s' not found for face `%s'" fn name))))
 270            (if fg
 271                (condition-case ()
 272                    (set-face-foreground face fg frame)
 273                  (error (message "color `%s' not allocated for face `%s'" fg name))))
 274            (if bg
 275                (condition-case ()
 276                    (set-face-background face bg frame)
 277                  (error (message "color `%s' not allocated for face `%s'" bg name))))
 278 ;;         (if bgp
 279 ;;             (condition-case ()
 280 ;;                 (set-face-background-pixmap face bgp frame)
 281 ;;               (error (message "pixmap `%s' not found for face `%s'" bgp name))))
 282            (if (or ulp set-anyway)
 283                (set-face-underline-p face ulp frame))
 284            )))
 285   face)
 286
 287 (defun copy-face (old-face new-name &optional frame)
 288   "Define a face just like OLD-FACE, with name NEW-NAME.
 289 If NEW-NAME already exists as a face, it is modified to be like OLD-FACE.
 290 If the optional argument FRAME is given, this applies only to that frame.
 291 Otherwise it applies to each frame separately."
 292   (setq old-face (internal-get-face old-face frame))
 293   (let* ((inhibit-quit t)
 294          (new-face (or (internal-find-face new-name frame)
 295                        (make-face new-name))))
 296     (if (null frame)
 297         (let ((frames (frame-list)))
 298           (while frames
 299             (copy-face old-face new-name (car frames))
 300             (setq frames (cdr frames)))
 301           (copy-face old-face new-name t))
 302       (set-face-font new-face (face-font old-face frame) frame)
 303       (set-face-foreground new-face (face-foreground old-face frame) frame)
 304       (set-face-background new-face (face-background old-face frame) frame)
 305 ;;;      (set-face-background-pixmap
 306 ;;;       new-face (face-background-pixmap old-face frame) frame)
 307       (set-face-underline-p new-face (face-underline-p old-face frame)
 308                             frame))
 309     new-face))
 310
 311 (defun face-equal (face1 face2 &optional frame)
 312   "True if the faces FACE1 and FACE2 display in the same way."
 313   (setq face1 (internal-get-face face1 frame)
 314         face2 (internal-get-face face2 frame))
 315   (and (equal (face-foreground face1 frame) (face-foreground face2 frame))
 316        (equal (face-background face1 frame) (face-background face2 frame))
 317        (equal (face-font face1 frame) (face-font face2 frame))
 318        (equal (face-background-pixmap face1 frame)
 319               (face-background-pixmap face2 frame))))
 320
 321 (defun face-differs-from-default-p (face &optional frame)
 322   "True if face FACE displays differently from the default face, on FRAME.
 323 A face is considered to be ``the same'' as the default face if it is
 324 actually specified in the same way (equivalent fonts, etc) or if it is
 325 fully unspecified, and thus inherits the attributes of any face it
 326 is displayed on top of."
 327   (let ((default (internal-get-face 'default frame)))
 328     (setq face (internal-get-face face frame))
 329     (not (and (or (equal (face-foreground default frame)
 330                          (face-foreground face frame))
 331                   (null (face-foreground face frame)))
 332               (or (equal (face-background default frame)
 333                          (face-background face frame))
 334                   (null (face-background face frame)))
 335               (or (equal (face-font default frame) (face-font face frame))
 336                   (null (face-font face frame)))
 337 ;;;           (or (equal (face-background-pixmap default frame)
 338 ;;;                      (face-background-pixmap face frame))
 339 ;;;               (null (face-background-pixmap face frame)))
 340               (equal (face-underline-p default frame)
 341                      (face-underline-p face frame))
 342               ))))
 343
 344
 345 (defun invert-face (face &optional frame)
 346   "Swap the foreground and background colors of face FACE.
 347 If the face doesn't specify both foreground and background, then
 348 set its foreground and background to the default background and foreground."
 349   (interactive (list (read-face-name "Invert face: ")))
 350   (setq face (internal-get-face face frame))
 351   (let ((fg (face-foreground face frame))
 352         (bg (face-background face frame)))
 353     (if (or fg bg)
 354         (progn
 355           (set-face-foreground face bg frame)
 356           (set-face-background face fg frame))
 357       (set-face-foreground face (or (face-background 'default frame)
 358                                     (cdr (assq 'background-color (frame-parameters frame))))
 359                            frame)
 360       (set-face-background face (or (face-foreground 'default frame)
 361                                     (cdr (assq 'foreground-color (frame-parameters frame))))
 362                            frame)))
 363   face)
 364
 365
 366 (defun internal-try-face-font (face font &optional frame)
 367   "Like set-face-font, but returns nil on failure instead of an error."
 368   (condition-case ()
 369       (set-face-font face font frame)
 370     (error nil)))
 371 \f
 372 ;; Manipulating font names.
 373
 374 (defconst x-font-regexp nil)
 375 (defconst x-font-regexp-head nil)
 376 (defconst x-font-regexp-weight nil)
 377 (defconst x-font-regexp-slant nil)
 378
 379 ;;; Regexps matching font names in "Host Portable Character Representation."
 380 ;;;
 381 (let ((-                "[-?]")
 382       (foundry          "[^-]+")
 383       (family           "[^-]+")
 384       (weight           "\\(bold\\|demibold\\|medium\\)")               ; 1
 385 ;     (weight\?         "\\(\\*\\|bold\\|demibold\\|medium\\|\\)")      ; 1
 386       (weight\?         "\\([^-]*\\)")                                  ; 1
 387       (slant            "\\([ior]\\)")                                  ; 2
 388 ;     (slant\?          "\\([ior?*]?\\)")                               ; 2
 389       (slant\?          "\\([^-]?\\)")                                  ; 2
 390 ;     (swidth           "\\(\\*\\|normal\\|semicondensed\\|\\)")        ; 3
 391       (swidth           "\\([^-]*\\)")                                  ; 3
 392 ;     (adstyle          "\\(\\*\\|sans\\|\\)")                          ; 4
 393       (adstyle          "[^-]*")                                        ; 4
 394       (pixelsize        "[0-9]+")
 395       (pointsize        "[0-9][0-9]+")
 396       (resx             "[0-9][0-9]+")
 397       (resy             "[0-9][0-9]+")
 398       (spacing          "[cmp?*]")
 399       (avgwidth         "[0-9]+")
 400       (registry         "[^-]+")
 401       (encoding         "[^-]+")
 402       )
 403   (setq x-font-regexp
 404         (concat "\\`\\*?[-?*]"
 405                 foundry - family - weight\? - slant\? - swidth - adstyle -
 406                 pixelsize - pointsize - resx - resy - spacing - registry -
 407                 encoding "[-?*]\\*?\\'"
 408                 ))
 409   (setq x-font-regexp-head
 410         (concat "\\`[-?*]" foundry - family - weight\? - slant\?
 411                 "\\([-*?]\\|\\'\\)"))
 412   (setq x-font-regexp-slant (concat - slant -))
 413   (setq x-font-regexp-weight (concat - weight -))
 414   nil)
 415
 416 (defun x-resolve-font-name (pattern &optional face frame)
 417   "Return a font name matching PATTERN.
 418 All wildcards in PATTERN become substantiated.
 419 If PATTERN is nil, return the name of the frame's base font, which never
 420 contains wildcards.
 421 Given optional arguments FACE and FRAME, try to return a font which is
 422 also the same size as FACE on FRAME."
 423   (if pattern
 424       (let ((fonts (x-list-fonts pattern face frame)))
 425         (or fonts
 426             (if face
 427                 (error "no fonts match `%S'." pattern)
 428               (error "no fonts matching pattern are the same size as `%s'."
 429                      pattern face)))
 430         (car fonts))
 431     (cdr (assq 'font (frame-parameters (selected-frame))))))
 432
 433 (defun x-frob-font-weight (font which)
 434   (if (or (string-match x-font-regexp font)
 435           (string-match x-font-regexp-head font)
 436           (string-match x-font-regexp-weight font))
 437       (concat (substring font 0 (match-beginning 1)) which
 438               (substring font (match-end 1)))
 439     nil))
 440
 441 (defun x-frob-font-slant (font which)
 442   (cond ((or (string-match x-font-regexp font)
 443              (string-match x-font-regexp-head font))
 444          (concat (substring font 0 (match-beginning 2)) which
 445                  (substring font (match-end 2))))
 446         ((string-match x-font-regexp-slant font)
 447          (concat (substring font 0 (match-beginning 1)) which
 448                  (substring font (match-end 1))))
 449         (t nil)))
 450
 451
 452 (defun x-make-font-bold (font)
 453   "Given an X font specification, this attempts to make a `bold' version
 454 of it.  If it fails, it returns nil."
 455   (x-frob-font-weight font "bold"))
 456
 457 (defun x-make-font-demibold (font)
 458   "Given an X font specification, this attempts to make a `demibold' version
 459 of it.  If it fails, it returns nil."
 460   (x-frob-font-weight font "demibold"))
 461
 462 (defun x-make-font-unbold (font)
 463   "Given an X font specification, this attempts to make a non-bold version
 464 of it.  If it fails, it returns nil."
 465   (x-frob-font-weight font "medium"))
 466
 467 (defun x-make-font-italic (font)
 468   "Given an X font specification, this attempts to make an `italic' version
 469 of it.  If it fails, it returns nil."
 470   (x-frob-font-slant font "i"))
 471
 472 (defun x-make-font-oblique (font) ; you say tomayto...
 473   "Given an X font specification, this attempts to make an `italic' version
 474 of it.  If it fails, it returns nil."
 475   (x-frob-font-slant font "o"))
 476
 477 (defun x-make-font-unitalic (font)
 478   "Given an X font specification, this attempts to make a non-italic version
 479 of it.  If it fails, it returns nil."
 480   (x-frob-font-slant font "r"))
 481
 482 \f
 483 ;;; non-X-specific interface
 484
 485 (defun make-face-bold (face &optional frame noerror)
 486   "Make the font of the given face be bold, if possible.
 487 If NOERROR is non-nil, return nil on failure."
 488   (interactive (list (read-face-name "Make which face bold: ")))
 489   (let ((ofont (face-font face frame))
 490         font f2)
 491     (if (null frame)
 492         (let ((frames (frame-list)))
 493           (while frames
 494             (make-face-bold face (car frames))
 495             (setq frames (cdr frames))))
 496       (setq face (internal-get-face face frame))
 497       (setq font (or (face-font face frame)
 498                      (face-font face t)
 499                      (face-font 'default frame)
 500                      (cdr (assq 'font (frame-parameters frame)))))
 501       (or (and (setq f2 (x-make-font-bold font))
 502                (internal-try-face-font face f2))
 503           (and (setq f2 (x-make-font-demibold font))
 504                (internal-try-face-font face f2))))
 505     (or (not (equal ofont (face-font face)))
 506         (and (not noerror)
 507              (error "No %s version of %S" face ofont)))))
 508
 509 (defun make-face-italic (face &optional frame noerror)
 510   "Make the font of the given face be italic, if possible.
 511 If NOERROR is non-nil, return nil on failure."
 512   (interactive (list (read-face-name "Make which face italic: ")))
 513   (let ((ofont (face-font face frame))
 514         font f2)
 515     (if (null frame)
 516         (let ((frames (frame-list)))
 517           (while frames
 518             (make-face-italic face (car frames))
 519             (setq frames (cdr frames))))
 520       (setq face (internal-get-face face frame))
 521       (setq font (or (face-font face frame)
 522                      (face-font face t)
 523                      (face-font 'default frame)
 524                      (cdr (assq 'font (frame-parameters frame)))))
 525       (or (and (setq f2 (x-make-font-italic font))
 526                (internal-try-face-font face f2))
 527           (and (setq f2 (x-make-font-oblique font))
 528                (internal-try-face-font face f2))))
 529     (or (not (equal ofont (face-font face)))
 530         (and (not noerror)
 531              (error "No %s version of %S" face ofont)))))
 532
 533 (defun make-face-bold-italic (face &optional frame noerror)
 534   "Make the font of the given face be bold and italic, if possible.
 535 If NOERROR is non-nil, return nil on failure."
 536   (interactive (list (read-face-name "Make which face bold-italic: ")))
 537   (let ((ofont (face-font face frame))
 538         font f2 f3)
 539     (if (null frame)
 540         (let ((frames (frame-list)))
 541           (while frames
 542             (make-face-bold-italic face (car frames))
 543             (setq frames (cdr frames))))
 544       (setq face (internal-get-face face frame))
 545       (setq font (or (face-font face frame)
 546                       (face-font face t)
 547                       (face-font 'default frame)
 548                       (cdr (assq 'font (frame-parameters frame)))))
 549       (or (and (setq f2 (x-make-font-italic font))
 550                (not (equal font f2))
 551                (setq f3 (x-make-font-bold f2))
 552                (not (equal f2 f3))
 553                (internal-try-face-font face f3))
 554           (and (setq f2 (x-make-font-oblique font))
 555                (not (equal font f2))
 556                (setq f3 (x-make-font-bold f2))
 557                (not (equal f2 f3))
 558                (internal-try-face-font face f3))
 559           (and (setq f2 (x-make-font-italic font))
 560                (not (equal font f2))
 561                (setq f3 (x-make-font-demibold f2))
 562                (not (equal f2 f3))
 563                (internal-try-face-font face f3))
 564           (and (setq f2 (x-make-font-oblique font))
 565                (not (equal font f2))
 566                (setq f3 (x-make-font-demibold f2))
 567                (not (equal f2 f3))
 568                (internal-try-face-font face f3))))
 569     (or (not (equal ofont (face-font face)))
 570         (and (not noerror)
 571              (error "No %s version of %S" face ofont)))))
 572
 573 (defun make-face-unbold (face &optional frame noerror)
 574   "Make the font of the given face be non-bold, if possible.
 575 If NOERROR is non-nil, return nil on failure."
 576   (interactive (list (read-face-name "Make which face non-bold: ")))
 577   (let ((ofont (face-font face frame))
 578         font font1)
 579     (if (null frame)
 580         (let ((frames (frame-list)))
 581           (while frames
 582             (make-face-unbold face (car frames))
 583             (setq frames (cdr frames))))
 584       (setq face (internal-get-face face frame))
 585       (setq font1 (or (face-font face frame)
 586                       (face-font face t)
 587                       (face-font 'default frame)
 588                       (cdr (assq 'font (frame-parameters frame)))))
 589       (setq font (x-make-font-unbold font1))
 590       (if font (internal-try-face-font face font)))
 591     (or (not (equal ofont (face-font face)))
 592         (and (not noerror)
 593              (error "No %s version of %S" face ofont)))))
 594
 595 (defun make-face-unitalic (face &optional frame noerror)
 596   "Make the font of the given face be non-italic, if possible.
 597 If NOERROR is non-nil, return nil on failure."
 598   (interactive (list (read-face-name "Make which face non-italic: ")))
 599   (let ((ofont (face-font face frame))
 600         font font1)
 601     (if (null frame)
 602         (let ((frames (frame-list)))
 603           (while frames
 604             (make-face-unitalic face (car frames))
 605             (setq frames (cdr frames))))
 606       (setq face (internal-get-face face frame))
 607       (setq font1 (or (face-font face frame)
 608                       (face-font face t)
 609                       (face-font 'default frame)
 610                       (cdr (assq 'font (frame-parameters frame)))))
 611       (setq font (x-make-font-unitalic font1))
 612       (if font (internal-try-face-font face font)))
 613     (or (not (equal ofont (face-font face)))
 614         (and (not noerror)
 615              (error "No %s version of %S" face ofont)))))
 616 \f
 617 ;;; Make the builtin faces; the C code knows these as faces 0, 1, and 2,
 618 ;;; respectively, so they must be the first three faces made.
 619
 620 (defun face-initialize ()
 621   (make-face 'default)
 622   (make-face 'modeline)
 623   (make-face 'highlight)
 624   ;;
 625   ;; These aren't really special in any way, but they're nice to have around.
 626   ;; The X-specific code is clever at them.
 627   ;;
 628   (make-face 'bold)
 629   (make-face 'italic)
 630   (make-face 'bold-italic)
 631   (make-face 'region)
 632   (make-face 'secondary-selection)
 633
 634   (setq region-face (face-id 'region))
 635
 636   ;; Set up the faces of all existing X Window frames.
 637   (let ((frames (frame-list)))
 638     (while frames
 639       (if (eq (framep (car frames)) 'x)
 640           (x-initialize-frame-faces (car frames)))
 641       (setq frames (cdr frames)))))
 642
 643 \f
 644 ;;; This really belongs in setting a frame's own font.
 645 ;;;     ;;
 646 ;;;     ;; No font specified in the resource database; try to cope.
 647 ;;;     ;;
 648 ;;;     (internal-try-face-font default "-*-courier-medium-r-*-*-*-120-*-*-*-*-iso8859-*"
 649 ;;;                          frame)
 650 ;;;     (internal-try-face-font default "-*-courier-*-r-*-*-*-120-*-*-*-*-iso8859-*"
 651 ;;;                          frame)
 652 ;;;     (internal-try-face-font default "-*-*-medium-r-*-*-*-120-*-*-m-*-iso8859-*" frame)
 653 ;;;     (internal-try-face-font default "-*-*-medium-r-*-*-*-120-*-*-c-*-iso8859-*" frame)
 654 ;;;     (internal-try-face-font default "-*-*-*-r-*-*-*-120-*-*-m-*-iso8859-*" frame)
 655 ;;;     (internal-try-face-font default "-*-*-*-r-*-*-*-120-*-*-c-*-iso8859-*" frame)
 656 ;;;     (internal-try-face-font default "-*-*-*-r-*-*-*-120-*-*-*-*-iso8859-*" frame)
 657
 658
 659 ;;; This is called from make-screen-initial-faces to make sure that the
 660 ;;; "default" and "modeline" faces for this screen have enough attributes
 661 ;;; specified for emacs to be able to display anything on it.  This had
 662 ;;; better not signal an error.
 663 ;;;
 664 (defun x-initialize-frame-faces (frame)
 665   (or (face-differs-from-default-p 'bold frame)
 666       (make-face-bold 'bold frame t)
 667       ;; if default font is bold, then make the `bold' face be unbold.
 668       (make-face-unbold 'bold frame t)
 669       ;; otherwise the luser specified one of the bogus font names
 670       (internal-x-complain-about-font 'bold frame)
 671       )
 672
 673   (or (face-differs-from-default-p 'italic frame)
 674       (make-face-italic 'italic frame t)
 675       (progn
 676         (make-face-bold 'italic frame t)
 677         (internal-x-complain-about-font 'italic frame))
 678       )
 679
 680   (or (face-differs-from-default-p 'bold-italic frame)
 681       (make-face-bold-italic 'bold-italic frame t)
 682       ;; if we couldn't get a bold-italic version, try just bold.
 683       (make-face-bold 'bold-italic frame t)
 684       ;; if we couldn't get bold or bold-italic, then that's probably because
 685       ;; the default font is bold, so make the `bold-italic' face be unbold.
 686       (and (make-face-unbold 'bold-italic frame t)
 687            (make-face-italic 'bold-italic frame t))
 688       ;; if that didn't work, try italic (can this ever happen? what the hell.)
 689       (progn
 690         (make-face-italic 'bold-italic frame t)
 691         ;; then bitch and moan.
 692         (internal-x-complain-about-font 'bold-italic frame))
 693       )
 694
 695   (or (face-differs-from-default-p 'highlight frame)
 696       (condition-case ()
 697           (condition-case ()
 698               (set-face-background 'highlight "darkseagreen2" frame)
 699             (error (set-face-background 'highlight "green" frame)))
 700 ;;;         (set-face-background-pixmap 'highlight "gray1" frame)
 701         (error (invert-face 'highlight frame))))
 702
 703   (or (face-differs-from-default-p 'region frame)
 704       (condition-case ()
 705           (set-face-background 'region "gray" frame)
 706         (error (invert-face 'region frame))))
 707
 708   (or (face-differs-from-default-p 'modeline frame)
 709       (invert-face 'modeline frame))
 710
 711   (or (face-differs-from-default-p 'secondary-selection frame)
 712       (condition-case ()
 713           (condition-case ()
 714               ;; some older X servers don't have this one.
 715               (set-face-background 'secondary-selection "paleturquoise"
 716                                    frame)
 717             (error
 718              (set-face-background 'secondary-selection "green" frame)))
 719 ;;;         (set-face-background-pixmap 'secondary-selection "gray1" frame)
 720         (error (invert-face 'secondary-selection frame))))
 721   )
 722
 723 (defun internal-x-complain-about-font (face frame)
 724 ;;; It's annoying to bother the user about this,
 725 ;;; since it happens under normal circumstances.
 726 ;;;  (message "No %s version of %S"
 727 ;;;        face
 728 ;;;        (or (face-font face frame)
 729 ;;;            (face-font face t)
 730 ;;;            (face-font 'default frame)
 731 ;;;            (cdr (assq 'font (frame-parameters frame)))))
 732 ;;;  (sit-for 1)
 733   )
 734 \f
 735 ;; Like x-create-frame but also set up the faces.
 736
 737 (defun x-create-frame-with-faces (&optional parameters)
 738   (if (null global-face-data)
 739       (x-create-frame parameters)
 740     (let* ((frame (x-create-frame parameters))
 741            (faces (copy-alist global-face-data))
 742            (rest faces))
 743       (set-frame-face-alist frame faces)
 744
 745       (if (cdr (or (assq 'reverse parameters)
 746                    (assq 'reverse default-frame-alist)
 747                    (cons nil
 748                          (x-get-resource "reverseVideo" "Reversevideo"))))
 749           (let ((params (frame-parameters frame)))
 750             (modify-frame-parameters
 751              frame
 752              (list (cons 'foreground-color (cdr (assq 'background-color params)))
 753                    (cons 'background-color (cdr (assq 'foreground-color params)))
 754                    (cons 'mouse-color (cdr (assq 'background-color params)))
 755                    (cons 'cursor-color (cdr (assq 'background-color params)))
 756                    (cons 'border-color (cdr (assq 'background-color params)))))))
 757
 758       ;; Copy the vectors that represent the faces.
 759       ;; Also fill them in from X resources.
 760       (while rest
 761         (setcdr (car rest) (copy-sequence (cdr (car rest))))
 762         (make-face-x-resource-internal (cdr (car rest)) frame t)
 763         (setq rest (cdr rest)))
 764
 765       (x-initialize-frame-faces frame)
 766
 767       frame)))
 768
 769 ;; If we are already using x-window frames, initialize faces for them.
 770 (if (eq (framep (selected-frame)) 'x)
 771     (face-initialize))
 772
 773 (provide 'faces)
 774
 775 ;;; faces.el ends here