| 1 | ;;; shell.el --- specialized comint.el for running the shell |
| 2 | |
| 3 | ;; Copyright (C) 1988, 1993, 1994, 1995, 1996, 1997, 2000, |
| 4 | ;; 2002, 2003, 2004, 2005, 2006 Free Software Foundation, Inc. |
| 5 | |
| 6 | ;; Author: Olin Shivers <shivers@cs.cmu.edu> |
| 7 | ;; Simon Marshall <simon@gnu.org> |
| 8 | ;; Maintainer: FSF |
| 9 | ;; Keywords: processes |
| 10 | |
| 11 | ;; This file is part of GNU Emacs. |
| 12 | |
| 13 | ;; GNU Emacs is free software; you can redistribute it and/or modify |
| 14 | ;; it under the terms of the GNU General Public License as published by |
| 15 | ;; the Free Software Foundation; either version 2, or (at your option) |
| 16 | ;; any later version. |
| 17 | |
| 18 | ;; GNU Emacs is distributed in the hope that it will be useful, |
| 19 | ;; but WITHOUT ANY WARRANTY; without even the implied warranty of |
| 20 | ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the |
| 21 | ;; GNU General Public License for more details. |
| 22 | |
| 23 | ;; You should have received a copy of the GNU General Public License |
| 24 | ;; along with GNU Emacs; see the file COPYING. If not, write to the |
| 25 | ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor, |
| 26 | ;; Boston, MA 02110-1301, USA. |
| 27 | |
| 28 | ;;; Commentary: |
| 29 | |
| 30 | ;; Please send me bug reports, bug fixes, and extensions, so that I can |
| 31 | ;; merge them into the master source. |
| 32 | ;; - Olin Shivers (shivers@cs.cmu.edu) |
| 33 | ;; - Simon Marshall (simon@gnu.org) |
| 34 | |
| 35 | ;; This file defines a shell-in-a-buffer package (shell mode) built on |
| 36 | ;; top of comint mode. This is actually cmushell with things renamed |
| 37 | ;; to replace its counterpart in Emacs 18. cmushell is more |
| 38 | ;; featureful, robust, and uniform than the Emacs 18 version. |
| 39 | |
| 40 | ;; Since this mode is built on top of the general command-interpreter-in- |
| 41 | ;; a-buffer mode (comint mode), it shares a common base functionality, |
| 42 | ;; and a common set of bindings, with all modes derived from comint mode. |
| 43 | ;; This makes these modes easier to use. |
| 44 | |
| 45 | ;; For documentation on the functionality provided by comint mode, and |
| 46 | ;; the hooks available for customising it, see the file comint.el. |
| 47 | ;; For further information on shell mode, see the comments below. |
| 48 | |
| 49 | ;; Needs fixin: |
| 50 | ;; When sending text from a source file to a subprocess, the process-mark can |
| 51 | ;; move off the window, so you can lose sight of the process interactions. |
| 52 | ;; Maybe I should ensure the process mark is in the window when I send |
| 53 | ;; text to the process? Switch selectable? |
| 54 | |
| 55 | ;; YOUR .EMACS FILE |
| 56 | ;;============================================================================= |
| 57 | ;; Some suggestions for your .emacs file. |
| 58 | ;; |
| 59 | ;; ;; Define M-# to run some strange command: |
| 60 | ;; (eval-after-load "shell" |
| 61 | ;; '(define-key shell-mode-map "\M-#" 'shells-dynamic-spell)) |
| 62 | |
| 63 | ;; Brief Command Documentation: |
| 64 | ;;============================================================================ |
| 65 | ;; Comint Mode Commands: (common to shell and all comint-derived modes) |
| 66 | ;; |
| 67 | ;; m-p comint-previous-input Cycle backwards in input history |
| 68 | ;; m-n comint-next-input Cycle forwards |
| 69 | ;; m-r comint-previous-matching-input Previous input matching a regexp |
| 70 | ;; m-s comint-next-matching-input Next input that matches |
| 71 | ;; m-c-l comint-show-output Show last batch of process output |
| 72 | ;; return comint-send-input |
| 73 | ;; c-d comint-delchar-or-maybe-eof Delete char unless at end of buff. |
| 74 | ;; c-c c-a comint-bol Beginning of line; skip prompt |
| 75 | ;; c-c c-u comint-kill-input ^u |
| 76 | ;; c-c c-w backward-kill-word ^w |
| 77 | ;; c-c c-c comint-interrupt-subjob ^c |
| 78 | ;; c-c c-z comint-stop-subjob ^z |
| 79 | ;; c-c c-\ comint-quit-subjob ^\ |
| 80 | ;; c-c c-o comint-kill-output Delete last batch of process output |
| 81 | ;; c-c c-r comint-show-output Show last batch of process output |
| 82 | ;; c-c c-l comint-dynamic-list-input-ring List input history |
| 83 | ;; send-invisible Read line w/o echo & send to proc |
| 84 | ;; comint-continue-subjob Useful if you accidentally suspend |
| 85 | ;; top-level job |
| 86 | ;; comint-mode-hook is the comint mode hook. |
| 87 | |
| 88 | ;; Shell Mode Commands: |
| 89 | ;; shell Fires up the shell process |
| 90 | ;; tab comint-dynamic-complete Complete filename/command/history |
| 91 | ;; m-? comint-dynamic-list-filename-completions |
| 92 | ;; List completions in help buffer |
| 93 | ;; m-c-f shell-forward-command Forward a shell command |
| 94 | ;; m-c-b shell-backward-command Backward a shell command |
| 95 | ;; dirs Resync the buffer's dir stack |
| 96 | ;; dirtrack-mode Turn dir tracking on/off |
| 97 | ;; comint-strip-ctrl-m Remove trailing ^Ms from output |
| 98 | ;; |
| 99 | ;; The shell mode hook is shell-mode-hook |
| 100 | ;; comint-prompt-regexp is initialised to shell-prompt-pattern, for backwards |
| 101 | ;; compatibility. |
| 102 | |
| 103 | ;; Read the rest of this file for more information. |
| 104 | |
| 105 | ;;; Code: |
| 106 | |
| 107 | (require 'comint) |
| 108 | |
| 109 | ;;; Customization and Buffer Variables |
| 110 | |
| 111 | (defgroup shell nil |
| 112 | "Running shell from within Emacs buffers." |
| 113 | :group 'processes |
| 114 | :group 'unix) |
| 115 | |
| 116 | (defgroup shell-directories nil |
| 117 | "Directory support in shell mode." |
| 118 | :group 'shell) |
| 119 | |
| 120 | (defgroup shell-faces nil |
| 121 | "Faces in shell buffers." |
| 122 | :group 'shell) |
| 123 | |
| 124 | ;;;###autoload |
| 125 | (defcustom shell-dumb-shell-regexp "cmd\\(proxy\\)?\\.exe" |
| 126 | "Regexp to match shells that don't save their command history, and |
| 127 | don't handle the backslash as a quote character. For shells that |
| 128 | match this regexp, Emacs will write out the command history when the |
| 129 | shell finishes, and won't remove backslashes when it unquotes shell |
| 130 | arguments." |
| 131 | :type 'regexp |
| 132 | :group 'shell) |
| 133 | |
| 134 | (defcustom shell-prompt-pattern "^[^#$%>\n]*[#$%>] *" |
| 135 | "Regexp to match prompts in the inferior shell. |
| 136 | Defaults to \"^[^#$%>\\n]*[#$%>] *\", which works pretty well. |
| 137 | This variable is used to initialize `comint-prompt-regexp' in the |
| 138 | shell buffer. |
| 139 | |
| 140 | If `comint-use-prompt-regexp' is nil, then this variable is only used |
| 141 | to determine paragraph boundaries. See Info node `Shell Prompts' for |
| 142 | how Shell mode treats paragraphs. |
| 143 | |
| 144 | The pattern should probably not match more than one line. If it does, |
| 145 | Shell mode may become confused trying to distinguish prompt from input |
| 146 | on lines which don't start with a prompt. |
| 147 | |
| 148 | This is a fine thing to set in your `.emacs' file." |
| 149 | :type 'regexp |
| 150 | :group 'shell) |
| 151 | |
| 152 | (defcustom shell-completion-fignore nil |
| 153 | "List of suffixes to be disregarded during file/command completion. |
| 154 | This variable is used to initialize `comint-completion-fignore' in the shell |
| 155 | buffer. The default is nil, for compatibility with most shells. |
| 156 | Some people like (\"~\" \"#\" \"%\"). |
| 157 | |
| 158 | This is a fine thing to set in your `.emacs' file." |
| 159 | :type '(repeat (string :tag "Suffix")) |
| 160 | :group 'shell) |
| 161 | |
| 162 | (defvar shell-delimiter-argument-list '(?\| ?& ?< ?> ?\( ?\) ?\;) |
| 163 | "List of characters to recognize as separate arguments. |
| 164 | This variable is used to initialize `comint-delimiter-argument-list' in the |
| 165 | shell buffer. The value may depend on the operating system or shell. |
| 166 | |
| 167 | This is a fine thing to set in your `.emacs' file.") |
| 168 | |
| 169 | (defvar shell-file-name-chars |
| 170 | (if (memq system-type '(ms-dos windows-nt cygwin)) |
| 171 | "~/A-Za-z0-9_^$!#%&{}@`'.,:()-" |
| 172 | "[]~/A-Za-z0-9+@:_.$#%,={}-") |
| 173 | "String of characters valid in a file name. |
| 174 | This variable is used to initialize `comint-file-name-chars' in the |
| 175 | shell buffer. The value may depend on the operating system or shell. |
| 176 | |
| 177 | This is a fine thing to set in your `.emacs' file.") |
| 178 | |
| 179 | (defvar shell-file-name-quote-list |
| 180 | (if (memq system-type '(ms-dos windows-nt)) |
| 181 | nil |
| 182 | (append shell-delimiter-argument-list '(?\s ?\* ?\! ?\" ?\' ?\` ?\# ?\\))) |
| 183 | "List of characters to quote when in a file name. |
| 184 | This variable is used to initialize `comint-file-name-quote-list' in the |
| 185 | shell buffer. The value may depend on the operating system or shell. |
| 186 | |
| 187 | This is a fine thing to set in your `.emacs' file.") |
| 188 | |
| 189 | (defvar shell-dynamic-complete-functions |
| 190 | '(comint-replace-by-expanded-history |
| 191 | shell-dynamic-complete-environment-variable |
| 192 | shell-dynamic-complete-command |
| 193 | shell-replace-by-expanded-directory |
| 194 | comint-dynamic-complete-filename) |
| 195 | "List of functions called to perform completion. |
| 196 | This variable is used to initialize `comint-dynamic-complete-functions' in the |
| 197 | shell buffer. |
| 198 | |
| 199 | This is a fine thing to set in your `.emacs' file.") |
| 200 | |
| 201 | (defcustom shell-command-regexp "[^;&|\n]+" |
| 202 | "Regexp to match a single command within a pipeline. |
| 203 | This is used for directory tracking and does not do a perfect job." |
| 204 | :type 'regexp |
| 205 | :group 'shell) |
| 206 | |
| 207 | (defcustom shell-command-separator-regexp "[;&|\n \t]*" |
| 208 | "Regexp to match a single command within a pipeline. |
| 209 | This is used for directory tracking and does not do a perfect job." |
| 210 | :type 'regexp |
| 211 | :group 'shell) |
| 212 | |
| 213 | (defcustom shell-completion-execonly t |
| 214 | "If non-nil, use executable files only for completion candidates. |
| 215 | This mirrors the optional behavior of tcsh. |
| 216 | |
| 217 | Detecting executability of files may slow command completion considerably." |
| 218 | :type 'boolean |
| 219 | :group 'shell) |
| 220 | |
| 221 | (defcustom shell-popd-regexp "popd" |
| 222 | "Regexp to match subshell commands equivalent to popd." |
| 223 | :type 'regexp |
| 224 | :group 'shell-directories) |
| 225 | |
| 226 | (defcustom shell-pushd-regexp "pushd" |
| 227 | "Regexp to match subshell commands equivalent to pushd." |
| 228 | :type 'regexp |
| 229 | :group 'shell-directories) |
| 230 | |
| 231 | (defcustom shell-pushd-tohome nil |
| 232 | "If non-nil, make pushd with no arg behave as \"pushd ~\" (like cd). |
| 233 | This mirrors the optional behavior of tcsh." |
| 234 | :type 'boolean |
| 235 | :group 'shell-directories) |
| 236 | |
| 237 | (defcustom shell-pushd-dextract nil |
| 238 | "If non-nil, make \"pushd +n\" pop the nth dir to the stack top. |
| 239 | This mirrors the optional behavior of tcsh." |
| 240 | :type 'boolean |
| 241 | :group 'shell-directories) |
| 242 | |
| 243 | (defcustom shell-pushd-dunique nil |
| 244 | "If non-nil, make pushd only add unique directories to the stack. |
| 245 | This mirrors the optional behavior of tcsh." |
| 246 | :type 'boolean |
| 247 | :group 'shell-directories) |
| 248 | |
| 249 | (defcustom shell-cd-regexp "cd" |
| 250 | "Regexp to match subshell commands equivalent to cd." |
| 251 | :type 'regexp |
| 252 | :group 'shell-directories) |
| 253 | |
| 254 | (defcustom shell-chdrive-regexp |
| 255 | (if (memq system-type '(ms-dos windows-nt)) |
| 256 | ; NetWare allows the five chars between upper and lower alphabetics. |
| 257 | "[]a-zA-Z^_`\\[\\\\]:" |
| 258 | nil) |
| 259 | "If non-nil, is regexp used to track drive changes." |
| 260 | :type '(choice regexp |
| 261 | (const nil)) |
| 262 | :group 'shell-directories) |
| 263 | |
| 264 | (defcustom shell-dirtrack-verbose t |
| 265 | "If non-nil, show the directory stack following directory change. |
| 266 | This is effective only if directory tracking is enabled." |
| 267 | :type 'boolean |
| 268 | :group 'shell-directories) |
| 269 | |
| 270 | (defcustom explicit-shell-file-name nil |
| 271 | "If non-nil, is file name to use for explicitly requested inferior shell." |
| 272 | :type '(choice (const :tag "None" nil) file) |
| 273 | :group 'shell) |
| 274 | |
| 275 | (defcustom explicit-csh-args |
| 276 | (if (eq system-type 'hpux) |
| 277 | ;; -T persuades HP's csh not to think it is smarter |
| 278 | ;; than us about what terminal modes to use. |
| 279 | '("-i" "-T") |
| 280 | '("-i")) |
| 281 | "Args passed to inferior shell by \\[shell], if the shell is csh. |
| 282 | Value is a list of strings, which may be nil." |
| 283 | :type '(repeat (string :tag "Argument")) |
| 284 | :group 'shell) |
| 285 | |
| 286 | (defcustom explicit-bash-args |
| 287 | ;; Tell bash not to use readline, except for bash 1.x which doesn't grook --noediting. |
| 288 | ;; Bash 1.x has -nolineediting, but process-send-eof cannot terminate bash if we use it. |
| 289 | (let* ((prog (or (and (boundp 'explicit-shell-file-name) explicit-shell-file-name) |
| 290 | (getenv "ESHELL") shell-file-name)) |
| 291 | (name (file-name-nondirectory prog))) |
| 292 | (if (and (not purify-flag) |
| 293 | (equal name "bash") |
| 294 | (file-executable-p prog) |
| 295 | (string-match "bad option" |
| 296 | (shell-command-to-string (concat prog " --noediting")))) |
| 297 | '("-i") |
| 298 | '("--noediting" "-i"))) |
| 299 | "Args passed to inferior shell by \\[shell], if the shell is bash. |
| 300 | Value is a list of strings, which may be nil." |
| 301 | :type '(repeat (string :tag "Argument")) |
| 302 | :group 'shell) |
| 303 | |
| 304 | (defcustom shell-input-autoexpand 'history |
| 305 | "If non-nil, expand input command history references on completion. |
| 306 | This mirrors the optional behavior of tcsh (its autoexpand and histlit). |
| 307 | |
| 308 | If the value is `input', then the expansion is seen on input. |
| 309 | If the value is `history', then the expansion is only when inserting |
| 310 | into the buffer's input ring. See also `comint-magic-space' and |
| 311 | `comint-dynamic-complete'. |
| 312 | |
| 313 | This variable supplies a default for `comint-input-autoexpand', |
| 314 | for Shell mode only." |
| 315 | :type '(choice (const :tag "off" nil) |
| 316 | (const input) |
| 317 | (const history) |
| 318 | (const :tag "on" t)) |
| 319 | :group 'shell) |
| 320 | |
| 321 | (defvar shell-dirstack nil |
| 322 | "List of directories saved by pushd in this buffer's shell. |
| 323 | Thus, this does not include the shell's current directory.") |
| 324 | |
| 325 | (defvar shell-dirtrackp t |
| 326 | "Non-nil in a shell buffer means directory tracking is enabled.") |
| 327 | |
| 328 | (defvar shell-last-dir nil |
| 329 | "Keep track of last directory for ksh `cd -' command.") |
| 330 | |
| 331 | (defvar shell-dirstack-query nil |
| 332 | "Command used by `shell-resync-dir' to query the shell.") |
| 333 | |
| 334 | (defvar shell-mode-map nil) |
| 335 | (cond ((not shell-mode-map) |
| 336 | (setq shell-mode-map (nconc (make-sparse-keymap) comint-mode-map)) |
| 337 | (define-key shell-mode-map "\C-c\C-f" 'shell-forward-command) |
| 338 | (define-key shell-mode-map "\C-c\C-b" 'shell-backward-command) |
| 339 | (define-key shell-mode-map "\t" 'comint-dynamic-complete) |
| 340 | (define-key shell-mode-map "\M-?" |
| 341 | 'comint-dynamic-list-filename-completions) |
| 342 | (define-key shell-mode-map [menu-bar completion] |
| 343 | (cons "Complete" |
| 344 | (copy-keymap (lookup-key comint-mode-map [menu-bar completion])))) |
| 345 | (define-key-after (lookup-key shell-mode-map [menu-bar completion]) |
| 346 | [complete-env-variable] '("Complete Env. Variable Name" . |
| 347 | shell-dynamic-complete-environment-variable) |
| 348 | 'complete-file) |
| 349 | (define-key-after (lookup-key shell-mode-map [menu-bar completion]) |
| 350 | [expand-directory] '("Expand Directory Reference" . |
| 351 | shell-replace-by-expanded-directory) |
| 352 | 'complete-expand))) |
| 353 | |
| 354 | (defcustom shell-mode-hook '() |
| 355 | "*Hook for customising Shell mode." |
| 356 | :type 'hook |
| 357 | :group 'shell) |
| 358 | |
| 359 | (defvar shell-font-lock-keywords |
| 360 | '(("[ \t]\\([+-][^ \t\n]+\\)" 1 font-lock-comment-face) |
| 361 | ("^[^ \t\n]+:.*" . font-lock-string-face) |
| 362 | ("^\\[[1-9][0-9]*\\]" . font-lock-string-face)) |
| 363 | "Additional expressions to highlight in Shell mode.") |
| 364 | |
| 365 | ;;; Basic Procedures |
| 366 | |
| 367 | (put 'shell-mode 'mode-class 'special) |
| 368 | |
| 369 | (define-derived-mode shell-mode comint-mode "Shell" |
| 370 | "Major mode for interacting with an inferior shell.\\<shell-mode-map> |
| 371 | \\[comint-send-input] after the end of the process' output sends the text from |
| 372 | the end of process to the end of the current line. |
| 373 | \\[comint-send-input] before end of process output copies the current line minus the prompt to |
| 374 | the end of the buffer and sends it (\\[comint-copy-old-input] just copies the current line). |
| 375 | \\[send-invisible] reads a line of text without echoing it, and sends it to |
| 376 | the shell. This is useful for entering passwords. Or, add the function |
| 377 | `comint-watch-for-password-prompt' to `comint-output-filter-functions'. |
| 378 | |
| 379 | If you want to make multiple shell buffers, rename the `*shell*' buffer |
| 380 | using \\[rename-buffer] or \\[rename-uniquely] and start a new shell. |
| 381 | |
| 382 | If you want to make shell buffers limited in length, add the function |
| 383 | `comint-truncate-buffer' to `comint-output-filter-functions'. |
| 384 | |
| 385 | If you accidentally suspend your process, use \\[comint-continue-subjob] |
| 386 | to continue it. |
| 387 | |
| 388 | `cd', `pushd' and `popd' commands given to the shell are watched by Emacs to |
| 389 | keep this buffer's default directory the same as the shell's working directory. |
| 390 | While directory tracking is enabled, the shell's working directory is displayed |
| 391 | by \\[list-buffers] or \\[mouse-buffer-menu] in the `File' field. |
| 392 | \\[dirs] queries the shell and resyncs Emacs' idea of what the current |
| 393 | directory stack is. |
| 394 | \\[dirtrack-mode] turns directory tracking on and off. |
| 395 | |
| 396 | \\{shell-mode-map} |
| 397 | Customization: Entry to this mode runs the hooks on `comint-mode-hook' and |
| 398 | `shell-mode-hook' (in that order). Before each input, the hooks on |
| 399 | `comint-input-filter-functions' are run. After each shell output, the hooks |
| 400 | on `comint-output-filter-functions' are run. |
| 401 | |
| 402 | Variables `shell-cd-regexp', `shell-chdrive-regexp', `shell-pushd-regexp' |
| 403 | and `shell-popd-regexp' are used to match their respective commands, |
| 404 | while `shell-pushd-tohome', `shell-pushd-dextract' and `shell-pushd-dunique' |
| 405 | control the behavior of the relevant command. |
| 406 | |
| 407 | Variables `comint-completion-autolist', `comint-completion-addsuffix', |
| 408 | `comint-completion-recexact' and `comint-completion-fignore' control the |
| 409 | behavior of file name, command name and variable name completion. Variable |
| 410 | `shell-completion-execonly' controls the behavior of command name completion. |
| 411 | Variable `shell-completion-fignore' is used to initialize the value of |
| 412 | `comint-completion-fignore'. |
| 413 | |
| 414 | Variables `comint-input-ring-file-name' and `comint-input-autoexpand' control |
| 415 | the initialization of the input ring history, and history expansion. |
| 416 | |
| 417 | Variables `comint-output-filter-functions', a hook, and |
| 418 | `comint-scroll-to-bottom-on-input' and `comint-scroll-to-bottom-on-output' |
| 419 | control whether input and output cause the window to scroll to the end of the |
| 420 | buffer." |
| 421 | (setq comint-prompt-regexp shell-prompt-pattern) |
| 422 | (setq comint-completion-fignore shell-completion-fignore) |
| 423 | (setq comint-delimiter-argument-list shell-delimiter-argument-list) |
| 424 | (setq comint-file-name-chars shell-file-name-chars) |
| 425 | (setq comint-file-name-quote-list shell-file-name-quote-list) |
| 426 | (set (make-local-variable 'comint-dynamic-complete-functions) |
| 427 | shell-dynamic-complete-functions) |
| 428 | (set (make-local-variable 'paragraph-separate) "\\'") |
| 429 | (make-local-variable 'paragraph-start) |
| 430 | (setq paragraph-start comint-prompt-regexp) |
| 431 | (make-local-variable 'font-lock-defaults) |
| 432 | (setq font-lock-defaults '(shell-font-lock-keywords t)) |
| 433 | (make-local-variable 'shell-dirstack) |
| 434 | (setq shell-dirstack nil) |
| 435 | (make-local-variable 'shell-last-dir) |
| 436 | (setq shell-last-dir nil) |
| 437 | (setq comint-input-autoexpand shell-input-autoexpand) |
| 438 | ;; This is not really correct, since the shell buffer does not really |
| 439 | ;; edit this directory. But it is useful in the buffer list and menus. |
| 440 | (make-local-variable 'list-buffers-directory) |
| 441 | (shell-dirtrack-mode 1) |
| 442 | (setq list-buffers-directory (expand-file-name default-directory)) |
| 443 | ;; shell-dependent assignments. |
| 444 | (when (ring-empty-p comint-input-ring) |
| 445 | (let ((shell (file-name-nondirectory (car |
| 446 | (process-command (get-buffer-process (current-buffer))))))) |
| 447 | (setq comint-input-ring-file-name |
| 448 | (or (getenv "HISTFILE") |
| 449 | (cond ((string-equal shell "bash") "~/.bash_history") |
| 450 | ((string-equal shell "ksh") "~/.sh_history") |
| 451 | (t "~/.history")))) |
| 452 | (if (or (equal comint-input-ring-file-name "") |
| 453 | (equal (file-truename comint-input-ring-file-name) |
| 454 | (file-truename "/dev/null"))) |
| 455 | (setq comint-input-ring-file-name nil)) |
| 456 | ;; Arrange to write out the input ring on exit, if the shell doesn't |
| 457 | ;; do this itself. |
| 458 | (if (and comint-input-ring-file-name |
| 459 | (string-match shell-dumb-shell-regexp shell)) |
| 460 | (set-process-sentinel (get-buffer-process (current-buffer)) |
| 461 | #'shell-write-history-on-exit)) |
| 462 | (setq shell-dirstack-query |
| 463 | (cond ((string-equal shell "sh") "pwd") |
| 464 | ((string-equal shell "ksh") "echo $PWD ~-") |
| 465 | (t "dirs"))) |
| 466 | ;; Bypass a bug in certain versions of bash. |
| 467 | (when (string-equal shell "bash") |
| 468 | (add-hook 'comint-output-filter-functions |
| 469 | 'shell-filter-ctrl-a-ctrl-b nil t))) |
| 470 | (comint-read-input-ring t))) |
| 471 | |
| 472 | (defun shell-filter-ctrl-a-ctrl-b (string) |
| 473 | "Remove `^A' and `^B' characters from comint output. |
| 474 | |
| 475 | Bash uses these characters as internal quoting characters in its |
| 476 | prompt. Due to a bug in some bash versions (including 2.03, |
| 477 | 2.04, and 2.05b), they may erroneously show up when bash is |
| 478 | started with the `--noediting' option and Select Graphic |
| 479 | Rendition (SGR) control sequences (formerly known as ANSI escape |
| 480 | sequences) are used to color the prompt. |
| 481 | |
| 482 | This function can be put on `comint-output-filter-functions'. |
| 483 | The argument STRING is ignored." |
| 484 | (let ((pmark (process-mark (get-buffer-process (current-buffer))))) |
| 485 | (save-excursion |
| 486 | (goto-char (or comint-last-output-start (point-min))) |
| 487 | (while (re-search-forward "[\C-a\C-b]" pmark t) |
| 488 | (replace-match ""))))) |
| 489 | |
| 490 | (defun shell-write-history-on-exit (process event) |
| 491 | "Called when the shell process is stopped. |
| 492 | |
| 493 | Writes the input history to a history file |
| 494 | `comint-input-ring-file-name' using `comint-write-input-ring' |
| 495 | and inserts a short message in the shell buffer. |
| 496 | |
| 497 | This function is a sentinel watching the shell interpreter process. |
| 498 | Sentinels will always get the two parameters PROCESS and EVENT." |
| 499 | ;; Write history. |
| 500 | (comint-write-input-ring) |
| 501 | (let ((buf (process-buffer process))) |
| 502 | (when (buffer-live-p buf) |
| 503 | (with-current-buffer buf |
| 504 | (insert (format "\nProcess %s %s\n" process event)))))) |
| 505 | |
| 506 | ;;;###autoload |
| 507 | (defun shell (&optional buffer) |
| 508 | "Run an inferior shell, with I/O through BUFFER (which defaults to `*shell*'). |
| 509 | Interactively, a prefix arg means to prompt for BUFFER. |
| 510 | If BUFFER exists but shell process is not running, make new shell. |
| 511 | If BUFFER exists and shell process is running, just switch to BUFFER. |
| 512 | Program used comes from variable `explicit-shell-file-name', |
| 513 | or (if that is nil) from the ESHELL environment variable, |
| 514 | or else from SHELL if there is no ESHELL. |
| 515 | If a file `~/.emacs_SHELLNAME' exists, it is given as initial input |
| 516 | (Note that this may lose due to a timing error if the shell |
| 517 | discards input when it starts up.) |
| 518 | The buffer is put in Shell mode, giving commands for sending input |
| 519 | and controlling the subjobs of the shell. See `shell-mode'. |
| 520 | See also the variable `shell-prompt-pattern'. |
| 521 | |
| 522 | To specify a coding system for converting non-ASCII characters |
| 523 | in the input and output to the shell, use \\[universal-coding-system-argument] |
| 524 | before \\[shell]. You can also specify this with \\[set-buffer-process-coding-system] |
| 525 | in the shell buffer, after you start the shell. |
| 526 | The default comes from `process-coding-system-alist' and |
| 527 | `default-process-coding-system'. |
| 528 | |
| 529 | The shell file name (sans directories) is used to make a symbol name |
| 530 | such as `explicit-csh-args'. If that symbol is a variable, |
| 531 | its value is used as a list of arguments when invoking the shell. |
| 532 | Otherwise, one argument `-i' is passed to the shell. |
| 533 | |
| 534 | \(Type \\[describe-mode] in the shell buffer for a list of commands.)" |
| 535 | (interactive |
| 536 | (list |
| 537 | (and current-prefix-arg |
| 538 | (read-buffer "Shell buffer: " |
| 539 | (generate-new-buffer-name "*shell*"))))) |
| 540 | (setq buffer (get-buffer-create (or buffer "*shell*"))) |
| 541 | ;; Pop to buffer, so that the buffer's window will be correctly set |
| 542 | ;; when we call comint (so that comint sets the COLUMNS env var properly). |
| 543 | (pop-to-buffer buffer) |
| 544 | (unless (comint-check-proc buffer) |
| 545 | (let* ((prog (or explicit-shell-file-name |
| 546 | (getenv "ESHELL") shell-file-name)) |
| 547 | (name (file-name-nondirectory prog)) |
| 548 | (startfile (concat "~/.emacs_" name)) |
| 549 | (xargs-name (intern-soft (concat "explicit-" name "-args")))) |
| 550 | (if (not (file-exists-p startfile)) |
| 551 | (setq startfile (concat "~/.emacs.d/.emacs_" name))) |
| 552 | (apply 'make-comint-in-buffer "shell" buffer prog |
| 553 | (if (file-exists-p startfile) startfile) |
| 554 | (if (and xargs-name (boundp xargs-name)) |
| 555 | (symbol-value xargs-name) |
| 556 | '("-i"))) |
| 557 | (shell-mode))) |
| 558 | buffer) |
| 559 | |
| 560 | ;; Don't do this when shell.el is loaded, only while dumping. |
| 561 | ;;;###autoload (add-hook 'same-window-buffer-names "*shell*") |
| 562 | |
| 563 | ;;; Directory tracking |
| 564 | ;; |
| 565 | ;; This code provides the shell mode input sentinel |
| 566 | ;; SHELL-DIRECTORY-TRACKER |
| 567 | ;; that tracks cd, pushd, and popd commands issued to the shell, and |
| 568 | ;; changes the current directory of the shell buffer accordingly. |
| 569 | ;; |
| 570 | ;; This is basically a fragile hack, although it's more accurate than |
| 571 | ;; the version in Emacs 18's shell.el. It has the following failings: |
| 572 | ;; 1. It doesn't know about the cdpath shell variable. |
| 573 | ;; 2. It cannot infallibly deal with command sequences, though it does well |
| 574 | ;; with these and with ignoring commands forked in another shell with ()s. |
| 575 | ;; 3. More generally, any complex command is going to throw it. Otherwise, |
| 576 | ;; you'd have to build an entire shell interpreter in Emacs Lisp. Failing |
| 577 | ;; that, there's no way to catch shell commands where cd's are buried |
| 578 | ;; inside conditional expressions, aliases, and so forth. |
| 579 | ;; |
| 580 | ;; The whole approach is a crock. Shell aliases mess it up. File sourcing |
| 581 | ;; messes it up. You run other processes under the shell; these each have |
| 582 | ;; separate working directories, and some have commands for manipulating |
| 583 | ;; their w.d.'s (e.g., the lcd command in ftp). Some of these programs have |
| 584 | ;; commands that do *not* affect the current w.d. at all, but look like they |
| 585 | ;; do (e.g., the cd command in ftp). In shells that allow you job |
| 586 | ;; control, you can switch between jobs, all having different w.d.'s. So |
| 587 | ;; simply saying %3 can shift your w.d.. |
| 588 | ;; |
| 589 | ;; The solution is to relax, not stress out about it, and settle for |
| 590 | ;; a hack that works pretty well in typical circumstances. Remember |
| 591 | ;; that a half-assed solution is more in keeping with the spirit of Unix, |
| 592 | ;; anyway. Blech. |
| 593 | ;; |
| 594 | ;; One good hack not implemented here for users of programmable shells |
| 595 | ;; is to program up the shell w.d. manipulation commands to output |
| 596 | ;; a coded command sequence to the tty. Something like |
| 597 | ;; ESC | <cwd> | |
| 598 | ;; where <cwd> is the new current working directory. Then trash the |
| 599 | ;; directory tracking machinery currently used in this package, and |
| 600 | ;; replace it with a process filter that watches for and strips out |
| 601 | ;; these messages. |
| 602 | |
| 603 | (defun shell-directory-tracker (str) |
| 604 | "Tracks cd, pushd and popd commands issued to the shell. |
| 605 | This function is called on each input passed to the shell. |
| 606 | It watches for cd, pushd and popd commands and sets the buffer's |
| 607 | default directory to track these commands. |
| 608 | |
| 609 | You may toggle this tracking on and off with \\[dirtrack-mode]. |
| 610 | If Emacs gets confused, you can resync with the shell with \\[dirs]. |
| 611 | |
| 612 | See variables `shell-cd-regexp', `shell-chdrive-regexp', `shell-pushd-regexp', |
| 613 | and `shell-popd-regexp', while `shell-pushd-tohome', `shell-pushd-dextract', |
| 614 | and `shell-pushd-dunique' control the behavior of the relevant command. |
| 615 | |
| 616 | Environment variables are expanded, see function `substitute-in-file-name'." |
| 617 | (if shell-dirtrackp |
| 618 | ;; We fail gracefully if we think the command will fail in the shell. |
| 619 | (condition-case chdir-failure |
| 620 | (let ((start (progn (string-match |
| 621 | (concat "^" shell-command-separator-regexp) |
| 622 | str) ; skip whitespace |
| 623 | (match-end 0))) |
| 624 | end cmd arg1) |
| 625 | (while (string-match shell-command-regexp str start) |
| 626 | (setq end (match-end 0) |
| 627 | cmd (comint-arguments (substring str start end) 0 0) |
| 628 | arg1 (comint-arguments (substring str start end) 1 1)) |
| 629 | (if arg1 |
| 630 | (setq arg1 (shell-unquote-argument arg1))) |
| 631 | (cond ((string-match (concat "\\`\\(" shell-popd-regexp |
| 632 | "\\)\\($\\|[ \t]\\)") |
| 633 | cmd) |
| 634 | (shell-process-popd (comint-substitute-in-file-name arg1))) |
| 635 | ((string-match (concat "\\`\\(" shell-pushd-regexp |
| 636 | "\\)\\($\\|[ \t]\\)") |
| 637 | cmd) |
| 638 | (shell-process-pushd (comint-substitute-in-file-name arg1))) |
| 639 | ((string-match (concat "\\`\\(" shell-cd-regexp |
| 640 | "\\)\\($\\|[ \t]\\)") |
| 641 | cmd) |
| 642 | (shell-process-cd (comint-substitute-in-file-name arg1))) |
| 643 | ((and shell-chdrive-regexp |
| 644 | (string-match (concat "\\`\\(" shell-chdrive-regexp |
| 645 | "\\)\\($\\|[ \t]\\)") |
| 646 | cmd)) |
| 647 | (shell-process-cd (comint-substitute-in-file-name cmd)))) |
| 648 | (setq start (progn (string-match shell-command-separator-regexp |
| 649 | str end) |
| 650 | ;; skip again |
| 651 | (match-end 0))))) |
| 652 | (error "Couldn't cd")))) |
| 653 | |
| 654 | (defun shell-unquote-argument (string) |
| 655 | "Remove all kinds of shell quoting from STRING." |
| 656 | (save-match-data |
| 657 | (let ((idx 0) next inside |
| 658 | (quote-chars |
| 659 | (if (string-match shell-dumb-shell-regexp |
| 660 | (file-name-nondirectory |
| 661 | (car (process-command (get-buffer-process (current-buffer)))))) |
| 662 | "['`\"]" |
| 663 | "[\\'`\"]"))) |
| 664 | (while (and (< idx (length string)) |
| 665 | (setq next (string-match quote-chars string next))) |
| 666 | (cond ((= (aref string next) ?\\) |
| 667 | (setq string (replace-match "" nil nil string)) |
| 668 | (setq next (1+ next))) |
| 669 | ((and inside (= (aref string next) inside)) |
| 670 | (setq string (replace-match "" nil nil string)) |
| 671 | (setq inside nil)) |
| 672 | (inside |
| 673 | (setq next (1+ next))) |
| 674 | (t |
| 675 | (setq inside (aref string next)) |
| 676 | (setq string (replace-match "" nil nil string))))) |
| 677 | string))) |
| 678 | |
| 679 | ;; popd [+n] |
| 680 | (defun shell-process-popd (arg) |
| 681 | (let ((num (or (shell-extract-num arg) 0))) |
| 682 | (cond ((and num (= num 0) shell-dirstack) |
| 683 | (shell-cd (car shell-dirstack)) |
| 684 | (setq shell-dirstack (cdr shell-dirstack)) |
| 685 | (shell-dirstack-message)) |
| 686 | ((and num (> num 0) (<= num (length shell-dirstack))) |
| 687 | (let* ((ds (cons nil shell-dirstack)) |
| 688 | (cell (nthcdr (1- num) ds))) |
| 689 | (rplacd cell (cdr (cdr cell))) |
| 690 | (setq shell-dirstack (cdr ds)) |
| 691 | (shell-dirstack-message))) |
| 692 | (t |
| 693 | (error "Couldn't popd"))))) |
| 694 | |
| 695 | ;; Return DIR prefixed with comint-file-name-prefix as appropriate. |
| 696 | (defun shell-prefixed-directory-name (dir) |
| 697 | (if (= (length comint-file-name-prefix) 0) |
| 698 | dir |
| 699 | (if (file-name-absolute-p dir) |
| 700 | ;; The name is absolute, so prepend the prefix. |
| 701 | (concat comint-file-name-prefix dir) |
| 702 | ;; For relative name we assume default-directory already has the prefix. |
| 703 | (expand-file-name dir)))) |
| 704 | |
| 705 | ;; cd [dir] |
| 706 | (defun shell-process-cd (arg) |
| 707 | (let ((new-dir (cond ((zerop (length arg)) (concat comint-file-name-prefix |
| 708 | "~")) |
| 709 | ((string-equal "-" arg) shell-last-dir) |
| 710 | (t (shell-prefixed-directory-name arg))))) |
| 711 | (setq shell-last-dir default-directory) |
| 712 | (shell-cd new-dir) |
| 713 | (shell-dirstack-message))) |
| 714 | |
| 715 | ;; pushd [+n | dir] |
| 716 | (defun shell-process-pushd (arg) |
| 717 | (let ((num (shell-extract-num arg))) |
| 718 | (cond ((zerop (length arg)) |
| 719 | ;; no arg -- swap pwd and car of stack unless shell-pushd-tohome |
| 720 | (cond (shell-pushd-tohome |
| 721 | (shell-process-pushd (concat comint-file-name-prefix "~"))) |
| 722 | (shell-dirstack |
| 723 | (let ((old default-directory)) |
| 724 | (shell-cd (car shell-dirstack)) |
| 725 | (setq shell-dirstack (cons old (cdr shell-dirstack))) |
| 726 | (shell-dirstack-message))) |
| 727 | (t |
| 728 | (message "Directory stack empty.")))) |
| 729 | ((numberp num) |
| 730 | ;; pushd +n |
| 731 | (cond ((> num (length shell-dirstack)) |
| 732 | (message "Directory stack not that deep.")) |
| 733 | ((= num 0) |
| 734 | (error (message "Couldn't cd"))) |
| 735 | (shell-pushd-dextract |
| 736 | (let ((dir (nth (1- num) shell-dirstack))) |
| 737 | (shell-process-popd arg) |
| 738 | (shell-process-pushd default-directory) |
| 739 | (shell-cd dir) |
| 740 | (shell-dirstack-message))) |
| 741 | (t |
| 742 | (let* ((ds (cons default-directory shell-dirstack)) |
| 743 | (dslen (length ds)) |
| 744 | (front (nthcdr num ds)) |
| 745 | (back (reverse (nthcdr (- dslen num) (reverse ds)))) |
| 746 | (new-ds (append front back))) |
| 747 | (shell-cd (car new-ds)) |
| 748 | (setq shell-dirstack (cdr new-ds)) |
| 749 | (shell-dirstack-message))))) |
| 750 | (t |
| 751 | ;; pushd <dir> |
| 752 | (let ((old-wd default-directory)) |
| 753 | (shell-cd (shell-prefixed-directory-name arg)) |
| 754 | (if (or (null shell-pushd-dunique) |
| 755 | (not (member old-wd shell-dirstack))) |
| 756 | (setq shell-dirstack (cons old-wd shell-dirstack))) |
| 757 | (shell-dirstack-message)))))) |
| 758 | |
| 759 | ;; If STR is of the form +n, for n>0, return n. Otherwise, nil. |
| 760 | (defun shell-extract-num (str) |
| 761 | (and (string-match "^\\+[1-9][0-9]*$" str) |
| 762 | (string-to-number str))) |
| 763 | |
| 764 | (defvaralias 'shell-dirtrack-mode 'shell-dirtrackp) |
| 765 | (define-minor-mode shell-dirtrack-mode |
| 766 | "Turn directory tracking on and off in a shell buffer." |
| 767 | nil nil nil |
| 768 | (setq list-buffers-directory (if shell-dirtrack-mode default-directory)) |
| 769 | (if shell-dirtrack-mode |
| 770 | (add-hook 'comint-input-filter-functions 'shell-directory-tracker nil t) |
| 771 | (remove-hook 'comint-input-filter-functions 'shell-directory-tracker t))) |
| 772 | |
| 773 | ;; For your typing convenience: |
| 774 | (defalias 'shell-dirtrack-toggle 'shell-dirtrack-mode) ;??Convenience?? |
| 775 | (defalias 'dirtrack-toggle 'shell-dirtrack-mode) |
| 776 | (defalias 'dirtrack-mode 'shell-dirtrack-mode) |
| 777 | |
| 778 | (defun shell-cd (dir) |
| 779 | "Do normal `cd' to DIR, and set `list-buffers-directory'." |
| 780 | (cd dir) |
| 781 | (if shell-dirtrackp |
| 782 | (setq list-buffers-directory default-directory))) |
| 783 | |
| 784 | (defun shell-resync-dirs () |
| 785 | "Resync the buffer's idea of the current directory stack. |
| 786 | This command queries the shell with the command bound to |
| 787 | `shell-dirstack-query' (default \"dirs\"), reads the next |
| 788 | line output and parses it to form the new directory stack. |
| 789 | DON'T issue this command unless the buffer is at a shell prompt. |
| 790 | Also, note that if some other subprocess decides to do output |
| 791 | immediately after the query, its output will be taken as the |
| 792 | new directory stack -- you lose. If this happens, just do the |
| 793 | command again." |
| 794 | (interactive) |
| 795 | (let* ((proc (get-buffer-process (current-buffer))) |
| 796 | (pmark (process-mark proc))) |
| 797 | (goto-char pmark) |
| 798 | ;; If the process echoes commands, don't insert a fake command in |
| 799 | ;; the buffer or it will appear twice. |
| 800 | (unless comint-process-echoes |
| 801 | (insert shell-dirstack-query) (insert "\n")) |
| 802 | (sit-for 0) ; force redisplay |
| 803 | (comint-send-string proc shell-dirstack-query) |
| 804 | (comint-send-string proc "\n") |
| 805 | (set-marker pmark (point)) |
| 806 | (let ((pt (point)) |
| 807 | (regexp |
| 808 | (concat |
| 809 | (if comint-process-echoes |
| 810 | ;; Skip command echo if the process echoes |
| 811 | (concat "\\(" (regexp-quote shell-dirstack-query) "\n\\)") |
| 812 | "\\(\\)") |
| 813 | "\\(.+\n\\)"))) |
| 814 | ;; This extra newline prevents the user's pending input from spoofing us. |
| 815 | (insert "\n") (backward-char 1) |
| 816 | ;; Wait for one line. |
| 817 | (while (not (looking-at regexp)) |
| 818 | (accept-process-output proc) |
| 819 | (goto-char pt))) |
| 820 | (goto-char pmark) (delete-char 1) ; remove the extra newline |
| 821 | ;; That's the dirlist. grab it & parse it. |
| 822 | (let* ((dl (buffer-substring (match-beginning 2) (1- (match-end 2)))) |
| 823 | (dl-len (length dl)) |
| 824 | (ds '()) ; new dir stack |
| 825 | (i 0)) |
| 826 | (while (< i dl-len) |
| 827 | ;; regexp = optional whitespace, (non-whitespace), optional whitespace |
| 828 | (string-match "\\s *\\(\\S +\\)\\s *" dl i) ; pick off next dir |
| 829 | (setq ds (cons (concat comint-file-name-prefix |
| 830 | (substring dl (match-beginning 1) |
| 831 | (match-end 1))) |
| 832 | ds)) |
| 833 | (setq i (match-end 0))) |
| 834 | (let ((ds (nreverse ds))) |
| 835 | (condition-case nil |
| 836 | (progn (shell-cd (car ds)) |
| 837 | (setq shell-dirstack (cdr ds) |
| 838 | shell-last-dir (car shell-dirstack)) |
| 839 | (shell-dirstack-message)) |
| 840 | (error (message "Couldn't cd"))))))) |
| 841 | |
| 842 | ;; For your typing convenience: |
| 843 | (defalias 'dirs 'shell-resync-dirs) |
| 844 | |
| 845 | |
| 846 | ;; Show the current dirstack on the message line. |
| 847 | ;; Pretty up dirs a bit by changing "/usr/jqr/foo" to "~/foo". |
| 848 | ;; (This isn't necessary if the dirlisting is generated with a simple "dirs".) |
| 849 | ;; All the commands that mung the buffer's dirstack finish by calling |
| 850 | ;; this guy. |
| 851 | (defun shell-dirstack-message () |
| 852 | (when shell-dirtrack-verbose |
| 853 | (let* ((msg "") |
| 854 | (ds (cons default-directory shell-dirstack)) |
| 855 | (home (expand-file-name (concat comint-file-name-prefix "~/"))) |
| 856 | (homelen (length home))) |
| 857 | (while ds |
| 858 | (let ((dir (car ds))) |
| 859 | (and (>= (length dir) homelen) |
| 860 | (string= home (substring dir 0 homelen)) |
| 861 | (setq dir (concat "~/" (substring dir homelen)))) |
| 862 | ;; Strip off comint-file-name-prefix if present. |
| 863 | (and comint-file-name-prefix |
| 864 | (>= (length dir) (length comint-file-name-prefix)) |
| 865 | (string= comint-file-name-prefix |
| 866 | (substring dir 0 (length comint-file-name-prefix))) |
| 867 | (setq dir (substring dir (length comint-file-name-prefix))) |
| 868 | (setcar ds dir)) |
| 869 | (setq msg (concat msg (directory-file-name dir) " ")) |
| 870 | (setq ds (cdr ds)))) |
| 871 | (message "%s" msg)))) |
| 872 | |
| 873 | ;; This was mostly copied from shell-resync-dirs. |
| 874 | (defun shell-snarf-envar (var) |
| 875 | "Return as a string the shell's value of environment variable VAR." |
| 876 | (let* ((cmd (format "printenv '%s'\n" var)) |
| 877 | (proc (get-buffer-process (current-buffer))) |
| 878 | (pmark (process-mark proc))) |
| 879 | (goto-char pmark) |
| 880 | (insert cmd) |
| 881 | (sit-for 0) ; force redisplay |
| 882 | (comint-send-string proc cmd) |
| 883 | (set-marker pmark (point)) |
| 884 | (let ((pt (point))) ; wait for 1 line |
| 885 | ;; This extra newline prevents the user's pending input from spoofing us. |
| 886 | (insert "\n") (backward-char 1) |
| 887 | (while (not (looking-at ".+\n")) |
| 888 | (accept-process-output proc) |
| 889 | (goto-char pt))) |
| 890 | (goto-char pmark) (delete-char 1) ; remove the extra newline |
| 891 | (buffer-substring (match-beginning 0) (1- (match-end 0))))) |
| 892 | |
| 893 | (defun shell-copy-environment-variable (variable) |
| 894 | "Copy the environment variable VARIABLE from the subshell to Emacs. |
| 895 | This command reads the value of the specified environment variable |
| 896 | in the shell, and sets the same environment variable in Emacs |
| 897 | \(what `getenv' in Emacs would return) to that value. |
| 898 | That value will affect any new subprocesses that you subsequently start |
| 899 | from Emacs." |
| 900 | (interactive (list (read-envvar-name "\ |
| 901 | Copy Shell environment variable to Emacs: "))) |
| 902 | (setenv variable (shell-snarf-envar variable))) |
| 903 | |
| 904 | (defun shell-forward-command (&optional arg) |
| 905 | "Move forward across ARG shell command(s). Does not cross lines. |
| 906 | See `shell-command-regexp'." |
| 907 | (interactive "p") |
| 908 | (let ((limit (save-excursion (end-of-line nil) (point)))) |
| 909 | (if (re-search-forward (concat shell-command-regexp "\\([;&|][\t ]*\\)+") |
| 910 | limit 'move arg) |
| 911 | (skip-syntax-backward " ")))) |
| 912 | |
| 913 | |
| 914 | (defun shell-backward-command (&optional arg) |
| 915 | "Move backward across ARG shell command(s). Does not cross lines. |
| 916 | See `shell-command-regexp'." |
| 917 | (interactive "p") |
| 918 | (let ((limit (save-excursion (comint-bol nil) (point)))) |
| 919 | (when (> limit (point)) |
| 920 | (setq limit (line-beginning-position))) |
| 921 | (skip-syntax-backward " " limit) |
| 922 | (if (re-search-backward |
| 923 | (format "[;&|]+[\t ]*\\(%s\\)" shell-command-regexp) limit 'move arg) |
| 924 | (progn (goto-char (match-beginning 1)) |
| 925 | (skip-chars-forward ";&|"))))) |
| 926 | |
| 927 | (defun shell-dynamic-complete-command () |
| 928 | "Dynamically complete the command at point. |
| 929 | This function is similar to `comint-dynamic-complete-filename', except that it |
| 930 | searches `exec-path' (minus the trailing Emacs library path) for completion |
| 931 | candidates. Note that this may not be the same as the shell's idea of the |
| 932 | path. |
| 933 | |
| 934 | Completion is dependent on the value of `shell-completion-execonly', plus |
| 935 | those that effect file completion. See `shell-dynamic-complete-as-command'. |
| 936 | |
| 937 | Returns t if successful." |
| 938 | (interactive) |
| 939 | (let ((filename (comint-match-partial-filename))) |
| 940 | (if (and filename |
| 941 | (save-match-data (not (string-match "[~/]" filename))) |
| 942 | (eq (match-beginning 0) |
| 943 | (save-excursion (shell-backward-command 1) (point)))) |
| 944 | (prog2 (message "Completing command name...") |
| 945 | (shell-dynamic-complete-as-command))))) |
| 946 | |
| 947 | |
| 948 | (defun shell-dynamic-complete-as-command () |
| 949 | "Dynamically complete at point as a command. |
| 950 | See `shell-dynamic-complete-filename'. Returns t if successful." |
| 951 | (let* ((filename (or (comint-match-partial-filename) "")) |
| 952 | (filenondir (file-name-nondirectory filename)) |
| 953 | (path-dirs (cdr (reverse exec-path))) |
| 954 | (cwd (file-name-as-directory (expand-file-name default-directory))) |
| 955 | (ignored-extensions |
| 956 | (and comint-completion-fignore |
| 957 | (mapconcat (function (lambda (x) (concat (regexp-quote x) "$"))) |
| 958 | comint-completion-fignore "\\|"))) |
| 959 | (dir "") (comps-in-dir ()) |
| 960 | (file "") (abs-file-name "") (completions ())) |
| 961 | ;; Go thru each dir in the search path, finding completions. |
| 962 | (while path-dirs |
| 963 | (setq dir (file-name-as-directory (comint-directory (or (car path-dirs) "."))) |
| 964 | comps-in-dir (and (file-accessible-directory-p dir) |
| 965 | (file-name-all-completions filenondir dir))) |
| 966 | ;; Go thru each completion found, to see whether it should be used. |
| 967 | (while comps-in-dir |
| 968 | (setq file (car comps-in-dir) |
| 969 | abs-file-name (concat dir file)) |
| 970 | (if (and (not (member file completions)) |
| 971 | (not (and ignored-extensions |
| 972 | (string-match ignored-extensions file))) |
| 973 | (or (string-equal dir cwd) |
| 974 | (not (file-directory-p abs-file-name))) |
| 975 | (or (null shell-completion-execonly) |
| 976 | (file-executable-p abs-file-name))) |
| 977 | (setq completions (cons file completions))) |
| 978 | (setq comps-in-dir (cdr comps-in-dir))) |
| 979 | (setq path-dirs (cdr path-dirs))) |
| 980 | ;; OK, we've got a list of completions. |
| 981 | (let ((success (let ((comint-completion-addsuffix nil)) |
| 982 | (comint-dynamic-simple-complete filenondir completions)))) |
| 983 | (if (and (memq success '(sole shortest)) comint-completion-addsuffix |
| 984 | (not (file-directory-p (comint-match-partial-filename)))) |
| 985 | (insert " ")) |
| 986 | success))) |
| 987 | |
| 988 | |
| 989 | (defun shell-match-partial-variable () |
| 990 | "Return the shell variable at point, or nil if none is found." |
| 991 | (save-excursion |
| 992 | (let ((limit (point))) |
| 993 | (if (re-search-backward "[^A-Za-z0-9_{}]" nil 'move) |
| 994 | (or (looking-at "\\$") (forward-char 1))) |
| 995 | ;; Anchor the search forwards. |
| 996 | (if (or (eolp) (looking-at "[^A-Za-z0-9_{}$]")) |
| 997 | nil |
| 998 | (re-search-forward "\\$?{?[A-Za-z0-9_]*}?" limit) |
| 999 | (buffer-substring (match-beginning 0) (match-end 0)))))) |
| 1000 | |
| 1001 | |
| 1002 | (defun shell-dynamic-complete-environment-variable () |
| 1003 | "Dynamically complete the environment variable at point. |
| 1004 | Completes if after a variable, i.e., if it starts with a \"$\". |
| 1005 | See `shell-dynamic-complete-as-environment-variable'. |
| 1006 | |
| 1007 | This function is similar to `comint-dynamic-complete-filename', except that it |
| 1008 | searches `process-environment' for completion candidates. Note that this may |
| 1009 | not be the same as the interpreter's idea of variable names. The main problem |
| 1010 | with this type of completion is that `process-environment' is the environment |
| 1011 | which Emacs started with. Emacs does not track changes to the environment made |
| 1012 | by the interpreter. Perhaps it would be more accurate if this function was |
| 1013 | called `shell-dynamic-complete-process-environment-variable'. |
| 1014 | |
| 1015 | Returns non-nil if successful." |
| 1016 | (interactive) |
| 1017 | (let ((variable (shell-match-partial-variable))) |
| 1018 | (if (and variable (string-match "^\\$" variable)) |
| 1019 | (prog2 (message "Completing variable name...") |
| 1020 | (shell-dynamic-complete-as-environment-variable))))) |
| 1021 | |
| 1022 | |
| 1023 | (defun shell-dynamic-complete-as-environment-variable () |
| 1024 | "Dynamically complete at point as an environment variable. |
| 1025 | Used by `shell-dynamic-complete-environment-variable'. |
| 1026 | Uses `comint-dynamic-simple-complete'." |
| 1027 | (let* ((var (or (shell-match-partial-variable) "")) |
| 1028 | (variable (substring var (or (string-match "[^$({]\\|$" var) 0))) |
| 1029 | (variables (mapcar (function (lambda (x) |
| 1030 | (substring x 0 (string-match "=" x)))) |
| 1031 | process-environment)) |
| 1032 | (addsuffix comint-completion-addsuffix) |
| 1033 | (comint-completion-addsuffix nil) |
| 1034 | (success (comint-dynamic-simple-complete variable variables))) |
| 1035 | (if (memq success '(sole shortest)) |
| 1036 | (let* ((var (shell-match-partial-variable)) |
| 1037 | (variable (substring var (string-match "[^$({]" var))) |
| 1038 | (protection (cond ((string-match "{" var) "}") |
| 1039 | ((string-match "(" var) ")") |
| 1040 | (t ""))) |
| 1041 | (suffix (cond ((null addsuffix) "") |
| 1042 | ((file-directory-p |
| 1043 | (comint-directory (getenv variable))) "/") |
| 1044 | (t " ")))) |
| 1045 | (insert protection suffix))) |
| 1046 | success)) |
| 1047 | |
| 1048 | |
| 1049 | (defun shell-replace-by-expanded-directory () |
| 1050 | "Expand directory stack reference before point. |
| 1051 | Directory stack references are of the form \"=digit\" or \"=-\". |
| 1052 | See `default-directory' and `shell-dirstack'. |
| 1053 | |
| 1054 | Returns t if successful." |
| 1055 | (interactive) |
| 1056 | (if (comint-match-partial-filename) |
| 1057 | (save-excursion |
| 1058 | (goto-char (match-beginning 0)) |
| 1059 | (let ((stack (cons default-directory shell-dirstack)) |
| 1060 | (index (cond ((looking-at "=-/?") |
| 1061 | (length shell-dirstack)) |
| 1062 | ((looking-at "=\\([0-9]+\\)/?") |
| 1063 | (string-to-number |
| 1064 | (buffer-substring |
| 1065 | (match-beginning 1) (match-end 1))))))) |
| 1066 | (cond ((null index) |
| 1067 | nil) |
| 1068 | ((>= index (length stack)) |
| 1069 | (error "Directory stack not that deep")) |
| 1070 | (t |
| 1071 | (replace-match (file-name-as-directory (nth index stack)) t t) |
| 1072 | (message "Directory item: %d" index) |
| 1073 | t)))))) |
| 1074 | |
| 1075 | (provide 'shell) |
| 1076 | |
| 1077 | ;; arch-tag: bcb5f12a-c1f4-4aea-a809-2504bd5bd797 |
| 1078 | ;;; shell.el ends here |